{Change Comments ***********************************************************}

{9/23/88
Copied & Modified: Heidenhain TNC 145C M082.53
For: Galaxy Die & Engineering.
Machine:
Control: Heidenhain TNC 145C
Modified to have only 1 space between codes.
Added L address before Z moves.
Use Speed from ncCam.
Modified SpinOn to be M13 [CW] and M14 [CCW].
Added first and last lines.
Added M6 after tool call.
Deleted CoolOn and CoolOff commands.
Jim Radcliffe}

{11/15/88
Updated: Heid TNC151 Bridgeport M139.55
For: Galaxy Die & Engineering.
Changed all RapidF to 'F3999'.
Deleted LBL 1 thru LBL 0 lines, toolchange subroutine, from beginning of prog.
Moved HomePos & CP1 after M06 in FirstOp & NewTool.
Changed M05 to M25 for spindle up.
Added missing FORMAT for ZDepth#.
Changed ClearancePlane2# in Milling to ZCP2.
Added FORMAT #9 for cycle defs SETUP & PECKG that require a negative sign which is literal.
Deleted ZDepth# preceding IncValue and following AbsOrInc.
Changed ZDepth# in PECKG to ZDepthInc#, using FORMAT #9.
Changed FORMAT for ClearancePlane2# to FORMAT #9.
Changed FORMAT for Peck# to FORMAT #9.
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{11/29/90
Copied & Modified: Heid TNC151 Bridgeport M139.58
For: Phoenix Machine & Design
Machine: Interact 412
Control: Heidenhain TNC 151B/151Q
Updated to Version 3.2 per Fanuc 6M M001.76.1 Format.
Customer requests:
Added SaveProgNum2 and replaced ProgID1 with Program# at beginning and end becuase decimal point
is not allowed in opening statement.
Add ASCII('3') at end to cause DNC to stop sending.
Form changes:
Modified Rapid FeedRate (XXXX^X) from 0 to 3999
Modified 'F' default format from '00^0' to '###^0'
Prog changes:
Cleaned up FORMATs for better readability.
Added SPZ#, EPX#, EPY#, EPZ#, ArcI# and ArcJ# and FORMATs for same, for AutoCycle output
which requires literal 'I' before each axis address to indicate incremental moves.
Added FORMATs for RepeatX#, RepeatY#, RepeatZ#, OriginUnShiftRX#, OriginUnShiftRY# and
OriginUnShiftRZ# for correct output.
Added TLDia#, TLLength# and TLNum# and FORMATs for same, for Tool Definition Loop at beginning.
Added RapidF# and FORMAT for same, and replaced all literal 'F3999' to RapidF for ease of
future conversions.
DWB}

{6/19/92
Updated: Heid TNC 151 BP M139.76.1 to .81 format
Other changes for simplicity and ease of future updates or modifications.
Changed HomeX# & HomeY# to Home
Changed StartPosX# & StartPosY# to StrtPos
Changed all literal L to use the sub DoL
Changed all literal R0 to use the sub DoR0
Jim Radcliffe}

{6/19/92
Copied & modified: Heid TNC 151 BP M139.81
For: Belden Wire & Cable
Machine: Bridgeport Series 1 Interact
Control: Heidenhain TNC 151A
Summary of major changed per customer requests:
Added an asterisk before comments.
Deleted the Tool List from the beginning of program.
Modified layout of output at beginning and ending of operations.
Modified repeats of subs.
Do a ' STOP' before ' Tool Call'.
Jim Radcliffe}

{11/11/94
Copied & modified: Heid TNC 151A BP S1 M508.81
For: Neilson Machine
Summary of major changes per customer requests:
Removed M25 and STOP M from after every operation except last operation
Added support for Rigid Tapping
Changed Tool Change from Manual to Automatic by removing the STOP M
and adding "L R F M06" to the line after the "TOOL CALL"
Fixed the Spindle on command to output the right command if CoolOff?
and handle CW & CCW spindle directions
Added TOOL DEF lines for every tool to start of program and hardcoded
the L and R values to -1.5 and 0
Tom Hubina}

{10/4/95, Updated Heid TNC 151A S1 [NM] M711.81.1 to .85 format per v2.20 Update Instructions .01, JR}

{
Format: Heid TNC 151A S1 [NM] M711.85.1
11/10/95
Changed format of CallMasterNum# to #5
TH}

{12/12/95, M711.85.1, Updated for Catalyst v2.20 per Fanuc 6M M001.85.02 Format, DWB}

{4/24/96,
Initial: Heid TNC 151A S1 [NM] M711.85.2
Created: Heid TNC 151A S1 MXXX.85
Added 'L Z0 R0 F6289 M91' before every tool change, changed Max Rpm to 6000, changed ZDepthInc
in drilling cycle to Zdepth for PECKG, eliminated M13/14, now uses M03/M04 and M08 on separate
lines, added CoolOff before tool changes, added SpinOn and CoolOn to SameTool and logic to
check whether coolant was on during the last operation, set program# to Zero after it is output
at beginning of program so that subs # correctly, reformatted speed to ####, MPK}
{5/1/96,
Initial: Heid TNC 151A MD M989.85
Created: Heid TNC 151A MD M989.85.1
Corrected problem with comments for FirstOp, Moved Z0 R0 F6289 M91 line from before First tool
call to before Tool Defs., MPK}
{5/6/96
Inital: Heid TNC 151 A MD M989.85.2
Created: Heid TNC 151 A MD M989.85.3
Followed template of M613.85 and eliminated the IF SPZMove? boolean from PointFeat. This was
causing the posted out put to have a Z move in the middle of the drill cycle. Could cause
problems if there is a Z shift between drill holes. MPK}

{5/24/96, Updated to .89 format, MPK}

{6/10/96
Modified: Heid TNC 151A MD M989.89
Created: Heid TNC 351B MD M989.89.1
For: Militec Defense Systems, Inc
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.05C/Compost 4.21.37/1.0a
Changes made per Jonathan Bell of Militec.
Deleted unbalanced END command at ToolPath PointFeat Drilling.
This was accidently left in during 5/6/96 modifications.
Changed all occurances of ZDepth# to FIRST SPZ# at IF Driiling.
ZDepth# has a problem with Inch>>Metric and Metric<DWB}

{6/17/96
Modified: Heid TNC 151A MD M989.89.1
Created: Heid TNC 351B MD M989.89.2
For: Militec Defense Systems, Inc
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.05C/Compost 4.21.37/Compost2
Changes made per Tom Sunnen of Militec.
Changed Program# to Program2# at FirstOperation.
Modified DrillCycles.
Deleted contents of DoDrillAbsOrInc.
Control does not support variable Drill Depthes.
Post positions to new PointFeat and re-defines Cycle Parameters.
Added support for RetractToCP1.
Post RetractsToCP1, positions to new PointFeat, Rapids to ZCP2 and re-defines Cycle Parameters.
Set "Keep Subs in Front of Program" to TRUE in Compost2 Subs Dialog.
DWB}

{6/27/96
Modified: Heid TNC 151A MD M989.89.2
Created: Heid TNC 351B MD M989.89.3
For: Militec Defense Systems, Inc
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.05C/Compost 4.21.37/1.0a
Changes made per Tom Sunnen of Militec.
Deleted ZCP1 block at SameTool.
Changed FORMATs for addresses X, Y and Z from 3 decimals to 4 in Compost2 General Defaults Dialog.
Set "Keep Subs in Front of Program" back to FALSE in Compost2 Subs Dialog.
DWB}

{7/26/96
Modified: Heid TNC 351B MD M989.89.3
Created: Heid TNC 351B MD M989.89.4
For: Militec Defense Systems, Inc
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.05C/Compost 4.21.37/1.0a
Changes made per Tom Sunnen of Militec.
Added FORMAT#9 *ą####0.0000 at Prog Numeric Format Definitions.
Deleted ZDepth# from FORMAT#4 at Prog Numeric Format Definitions.
Added CalcZFmSurf# to FORMAT#4 at Prog Numeric Format Definitions.
Added SUB# to FORMAT#9 at Prog Numeric Format Definitions.
Added CalcCP2FmSurf# to FORMAT#9 at Prog Numeric Format Definitions.
Changed ClearancePlane2# to CalcCP2FmSurf# 3 places at DrillCycle sub.
Changed SPZ# to SUB# CalcZSurf# SPZ# 4 places at DrillCycle sub.
Changed ClearancePlane2# to CalcCP2FmSurf# 3 places at IF Drilling.
Changed FIRST SPZ# to CalcZSurf# 4 places at IF Drilling.
Added Z0 M91 block at end of prog.
Raises spindle to ToolChange level.
Added X0 Y0 M91 block at end of prog.
Brings table forward for changing parts.
DWB}

{3/4/97
Updated & Modified: Heid TNC 351B MD M989.89.4
Created: Heid TNC 351B MD M989.89.5
For: Militec Defense Systems, Inc
Versions: Catalyst v3.30C/ComPost2 MSL 68K
Changes made per Tom Sunnen of Militec.
Updated for Catalyst v3.30C per Fanuc 6M M001.89b Format
Customer reported that Tool was not Retracting to CP1 between first and second hole.
Corrected logic at ToolPath PointFeat.
Added test for RetractToCP1 and SPZMove at IF Drilling.
Purpose is to bypass MasterOp OR CallMasterOp situation.
RetractToCP1 and SPZMove condition requires re-definition of Cycle when TRUE.
Redefining Cycle inside of MasterOp Sub creates potential problem for CallMasterOp.
Added Flag(4) for SPZMove test.
NOTE: Bug exists when MasterOp is bypassed but CallMasterOp does not RetractToCP1.
CallMasterOp calls a sub that makes no sense.
DWB}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = 'ą####0.0000'
#5 = '#######0'
#6 = '####0.000'
#7 = '+####0.0000'
#8 = '###^0'
#9 = '*ą####0.0000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ClearancePlane1#,4)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(SPZ#,4)
FORMAT(EPX#,4)
FORMAT(EPY#,4)
FORMAT(EPZ#,4)
FORMAT(ArcI#,4)
FORMAT(ArcJ#,4)
FORMAT(CalcZFmSurf#,4)
FORMAT(RepeatX#,4)
FORMAT(RepeatY#,4)
FORMAT(RepeatZ#,4)
FORMAT(PartShiftX#,4)
FORMAT(PartShiftY#,4)
FORMAT(PartShiftZ#,4)
FORMAT(OriginUnShiftPX#,4)
FORMAT(OriginUnShiftPY#,4)
FORMAT(OriginUnShiftPZ#,4)
FORMAT(OriginUnShiftRX#,4)
FORMAT(OriginUnShiftRY#,4)
FORMAT(OriginUnShiftRZ#,4)
FORMAT(FeedTapIPR#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(TLDia#,4)
FORMAT(TLLength#,4)
FORMAT(TLNum#,5)
FORMAT(Program#,5)
FORMAT(Program2#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(ClearancePlane2#,7)
FORMAT(ZDepthInc#,7)
FORMAT(Peck#,7)
FORMAT(FeedEntry#,8)
FORMAT(RapidF#,8)
FORMAT(SUB#,9)
FORMAT(CalcCP2FmSurf#,9)

{Special Subs **************************************************************}

DoL:
' L'
RETURN

DoZL:
' L'
RETURN

Space: { 0 Spaces }
''
RETURN

XYZSpace:
'' Space
RETURN

XYSpace:
'' Space Space
RETURN

ZSpace:
'' Space Space Space
RETURN

IXYZSpace:
Space
RETURN

IXYSpace:
Space Space
RETURN

IZSpace:
Space Space Space
RETURN

DoR0:
IF NOT Flag?('3') { ArcFeat }
''
END
IF Flag?('2') { CutterRadiusCompensation }
IF CRCleft?
' RL'
ELSE
' RR'
END
ELSE
' R0'
END
RETURN

RF: { RapidF }
' F6289'
RETURN

DoM:
' M'
RETURN

ckCRCOff:
IF Flag?('2') { CRCOn }
SetFlagF('2')
SeqLab DoL ' IX+0.0000 IY+0.0000' IXYSpace DoR0 RF DoM EOL
END
RETURN

{Prog Subroutines ****}

RestoreScale:
IF Metric? { CAM file is in Metric, tools and tool path }
SetScale('.03937007874') { change to English, this is an English post }
ELSE
SetScale('1')
END
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'*( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'*( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'*( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'*( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'*( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'*( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab ' A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab ' A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab ' B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab ' B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
SeqLab DoZL
IF NOT AbsValue?
' IZ' SPZ# IZSpace
ELSE
ZIn ZSpace
END
DoR0
IF FeedEntry?
Feed {no output}
FeedEnt ''
ELSE
RF
END
DoM EOL
RETURN

StartSub:
OpenSub
SeqLab ' LBL ' Program# EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'*( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLab ' CALL LBL ' Program# EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
SeqLab DoZL ZCP3 ZSpace
IF Flag?('2') { CRCOn }
SetFlagF('2')
DoR0
SetFlag('2')
ELSE
DoR0
END
IF AutoCycle?
RF
ELSE
IF FIFO?
Feed {no output}
FeedEnt ''
ELSE
RF
END
END
DoM EOL
END
ckCRCOff
RETURN

FinishSubG92: {part 2}
SeqLab ' CYCL DEF 7.0 DATUM SHIFT' EOL
SeqLab ' CYCL DEF 7.1 IX' RepeatX# EOL
SeqLab ' CYCL DEF 7.2 IY' RepeatY# EOL
SeqLab ' CYCL DEF 7.3 IZ' RepeatZ# EOL
SeqLab ' CALL LBL ' Program# ' REP ' RepsLess1 '/ ' RepsLess1 EOL
SeqLab ' LBL 0' EOL
CloseSub
SeqLab ' CYCL DEF 7.0 DATUM SHIFT' EOL
SeqLab ' CYCL DEF 7.1 IX' OriginUnShiftRX#('0') EOL
SeqLab ' CYCL DEF 7.2 IY' OriginUnShiftRY#('0') EOL
SeqLab ' CYCL DEF 7.3 IZ' OriginUnShiftRZ#('0') EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
NewProg
SeqLab ' CALL LBL ' Program# EOL
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
SeqLab ' CYCL DEF 7.0 DATUM SHIFT' EOL
SeqLab ' CYCL DEF 7.1 IX' PartShiftX# EOL
SeqLab ' CYCL DEF 7.2 IY' PartShiftY# EOL
SeqLab ' CYCL DEF 7.3 IZ' PartShiftZ# EOL
SeqLab ' CALL LBL ' Program# ' REP ' PartsLess1 ' / ' PartsLess1 EOL
SeqLab ' LBL 0' EOL
CloseSub
SeqLab ' CYCL DEF 7.0 DATUM SHIFT' EOL
SeqLab ' CYCL DEF 7.1 IX' OriginUnShiftPX#('0') EOL
SeqLab ' CYCL DEF 7.2 IY' OriginUnShiftPY#('0') EOL
SeqLab ' CYCL DEF 7.3 IZ' OriginUnShiftPZ#('0') EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
SetInc
ELSE
IF NOT ZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

DoDrillAbsOrInc:
{ Not Supported }
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SetAbs
END
RETURN

CheckMove:
IF AutoCycle? OR NOT AbsValue?
IF XMove? OR YMove? OR ArcFeat?
' IX' EPX# ' IY' EPY#
IF ZMove?
' IZ' EPZ# IXYZSpace
ELSE
IXYSpace
END
ELSE
IF ZMove?
' IZ' EPZ# IZSpace
END
END
ELSE
IF XMove? OR YMove? OR ArcFeat?
MoveX MoveY
IF ZMove?
MoveZC XYZSpace
ELSE
XYSpace
END
ELSE
IF ZMove?
MoveZC ZSpace
END
END
END
RETURN

FormatArc:
DoAbsOrInc
SeqLab ' CC'
IF AutoCycle? OR NOT AbsValue? {implies incremental}
' IX' ArcI# ' IY' ArcJ#
ELSE
ArcIJ
END
EOL
SeqLab ' C' CheckMove
IF ArcCW?
' DR-' CWArc {no output}
ELSE
' DR+' CCWArc {no output}
END
SetFlag('3')
DoR0
SetFlagF('3')
RETURN

ckCRC:
IF CutterRadiusCompensation?
IF LastFeat?
SetFlagF('2') { CRCOff }
ELSE
IF NOT ZMove?
SetFlag('2') { CRCOn }
END
END
END
RETURN

ckCRCNum:
{ Not Supported }
RETURN

FormatLine:
IF ZMove? AND NOT XMove? AND NOT YMove?
DoZL
ELSE
DoL
END
DoAbsOrInc CheckMove CkCRC DoR0
RETURN

DrillCycle:
IF Tap?
IF OptCyc1?
SeqLab ' CYCL DEF 17.0 RIGID TAPPING' EOL
SeqLab ' CYCL DEF 17.1 SETUP ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 17.2 DEPTH ' SUB# CalcZSurf# SPZ# EOL
SeqLab ' CYCL DEF 17.3 PITCH ' FeedTapIPR# ('1') EOL
ELSE
SeqLab ' CYCL DEF 2.0 TAPPING' EOL
SeqLab ' CYCL DEF 2.1 SETUP ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 2.2 DEPTH ' SUB# CalcZSurf# SPZ# EOL
SeqLab ' CYCL DEF 2.3 DWELL 0' EOL
SeqLab ' CYCL DEF 2.4 F' FeedEntry# EOL
END
ELSE
SeqLab ' CYCL DEF 1.0 PECKING' EOL
SeqLab ' CYCL DEF 1.1 SETUP ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 1.2 DEPTH ' SUB# CalcZSurf# SPZ# EOL
SeqLab ' CYCL DEF 1.3 PECKG '
IF Peck?
'-' Peck#
ELSE
SUB# CalcZSurf# SPZ#
END
EOL
SeqLab ' CYCL DEF 1.4 DWELL '
IF Dwell?
Dwell#
ELSE
'0'
END
EOL
SeqLab ' CYCL DEF 1.5 F' FeedEntry# EOL
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
Rapid {no output}
IF AutoCycle?
IF NOT FirstFeat?
SeqLab DoL MoveSX MoveSY XYSpace DoR0 RF DoM EOL
END
SeqLab ' CALL LBL ' Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF NOT FirstFeat?
IF SPZMove? OR RetractToCP1?
SeqLab DoL MoveSX MoveSY XYSpace DoR0 RF DoM EOL
IF RetractToCP1?
SeqLab DoZL ZCP2 ZSpace DoR0 RF DoM EOL
END
DrillCycle
END
TrackZNO# SPZ#
SeqLab DoL MoveSX MoveSY XYSpace DoR0 RF ' M99' EOL
END
IF RetractToCP1?
SeqLab DoZL ZCP1 ZSpace DoR0 RF DoM EOL
END
END
ELSE
IF RapidFeat?
Rapid {no output}
IF XMove? OR YMove? OR ZMove?
SeqLab FormatLine RF DoM EOL
END
ELSE
IF LineFeat?
Feed {no output}
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatLine FeedRate '' DoM EOL
DecelMove2
END
SeqLab FormatLine DecelFeed '' DoM EOL
ELSE
SeqLab FormatLine FeedRate '' DoM EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
FormatArc ArcFeed '' DoM EOL
DecelMove2
END
FormatArc DecelFeed '' DoM EOL
ELSE
FormatArc ArcFeed '' DoM EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbs
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
SeqLab DoZL ZCP2 ZSpace DoR0
IF FIFO?
FeedEnt ''
ELSE
RF
END
DoM EOL
END
SeqLab ' LBL 0' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SetAbs
SeqLab DoL StrtPos XYSpace DoR0
IF FeedConnect?
FeedEnt ''
ELSE
RF
END
DoM EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed {no output}
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc
SeqLab DoL ' IX' SPX# ' IY' SPY# IXYSpace DoR0 FeedRate '' DoM EOL
SetAbsOrInc
END
END
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt '' DoM EOL
ELSE
IF NOT FirstCycle?
Rapid {no output}
IF SPXMove? OR SPYMove?
SetInc
SeqLab DoL ' IX' SPX# ' IY' SPY# DoR0 RF DoM EOL
SetAbsOrInc
END
IF FeedEntry?
SeqLab DoZL ZCP2PlusInc ZSpace DoR0 RF DoM EOL
END
END
IF FeedEntry?
Feed {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt '' DoM EOL
ELSE
Rapid {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 RF DoM EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab ' CALL LBL ' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
SeqLab DoZL ZCP2 ZSpace DoR0
IF FIFO?
Feed {no output}
FeedEnt ''
ELSE
Rapid {no output}
RF
END
DoM EOL
END
SeqLab ' LBL 0' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab DoL StrtPos XYSpace DoR0
IF FeedConnect?
Feed {no output}
FeedEnt ''
ELSE
Rapid {no output}
RF
END
DoM EOL
END
IF FeedConnect?
Feed {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt '' DoM EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
Rapid {no output}
SeqLab DoZL ZCP2PlusIncC ZSpace DoR0 RF DoM EOL
END
Feed {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt '' DoM EOL
ELSE
Rapid {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 RF DoM EOL
END
END
SeqLab ' CALL LBL ' Program# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLab ' LBL 0' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('6000')
SaveProgNum2
SetProgNum('0')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { CRCOff }
SetFlagF('3') { ArcFeat }
SetFlagF('4') { Variable Drill Depths }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END

IF MultipleParts? AND WorkFixtureOffsets?
'*( *** WARNING *** )' EOL
'*( THIS POST PROCESSOR DOES NOT SUPPORT WORKFIXTURE OFFSETS. )' EOL
'*( PLEASE SELECT EQUALLY SPACED OFFSETS. )' EOL
'*( *** WARNING *** )' EOL
END

EachOp {Start of post processing *********************}
IF FirstOperation?
SeqLab ' BEGIN PGM ' Program2# ' INCH' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'*( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'*( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'*( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'*( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'*( OUTPUT IN ABSOLUTE INCHES )' EOL
END
IF PartsComment?
'*( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'*( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
SetAbs
Plane Rapid {no output}
SeqLab DoL ' Z0' DoR0 RF ' M91' EOL
EachTool
SetScale('1')
SeqLab ' TOOL DEF ' TLNum#
RestoreScale
DoL '-1.5 R0.0'
EOL
NextTool
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
IF ToolChangeAtHome?
SeqLab DoL Home XYSpace EOL
END

DoOpComments
DoPostScript
SeqLab ' TOOL CALL ' Tool# ' Z' Speed EOL
SeqLab DoL ' R F M06' EOL
IF MultipleParts? AND OneToolAllParts?
OpenMP
END
CheckPass
SeqLab DoL StrtPos XYSpace DoR0 RF SpinOn EOL
SeqLab DoZL ' Z' ClearancePlane1# ZSpace DoR0 RF
IF NOT CoolOff?
CoolOn
ELSE
DoM
END
EOL
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts?
CloseMP
END
DoEndOpPS
SeqLab DoL
IF ToolChangeAtHome?
Home XYSpace
END
DoR0 RF CoolOff EOL

{Start new Operation}

SetAbs
Plane Rapid {no output}
DoOpComments
DoPostScript
SeqLab DoL ' Z0' DoR0 RF ' M91' EOL
SeqLab ' TOOL CALL ' Tool# ' Z' Speed EOL
SeqLab DoL ' R F M06' EOL
IF MultipleParts? AND OneToolAllParts?
OpenMP
END
CheckPass
SeqLab DoL StrtPos XYSpace DoR0 RF SpinOn EOL
SeqLab DoZL ' Z' ClearancePlane1# ZSpace DoR0 RF
IF NOT CoolOff?
CoolOn
ELSE
DoM
END
EOL
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab DoL DoR0 RF DoM EOL

{Start new Operation}

GetStartOfSameTool
SetAbs Plane Rapid {no output}
SeqLab DoL StrtPos XYSpace DoR0 RF SpinOn EOL
SeqLab DoZL ' Z' ClearancePlane1# ZSpace DoR0 RF CoolOn EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SetAbs Plane Rapid {no output}
SeqLab DoL StrtPos XYSpace DoR0 RF DoM EOL
END
END
END
END {common point for all operations}
IF Milling?
SeqLab DoZL ZCP2 ZSpace DoR0 RF DoM EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
Rapid {no output}
SeqLab DoZL ZCP3 ZSpace
IF Flag?('2') { CRCOn }
SetFlagF('2')
DoR0
SetFlag('2')
ELSE
DoR0
END
IF AutoCycle?
RF
ELSE
IF FIFO? {.81}
Feed {no output}
FeedEnt ''
ELSE
RF
END
END
DoM EOL
END
ckCRCOff
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
Rapid {no output}
SeqLab DoL StrtPos XYSpace DoR0 RF DoM EOL
END
LoadFeat Num#('0') Num#('0') ClearancePlane2#
IF ZMove?
SeqLab DoZL ZCP2 ZSpace DoR0 RF DoM EOL
END
GetCycle
IF Tap?
IF OptCyc1?
SeqLab ' CYCL DEF 17.0 RIGID TAPPING' EOL
SeqLab ' CYCL DEF 17.1 SETUP ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 17.2 DEPTH ' CalcZFmSurf# EOL
SeqLab ' CYCL DEF 17.3 PITCH ' FeedTapIPR# ('1') EOL
ELSE
SeqLab ' CYCL DEF 2.0 TAPPING' EOL
SeqLab ' CYCL DEF 2.1 SETUP ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 2.2 DEPTH ' CalcZFmSurf# EOL
SeqLab ' CYCL DEF 2.3 DWELL 0' EOL
SeqLab ' CYCL DEF 2.4 F' FeedEntry# EOL
END
ELSE
SeqLab ' CYCL DEF 1.0 PECKING' EOL
SeqLab ' CYCL DEF 1.1 SETUP ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 1.2 DEPTH ' CalcZFmSurf# EOL
SeqLab ' CYCL DEF 1.3 PECKG '
IF Peck?
'-' Peck#
ELSE
CalcZFmSurf#
END
EOL
SeqLab ' CYCL DEF 1.4 DWELL '
IF Dwell?
Dwell#
ELSE
'0'
END
EOL
SeqLab ' CYCL DEF 1.5 F' FeedEntry# EOL
END
TrackZNO# FIRST SPZ#
IF RetractToCP1?
SeqLab DoL StrtPos XYSpace DoR0 RF ' M99' EOL
ToolPath
ELSE
EachFeat
IF SPZMove?
SetFlag('4')
END
NextFeat
IF Flag?('4')
SetFlagF('4')
TrackZNO# FIRST SPZ#
SeqLab DoL StrtPos XYSpace DoR0 RF ' M99' EOL
ToolPath
ELSE
IF CallMasterOp?
SeqLab ' CALL LBL ' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
NewMasterProg
SeqLab ' CALL LBL ' Program# EOL
StartSub
SeqLab DoL StrtPos XYSpace DoR0 RF ' M99' EOL
ToolPath
SeqLab ' LBL 0' EOL
CloseSub
ELSE
SeqLab DoL StrtPos XYSpace DoR0 RF ' M99' EOL
ToolPath
END
END
END
END
SetDrillEndOpZ
Rapid {no output}
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
SeqLab DoZL ZCP3 ZSpace DoR0 RF DoM EOL
END
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts?
CloseMP
END
DoEndOpPS
Rapid {no output}
SeqLab DoL ' Z0' DoR0 RF ' M91' EOL
SeqLab DoL
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
FirstHome
ELSE
' X0 Y0'
END
XYSpace DoR0 RF ' M91' EOL
IF ProgStop?
SeqLab ' STOP M02' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLab ' STOP M02' EOL
Post
Close
Reopen
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
'*( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'*( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'*( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
SeqLab ' END PGM ' Program2# ' INCH' EOL
ASCII('3') EOL
Close
Retag