{Change Comments ***********************************************************}

{1/9/96
Copied: Heid TNC 155 [HM] M654.81.3m
Created: Heid TNC 415 [ABB] A022.81.3m
For: Fructus
Machine:
Control: Heidenhain TNC 415B
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.08/Catalyst v2.28.08/Compost 4.21.34/1.0a
Changes made per Mikael Bagge of Fructus, faxes, sample part and output file.
This processor is a G-Code Heidenhain and resembles Fanuc control code.
Updated for Catalyst v2.20 per Fanuc 6M M001.85.02 Format.
Converted to 4-Axis per Fanuc 6M A001.85.02.
Numerous changes made per customer requests, including:
Modified coordinate decimal formats.
Changed basic #0.### part to #0.0##.
Deleted TLNum# at Prog Numeric Format Definitions.
Deleted DIV# at Prog Numeric Format Definitions.
Deleted ToolLength# at Prog Numeric Format Definitions.
Deleted TLLength# at Prog Numeric Format Definitions.
Added StartPosX# at Prog Numeric Format Definitions.
Added CalcZFmSurf# at Prog Numeric Format Definitions.
Added special subs to compensate Z Axis value.
For Radial Workgroups, Z value is subtracted from ZStockMax#.
Some LoadFeat for testing conditional moves.
All subs contain TrackZNO# for correct register updating.
For Flat Workgroups, no compensation is output.
Modified ToolPath PointFeat Drilling.
Post outputs move to Retract Plane between each hole for all Drilling Operations.
Added M99, Cycle Call Code to ZRetract and MoveXYC blocks.
Deleted SetUpStuff sub.
Deleted EachTool/NextTool sub.
Moved remaining contents to FirstOperation.
Added UseCommaForDecPt at setup and initializations.
Added SetLineStrtChr('/') for two block output at FirstOperation.
Added G51, PreTool, command at FirstOperation, NewTool and end of Prog.
Deleted G54 command at FirstOperation, NewTool, SameTool and end of Prog.
Changed Home command to ' X' XStockMax#, safety position, at FirstOperation, NewTool and end of
Prog.
Moved ZCP1 to StartPos block at FirstOperation, NewTool and SameTool.
Modified P02 parameter at IF Drilling.
Modified P03 parameter at IF Drilling.
Deleted literal XYZ Positioning moves at end of Prog.
Changed literal N9999 to N99999 at end of Prog.
DWB}

{5/20/96
Modified: Heid TNC 415 [ABB] A022.81.3m
Created: Heid TNC 415 [ABB] A022.81.4m
For: Fructus
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.04.05C/Compost 4.21.37/1.0a
Changes made per Mikael Bagge of Fructus, faxes, sample part and output file.
Added TrackZNO# to FORMAT#4 at Prog Numeric Format Definitions.
Added CallMasterNum# to FORMAT#4 at Prog Numeric Format Definitions.
Changed Program# from FORMAT#5, '#######0' to FORMAT#4, '###0.0##;0'.
Deleted support of variable Drill Depths at ToolPath PointFeat.
Deleted Rapid AbsOrInc ' X' XStockMax# block at FirstOperation.
Added ' G51' PreTool at FirstOperation and NewTool.
Deleted ' G51' OpToolID at NewTool.
Deleted Rapid ' X' XStockMax# block at NewTool.
Deleted SubCall CallLabB CallMasterNum# at IF Drilling.
DWB}

{5/21/96
Copied: Heid TNC 415 [ABB] A022.81.4m
Created: Heid TNC 415 [ABB] M054.81.4m
For: Fructus
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.04.05C/Compost 4.21.37/1.0a
Changes made per Mikael Bagge of Fructus, faxes, sample part and output file.
Converted to Version 4.2 per Fanuc 6M M001.81.2g Format.
DWB}

{7/2/96
Modified: Heid TNC 415 [ABB] M054.81.4m
Created: Heid TNC 415 [ABB] M054.81.5m
For: Fructus
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.05C/Compost 4.21.37/1.0a
Changes made per Mikael Bagge of Fructus, faxes, sample part and output file.
Changed Program# back from FORMAT#4, '###0.0##;0' to FORMAT#5, '#######0'.
Added literal ',0' for Loops at all occurances of SubCall blocks.
Deleted UnTool ToolChng at end of Prog.
DWB}

{9/18/96,
Initial: Heid TNC 415 [ABB] M054.81.5m
Created: Heid TNC 415 Mxxx.87m
Deleted Pretool stuff,
Deleted G51 lines
deleted SetLineStrtChr commands,
deleted ToolChng commands,
put ZCP1 and GetCoolOn on separate line,
reformatted CalcCP2FmSurf# to format 8,
corrected ZOnlyRepAutoCycle
MPK}

