{Change Comments ***********************************************************}

{1/10/90
Copied & modified: Allen Bradley Hard L019.53
For: Bio-Rad
Machine: Sheldon 1710
Control: Allen Bradley
Front turret consists of tools 1-4 and 9-12.
Front turret situation will have ReverseXZArcs, PosSideLathe, SpinFor and Positive Home.
Rear turret consists of tools 5-8.
Rear turret situation will have StandardXZArcs, NegSideLathe, SpinRev and Negative Home.
NOTE: We need a command to output current 'X' position for use with 'G96' CSSOn.
Control requires block to be 'G96R' CurrXPos# when activating CSS.
DWB}

{2/23/90
Modified: AB Sheldon [-] L141.53
For: Gibbs & Associates
Reversed G02 and G03 in Mach Spec per Joe C.
Updated to Version 3.2 per Fanuc 10T MS [-] L001.69.3 Format.
JR}

{6/1/90
Modified: AB Sheldon [-] L141.69.3
For: Gibbs & Associates
Added CycleStartXRadius# per NOTE of 1/10/90.
DWB}

{6/11/91
Modified: AB Sheldon [-] L141.70
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
Changed CycleStartXRadius# to CycleStartX#.
Changed SpinFor and SpinRev to SpinOn as this is handled in 4.0.
Only Canned Cycles supported are Threading and Tapping.
DWB}

{01/14/92
Modified: AB Sheldon [-] L141.80
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1 Format.
Kim Michelman}

