{Change Comments ***********************************************************}

{12/7/92
Copied & modifed: Cin T10 Acr 950MC M324.81.1
For: John Deere
Control: Acramatic 950MC
Machine: Cincinatti T10
Changed PGM line to MSG line at beginning of program, no ProgID.
Changed ':?' alignment on Approach line to use SeqLabC, colon alignment blocks for tool changes only.
Moved WFOStuff to be before SpinOn on the same line.
Deleted Approach sub, changed drilling approach to the same as milling so it was no longer needed.
Modified WFO handling to be able to use NewWFO PostScript and MultipleParts.
Added ToolOfst.
JR}

{2/16/93
Modified: Cin T10 Acr 950MC [JD] M535.81
For: John Deere
Corrected NewWFO PSComment.
Changed ZDepth# to formula.
ZDepth# was outputting from CP2, we need to output from the top of the part, i.e. .1 below CP2.
JR}

{5/12/93
Modified: Cin T10 Acr 950MC [JD] M535.82
For: John Deere
Changed OpToolID to use 8 digit tool coding.
Added logic for SameTool NewToolOffset handling.
NOTE: All tools are preset and the ToolOfst is used for minor offset amounts.
JR}

{8/19/93
Modified: Cin T10 Acr 950MC [JD] M535.83
For: John Deere
Changes made per conversation with Bob Moore at John Deere.
Updated to Version 4.2 per Fanuc 6M M001.81.2b Format.
Deleted call to GetWFO at CloseMP sub.
Added logic to output Incremental Variable Drill Depths at ToolPath PointFeat and Drilling.
Added standard FullUp and ExitClearancePlan handling for MultipleParts at FirstOperation, NewTool
and end of Prog.
Deleted extra call to CheckIndexer for MultipleParts OneToolAllParts at FirstOperation and NewTool.
Added Rapid LAST ZCP3 following CloseMP for MultipleParts OneToolAllParts ExitClearancePlane at
NewTool.
Added Rapid LAST ZCP3 prior to CloseMP for MultipleParts OneToolAllParts FullUp at NewTool.
Added TrackZNO# ClearancePlane2# for correct Incremental ZDepth at Drilling.
Changed 'Z' ADD# ZDepth# Num#('.1') to FIRST MoveSZ at Drilling.
Changed RLevelCin to RLevel at Drilling.
Customer requested standard Fanuc style.
Added Rapid ZCP3 following CloseMP for MultipleParts OneToolAllParts ExitClearancePlane at end
of prog.
Added Rapid ZCP3 prior to CloseMP for MultipleParts OneToolAllParts FullUp at end of prog.
DWB}

{9/3/93
Modified: Cin T10 Acr 950MC [JD] M535.831
For: John Deere
Changes made per conversation with Bob Moore at John Deere.
Deleted move to ZCP3 for MultipleParts OneToolAllParts at NewTool and end of Prog.
This was not needed because all operations send tool to ZCP3 anyway. I told Bob to
use a PostScript literal to move his Tool. He was concerned about clearing his
TombStone fixture prior to indexing. I told him to insert the literal prior to
issuing the 4ACW command.
Added AND ExitClearancePlane? boolean for calling OpenMP at NewTool.
This was accidentally left out.
DWB}

