{Change Comments ***********************************************************}

{8/3/90
Copied & modified: Allen Bradley Hard L019.70
For: Quality Machine
Machine: Allen Bradley
Control: Hardinge
Modified formats to leading zeros.
Deleted all occurances of G94's, G95's and F190's.
Added 'G99' followed by 'G00X00Z00' just before each Preset.
Replaced Speed with GearRange SpeedRPM#/SpeedSFPM#
Added GearRange to Form.
Moved OpToolID LatheOffset to before Approach call.
Added G0 and G1 in prog and form.
Added RapidF to prog.
Modified M13 SpinOn to M3 in form.
Added CoolOn and CoolOff to prog.
Deleted all occurances of SeqC 'O' Speed SpinOn EOL.
Moved Speed SpinOn to line after Preset MaxRPM.
Removed '(TN,0001)','(CP,1)' and '(CP,2)' commands.
Modified G96/G97 handeling at home.
Updated to Version 3.2 per Fanuc 10T MS [-] L001.71.1 Format
DWB}

{10/25/90
Added AbsOrInc per Pete's request.
DWB}

{3/26/91
Modified: AB 7360 Hardinge L167.71.2
For: Quality Machine
Moved AbsOrInc to beginning of operation before tool call line.
Moved 'G95' at beginning of program to tool call line and added it to NewTool.
Changed format T to suppress leading zeros.
Changed format G & M to show leading zeros.
Changed LatheOffset to ToolOffset#.
Changed AbsValue to Rapid on line following 'G99'.
Added Home to Preset line and moved it out of CSS discrimination.
Corrected speed calls in FirstOp & NewTool.
Changed format F from 1 to 2 preceding zeros.
Added offset cancel at end of tools.
Deleted the 'G40G0F0(THE END)' and 'G99G97' lines from the end of the program.
Changed the EOP code to M30.
Added SpinOff to NewTool if NewGear.
Moved CoolOff to be on line with ZCPC.
JR}

{6/11/91
Modified: AB 7360 Hardinge L167.71.3
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
Only Canned Cycles supported are SimpleRough, Threading and PeckFullRetract.
DWB}

{9/7/95, Updated AB 7360 Hardinge L167.80 to .85 format per v2.20 Update Instructions .01, JR}