{9/7/95, Updated AB Sheldon [-] L141.82.1 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{4/18/97
Initial: AB Sheldon [-] L141.85
Created: AB 8400 Monarch L000.85
ForUser: Braden Engineering / Los Alamos National Labs
Control: Allen Bradley 8400 LP Firmware version A2002
Machine: Monarch
Develop: ComPost2 68K 1.0b11, CatalystPPC v3.33C
Comment: New processor per marked up readout from Steve Rivera
One G code per line.
Single turret.
Added RapidF# to force output of FeedRateC after every Rapid commad.
Absolute arc centers.
Jim Radcliffe}

{7/30/97
Initial: AB 8400 Monarch L610.85
Created: AB CNC 8400 LP Lxxx.85
ForUser: Sang Myeong
Control: Allen-Bradley Series 8400LP
Machine: ????
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.35 PPC
Comment: New processor per manual. Many changes too numerous to detail!
There are a number of parameters that are set by the installer of the control
and effect how the program should be written. These are known as
AMP (Ajustable Machine Parameters). This processor follows the manual supplied
and may not reflect the actual state of this Contal/Machine this processor
is being written for!!!
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0'
#3 = '#######0'
#4 = '###.##;0'
#5 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2)
FORMAT(FinishXRadius#,2)
FORMAT(FinishZ#,2)
FORMAT(ABS#,2)
FORMAT(CutDepth#,2)
FORMAT(DiaDistanceToThread#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(SpringPasses#,3)
FORMAT(Dwell#,4) {.72}
FORMAT(ADD#,4)
FORMAT(RapidF#,5)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
';OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
';' OperationComment$ EOL
END
IF WorkGroupComment?
';' WorkGroupComment$ EOL
END
IF ToolTypeComment?
';TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ EOL
END
IF ToolComment?
';' ToolComment$ EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC EOL
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
DoOpComments
DoPostScript
IF NewToolOffset?
SeqC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqC Preset MaxRPM EOL
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqC Speed EOL
END
ELSE
SeqC Preset MaxRPM EOL
SeqC CSSOn 'G96' Speed EOL
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqC CSSOff 'G97' Speed EOL
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqC Speed EOL
END
END
END
IF LAST ProgStop?
SeqC SpinOn EOL
SeqC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

FormatArc:
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveXC MoveZC ArcIJC
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC 'G04F2.' EOL
SeqC InverseSpinOn EOL
ELSE
IF Dwell?
SeqC 'G04F' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC
IF LAST ThreadFeat?
Rapid
ELSE
RapidC
END
MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC CkCRC EOL
SeqC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G33' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
SeqC CRCOffC EOL
IF LAST CannedCycle?
Rapid
ELSE
IF LAST Threading?
Rapid
ELSE
RapidC
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
StandardXZArcs
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
ASCII('13') ';' Program# EOL
IF UseComments?
IF ProgramNameComment?
';' ProgramName$ EOL
END
IF ProgramComment?
';' ProgramComment$ EOL
END
IF FormatNameComment?
';FORMAT: ' FormatName$ EOL
END
IF TimeComment?
';' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
';OUTPUT IN ' MoveType$ ' INCHES' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
Plane
SeqC 'G20' EOL { Diameter Programming }
SeqC 'G70' EOL { inch }
SeqC 'G95' EOL { IPR }
SeqC AbsOrInc EOL
DoOpComments
DoPostScript
Seq Preset Home MaxRPM EOL
SeqC OpToolID LatheOffset EOL
SeqC CoolOn EOL
IF ConstantSurfaceFeed?
SeqC CSSOn 'G96' Speed EOL
ELSE
SeqC CSSOff 'G97' Speed EOL
END
SeqC SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
END
SeqC LAST OpExitZCPC EOL
DoEndOpPS
SeqC NewHome 'T00' EOL
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Seq Preset Home MaxRPM EOL
SeqC OpToolID LatheOffset EOL
SeqC CoolOn EOL
IF ConstantSurfaceFeed?
SeqC CSSOn 'G96' Speed EOL
ELSE
SeqC CSSOff 'G97' Speed EOL
END
SeqC SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
NewProg
SeqC LCycle XSP ZSP XStkLeft ZStkLeft CutDepth FeedRate CallLab
IF AutoFinish?
'U1'
ELSE
'U0'
END
'V' CutDepth# { pull out distance }
EOL
SetPass2
OpenSub
ASCII('13') ';' Program# EOL
SeqC StepMove XSP ZSP EOL
ToolPath
SeqC EndSub EOL
CloseSub
ELSE
IF Threading?
SeqC LCycle
'X' MUL# Num#('2') ADD# FinishXRadius# Taper#
FinZ
IF Taper?
'I' ABS# MUL# MUL# DIV# Taper# FinishZInc# Num#('2') FeedIPR#
END
ThrdLead
IF SingleEdgeCut?
'B' ADD# InFeedAngle# InFeedAngle#
END
CutDepth 'E' DiaDistanceToThread# 'U' MUL# Num#('2') LastCutXRadius#
IF NotEqual? RunOutZ# Num#('0')
IF Equal? RunOutZ# RunOutX#
'W2'
ELSE
IF GreaterThan? RunOutZ# RunOutX#
'W3'
ELSE
'W1'
END
END
END
'L' SpringPasses# EOL
ELSE
IF Drilling?
SeqC LCycle XSP ZDepth RLevel FeedRate Peck Dwell Retract
IF PeckChipBreaker?
'U' ABS# ZDepthInc#
END
EOL
SeqC 'G80' EOL
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqC RapidC ZOpECPC EOL
ELSE
SeqC RapidC XOpECDC EOL
END
ApproachSP
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC RapidC XSPC ZSPC EOL
SeqC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqC 'X' ADD# FinishXRadius# MUL# Taper# NumSc#('1') EOL
SeqC 'G33'
IF Taper?
'X' FinishXRadius#
END
'Z' FinishZ# FeedRateC EOL
SeqC Rapid XSP EOL
SeqC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap? AND NOT CannedCycle?
SeqC SpinOff EOL
SeqC 'G04F2.' EOL
SeqC SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
SeqC CRCOffC EOL
IF CannedCycle?
Rapid
ELSE
IF Threading?
Rapid
ELSE
RapidC
END
END
IF ApproachOD?
SeqC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC EOL
END
END
SeqC OpExitZCPC EOL
DoEndOpPS
SeqC FirstHome 'T00' EOL
SeqC EOP EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
';FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
';FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
';FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END