{11/26/96
Initial: Heid TNC 415 [Gimbel] MZ34.87
Created: Heid TNC 415 [Gimbel] MZ34.87.1
ForUser: Gimbel
Develop: ComPost2 68k v1.0b4, Catalyst68K v3.09.05C
Comment: Modified per before and after edits.
Deleted ' %900' & ' M00' lines from beginning of program.
Moved ' %900' & ' M00' lines beginning of NewTool to before OpToolID line.
Changed move to XStockMax# at end of program to ' %901'.
Changed StartToolComment to FIRST TOOL NOT IN SPINDLE.
Jim Radcliffe}

{12/17/96,
Iniital: Heid TNC 415 MZ34.87m
Created: Heid TNC 415 MZ34.89m
Incremented version number to .89, post already supported drill subs and sep subs,
Changed Peck Chip Breaker and FIFO to non-canned output
****warning: because of drill subs, the peck chip breaker or FIFO cycle cannot be the first porcess in a multiproccess
operation, otherwise no drill coordinate sub will be created*****
MPK}

{2/13/97
Initial: Heid TNC 415 [Gimbel] MZ34.89m
Created: Heid TNC 415 [Gimbel] MZ34.89.1m
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.23
Comment: Corrected Sequencing output of N without number 3 places.
Jim Radcliffe}

