{Change Comments ***********************************************************}

{9/25/95, L273.82.2, Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85.02 Format, DWB}

{7/13/96
Modified: Cin Acr CNC-TC [12] L273.85
Created: Cin Acr CNC-TC [12] L273.85.1
For: Micron Machine
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.05C/Compost 4.21.37/1.0a
Changes made per Mark Conley of Micron Machine, fax, Cam and NCF files, phone conversations.
Added support for 29.5 degree infeed for Thread SingleEdgeCut Operations at ToolPath RapidFeat.
On approach to start of each G33 pass, formulas calculate 29.5 degree infeed to avoid cutting
on backside of tool.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###^###0'
#3 = '#######0'
#4 = '##^#0'
#5 = '#^####0'
#6 = '###0'
#7 = '#'
#8 = '#^###0'
#9 = '##^####0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Recall#,2) { Non-Canned Threading AutoFinish }
FORMAT(ABS#,2) { For CSS R Parameter }
FORMAT(ADD#,2) { Non-Canned Threading AutoFinish }
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(TrackZNO#,2)
FORMAT(TurretX#,2)
FORMAT(TurretZ#,2)
FORMAT(StartPosX#,2)
FORMAT(CycleStartX#,2)
FORMAT(FinishXRadiusInc#,2)
FORMAT(FinishZ#,2)
FORMAT(FinishZInc#,2)
FORMAT(DistanceToThread#,2)
FORMAT(InFeedAngle#,2)
{*FORMAT(TanToolAngle#,2)}
{*FORMAT(ThrdLead#,2)}
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(CutDepth#,8)
{*FORMAT(XThrdLead#,9)}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLabC '(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLabC '(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLabC '(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLabC '(MSG, TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLabC '(MSG, ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

GetCSS:
CSSOn 'G96' Speed
SetAddToolsF
SetStatusOff
'R' ABS# StartPosX#
SetStatusOn
SetAddTools
RETURN

AutoApproach:
IF NOT Flag?('1') { Set at Non-CannedCycle AutoFinish }
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC 'G95' EOL { Inches Per Revolution }
SeqLabC GetCSS EOL
ELSE
SeqLabC 'G95' EOL { Inches Per Revolution }
END
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
IF NOT SameTool?
AutoApproach
END
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
IF NOT SameTool?
AutoApproach
END
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

SpinCoolOn:
IF CoolOff?
SpinOn
ELSE
IF CWSpindle?
'M13'
ELSE
'M14'
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP SpinCoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewGear?
SeqLabC SpinOff EOL
END
END
CSSOff
IF ConstantSurfaceFeed?
IF NewGear?
SeqLabC CSSOff 'G97' CalcRPM1 GearRange EOL
SeqLabC Preset MaxRPM EOL
GetCSS
ELSE
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF LAST ProgStop?
GetCSS
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
GetCSS
END
END
END
END
ELSE
IF NewGear?
SeqLabC 'G97' Speed GearRange EOL
ELSE
IF LAST ConstantSurfaceFeed?
'G97' Speed
ELSE
IF LAST ProgStop?
'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
'G97' Speed
END
END
END
END
END
IF LAST ProgStop? OR NewGear?
SeqLabC {SpeedC} SpinCoolOn EOL
ELSE
SeqLabC {SpeedC} EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF LastFeat?
CRCOffC { Exit Length Feature }
ELSE
CRCOnC { Entry Length Feature }
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04F2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G04F' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC
IF NOT LastFeat? AND NEXT ThreadFeat? AND SingleEdgeCut?
SetStatusOff
Save# Num#('2') SUB# SPX# EPX#
Save# Num#('2') MUL# Recall# Num#('2') TAN# Num#('29.5')
Save# Num#('2') SUB# SPZ# Recall# Num#('2')
SetStatusOn
'Z' Recall# Num#('2')
TrackZNO# EPZ#
ELSE
MoveZC
END
EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G33' MoveXC MoveZC ThrdLead EOL
Rapid
IF AutoFinish? AND Taper?
Save# Num#('1') EPX#
END
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
StandardXZArcs
XsAreRadii
SetMaxRPM('2240')
SetMaxFeed('200')
SetAddToolsF
Save# Num#('1') Num#('0') { Taper Thread AutoFinish XatFinZ }
Save# Num#('2') Num#('0') { Thread SingleEdgeCut XMoveInc * TAN 29.5 = ThreadZSP }
SetFlagF('1') { AutoFinish Approach }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
SeqLabC '(MSG, ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqLabC '(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLabC '(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqLabC '(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqLabC '(MSG, OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
Plane
'O?' AbsOrInc 'F2000' EOL { Limit FeedRate to 200 IPR }
SeqLabC 'G70' EOL { Inch Mode }
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
GearRange EOL
SeqLabC 'G94' EOL { Inches Per Minute }
SeqLabC Rapid 'X' TurretX# 'Z' TurretZ# EOL
SeqLabC OpToolID '00' ToolChng EOL
DoOpComments
DoPostScript
SetAddTools
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC SETLASTOP LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC SETLASTOP LAST XOpECDC EOL
END
END
SeqLabC SETLASTOP LAST OpExitZCPC EOL
DoEndOpPS
SetAddToolsF
SeqLabC 'X' LAST TurretX# 'Z' LAST TurretZ# EOL
SeqLabC SpinOff EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

' ' EOL
'O?' AbsOrInc 'F2000' EOL { Limit FeedRate to 200 IPR }
SeqLabC 'G70' EOL { Inch Mode }
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
GearRange EOL
SeqLabC 'G94' EOL { Inches Per Minute }
SeqLabC Rapid 'X' TurretX# 'Z' TurretZ# EOL
SeqLabC OpToolID '00' ToolChng EOL
DoOpComments
DoPostScript
SetAddTools
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing? { RoughContour and RoughPatternShift not supported }
IF RoughSimple?
StockOn
SetPass1
SeqLabC '(DIN,G' CutDepth# ')' EOL
IF ApproachFace?
SeqLabC '(EXS,Z' CutDepth# ')' EOL {exit cut}
SeqLabC LCycle FinZ 'I' FinishXRadiusInc# XTapAtZ 'A0' EOL
ELSE
SeqLabC '(EXS,X' CutDepth# ')' EOL {exit cut}
SeqLabC LCycle XatFinZ XTapAtZ 'K' FinishZInc# 'A0' EOL {A must be programmed but Cam already has it at the first position so A=0}
END
END
ELSE
IF Threading?
IF AbsoluteMoves?
SeqLabC IncValue EOL
END
SeqLabC '(DIN,' CutDepth ')' EOL
SeqLabC '(DTH,' ThrdHeight ')' EOL
IF SingleEdgeCut?
SeqLabC '(TAA,G' {*TanToolAngle#} ')' EOL
END
SeqLabC LCycle
IF Chamfer?
'X' {*ThrdLead#} {major dia at finish Z, end of thread}
ELSE
{*IF Taper?
XatFinZ {minor dia at finish Z, end of thread}
END}
END
FinZ
{*IF Taper?
'I' {*XThrdLead#} {calc: X radius taper amount * Z thread lead / Z thread distance}
END}
ThrdLead 'A' DistanceToThread# EOL
IF AbsoluteMoves?
SeqLabC AbsValue EOL
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
SetFlag('1') { AutoFinish Approach }
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SetFlagF('1') { AutoFinish Approach }
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' ADD# FinishXRadius# Taper# EOL
SeqLabC 'G33'
IF Taper?
'X' Recall# Num#('1')
END
'Z' FinishZ# ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04F2000' EOL
SeqLabC Speed SpinOn EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SetAddToolsF
SeqLabC 'X' FIRST TurretX# 'Z' FIRST TurretZ# EOL
SeqLabC SpinOff EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
END
SeqLabC EOP EOL
Post
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
SeqLabC '(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
SeqLabC '(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
SeqLabC '(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END