{Change Comments ***********************************************************}

{5/20/93
Copied & modified: Fanuc 10M M008.81.2
For: Haas Automation
Combined OpToolID and ToolChng on one block at FirstOperation and NewTool.
Combined WFOStuff Speed SpinOn AbsOrInc Rapid StrtPos and OfstOn on one block at FirstOperation,
NewTool and SameTool.
Added CkCRC sub to cancel CutterRadiusCompensation on LastFeature of ToolPath.
Added literal 'G74' for Left-Handed Tapping at Drilling.
Moved Canned Drill Cycle Block to Main Program when Repeats = TRUE at Drilling.
Main program will output the Canned Drill Cycle, and the SubPrograms will contain only the
positions from the second feature on.
DWB}

{8/2/93
Modified: Haas M573.81.2
For: Haas Automation
Changes made per visit with Harold Moon at Haas Automation.
Added ProgramName$ to SubID block at StartSub.
Added blank lines between subs.
Deleted RepLab OnePart at OpenMP.
Moved Rapid, Feed and Connect Commands to be output in front of AbsOrInc on same block.
Deleted colons from all Comments.
Deleted Spaces following '(, and preceeding )' from ProgramNameComment at FirstOperation.
Changed Seq to 'N' Tool# EOL at FirstOperation and NewTool, output on block by itself.
Changed Safe Start block from G17G80G40 to G0G90G54G40G80G17 at FirstOperation and NewTool.
Changed StrtPos block from WFOStuff Speed SpinOn AbsOrInc Rapid StrtPos OfstOn to
Rapid AbsOrInc WFOStuff StrtPos Speed SpinOn at FirstOperation and NewTool.
Added PlaneC to StrtPos block at NewTool.
Moved OfstOn to beginning of CoolOn block at FirstOperation and NewTool.
Changed WFOStuff PlaneC AbsOrInc Rapid to Rapid AbsOrInc WFOStuff PlaneC at SameTool StrtPos block.
Added IF RetractToCP1 boolean at SameTool.
This is to force output of ZCP1 or ZCP2 for Drilling.
Changed RapidC ZCP3C to Rapid ZCP3 at Drilling.
Moved 'G80' to Rapid ZCP3 at Drilling.
Added literal 'M19', Spindle Orient, at OfstOff block at end of Prog.
Added MasterOp/CallMasterOp PostScript Command support for Drilling.
Routines have been added to call previously created subroutines.
Added MasterOpF and CallMasterOpF at PSInit.
Added PostScript Comments regarding MasterOp and CallMasterOp Commands.
Added support of MasterOp and CallMasterOp Commands at Drilling.
Added FORMAT for Recall# to output called sub.
DWB}

{8/16/93
Copied & modified: Haas M573.81.3
For: Q Corp
Control: Haas
Machine: Haas
Modified StdLine sub to use a D label and value same as tool number for CRCOffsetC.
Not using IncValue OfstOff for ToolChng, still using it for everything else.
Jim Radcliffe}

{8/19/93, .81.4, changed to First Tool In Spindle format, JR}
{8/26/93, .81.5, delete G74 Tapping Cycle, move ProgStop after M06, JR}
{9/9/93, .81.6, replaced tool change at first op, JR}