{4/18/96
Initial: AB 7360 Hardinge L167.85
Created: AB 7360 Hardinge Lxxx.85
ForUser: Industrial Nut
Control: ????
Machine: ????
Develop: ComPost 4.21.34, Catalyst68K v3.02.13C
Comment: New processor per marked up readout from Steve Mariea
Modified sequence of commands at beginning of tools
Deleted G99s
Modified Speed output to specify gear range:
Even speeds trigger high gear, Odd speeds trigger low gear.
Using 827 RPM/MaxRPM as the upper limit for low gear.
Using math to force either even or odd output.
Added M80 & M81 codes with Flag #1 to test for it.
Changed Rapid from G0 to G21
Changed Feed from G1 to G21
Changed ArcCW from G2 to G22
Changed ArcCCW from G3 to G23
Added NoIJKSigns to initializations
No Canned Threading Cycle!
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '0#^####;0'
#3 = '########;0'
#4 = '0^####;0'
#5 = '0000'
#6 = '0^#####;0'
#7 = '0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CutDepth#,2)
FORMAT(FirstCutRadius#,2)
FORMAT(FinishXRadius#,2)
FORMAT(DistanceToThread#,2)
FORMAT(CycleStartZ#,2)
FORMAT(ThisOpEntryXCP#,2)
FORMAT(XOpCD#,2)
FORMAT(StartPosX#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(ADD#,5)
FORMAT(MUL#,5)
FORMAT(FeedIPR#,6)
FORMAT(RapidF#,7)

{Special Subroutines *******************************************************}

CSSOnSpeed:
IF GreaterThan? MaxRPM# Num#('827')
'S' MUL# Trunc# DIV# SpeedSFPM# Num#('2') Num#('2')
ELSE
'S' ADD# MUL# Trunc# DIV# SpeedSFPM# Num#('2') Num#('2') Num#('1')
END
RETURN

CSSOffSpeed:
IF GreaterThan? SpeedRPM# Num#('827')
'S' MUL# Trunc# DIV# SpeedRPM# Num#('2') Num#('2')
ELSE
'S' ADD# MUL# Trunc# DIV# SpeedRPM# Num#('2') Num#('2') Num#('1')
END
RETURN

M80:
'M80'
SetFlagF('1')
RETURN

M81:
'M81'
SetFlag('1')
RETURN

RValue:
'R'
IF ApproachOD?
ThisOpEntryXCP#
ELSE
IF ApproachID?
XOpCD#
ELSE {ApproachFace}
StartPosX#
END
END
RETURN

RValueM81C:
IF ConstantSurfaceFeed?
IF NOT EmptyLine?
IF NOT Flag?('1')
RValue M81
END
END
END
RETURN

{Prog Subroutines **********************************************************}

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC RValueM81C EOL
SeqC StockOff ZOpCPC RValueM81C EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan RValueM81C EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC RValueM81C EOL
SeqC StockOff XOpCDC RValueM81C EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan RValueM81C EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP RapidF
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqC Rapid ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqC Rapid XOpCD AppMove EOL
ELSE {ApproachFace}
SeqC Rapid StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC LOfstOff '00' EOL
SeqC OpToolID ToolOffset# EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqC Preset MaxRPM EOL
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC CSSOnSpeed
END
ELSE
SeqC Preset MaxRPM EOL
SeqC CSSOn 'G96' CSSOnSpeed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqC CSSOff 'G97' CSSOffSpeed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC CSSOffSpeed
END
END
END
IF LAST ProgStop?
SpinOn EOL
SeqC CoolOn EOL
ELSE
EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC 'G94' EOL
SeqC 'G4F2' EOL
SeqC 'G95' InverseSpinOn EOL
ELSE
IF Dwell?
SeqC 'G94' EOL
SeqC 'G4F' Dwell# EOL
SeqC 'G95' EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC
IF LAST ThreadFeat?
Rapid
ELSE
RapidC
END
MoveXC MoveZC
IF LAST ThreadFeat?
RapidF
ELSE
RapidFC
END
EOL
ELSE
IF LineFeat?
SeqC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G33' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid1:
CRCOffC
IF LAST CannedCycle?
IF LAST Roughing?
IF LAST RoughSimple?
Rapid
END
ELSE
IF LAST Threading?
IF LAST NOT AutoFinish?
Rapid
END
ELSE
IF LAST Drilling?
IF LAST PeckFullRetract?
IF LAST NOT AutoFinish?
Rapid
END
END
END
END
END
ELSE
IF LAST Threading?
Rapid
ELSE
RapidC
END
END
RETURN

CheckRapidF1:
IF LAST CannedCycle?
IF LAST Roughing?
IF LAST RoughSimple?
RapidF
END
ELSE
IF LAST Threading?
IF LAST NOT AutoFinish?
RapidF
END
ELSE
IF LAST Drilling?
IF LAST PeckFullRetract?
IF LAST NOT AutoFinish?
RapidF
END
END
END
END
END
ELSE
IF LAST Threading?
RapidF
ELSE
RapidFC
END
END
RETURN

CheckRapid2:
CRCOffC
IF CannedCycle?
IF Roughing?
IF RoughSimple?
Rapid
END
ELSE
IF Threading?
IF NOT AutoFinish?
Rapid
END
ELSE
IF Drilling?
IF PeckFullRetract?
IF NOT AutoFinish?
Rapid
END
END
END
END
END
ELSE
IF Threading?
Rapid
ELSE
RapidC
END
END
RETURN

CheckRapidF2:
IF CannedCycle?
IF Roughing?
IF RoughSimple?
RapidF
END
ELSE
IF Threading?
IF NOT AutoFinish?
RapidF
END
ELSE
IF Drilling?
IF PeckFullRetract?
IF NOT AutoFinish?
RapidF
END
END
END
END
END
ELSE
IF Threading?
RapidF
ELSE
RapidFC
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
XsAreRadii
NoIJKSigns
SetMaxRPM('2558')
SetMaxFeed('500')
SetFlagF('1') { M81 output }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
Seq Preset Home MaxRPM CoolOn EOL
IF ConstantSurfaceFeed?
SeqC CSSOn 'G96' CSSOnSpeed SpinOn RValue EOL
ELSE
SeqC CSSOff 'G97' CSSOffSpeed SpinOn EOL
END
Seq AbsOrInc OpToolID LatheOffset EOL
SeqC 'G95'
IF ConstantSurfaceFeed?
M80
ELSE
M81
END
EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
IF LAST ApproachOD?
SeqC CheckRapid1 LAST OpExitXCPC CheckRapidF1 EOL
SeqC LAST OpExitZCPC CoolOff EOL
ELSE
IF LAST ApproachID?
SeqC CheckRapid1 LAST XOpECDC CheckRapidF1 EOL
SeqC LAST OpExitZCPC CoolOff EOL
ELSE
IF LAST ApproachFace?
SeqC CheckRapid1 LAST OpExitZCPC CheckRapidF1 CoolOff EOL
END
END
END
DoEndOpPS
SeqC NewHome EOL
SeqC 'T0000' EOL
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Seq Preset Home MaxRPM CoolOn EOL
IF ConstantSurfaceFeed?
SeqC CSSOn 'G96' CSSOnSpeed SpinOn RValue EOL
ELSE
SeqC CSSOff 'G97' CSSOffSpeed SpinOn EOL
END
Seq AbsOrInc OpToolID LatheOffset EOL
SeqC 'G95'
IF ConstantSurfaceFeed?
M80
ELSE
M81
END
EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
SeqC CheckRapid1 StockOnNoCan XSPC ZSPC CheckRapidF1 EOL
ELSE
IF ApproachOD?
IF LAST ApproachOD?
SeqC CheckRapid1 LAST XOpECDC CheckRapidF1 EOL
ELSE {around}
IF LAST ApproachID?
SeqC CheckRapid1 LAST XOpECDC CheckRapidF1 EOL
SeqC LAST OpExitZCPC EOL
ELSE
IF LAST ApproachFace?
SeqC CheckRapid1 LAST OpExitZCPC CheckRapidF1 EOL
END
END
SeqC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC CheckRapid1 LAST XOpECDC CheckRapidF1 EOL
ELSE
IF LAST ApproachOD? {around}
SeqC CheckRapid1 LAST OpExitXCPC CheckRapidF1 EOL
SeqC LAST OpExitZCPC EOL
ELSE
IF LAST ApproachFace?
SeqC CheckRapid1 LAST OpExitZCPC CheckRapidF1 EOL
END
END
SeqC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC CheckRapid1 LAST ZOpECPC CheckRapidF1 EOL
ELSE
IF LAST ApproachOD? {around}
SeqC CheckRapid1 LAST OpExitXCPC CheckRapidF1 EOL
ELSE {LAST ApproachID}
SeqC CheckRapid1 LAST XOpECDC CheckRapidF1 EOL
END
SeqC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqC LCycle FinZ XatFinZ 'K' CutDepth# FeedRate EOL
ELSE
SeqC LCycle XatFinZ FinZ 'I' CutDepth# FeedRate EOL
END
END
ELSE
IF Threading?
IF ConstantVolumeCut?
SeqC LCycle 'X' FirstCutRadius# ZCSP 'D' FinishXRadius# 'F100' EOL
SeqC 'G29G33' FinZ 'D' DistanceToThread# ThrdLead 'F100L0' EOL
IF AutoFinish?
SeqC Rapid XatFinZ RapidF EOL
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
SeqC RapidC XatFinZ RapidFC EOL
END
END
IF AutoFinish?
SeqC 'G33' FinZ ThrdLead EOL
SeqC Rapid XCSP RapidF EOL
SeqC ZCSP EOL
END
ELSE
IF Drilling?
IF Tap?
SeqC LCycle 'Z' FinishZ# 'K' FeedIPR# EOL
SeqC SpinOff EOL
SeqC 'G94' EOL
SeqC 'G4F2' EOL
SeqC 'G95' InverseSpinOn EOL
SeqC LCycle ZSP 'K' FeedIPR# EOL
ELSE
SeqC LCycle ZDepth Peck Retract FeedRate 'L0' EOL
SeqC 'G80' EOL
IF AutoFinish?
SeqC Feed ZDepth FeedRate EOL
SeqC Rapid 'Z' CycleStartZ# RapidF EOL
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqC RapidC ZOpECPC RapidFC EOL
ELSE
SeqC RapidC XOpECDC RapidFC EOL
END
ApproachSP
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC RapidC XSPC ZSPC RapidFC EOL
SeqC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqC 'G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqC Rapid XSP RapidF EOL
SeqC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC 'G94' EOL
SeqC 'G4F2' EOL
SeqC SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF ApproachOD?
SeqC CheckRapid2 OpExitXCPC CheckRapidF2 EOL
SeqC OpExitZCPC CoolOff EOL
ELSE
IF ApproachID?
SeqC CheckRapid2 XOpECDC CheckRapidF2 EOL
SeqC OpExitZCPC CoolOff EOL
ELSE
IF ApproachFace?
SeqC CheckRapid2 OpExitZCPC CheckRapidF2 CoolOff EOL
END
END
END
DoEndOpPS
SeqC FirstHome EOL
SeqC 'T0000' EOL
SeqC EOP EOL
Post
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END