{Change Comments ***********************************************************}

{3/9/89 minor corections by JR}

{4/25/89
Copied & Modified; Fanuc 10T-MS [-] L001.58, for Brunswick.
Machine is a Cincinnati Series 208 Turning Center, Acramatic 850TC
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{5/17/91, Updated Cincinnati Acr 850TC L102.56 to .81 format, JR}

{8/6/91
Updated: Cincinnati Acr 850TC L102.81
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.82 Format.
Kim Michelman}

{8/6/91
Using "Reference Rewind Stop" characters (:) unstead of SeqLab (N) at beginning of operations.
Changed the startup code per the manual, ':' Program# Rapid Plane 'G62G70' AbsOrInc 'G95' Home GearRange EOL.
Added the GetSpinOn sub to differentiate the 'M13' from 'M03' and 'M14' from 'M04'.
The GetSpinOn replaced the SpinOn command throughout the processor.
Added the missing NextOp at the end of the prog.
Put the EOP on the same line as the FirstHome, per the manual.
Deleted the ProgStop and the Untool ToolChng from the end of the prog.
Kim Michelman}

{6/8/93
Copied & modified: Cincinnati Acr 850TC L102.82.1
For: Braden Eng / Illiana Machine
Control: Acramatic 850 TC
Machine: Cincinnati Milicron Cinturn 18" Universal Turning Center
Use sequence number for colon blocks.
Added leading zero supression on G & M & T codes.
Changed ToolChng from M26 to M6.
Modified GearRanges.
Added XsAreRadii to initializations.
Added CoolOff at end of tool.
Reduce RPM to 125 at end of tool if next tool has a new gear or spindle direction.
Changed to use absolute arc centers.
Added spaces between codes.
Deleted "XatFinZ ThrdHeight" line before thread cycle.
This was to position to the major dia,
set CAM document to have Start X and Major Ż set the same.
Jim Radcliffe}

{8/6/93
Modified: Cin Acr 850 TC [IM] L289.82.1
For: Braden Eng / Illiana Machine
Control: Acramatic 850 TC
Machine: Cincinnati Milicron Cinturn 18" Universal Turning Center
Modified retract to index position.
Machine has 2 turrets: Lower = Tools 1 thru 6 Upper = Tools 11 thru 16
When indexing from Lower to Upper retract Z to NewHome + 20"
When indexing from Upper to Lower retract X to NewHome + 13"
Unconditional axis output in FormatArc.
Deleted extra Rapid from Approach.
Moved callout of CSSOn for FirstOp and NewTool.
Changed format of output from 0. to 0 for a zero output.
Due to a recent visit to the Twilite Zone,
I had to start with a fresh Form (I used L001) to get this to work.
Colon block must imediatly follow a program stop.
Moved ProgStop to a line by itself after DoOpComments in same tool.
Rewrote CheckOffset to add Colon Block if ProgStop.
Modified R value for Threading by .050 for clearance
Jim Radcliffe}

{11/1/94
Copied & modified: Cin Acr 850 TC [IM] L289.82.2
For: Accurate Tool Co.
Control: Acramatic 850 SX
Machine: Cincinnati Milicron Avenger
Changed G76 to G33 for Threading Canned Cycle.
Moved EOP down to line by itself.
Added 1 NULL character to end of program.
Added X and I values for Tapered threading.
Jim Radcliffe}

{3/2/95
Updated: Cin Acr 850 SX L315.82.2
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Compost 4.21.27
Changes made per Pete Jackson
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1c Format.
Added RestoreScale Sub per 4-Axis Post Processor.
Added Logic to suppress Feed and FeedRate for Approaches.
Added bypass of AutoFinish for Non-Canned RoughSimple Operations.
Added XSPC ZSPC at AutoFinish for NOT CannedCycle AND NOT Turning Operations.
Changed RapidC StrtPos to StockOff StrtPosC at AutoFinish for NOT CannedCycle Operations.
Modified non-CannedCycle AutoFinish.
Method of testing for IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple? AND NOT Threading?
did not allow for AutoFinish pass of IF Turning?
Rewrote to test for IF Turning? ELSE IF Roughing? AND NOT RoughSimple?
Added support for AutoFinish of non-Canned Threading Cycle.
Miscellaneous other changes.
DWB}

{3/15/95
Modified: Cin Acr 850 SX L315.82.3
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Catalyst v2.14.30/Compost 4.21.27
Added Address Spaces to Canned Tap and Peck Drilling Cycles in Mach Spec Drilling Dialog.
Added '##.0####;0 Format back in Address K of Mach Spec Threading Dialog.
Somehow, this disappeared.
Added call to RestoreScale prior to SafeStart Home block at beginning of FirstOperation.
Prior to calling RestoreScale, we were outputting Home on the SafeStart block, which did not get
correctly scaled during Metric>English conversion, and vice-versa.
DWB}

{7/27/95, Updated Cin Acr 850 SX L315.82.4 to .85 format, JR}

{10/3/95
Initial: Cin Acr 850 SX L315.85
Created: Cin Acr 850 SX [WT] L381.85
ForUser: Braden Eng / Wilson Tool
Control: Cincinnati Acramatic 850SX
Machine: Cincinnati Avenger 200T
Develop: ComPost 4.21.33, Catalyst v2.26C
Comment: New Processor per marked up readout and conversation with Brad Schulte
Specifications:
Single Turret, Single Gear, SameTool treated same as NewTool
Canned Cycles RoughContour and RoughPatternShift.
Jim Radcliffe}

{12/12/95
Initial: Cin Acr 850 SX [WT] L381.85
Created: Cin Acr 850 SX [WT] L381.85.1
ForUser: Braden Eng / Wilson Tool
Develop: ComPost 4.21.33, Catalyst68K v2.30.18C
Comment: Added machine registers, separate SpinOn and CoolOn, unconditional SameTool FeedRate.
Jim Radcliffe}

{2/2/96
Initial: Cin Acr 850 SX [WT] L381.85.1
Created: Cin Acr 850 SX [WT] L381.85.2
ForUser: Braden Eng / Wilson Tool
Develop: ComPost 4.21.33, Catalyst68K v2.30.27C
Comment: Modified per marked up readout from Brad Shulte
Added RapidF# to CheckOffset to force output of feedrate in SameTool after literal F.05 call.
Added G50 to end of program.
Jim Radcliffe}

{3/21/96
Initial: Cin Acr 850 SX [WT] L381.85.2
Created: Cin Acr 850 SX [WT] L381.85.3
Develop: ComPost 4.21.34, Catalyst68K v3.02.07C
Comment: Changed G50 to M50 at end of program.
Jim Radcliffe}

{7/12/96
Initial: Cin Acr 850 SX [WT] L381.85.3
Created: Cin Acr 850 SX [CS] L000.85
ForUser: CIM Solutions / Century Specialties
Control: Cin Acr 850 SX
Machine: Leblond ??
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: New Processor per marked up readout from Tom Raymond
Jim Radcliffe}

{7/29/96
Initial: Cin Acr 850 SX [CS] L000.85
Created: Cin Acr 850 SX [CS] L000.85.1
ForUser: CIM Solutions / Century Specialties
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: Modified per marked up readout from Tom Raymond
Added AbsValue to Start Blocks
Added Start Block as first line in program.
Moved M50 line from before return to home line to after it.
Added EOR to end of program.
Jim Radcliffe}

{5/9/97.
Initial: Cin Acr 850 SX [CS] L519.85.1
Created: Cin Acr 850 SX Lxxx.85
added blank line to program start and null character to program end, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '0.00'
#2 = '###.0###;0'
#3 = '#######0'
#4 = '##.#0'
#5 = '+#.0###;0'
#6 = '0000'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(MUL#,2)
FORMAT(StartPosX#,2)
FORMAT(HomeX#,2)
FORMAT(HomeZ#,2)
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(CalcEPRPM#,3)
FORMAT(Dwell#,4) {.72}
FORMAT(XCutDepth#,5)
FORMAT(ZCutDepth#,5)
FORMAT(CycleStartXRadius#,5)
FORMAT(Program#,6) {.72}
FORMAT(RapidF#,7)

{Special Subroutines *******************************************************}

ckHome:
IF ToolChangeAtHome?
'X' HomeX# '-[M15]-[M40]' 'Z' HomeZ# '-[M16]-[M41]'
ELSE
' X[M3]-[M15]-[M40] Z[M4]-[M16]-[M41]'
END
RETURN

ckNewHome:
IF ToolChangeAtHome?
NewHome
END
RETURN

ckFirstHome:
IF ToolChangeAtHome?
FirstHome
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLabC '(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLabC '(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLabC '(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLabC '(MSG, TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLabC '(MSG, ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

StartSpeed:
CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF NewGear?
SeqLabC SpinOff EOL
END
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
END
END
SeqLabC
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
StartSpeed
END
END
ELSE
IF LAST ConstantSurfaceFeed?
StartSpeed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
END
END
IF LAST ProgStop?
SpinOn
END
IF NewGear?
GearRange
END
EOL
SeqLabC
IF LAST ProgStop?
CoolOn
ELSE
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
END
EOL
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveX MoveZ
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat? AND Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4F2.' EOL
SeqLabC InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4F' Dwell# EOL
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G33' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
XsAreRadii
SetMaxRPM('5000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
' ' EOL
SeqLab Rapid Plane CRCOff 'G63G70' AbsValue ckHome EOL
IF UseComments?
IF ProgramNameComment?
SeqLabC '(MSG, PROGRAM NUMBER ' Program# ' )' EOL
SeqLabC '(MSG, ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqLabC '(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLabC '(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF MovesComment?
SeqLabC '(MSG, OUTPUT IN ABSOLUTE INCHES )' EOL
END
IF TimeComment?
SeqLabC '(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
':?' Rapid Plane CRCOff 'G63G70' AbsValue ckHome EOL
DoOpComments
DoPostScript
SeqLabC StartSpeed SpinOn GearRange EOL
SeqLabC 'G95' FeedRate EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
SeqLabC OpToolID ToolChng EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC CoolOff EOL
SeqLabC LAST OpExitZCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC CoolOff EOL
SeqLabC LAST OpExitZCPC EOL
ELSE
SeqLabC LAST OpExitZCPC CoolOff EOL
END
END
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
SeqLabC ckNewHome EOL
SeqLabC 'M50' EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

':?' Rapid Plane CRCOff 'G63G70' AbsValue ckHome EOL
DoOpComments
DoPostScript
SeqLabC StartSpeed SpinOn GearRange EOL
SeqLabC 'G95' FeedRate EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
SeqLabC OpToolID ToolChng EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed?
IF SameTool?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC CSSOn 'G96R' StartPosX# Speed EOL
END
ELSE
SeqLabC CSSOn 'G96R' StartPosX# Speed EOL
END
ELSE
SeqLabC CSSOn 'G96R' StartPosX# Speed EOL
END
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
ToolPath
ELSE
SetPass2
SeqLabC Feed FeedRate EOL
IF RoughContour?
SeqLabC '(BAR,'
IF ApproachFace?
'H1'
END
IF NOT AutoFinish?
'C1'
END
CutDepth XStkLeft ZStkLeft XSP ZSP ')' EOL
ELSE
IF RoughPatternShift?
SeqLabC '(CPY,'
IF ApproachFace?
'H1'
END
IF NOT AutoFinish?
'C1'
END
IF ApproachFace?
'D' ZCutDepth#
ELSE
'D' XCutDepth#
END
XStkLeft ZStkLeft XSP ZSP ')' EOL
END
END
SeqLabC Feed XSP ZSP FeedRate EOL
ToolPath
SeqLabC '(ENC)' EOL
END
ELSE
IF Threading?
SeqLabC '(THD,' CutDepth
IF SingleEdgeCut?
ToolAngle
ELSE
'A0'
END
'R' ADD# CycleStartXRadius#
IF ApproachOD?
Num#('.05')
ELSE {Approach ID}
Num#('-.05')
END
XatFinZ ZSP ')' EOL
SeqLabC LCycle
IF Chamfer?
ThrdHeight {move to major diameter. force auto 45Ą pullout}
END
IF Taper?
XAtFinZ FinZ 'I' MUL# DIV# Num#('1') Thread# DIV# Taper# FinishZInc#
ELSE
FinZ
END
ThrdLead EOL
SeqLabC '(ENC)' EOL
IF AutoFinish?
SeqLabC Rapid XatFinZ ZSP EOL
SeqLabC LCycle
IF Chamfer?
ThrdHeight {move to major diameter. force auto 45Ą pullout}
END
FinZ ThrdLead EOL
SeqLabC RapidC 'X' CycleStartXRadius# EOL
SeqLabC ZCSP EOL
END
ELSE
IF Drilling?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
SeqLabC RLevel EOL
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' ADD# FinishXRadius# Taper# EOL
SeqLabC 'G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4F2.' EOL
SeqLabC SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC CoolOff EOL
SeqLabC OpExitZCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC CoolOff EOL
SeqLabC OpExitZCPC EOL
ELSE
SeqLabC OpExitZCPC CoolOff EOL
END
END
DoEndOpPS
IF ConstantSurfaceFeed?
SeqLabC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqLabC ckFirstHome EOL
SeqLabC 'M50' EOL
SeqLabC EOP EOL
EOR EOL
ASCII('0') EOL
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
SeqLabC '(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
SeqLabC '(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
SeqLabC '(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Post
Close
Retag