{2/9/96, Updated .81 version to .84, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '###.####;0.'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SUB#,4)
FORMAT(CP1LessCP2#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Tag#,5)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Repeats#,5)
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'(MSG, SUB NUMBER: ' Tag# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'(MSG, TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'(MSG, ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
{FourthCW is handled at CheckIndexer sub}
{FifthCCW doesn't exist}
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'(DFS,L' Tag# ')' EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLabC 'G10=[T2]V0' EOL {sets register to 0}
SeqLabC 'Q' Tag# '1' EOL {branch label 1}
SeqLabC '(CLS,L' Tag# ')' EOL {call subroutine}
SeqLabC 'G10=[T2]V[T2]+1' EOL {increment register by 1}
SeqLabC 'G11E[T2]=' Repeats# 'L' Tag# '2' EOL {if register is equal to RepCycs then jump to branch label 2}
SeqLabC 'G11L-' Tag# '1' EOL {jump backwards to branch label 1}
SeqLabC 'Q' Tag# '2' EOL {branch label 2}
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC '(ENS)' EOL
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN

GetWFO:
'H' Recall# Num#('1') {output current register 1 WFO}
RETURN

OpenMP:
TagInc
IF WorkFixtureOffsets?
NewWFO Save# Num#('2') Recall# Num#('1') {store register 1 WFO to register 2}
EachWFO
IF OneToolAllParts? AND FirstPart?
{skip redundant wfo output}
ELSE
SeqLabC 'H' Recall# Num#('2') EOL {output current register 2 WFO}
END
SeqLabC '(CLS,L' Tag# ')' EOL
IncWFO
Save# Num#('2') ADD# Recall# Num#('2') Num#('1') {increment register 2 WFO}
NextWFO
ELSE
SeqLabC 'G10=[T1]V0' EOL {sets register to 0}
SeqLabC 'Q' Tag# '1' EOL {branch label 1}
SeqLabC '(CLS,L' Tag# ')' EOL {call subroutine}
SeqLabC 'G10=[T1]V[T1]+1' EOL {increment register by 1}
SeqLabC 'G11E[T1]=' Parts# 'L' Tag# '2' EOL {if register is equal to Parts then jump to branch label 2}
SeqLabC 'G11L-' Tag# '1' EOL {jump backwards to branch label 1}
SeqLabC 'Q' Tag# '2' EOL {branch label 2}
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqLabC '(ENS)' EOL
CloseSub
ELSE
SeqLabC Preset ShiftPC EOL
SeqLabC '(ENS)' EOL
CloseSub
SeqLabC Preset UnshftPC EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: {4.2}
IF LastFeat?
CRCOffC
ELSE
CRCOnC
END
RETURN

StdLine: {.70, enables CRCOnC on first call; 4.2, enables CRCOffC on LastFeat}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC CkCRC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqLabC CkCRC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC CkCRC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC '(CLS,L' Tag# ')' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC MoveSXYC
IF SPZMove?
TrackZNO# ClearancePlane2#
SetInc
END
MoveSZC EOL {.80.01}
SetAbsOrInc
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
IF LastFeat? AND AutoCycle? {.70}
CRCOffC
END
SeqLabC RapidC MoveXYZC EOL {4.2}
END
ELSE
IF LineFeat?
IF AutoCycle? AND ZMove? {.70, skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {.70, enables CRCOnC on first call; 4.2, enables CRCOffC on LastFeat}
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets? AND SameTool?
EOL
'*** WARNING ***' EOL
'NewWFO PostScript command was used on a SameTool operation,' EOL
'and then processed with MultipleParts, this cannot be done.' EOL
ELSE
Save# Num#('1') NewWFO# {store NewWFO to register 1}
GetWFO
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
GetWFO
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLabC '(ENS)' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Feed IncValue StrtPosC EOL
SeqLabC AbsOrInc
ELSE
SeqLabC Feed
END
ELSE
SeqLabC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLabC AbsOrInc ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLabC Rapid ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC '(CLS,L' Tag# ')' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLabC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqLabC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqLabC '(ENS)' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLabC '(CLS,L' Tag# ')' EOL
NextCycle
StartSub
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
FinishSub1
SeqLabC '(ENS)' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

CheckPreTool:
IF NOT LastTool?
'T' SetNextToolOp TrimToolComment$('8')
END
RETURN

CheckSpinOn: {turns on spindle and coolant}
IF CoolOff?
IF CWSpindle?
'M03'
ELSE
'M04'
END
ELSE
IF ThruSpin?
IF CWSpindle?
'M20'
ELSE
'M21'
END
ELSE
IF Pulse?
IF CWSpindle?
'M24'
ELSE
'M25'
END
ELSE
IF CWSpindle?
'M13'
ELSE
'M14'
END
END
END
END
RETURN

CheckIndexer:
IF Rotate?
IF FourthCW?
FORMAT(FourthDegree#,2)
'B' FourthDegree#
ELSE
IF FourthCCW?
FORMAT(FourthDegree#,3)
'B' FourthDegree#
END
END
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
Save# Num#('1') NewWFO# {store WFO1 to register 1}
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use on a same tool operation with the ncPost multiple part option.' EOL
' THRUSPINDLECOOLANT, TSCOOL' EOL
' This is a non-modal command affecting the current operation only.' EOL
' Turns on the spindle with thru spindle flood coolant.' EOL
' SETTHRUSPINDLE, STS' EOL
' This is a modal command affecting all operations.' EOL
' Turns on the spindle with thru spindle flood coolant.' EOL
' PULSECOOLANT, PCOOL' EOL
' This is a non-modal command affecting the current operation only.' EOL
' Turns on the spindle with thru spindle pulse coolant.' EOL
' SETPULSE, SP' EOL
' This is a modal command affecting all operations.' EOL
' Turns on the spindle with thru spindle pulse coolant.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' This is a non-modal command affecting the current operation only.' EOL
' generates a + B move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' This is a non-modal command affecting the current operation only.' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'(MSG, ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'(MSG, OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'(MSG, PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'(MSG, FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
':?' Rapid 'T' TrimToolComment$('8') ToolChng EOL
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC Plane Rapid StrtPos ZCP1 CheckIndexer WFOStuff Speed CheckSpinOn CheckPreTool EOL
SeqLabC ToolOfst EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC Rapid StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC RapidC Home EOL
END
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

':?' Rapid 'T' TrimToolComment$('8') ToolChng EOL
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC Plane Rapid StrtPos ZCP1 CheckIndexer WFOStuff Speed CheckSpinOn CheckPreTool EOL
SeqLabC ToolOfst EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC Rapid StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC Rapid StrtPos ZCP1 CheckIndexer WFOStuff Speed CheckSpinOn EOL
SeqLabC ToolOfst EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC Rapid StrtPos ZCP1 CheckIndexer WFOStuff SpeedC EOL
SeqLabC ToolOfst EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC Rapid StrtPos CheckIndexer WFOStuff SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLabC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagInc
StdSub
SeqLabC StrtPos EOL
END
GetCycle
SeqLabC
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
TrackZNO# ClearancePlane2#
SetInc
FIRST MoveSZ { ZDepth to be incremental from ZCP2 }
SetAbsOrInc
RLevel
IF RetractToCP1?
'W' CP1LessCP2#
END
Peck
IF Peck?
IF PeckChipBreaker?
'J0'
ELSE
'J1'
END
END
FeedEnt EOL
TrackZNO# FIRST SPZ# {.81.2}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
IF Repeats?
FinishSubG92
END
SeqLabC DrillOff EOL
SeqLabC Rapid ZCP3 EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqLabC Rapid FirstHome EOL
END
IF ProgStop?
SeqLabC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLabC EOP EOL
CloseSub
Post2 {organize Subs into one program}
Close
ReTag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END