{Change Comments ***********************************************************}

{5/20/93
Copied & modified: Fanuc 10M M008.81.2
For: Haas Automation
Combined OpToolID and ToolChng on one block at FirstOperation and NewTool.
Combined WFOStuff Speed SpinOn AbsOrInc Rapid StrtPos and OfstOn on one block at FirstOperation,
NewTool and SameTool.
Added CkCRC sub to cancel CutterRadiusCompensation on LastFeature of ToolPath.
Added literal 'G74' for Left-Handed Tapping at Drilling.
Moved Canned Drill Cycle Block to Main Program when Repeats = TRUE at Drilling.
Main program will output the Canned Drill Cycle, and the SubPrograms will contain only the
positions from the second feature on.
DWB}

{8/2/93
Modified: Haas M573.81.2
For: Haas Automation
Changes made per visit with Harold Moon at Haas Automation.
Added ProgramName$ to SubID block at StartSub.
Added blank lines between subs.
Deleted RepLab OnePart at OpenMP.
Moved Rapid, Feed and Connect Commands to be output in front of AbsOrInc on same block.
Deleted colons from all Comments.
Deleted Spaces following '(, and preceeding )' from ProgramNameComment at FirstOperation.
Changed Seq to 'N' Tool# EOL at FirstOperation and NewTool, output on block by itself.
Changed Safe Start block from G17G80G40 to G0G90G54G40G80G17 at FirstOperation and NewTool.
Changed StrtPos block from WFOStuff Speed SpinOn AbsOrInc Rapid StrtPos OfstOn to
Rapid AbsOrInc WFOStuff StrtPos Speed SpinOn at FirstOperation and NewTool.
Added PlaneC to StrtPos block at NewTool.
Moved OfstOn to beginning of CoolOn block at FirstOperation and NewTool.
Changed WFOStuff PlaneC AbsOrInc Rapid to Rapid AbsOrInc WFOStuff PlaneC at SameTool StrtPos block.
Added IF RetractToCP1 boolean at SameTool.
This is to force output of ZCP1 or ZCP2 for Drilling.
Changed RapidC ZCP3C to Rapid ZCP3 at Drilling.
Moved 'G80' to Rapid ZCP3 at Drilling.
Added literal 'M19', Spindle Orient, at OfstOff block at end of Prog.
Added MasterOp/CallMasterOp PostScript Command support for Drilling.
Routines have been added to call previously created subroutines.
Added MasterOpF and CallMasterOpF at PSInit.
Added PostScript Comments regarding MasterOp and CallMasterOp Commands.
Added support of MasterOp and CallMasterOp Commands at Drilling.
Added FORMAT for Recall# to output called sub.
DWB}
{3/8/94, wfg, changed MasterOps to label Master subs as starting prog# + 200}
{3/11/94, wms, changed WFO's to be 54-59 & 112-129 }

{10/4/95, Updated Haas [SV] M642.81.4 to .85 format per Fanuc 6M M001.85.01.03, JR}

{12/15/95, Fixed OfstOff calls so they now call AbsValue afterwards, TH}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Recall#,5)
FORMAT(Program#,5) {.72}
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ' ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ' ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
' ' EOL
SubID
IF UseComments? AND ProgramNameComment?
'(' ProgramName$ ')'
END
EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
END
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

HaasWFO:
{This routine used to break the WFO# as follows: 54-59,110+}

{On the expr below, PartNum# increments the expr, You need to subtract 1}
{since NewWFO# = 54 and PartNum# = 1 the first time through the routine.}

Save# Num#('2') SUB# ADD# PartNum# NewWFO# Num#('1')
IF GreaterThan? Recall# Num#('2') NUM#('59')
Save# Num#('2') ADD# Recall# Num#('2') NUM#('50')
END
'G' Recall# Num#('2')

RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC HaasWFO EOL
SeqC SubCall CallLab EOL
IncWFO
NextWFO
ELSE
SeqC SubCall CallLab RepLab Parts EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC RapidC MoveXYZC CRCOffsetC EOL
END
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
SeqC
ELSE
HaasWFO
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
HaasWFO
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqC AbsOrInc EOL {.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
SeqC FeedC AbsOrInc ZCP2 FeedEntC EOL
ELSE
SeqC RapidC AbsOrInc ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC Connect AbsOrInc StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

MOPSubNum:
ADD# ADD# Recall# Num#('1') Num#('200') Operation#
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' MasterOp(1), MOP(1) -' EOL
' IF Repeats? AND Drilling? = TRUE, will place Drill Points in next available Subroutine' EOL
' Minimum = MasterOp(1); Maximum = MasterOp(25)' EOL
' CallMasterOp(1), CMOP(1) -' EOL
' IF Repeats? AND Drilling? = TRUE, will call Subroutine created during MasterOp(1) operation' EOL
' CallMasterOp(1) operations MUST follow MasterOp(1) operations for output to be correct' EOL
' MasterOp subs will be numbered as the starting program number plus 200 plus Op number' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
Save# Num#('1') Program# {for use in calculating MasterOp Sub #'s}
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'(' ProgramName$ ')'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
'N' Tool# EOL
SeqC OpToolID ToolChng EOL
DoOpComments
DoPostScript
SeqC Rapid AbsOrInc WFOStuff CRCOff 'G80' Plane EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Rapid AbsOrInc WFOStuff StrtPos Speed SpinOn EOL
SeqC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid AbsOrInc Home SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

'N' Tool# EOL
SeqC OpToolID ToolChng EOL
DoOpComments
DoPostScript
SeqC Rapid AbsOrInc WFOStuff CRCOff 'G80' Plane EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Rapid AbsOrInc WFOStuff PlaneC StrtPos Speed SpinOn EOL
SeqC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?

{Finish off last Operation}

IF LAST ProgStop? OR CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF LAST ProgStop? OR NewToolOffset?
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
END
DoEndOpPS
IF LAST ProgStop?
SeqC SpinOff EOL
SeqC 'M0' EOL
END

{Start new Operation}

DoOpComments
DoPostScript
CheckPass
SeqC Rapid AbsOrInc WFOStuff PlaneC StrtPos SpeedC
IF LAST ProgStop?
SpinOn
END
EOL
SeqC
IF LAST ProgStop? OR NewToolOffset?
OfstOn
ELSE
IF Drilling?
IF RetractToCP1?
ZCP1
ELSE
ZCP2
END
END
END
IF LAST ProgStop? OR NOT CoolOff? AND LAST CoolOff?
CoolOn
END
EOL
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
SeqC DrillCP EOL
GetCycle
IF Tap? AND NOT CWSpindle?
'G74'
ELSE
Cycle
END
SeqC FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF Repeats?
NewProg
StdSub
END
IF CallMasterOp?
SeqLabC SubCall 'P' ADD# ADD# Recall# Num#('1') Num#('200') CallMasterNum# EOL
SkipToLastFeat
SetDrillEndOpZ
ELSE
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
SeqC SubCall 'P' MOPSubNum EOL
OpenSub
' ' EOL
'O' MOPSubNum
IF UseComments? AND ProgramNameComment?
'(' ProgramName$ ')'
END
EOL
IF UseComments? AND SubComment?
'( SUB NUMBER ' MOPSubNum ' )' EOL
END
END
TrackZNO# FIRST SPZ# {.81.2}
ToolPath
SetDrillEndOpZ
IF MasterOp?
SeqC Rapid 'G80' ZCP3 EOL
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
END
END
IF Repeats?
FinishSubG92
END
IF NOT MasterOp? AND NOT CallMasterOp?
SeqC Rapid 'G80' ZCP3 EOL
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF AbsoluteMoves?
SeqC IncValue OfstOff 'M19' EOL { Spindle Orient }
SeqC AbsValue EOL
ELSE
SeqC OfstOff 'M19' EOL { Spindle Orient }
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC Rapid AbsOrInc FirstHome SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH ' FileMeters# ' METERS )' EOL
END
Close
END