{11/14/94, .81.7, changed the arc format to use R's instead of I's and J's, TH}

{
Format: Haas [QC] M587.81.8
5/23/95
Fixed MasterOp to support Virtual Gibbs v2.20 specs
TH}

{
10/3/95
Added support for WFO's beyond G59. Now supports G54-G59, G110 - G129
TH}

{11/20/95
Initial: Haas [QC] M587.81.9
Created: Haas [QC] M587.85
ForUser: Q Corp
Develop: ComPost 4.21.33, Catalyst68K v2.30.18C
Comment: Modifications per marked up readout from Kelly Angle
Updated to .85 format per Fanuc 6M M001.85.01.03
Commented out select Header Operation and footer comments.
Deleted 'N' Tool#.
Changed SeqC to Seq at beginning of tools.
Putput DoOpComments before ToolChng.
Jim Radcliffe}

{11/22/95, .85.1, Deleted FromCP command per Kelly at Q Corp, JR}

{11/30/95
Initial: Haas [QC] M587.85.1
Created: Haas [QC] M587.85.2
Comment: Changed to IJ format arcs
Jim Radcliffe}

{
Format: Haas [QC] M587.85.4
12/4/95
Turned off Allow R Format Arcs in Form
TH}

{12/15/95, Fixed OfstOff calls so they now call AbsValue afterwards, TH}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{6/24/97
Updated & Modified: Haas [QC] M587.89
Created: Haas [QC] M587.89.1
For: Q Corp
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per Pete Jackson.
Updated for Catalyst v3.33C per Fanuc 6M M001.89b Format.
Added M001.15 source.
Changed FORMAT#2 from ###.###;0. to #####.###;0. at Prog Numeric Format Definitions.
Changed FORMAT#3 from *###.###;0. to *#####.###;0. at Prog Numeric Format Definitions.
Added TrackZNO# to FORMAT#4 at Prog Numeric Format Definitions.
Deleted version comments.
Added ckCRC and ckCRCNum subs.
Added Flag(6) to test for output of 'D' Tool# at ckCRCNum subs.
Allowed me to simplify ToolPath RapidFeat and LineFeat.
Modified WorkFixtureOffset logic.
Added Flag(2) for WFOStuff at setup and initializations.
Added SetFlag(2) for EquallySpacedOffsets at OpenMP sub.
Added WFONum sub.
Rewrote logic at WFOStuff sub.
Added Flag(2) logic at start of EachOp/NextOp Loop.
Moved call to WFOStuff from SafeStart block to StrtPos block at FirstOperation and NewTool.
Added Rapid AbsOrInc WFOStuff Speed SpinOn to StrtPos block for MP-OTAP-ECP condition at
FirstOperation and NewTool.
Added SetMaxFeed(12700) for Metric VNC files.
Moved Speed SpinOn after MP-OTAP-FU condition at FirstOperation and NewTool.
Added Speed SpinOn for MP-OTAP-ECP condition at FirstOperation and NewTool.
Modifications:
Added ADD# to FORMAT#5 at Prog Numeric Format Definitions.
Needed for WFOStuff and OpenMP Formulas.
Rewrote ZonlyRepAutoCycle sub.
Rewrote IF SameTool? section.
IF NOT CoolOff? AND LAST CoolOff? was not working.
DWB}

{8/21/97
Modified: Haas [QC] M587.89.1
Created: Haas [QC] M587.89.2
For: Q Corp
Versions: Catalyst v3.35C/ComPost2 MSL 68K
Changes made per Kelly Angle of Q Corp, fax and phone calls.
Customer requested G98/G99 for Canned Drill Cycles.
Added FromCP to Canned Drill Cycle block at IF Drilling.
Undoes modification made on 11/22/95.
Moved DoEndOpPS to after SpinOff at end of Prog.
Customer requested support of RFormatArcs.
According to previous developer notes, this post used to output IJFormatArcs until RFormatArcs
modifications to M587.81.6 on 9/9/93.
Post was changed back to IJFormatArcs for M587.85.1 on 11/30/95.
Customer was using M587.85.1 which output RFormatArcs, but reported that certain situations
caused his control to choke forcing him to use M587.81.6 which output IJFormatArcs.
Some situations were determined to be Pocketting Operations with CRCOn.
Explained our policy recommendations against this and alternative methods of programming
Operations.
Additional situation was determined to be FullArc with RFormatArcs.
Explained that RFormatArcs do not work well with FullArc as ArcCenterPoints could be located at
an infinate number of places around the End Point.
Checked Allow R-Format Arcs to be TRUE in Mach Spec Arcs Dialog.
Changed I-J-R Arc Discrimination from By Maximun Radius to By Maximum Angle in Mach Spec Arcs
Dialog.
Changed R-Format Maximum Arc Angle from 0.000 to 359.999 in Mach Spec Arcs Dialog.
Changed ArcIJC to ArcIJ at FormatArc.
Changed ArcRC to ArcR at FormatArc.
Customer requested that previous commented out comments be uncommented back in.
Undoes modification made on 11/20/95.
Comments included OperationComment, FormatNameComment, TimeComment, MovesComment, PartsComment,
StartToolComment, FileBytesComment, FileFeetComment and FileMetersComment.
DWB}

{11/26/97,
Created Metric Version.
CDH}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '#####.###;0.'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(ADD#,5)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)

{Prog Subroutines ****}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
RETURN

WFONum:
'G'
IF GreaterThan? NewWFO# Num#('59')
ADD# NewWFO# Num#('50')
ELSE
NewWFO#
END
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
WFONum
END
ELSE
IF Flag?('2')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
WFO1
ELSE
WFONum
END
ELSE
WFONum
END
END
END
END
SetFlagF('2')
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ' ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ' ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
' ' EOL
SubID
IF UseComments? AND ProgramNameComment?
'(' ProgramName$ ')'
END
EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
NewWFO
EachWFO {simple eachPart}
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
IF GreaterThan? PartNum# Num#('6')
SeqC 'G' ADD# PartNum# Num#('103') EOL
ELSE
SeqC SetWFO EOL
END
END
SeqC SubCall CallLab EOL
IncWFO
NextWFO {simple NextPart}
ELSE
SeqC SubCall CallLab RepLab Parts EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
IF NOT EmptyLine?
SetFlag('6')
END
END
END
RETURN

ckCRCNum:
IF Flag?('6')
SetFlagF('6')
'D' Tool# { CRCOffsetC }
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC DoAbsOrInc RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC ckCRC DoAbsOrInc FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC ckCRC DoAbsOrInc FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqC ckCRC DoAbsOrInc FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC
IF Repeats? AND FeedConnect? AND ZshiftOnly?
AbsOrInc
ELSE
IF FIFO?
FeedC AbsOrInc ZCP2 FeedEntC
ELSE
RapidC AbsOrInc ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC Connect AbsOrInc StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
SetFlagF('6') { 'D' Tool# at ckCRCNum }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF MultipleParts?
IF AllToolsOnePart?
IF EquallySpacedOffsets?
SetFlag('2') { WFOStuff }
END
ELSE {implied OneToolAllParts?}
IF FullUp?
IF EquallySpacedOffsets?
SetFlag('2') { WFOStuff }
END
ELSE {implied ExitClearancePlane?}
SetFlag('2') { WFOStuff }
END
END
ELSE
SetFlag('2') { WFOStuff }
END
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' MILLIMETERS )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
Seq OpToolID ToolChng EOL
DoPostScript
SeqC Rapid AbsOrInc CRCOff 'G80' Plane EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Rapid AbsOrInc WFOStuff StrtPos Speed SpinOn EOL
SeqC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC Rapid AbsOrInc WFOStuff StrtPos Speed SpinOn EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home SpinOff EOL
ELSE
SeqC SpinOff EOL
END

{Start new Operation}

DoOpComments
Seq OpToolID ToolChng EOL
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
DoPostScript
SeqC Rapid AbsOrInc CRCOff 'G80' Plane EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Rapid AbsOrInc WFOStuff StrtPos Speed SpinOn EOL
SeqC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC Rapid AbsOrInc WFOStuff StrtPos Speed SpinOn EOL
END
ELSE
IF SameTool?
IF LAST ProgStop?
SeqC CoolOff EOL
IF AbsoluteMoves?
IncValue
END
SeqC OfstOff EOL
DoEndOpPS
SeqC SpinOff EOL
SeqC 'M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqC Rapid AbsOrInc WFOStuff PlaneC StrtPos SpeedC SpinOn EOL
SeqC OfstOn CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
IF AbsoluteMoves?
IncValue
END
SeqC OfstOff EOL
DoEndOpPS

{Start new Operation}

GetStartOfSameTool
SeqC Rapid AbsOrInc WFOStuff PlaneC StrtPos SpeedC EOL
OfstOn
ELSE
DoEndOpPS

{Start new Operation}

GetStartOfSameTool
SeqC Rapid AbsOrInc WFOStuff PlaneC StrtPos SpeedC EOL
IF Drilling?
IF RetractToCP1?
ZCP1
ELSE
ZCP2
END
END
END
SeqC
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
EOL
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
SeqC DrillCP EOL
GetCycle
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF Repeats?
NewProg
StdSub
END
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
SetDrillEndOpZ
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
SetDrillEndOpZ
END
END
IF Repeats?
FinishSubG92
END
IF NOT MasterOp? AND NOT CallMasterOp?
SeqC Rapid 'G80' ZCP3 EOL
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
CloseMP
END
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC Rapid FirstHome SpinOff EOL
ELSE
SeqC SpinOff EOL
END
DoEndOpPS
SeqC UnTool ToolChng EOL
IF ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH ' FileMeters# ' METERS )' EOL
END
Close
END