{Change Comments ***********************************************************}

{5/26/94
Copied & modified: Fanuc 6M NoNest M001.81.3
For: Walker Machine per Craig Wahlstrom
Control: Yasnac i80M
Machine: Matsuura High Speed Vertical RA-III F
Set up for 54 Work Fixture Offsets, G54J1 thru G59J9.
CRCOff on last line feature in ToolPath.
So, if the last feat is not a line feat the CRCOff is called same as usuall.
Changed formats do that zero is output "0" instead of "0."
OpToolID & ToolChng on the same line.
Added G74 & G89 drill cycles.
Jim Radcliffe}

{6/2/94, .81.3, format Recall#, no WFO1 in CloseMP, AbsOrInc with StrtPos in subs, JR}

{7/28/94, .81.4
Using Variables for MultipleParts G92 shifts and Work Fixture Offsets.
Variables are stored in and called by the program.
NewWFO PostScript command is not supported with variables.
Variables are not used for Repeats, which will be handled with the standard use of G92 shifts.
This is due to that each operation can have different shift values, which would make
the use of variables quite extensive, but possible!? I am developing this processor
for Virtual wich currently does not have repeated operations on XY. Z Repeats
could be avoided or set up to use separate sub calls. This is a mute point if
we are outputting multiple parts as this processor does not nest subs. The customer
expresses that he mainly will be doing multiple parts.
Requested that all preset calls be made with the machine at program zero!
Using LoadFeat to make a karate move to program zero before doing a preset call.
Z is not moved to program zero, this would be too dangerous. Added a warning for doing
a Z shift with the Exit Clearance Plane selection. It should be OK with the Full Up
selection as we do not need to make a move to Z program zero it is done at Machine Z zero.
Again, using this format for MultipleParts only, Repeats done in the standard way!
Added block delete to all Multiple Parts sub calls after the first one.
Moved ToolComment to tool change block.
Moved WFOStuff call to StrtPos line.
Jim Radcliffe}

{8/4/94
Modified: Yasnac I80M M661.81.4
For: Walker
Moved CoolOn.
Added OperationIDComment to begining of sub.
Jim Radcliffe}

{8/17/94
Modified: Yasnac I80M M661.81.5
For: Walker
Changed Max RPM to 15000
Added PreTool
Moved DoEndOpPS call.
Added DoToolComment call to StartSub sub.
Jim Radcliffe}

{12/14/94
Modified: Yasnac I80M M661.81.6
For: Walker
All output is output as MultipleParts ExitClearancePlane WorkFixtureOffsets.
Added logic to handle if MultipleParts was not selected.
Corrected NoNest checks so everything else is output long hand.
Jim Radcliffe}

{2/13/95
Modified: Yasnac I80M M661.81.7
For: Pilot Metal
Added PreTool
Added M29 to orient spindle on G91G20Z0 line
Dan Pilone}

{5/1/95
Modified: Yasnac I80M M661.81.8
For: Close Tolerance
Forced WFO and Sub callout to be on separate lines.
Moved PreTool to OfstOn line.
Killed all variable WFO stuff at start of program.
Dan Pilone}

{11/15/99,
Initial: Yasnac I80M M661.81.8
Created: Yasnac I80M M661.89
For: Dan Pilone

Changes to Prog:
1) Updated to .89
2) Deleted extraneous code that Dan had commented out.
CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '####.####;0'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(ADD#,5)
FORMAT(SUB#,5)
FORMAT(Tag#,5)
FORMAT(Recall#,5)
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoToolComment:
IF UseComments?
IF ToolComment?
'( ' ToolComment$ ' )'
END
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF SameTool? { it is called on OpToolID line for FirstOperation and NewTool }
DoToolComment EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SubID DoToolComment EOL
DoSubComment
IF UseComments? { output the operation comment of the first operation used in the sub }
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
END
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

DoNewWFO:
NewWFO
Save# Num#('1') Num#('54') { set to start with G54 series WFOs }
Save# Num#('2') Num#('1') { set to start with J1 }
RETURN

DoSetWFO:
'G' Recall# Num#('1') 'J' Recall# Num#('2') { outputs G54 J1 thru J9 thru G59 J1 thru J9 }
RETURN

DoIncWFO:
IncWFO
Save# Num#('2') ADD# Recall# Num#('2') Num#('1')
IF Equal? Recall# Num#('2') Num#('10') { registers only go up to 9 }
Save# Num#('2') Num#('1') { re-set to start with J1 }
Save# Num#('1') ADD# Recall# Num#('1') Num#('1') { increment WFO series, 55, 56 etc }
END
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets? OR NOT MultipleParts?
DoNewWFO
EachWFO
SeqC DoSetWFO EOL
SeqC SubCall CallLab EOL {DP 5/1}
DoIncWFO
SetLineStrtChr('/')
NextWFO
SetLineStrtChr('')
ELSE
SeqC SubCall CallLab RepLab Parts EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets? OR NOT MultipleParts?
SeqC EndSub EOL
CloseSub
ELSE
SetAbs
LoadFeat Num#('0') Num#('0') Num#('0')
SetAbsOrInc
SeqC AbsOrInc Rapid MoveXY EOL
SeqC Preset ' X[-1*#100] Y[-1*#101] Z[-1*#102]' EOL
SeqC EndSub EOL
CloseSub
SeqC Preset ' X[' PartsLess1# '*#100]' ' Y[' PartsLess1# '*#101]' ' Z[' PartsLess1# '*#102]' EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdRapid:
IF LastFeat?
SeqC DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC RapidC MoveXYZC CRCOffsetC EOL
END
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF LastFeat?
SeqC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
END
RETURN

StdArc:
EACHQuadrant
SeqC FormatArc ArcFeedC EOL
NEXTQuadrant
RETURN

ToolPath2: {NoNesting} {.72.1, this is for AutoCycles only}
EACHFeat
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

CutAutoCycle: {NoNesting}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
Seq IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
IF FIFO? {.81}
SeqC FeedC PRIME ZCP2 FeedEntC EOL
ELSE
SeqC RapidC PRIME ZCP2 EOL
END
END
NextRep
ELSE
EntryMove
ToolPath2
END
IF FIFO? {.81}
SeqC AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL
END
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
CutAutoCycle {NoNesting}
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS' EOL
ELSE
'G' NewWFO# 'J1'
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
'G' NewWFO# 'J1'
END
END
END
RETURN

Milling:
IF AutoCycle?
ToolPath {NoNesting}
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub: {NoNesting}
EachRep
IF AutoCycle?
ToolPath
ELSE
IF FirstCycle?
EntryMove
ELSE
IF FeedConnect? {.72.1, minor changes to entry}
SeqC FeedC StrtPosC EOL
SeqC ZInC FeedEntC EOL
ELSE
SeqC RapidC StrtPosC EOL
SeqC ZCP2C EOL
IF FeedEntry?
SeqC FeedC ZInC FeedEntC EOL
ELSE
SeqC RapidC ZInC EOL
END
END
END
ToolPath
FinishSub1
END
NextRep
RETURN

ZonlyRepAutoCycle: {NoNesting}
ToolPath
RETURN

ZonlyRep: {NoNesting}
NewProg
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
FinishSub1
NextCycle
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

TagInc100:
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
RETURN

SetTagValue: { Variables start at 103 }
TagInit
TagInc100
TagInc TagInc
RETURN

CheckTagValue: { Variables go thru 198 then continue from 500 }
IF Equal? Tag# Num#('198')
TagInc100
TagInc100
TagInc100
TagInc
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('15000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' It will be the J1 of the Work Offset series. For this example G56J1.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale

IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq OpToolID ToolChng DoToolComment EOL
DoOpComments
SeqC WFOStuff Plane DrillOff CRCOff AbsOrInc Rapid StrtPos {PreTool} Speed SpinOn EOL
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC OfstOn CoolOn PreTool EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
IF NOT MultipleParts? { output all tools in a subroutine }
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
ELSE
IF NewTool?
{Finish off last Operation}

IF NOT MultipleParts? { output all tools in a subroutine }
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
SeqC IncValue OfstOff 'M29' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
IF ToolChangeAtHome?
SeqC AbsOrInc Rapid Home EOL
END
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

Seq OpToolID ToolChng DoToolComment EOL
DoOpComments
SeqC WFOStuff AbsOrInc Plane DrillOff CRCOff Rapid StrtPos {PreTool} Speed SpinOn EOL
DoPostScript
SeqC OfstOn CoolOn PreTool EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
IF NOT MultipleParts? { output all tools in a subroutine }
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
ELSE
IF SameTool?
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC IncValue OfstOff 'M29' EOL
DoEndOpPS
SeqC 'M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc WFOStuff PlaneC Rapid StrtPos SpeedC SpinOn EOL
SeqC OfstOn CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC IncValue OfstOff EOL
DoEndOpPS

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc WFOStuff PlaneC Rapid StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE
DoEndOpPS

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc WFOStuff PlaneC Rapid StrtPos SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
SeqC DrillCP EOL
GetCycle
SeqC
IF Tap?
IF NOT CWSpindle?
'G74'
ELSE
'G93' EOL
Cycle
END
ELSE
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
END
FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
TrackZNO# ZDepth# {.81}
ToolPath
IF Tap?
SeqC 'G94' EOL
End
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC DrillOff RapidC ZCP3C EOL
IF Repeats? {NoNesting}
NextRep
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF NOT MultipleParts? { output all tools in a subtoutine }
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
SeqC IncValue OfstOff 'M29' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC AbsOrInc Rapid FirstHome {SpinOff} EOL
END
DoEndOpPS
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC ToolChng EOL
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END