{4/23/97
Initial: Heid TNC 415 [Gimbel] MZ34.89.1m
Created: Heid TNC 415 [Gimbel] MZ34.89.2m
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.23
changer comments to start and end with ';' instead of '(' ')'.
block no longer end with '*'
Charles Winston}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = 'ą##0.0##;+0'
#3 = '*ą##0.0##;+0'
#4 = '###0.0##;0'
#5 = '#######0'
#6 = '###0.0##;0'
#7 = 'ą####0.0##;+0'
#8 = '*ą####0.0##;+0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(TrackZNO#,4)
FORMAT(CallMasterNum#,4)
FORMAT(FeedEntry#,5)
FORMAT(Program2#,5)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(Recall#,6)
FORMAT(TrackZ#,6)
FORMAT(XStockMin#,7)
FORMAT(XStockMax#,7)
FORMAT(YStockMin#,7)
FORMAT(YStockMax#,7)
FORMAT(ZStockMin#,7)
FORMAT(ZStockMax#,7)
FORMAT(CurOriginPosZ#,7)
FORMAT(StartPosX#,7)
FORMAT(CalcZFmSurf#,7)
FORMAT(CalcCP2FmSurf#,8)
FORMAT(SUB#,8)
FORMAT(Peck#,8)

{Prog Subroutines ;*********************************************************}

RestoreScale:
IF NOT Metric? { CAM file is in English, tools and tool path }
SetScale('25.4') { change to Metric, this is a Metric post }
ELSE
SetScale('1')
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'; SUB NUMBER: ' Program# ' ;' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'; OPERATION ' Operation# ': ' OperationType$ ' ;' EOL
END
IF OperationComment?
'; ' OperationComment$ ' ;' EOL
END
IF WorkGroupComment?
'; ' WorkGroupComment$ ' ;' EOL
END
IF ToolTypeComment?
'; TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' ;' EOL
END
IF ToolComment?
'; ' ToolComment$ ' ;' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SeqC ' G98 L' Program# EOL { SubID }
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'; WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT ;' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC ' L' Program# ',' Repeats# EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC ' G98 L0' EOL { EndSub }
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
NewProg
Save# Num#('1') Program#
SeqC ' G98 L' Program# EOL { SubID }
DoSubComment
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
SeqC ' G98 L0' EOL { EndSub }
EachPart
IF NOT FirstPart?
SeqC ' G54' AbsOrInc
IF AllToolsOnePart?
FirstHome
ELSE
LAST Home
END
IF NotEqual? PartShiftZ# Num#('0')
' Z' CurOriginPosZ#
END
FORMAT(Recall#, 5)
' L' Recall# Num#('1') EOL { SubCall CallLab }
FORMAT(Recall#, 6)
END
NextPart
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
ArcIJ
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveXY MoveZC
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

FormatLine:
DoAbsOrInc ckCRC FeedC MoveXYZC
RETURN

ckCRCNum:
{ Not Supported }
RETURN

DoLastPeck:
SeqC Feed 'Z' TrackZ# SPZ# FeedEntC EOL
IF RetractToCP1?
SeqC Rapid ZCP1 EOL
ELSE
SeqC Rapid ZCP2 EOL
END
RETURN

DoPeck:
IF GreaterThan? SUB# Recall# Num#('5') Peck# SPZ# {IF OldZ - Peck# > Depth}
Save# Num#('5') SUB# Recall# Num#('5') Peck# {Save#1 = OldZ - Peck# = NewZ}
SeqC Feed 'Z' TrackZ# Recall# Num#('5') FeedEntC EOL {move to NewZ}
SeqC RapidC 'Z' TrackZ# ADD# Recall# Num#('5') Retract# EOL {move to RetractZ}
END
RETURN

DrillPath:
EACHFeat
SeqC RapidC MoveSXYC EOL
SeqC ZCP2C EOL
Save# Num#('5') ClearancePlane2#
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoLastPeck
NEXTFeat
RETURN

DoFIFO:
EACHFeat
IF NOT FirstFeat?
SeqC RapidC MoveSXYC EOL
END
SeqC RapidC ZCP2C EOL
SeqC FeedC ZDepth FeedEntC EOL
IF RetractToCP1?
SeqC ZCP1 EOL
ELSE
SeqC ZCP2 EOL
END
NEXTFeat
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC ' L' Program# ',0' EOL { SubCall CallLab }
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC
IF NOT FirstFeat?
Rapid MoveSXYC
END
' M99' EOL { Cycle Call }
TrackZNO# SPZ#
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatLine FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC FormatLine DecelFeed ckCRCNum EOL
ELSE
SeqC FormatLine FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC ' G98 L0' EOL { EndSub }
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC ' L' Program# ',0' EOL { SubCall CallLab }
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqC ' G98 L0' EOL { EndSub }
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC ' L' Program# ',0' EOL { SubCall CallLab }
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC ' G98 L0' EOL { EndSub }
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

GetCoolOn:
IF CoolOff?
SpinOn
ELSE
' M13' { CoolOn and SpinOn }
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
UseCommaForDecPt
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('1000')
SaveProgNum2
SetProgNum('1')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ; RETURN key ; will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR Program2# ' G71' EOL { Metric }
SeqC ' G30' Plane ' X' XStockMin# ' Y' YStockMin# ' Z' ZStockMin# EOL
SeqC ' G31' AbsValue ' X' XStockMax# ' Y' YStockMax# ' Z' ZStockMax# EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'; PROGRAM: ' ProgramName$ ' ;' EOL
END
IF ProgramComment?
'; ' ProgramComment$ ' ;' EOL
END
IF FormatNameComment?
'; FORMAT: ' FormatName$ ' ;' EOL
END
IF TimeComment?
'; ' Date$ ' AT ' Time$ ' ;' EOL
END
IF MovesComment?
'; OUTPUT IN ' MoveType$ ' MILLIMETERS ;' EOL
END
IF PartsComment?
'; PARTS PROGRAMMED: ' Parts# ' ;' EOL
END
IF StartToolComment?
'; FIRST TOOL IN SPINDLE ;' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
SeqC OpToolID Plane Speed EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Rapid AbsOrInc CRCOff StrtPos EOL
SeqC ZCP1 GetCoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqC ' %900' EOL
SeqC ' M00' EOL

{Start new Operation}

DoOpComments
DoPostScript
Seq OpToolID Plane Speed EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Rapid AbsOrInc CRCOffC StrtPos EOL
SeqC ZCP1 GetCoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
SeqC ToolOfst PlaneC SpeedC EOL
SeqC Rapid CRCOff AbsOrInc StrtPos ZCP1 GetCoolOn EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC SpeedC EOL
SeqC RapidC CRCOffC StrtPos
IF LAST CoolOff? AND NOT CoolOff?
' M13'
END
EOL
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
GetCycle
IF NOT PeckChipBreaker? AND NOT FIFO?
SeqC DrillCP EOL
SeqC Cycle
IF Tap?
' P01' CalcCP2FmSurf#
' P02' CalcZFmSurf#
' P03'
IF Dwell?
Dwell#
ELSE
'0'
END
' P04' FeedEntry#
ELSE
' P01' CalcCP2FmSurf#
' P02' CalcZFmSurf#
' P03'
IF Peck?
Peck#
ELSE
CalcZFmSurf#
END
' P04'
IF Dwell?
Dwell#
ELSE
'0'
END
' P05' FeedEntry#
END
EOL
IF CallMasterOp?
SeqC ' L' CallMasterNum# EOL { SubCall CallLab }
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC ' L' Program# ',0' EOL { SubCall CallLab }
StartSub
ToolPath
SeqC ' G98 L0' EOL { EndSub }
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
ELSE
IF PeckChipBreaker?
Drillpath
ELSE
DoFIFO
END
END
SeqC RapidC ZCP3C EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqC ' %901' EOL { Safety Position ???? }
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
'N99999' EOR Program2# ' G71' EOL { Metric }
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'; FILE LENGTH: ' FileBytes# ' CHARACTERS ;' EOL
END
IF FileFeetComment?
'; FILE LENGTH: ' FileFeet# ' FEET ;' EOL
END
IF FileMetersComment?
'; FILE LENGTH: ' FileMeters# ' METERS ;' EOL
END
Close
END