{
MILL=F
LATHE=T
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=F
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{3/9/89 minor corections by JR}

{4/25/89
Copied & Modified; Fanuc 10T-MS [-] L001.58, for Brunswick.
Machine is a Cincinnati Series 208 Turning Center, Acramatic 850TC
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{5/17/91, Updated Cincinnati Acr 850TC L102.56 to .81 format, JR}

{8/6/91
Updated: Cincinnati Acr 850TC L102.81
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.82 Format.
Kim Michelman}

{8/6/91
Using "Reference Rewind Stop" characters (:) unstead of SeqLab (N) at beginning of operations.
Changed the startup code per the manual, ':' Program# Rapid Plane 'G62G70' AbsOrInc 'G95' Home GearRange EOL.
Added the GetSpinOn sub to differentiate the 'M13' from 'M03' and 'M14' from 'M04'.
The GetSpinOn replaced the SpinOn command throughout the processor.
Added the missing NextOp at the end of the prog.
Put the EOP on the same line as the FirstHome, per the manual.
Deleted the ProgStop and the Untool ToolChng from the end of the prog.
Kim Michelman}

{6/8/93
Copied & modified: Cincinnati Acr 850TC L102.82.1
For: Braden Eng / Illiana Machine
Control: Acramatic 850 TC
Machine: Cincinnati Milicron Cinturn 18" Universal Turning Center
Use sequence number for colon blocks.
Added leading zero supression on G & M & T codes.
Changed ToolChng from M26 to M6.
Modified GearRanges.
Added XsAreRadii to initializations.
Added CoolOff at end of tool.
Reduce RPM to 125 at end of tool if next tool has a new gear or spindle direction.
Changed to use absolute arc centers.
Added spaces between codes.
Deleted "XatFinZ ThrdHeight" line before thread cycle.
This was to position to the major dia,
set CAM document to have Start X and Major Å» set the same.
Jim Radcliffe}

{8/6/93
Modified: Cin Acr 850 TC [IM] L289.82.1
For: Braden Eng / Illiana Machine
Control: Acramatic 850 TC
Machine: Cincinnati Milicron Cinturn 18" Universal Turning Center
Modified retract to index position.
Machine has 2 turrets: Lower = Tools 1 thru 6 Upper = Tools 11 thru 16
When indexing from Lower to Upper retract Z to NewHome + 20"
When indexing from Upper to Lower retract X to NewHome + 13"
Unconditional axis output in FormatArc.
Deleted extra Rapid from Approach.
Moved callout of CSSOn for FirstOp and NewTool.
Changed format of output from 0. to 0 for a zero output.
Due to a recent visit to the Twilite Zone,
I had to start with a fresh Form (I used L001) to get this to work.
Colon block must imediatly follow a program stop.
Moved ProgStop to a line by itself after DoOpComments in same tool.
Rewrote CheckOffset to add Colon Block if ProgStop.
Modified R value for Threading by .050 for clearance
Jim Radcliffe}

{11/1/94
Copied & modified: Cin Acr 850 TC [IM] L289.82.2
For: Accurate Tool Co.
Control: Acramatic 850 SX
Machine: Cincinnati Milicron Avenger
Changed G76 to G33 for Threading Canned Cycle.
Moved EOP down to line by itself.
Added 1 NULL character to end of program.
Added X and I values for Tapered threading.
Jim Radcliffe}

{3/2/95
Updated: Cin Acr 850 SX L315.82.2
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Compost 4.21.27
Changes made per Pete Jackson
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1c Format.
Added RestoreScale Sub per 4-Axis Post Processor.
Added Logic to suppress Feed and FeedRate for Approaches.
Added bypass of AutoFinish for Non-Canned RoughSimple Operations.
Added XSPC ZSPC at AutoFinish for NOT CannedCycle AND NOT Turning Operations.
Changed RapidC StrtPos to StockOff StrtPosC at AutoFinish for NOT CannedCycle Operations.
Modified non-CannedCycle AutoFinish.
Method of testing for IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple? AND NOT Threading?
did not allow for AutoFinish pass of IF Turning?
Rewrote to test for IF Turning? ELSE IF Roughing? AND NOT RoughSimple?
Added support for AutoFinish of non-Canned Threading Cycle.
Miscellaneous other changes.
DWB}

{3/15/95
Modified: Cin Acr 850 SX L315.82.3
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Catalyst v2.14.30/Compost 4.21.27
Added Address Spaces to Canned Tap and Peck Drilling Cycles in Mach Spec Drilling Dialog.
Added '##.0####;0 Format back in Address K of Mach Spec Threading Dialog.
Somehow, this disappeared.
Added call to RestoreScale prior to SafeStart Home block at beginning of FirstOperation.
Prior to calling RestoreScale, we were outputting Home on the SafeStart block, which did not get
correctly scaled during Metric>English conversion, and vice-versa.
DWB}

{3/16/95
Copied: Cin Acr 850 SX L315.82.4
Created: Cin Acr 850 SX [STM] L324.82.4
For: Sterling Thermal Motors
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Catalyst v2.14.30/Compost 4.21.27
Changed SetMaxRPM('1600') to SetMaxRPM('4000') at setup and initializations.
Added SetMinRPM('30') at setup and initializations.
Added literal 'G70', Inch Mode at Safe Start blocks at FirstOperation and NewTool.
Added GetToolChng sub called from FirstOperation, NewTool and end of Prog.
Contains condition to output ' M26' instead of ToolChng when NOT ToolChangeAtHome.
DWB}

{
Format: Cin Acr 850 SX L324.82.5
5/1/95
Moved 'G70' so it follows 'G97'
TH}

{5/26/95
Initial: Cin Acr 850 SX [STM] L324.82.5
Created: Cin Acr 850 SX [STM] L324.82.6
ForUser: Stirling Thermal Motors, Inc.
Machine: Model 250T
Comment: Changed Tap Cycle to G84 per faxed manual pages. Deleted DrillOff.
Jim Radcliffe}

{
Format: Cin Acr 850 SX L324.82.7
6/29/95
For: StoneAge
Added blank line to beginnning of program
TH}

{9/7/95, Updated Cin Acr 850 SX [STM] L324.82.7 to .85 format per v2.20 Update Instructions .01, JR}

{
Format: Cin Acr 850 SX L324.85.1
1/3/95
For: StoneAge
Changed ToolChng from M6 to M26.
Added I to G33 toolpath threading
Removed special GetNewHome sub and replaced with standard NewHome
TH}

{1/25/96
Initial: Cin Acr 850 SX [STM] L324.85.1
Created: Cin Acr 850 SX [STM] LXXX.85.2
For: StoneAge
Removed GoFirstHome sub, replaced with FirstHome command as per customer request,
eliminated 'I' value for straight threads, MPK}
{2/21/96,
Initial: Cin Acr 850 SX [STM] L324.85.2
Created: Cin Acr 850 SX [STM] L324.85.3
Multiplied 'I' value for tapered threads in order to get positive valued for OD threads and negative
for ID threads, MPK}
{3/5/96
Initial: Cin Acr 850 SX [STM] L324.85.3
Created: Cin Acr 850 SX [STM] L324.85.4
Made I vaule for threading always positive, MPK}

{
Format: Cin Acr 850 SX [STM] Lxxx.85.5
3/27/96
Changed ToolChng from M26 to M6.
TH}

{5/21/96,
Previous revision number is incorrect, should be M437.85, changing to .1 to match metric revision number,
no changess necessary, MPK}

{8/13/96
Initial: Cin Acr 850 SX [STM] L437.85.1
Created: Cin Acr 850 SX [STM] L437.85.2
ForUser: Boeing
Develop: ComPost2 68k, Catalyst68K v3.04.10.C
Comment: Corrected handling of Home commands, CSS and M6/M26
M26 sends machine home before indexing. Use in place of M6 IF NOT ToolChangeAtHome!
IF NOT ToolChangeAtHome, Home commands need to be suppressed!
G96 needs to come after the start position on X where CalcRPM1 calculates for and for R value!
Jim Radcliffe}

{9/6/96
Initial: Cin Acr 850 SX [STM] L437.85.2
Created: Cin Acr 850 SX [STM] L437.85.6 ( had to call .85.6 as STM has .85.5 version!!! )
ForUser: Boeing per Art Phelan at 206-655-5016
ForUser: Stirling Thermal Motors per Mike Slater at 313-995-1755
ForUser: Stone Age per Ed Deason at 970-259-2869
Develop: ComPost2 68k v1.0b3, Catalyst68K v3.04.10.C
Comment: Corrected M06/M26, Home/NoHome, colon block X&Z move & G33 G0.
Changed CheckHome on colon block to ThisOpEntryXCP ThisOpEntryZCP.
The colon block must have an X and Z move.
This move will occur AFTER the M6/M26 tool change!
Modified Approach sub accordingly to prevent redundant output & deleted AppMove sub.
NOTE: Colon block in CheckOffset laft alone as there is no program stop in Virtual!
This will have to be addressed when Virtual supports a program stop!
Corrected threading output of G33 and G0 on same line.
Updated Approach subs, SameTool and non-canned sections per Fanuc 10T MS [-] L001.85.01.02
Jim Radcliffe - Please refer this processor back to me for any future development!}

{9/23/96
Initial: Cin Acr 850 SX [STM] L437.85.6
Created: Cin Acr 850 SX [STM] L437.85.7
Develop: ComPost2 68k v1.0b3, Catalyst68K v3.04.10.C
Comment: Modified per very reasonable and globaly OK requests by Mike Slater
Changed colon block ThisOpEntryXCP ThisOpEntryZCP to Approach.
Moved ApproachSP from Approach to main.
Moved G96 up to right after the preset line.
Added ApproachDia# sub for calculation of G97 and R values.
Fixed SameTool support of colon block and G96
Changed NewTool? to NewTool? OR LAST ProgStop? to treat SameTool ProgStop same as new tool!
Jim Radcliffe - Please refer this processor back to me for any future development!}

{10/7/96
Initial: Cin Acr 850 SX [STM] L437.85.7
Created: Cin Acr 850 SX [STM] L437.85.8
ForUser: Stirling Thermal Motors per Mike Slater at 313-995-1755
Control: Cincinnati Acramatic 850 SX
Machine: Cincinnati Avenger T250
Comment: Corrected StartSpeed to incorporate Max and Min RPM settings! G33 is Modal!
Jim Radcliffe}

{1/24/97
Initial: Cin Acr 850 SX [STM] L437.85.8
Created: Cin Acr 850 SX [STM] L437.85.9
ForUser: Boeing
Control: Cin Acr 850 SX
Machine: Cinturn 12" Universal Turning Center
Develop: ComPost2 MSL 68K, Virtual Gibbs 3.23
Comment: Corrected StartSpeed to incorporate MaxRPM# from Virtual.
Jim Radcliffe}

{6/18/97
Initial: Cin Acr 850 SX [STM] L437.85.9
Created: Cin Acr 850 SX [AG] L590.85.1
ForUser: Amarillo Gear
Control: Cin Acr 850 SX
Machine: Cinturn 18" Universal Turning Center
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.35 PPC
Comment: New processor per faxes and conversation with Don Rowland.
Deleted G70 and F.05 from colon blocks.
Added AbsValue to colon blocks.
Moved OpToolID to end of line and added ToolOfst after it.
Also added 'H00' to cancel offset.
Moved G95 to first feed move after the colon block. Using flag#1 for control.
Changed GetToolChng control to output M06 for tool# 2, 3, 5 & 6 and M26 for all others.
Deleted Preset MaxRPM lines.
Changed to R format arcs using P label
Changed format of G, M, H and T to 2 places.
Delete trailing zeros from axis commands.
Commented out CoolOff command at end of tools.
Deleted spaces between codes.
Moved G96 line to be output after ApproachSP. Changed ApproachDia# to StartPosX#
Deleted UnTool line from end of program.
Jim Radcliffe - Please refer this processor back to me for any future development!}

{8/1/97
Initial: Cin Acr 850 SX [AG] L590.85.1
Created: Cin Acr 850 SX [AG] L590.85.2
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.35 PPC
Comment: Modified per conversation with Don Rowland.
Added first line to program as comment to completely prove out this program.
Moved GetSpinOn to be right after StartSpeed on colon blocks.
Removed sequence numbers from comment blocks.
Supressed tool comments for same tool operations.
Added blank line before colon block in new tool.
Deleted G97 line from end of tools.
Added OptCyc1 to suppress OpExitZCPC output at the end of non-ID operation.
Jim Radcliffe - Please refer this processor back to me for any future development!}

{8/7/97
Initial: Cin Acr 850 SX [AG] L590.85.2
Created: Cin Acr 850 SX [AG] L590.85.3
Comment: Modified per conversation with Don Rowland
Deleted special handling a Z axis with OptCyc1 and replaced with the following:
When indexing tools 2, 3, 5 or 6 into position:
1. Suppress OpExitZCPC from previous operation.
2. Override ThisOpEntryZCP Appraoch Z Position on the colon block with
ZSPC for OD and ID work
ZOpCPC for face work
3. Tool change command M6 instead of M26
Deleted the program# comment line.
Jim Radcliffe - Please refer this processor back to me for any future development!}

{8/14/97
Initial: Cin Acr 850 SX [AG] L590.85.3
Created: Cin Acr 850 SX [AG] L590.85.4
Comment: Modified per marked up readout and conversation with Don Rowland
Deleted spaces at beginning and end of comments.
Suppress output of OpExitZCPC at the end of tool# 3 always regardless of flag# 2.
Jim Radcliffe}

{11/25/97
Initial: Cin Acr 850 SX [AG] L590.85.4
Created: Cin Acr 850 SX [AG] L590.85.5
For: Amarillo Gear
Post now outputs to tool center when OptCyc1 is true in FirstOp,
MPK
}

{1/22/98,
Initial: Cin Acr 850 SX [AG] L590.85.5
Created: Cin Acr 850 SX [AG] L590.85.6
For: Amarillo Gear
Changed the Edit Tables in the form.
New Gear Ranges: 421-M41
1600-M42
CDH}

{2/5/98,
Initial: Cin Acr 850 SX [AG] L590.85.6
Created: Cin Acr 850 SX [AG] L590.85.7
For: Amarillo Gear
Deleted all extraneous literals in the post.
CDH}

{1/6/99
Initial: Cin Acr 850 SX [AG] L590.85.7
Created: Cin Acr 850 SX [AG] L590.85.8
ForUser: Amarillo Gear
Develop: Compost2 1.7b13, Virtual v5.02
Comment: Corrected optional tool radius center output per Don Rowland
Don wants the output to be to the tool center (standard Virtual
output is to the tool tip) as an option. He wants values typed into
dialogs to be output as they are entered and is aware that in doing
so Virtual rendering will be off by the tool tips radius at these
positions when outputting tool center.
Processor was set up with SetTTOff at the beginning of the program
which was activated by the OptCyc1 command. This had to be cleaned
up to get it before the first positioning move and to use a flag.
The flag is used to control SetTTOff and SetTTOk. When outputting
values typed into dialog boxes we want SetTTOk to get the value as it
is entered, otherwise we want SetTTOff to get the tool center.
There is a problem with the initial positioning moves of some
operations. There are some commands that are not effected by the
SetTTOff command. They are: ThisOpEntryXCP, XCP, OpExitXCP,
ThisOpEntryZCP, ZCP and OpExitZCP. It was decided that these
commands were not going to be modified at this time. I left in the
subs, Report and ReportValues, that I used for testing to facilitate
testing future versions of Virtual. Add a call to Report at the
beginning of the operation to see the effect of the SetTTOff and
SetTTOk commands.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '0.00'
#2 = '###.0###;0'
#3 = '#######0'
#4 = '##.#0'
#5 = '+#.0###;0'
#6 = '0000'
#7 = '#'
#8 = '+###.0###;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(InFeedAngle#,2)
FORMAT(ThisOpEntryXCP#,2)
FORMAT(XOpCD#,2)
FORMAT(StartPosX#,2)
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(DIV#,3)
FORMAT(MaxRPM#,3)
FORMAT(Dwell#,4) {.72}
FORMAT(XCutDepth#,5)
FORMAT(ZCutDepth#,5)
FORMAT(CycleStartXRadius#,5)
FORMAT(Program#,6) {.72}
FORMAT(RapidF#,7)
FORMAT(MUL#,8)

{Special Testing Subroutines ***********************************************}

ReportValues:
' ThisOpEntryXCP = ' ThisOpEntryXCP EOL
' XCP = ' XCP EOL
' XOpCD = ' XOpCD EOL
' XSP = ' XSP EOL
' OpExitXCP = ' OpExitXCP EOL
' XOpECD = ' XOpECD EOL

' ThisOpEntryZCP = ' ThisOpEntryZCP EOL
' ZCP = ' ZCP EOL
' ZOpCP = ' ZOpCP EOL
' ZSP = ' ZSP EOL
' OpExitZCP = ' OpExitZCP EOL
' ZOpECP = ' ZOpECP EOL
RETURN

Report:
SetStatusOff
SetTTOff '---- Tool Tip is Off ----' EOL
ReportValues
SetTTOk '---- Tool Tip is Ok ----' EOL
ReportValues
SetStatusOn
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'(MSG, OPERATION ' Operation# ': ' OperationType$ ')' EOL
END
IF OperationComment?
'(MSG, ' OperationComment$ ')' EOL
END
IF WorkGroupComment?
'(MSG, ' WorkGroupComment$ ')' EOL
END
IF NOT SameTool?
IF ToolTypeComment?
'(MSG, TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ')' EOL
END
IF ToolComment?
'(MSG, ' ToolComment$ ')' EOL
END
END
RestoreScale
END
RETURN

ckAutoClearToolTipOff:
IF Flag?('11') AND AutoClearance?
SetTTOff
ELSE
SetTTOk
END
RETURN

ckToolTipOff:
IF Flag?('11')
SetTTOff
ELSE
SetTTOk
END
RETURN

ckToolTipOk:
IF Flag?('11')
SetTTOk
END
RETURN

PSInit: {reset flags from last Op, .70}
OptCyc1F
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

ckG95:
IF NOT Flag?('1')
'G95'
SetFlag('1')
END
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC ckG95
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC ckToolTipOff StockOnNoCan XSPC EOL
SeqLabC ckAutoClearToolTipOff StockOff ZOpCPC EOL
ckToolTipOff StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
IF CannedCycle? AND Threading?
{back off 2 threads from start point}
SeqLabC StockOnNoCan 'Z' ADD# CycleStartZ# MUL# NUM#('2') DIV# NUM#('1') Thread# EOL
ELSE
SeqLabC ckToolTipOff StockOnNoCan ZSPC EOL
END
SeqLabC ckAutoClearToolTipOff StockOff XOpCDC EOL
ckToolTipOff StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
IF Flag?('2')
IF ApproachFace?
ckAutoClearToolTipOff StockOff ZOpCP
ELSE
ckToolTipOff StockOnNoCan ZSP
END
ELSE
ckAutoClearToolTipOff StockOff ThisOpEntryZCP
END
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
RapidF# { RapidF# forces FeedRateC to output }
IF ApproachOD?
ckAutoClearToolTipOff ThisOpEntryXCP AppMove
ELSE
IF ApproachID?
ckAutoClearToolTipOff XOpCD AppMove
ELSE {ApproachFace}
ckToolTipOff StockOnNoCan XSP AppMove
END
END
RETURN

ApproachDia#:
IF ApproachOD?
ThisOpEntryXCP#
ELSE
IF ApproachID?
XOpCD#
ELSE {ApproachFace}
StartPosX#
END
END
RETURN

GetSpinOn:
IF CWSpindle?
IF CoolOff?
'M3'
ELSE
'M13'
END
ELSE
IF CoolOff?
'M4'
ELSE
'M14'
END
END
RETURN

Constant#:
IF Metric?
Num#('.1503937008') { 3.82 / 25.4 }
ELSE
Num#('3.82')
END
RETURN

ApproachDiaCalcRPM1#:
DIV# MUL# SpeedSFPM# Constant# MUL# StartPosX# Num#('2')
RETURN

StartSpeed:
CSSOff
IF ConstantSurfaceFeed?
'S'
IF GreaterThan? ApproachDiaCalcRPM1# MaxRPM#
MaxRPM#
ELSE
IF GreaterThan? ApproachDiaCalcRPM1# Num#('4000') { SetMaxRPM('4000') }
'4000'
ELSE
IF LessThan? ApproachDiaCalcRPM1# Num#('30') { SetMinRPM('30') }
'30'
ELSE
ApproachDiaCalcRPM1#
END
END
END
ELSE
Speed
END
RETURN

CheckOffset:
DoEndOpPS
IF NewGear?
SeqLabC SpinOff EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
SeqLabC
IF NewGear?
GearRange
END
IF NewToolOffset?
ToolOfst
END
EOL
IF ConstantSurfaceFeed?
{ moved to main common section }
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed EOL
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed EOL
END
END
END
IF NewGear?
SeqLabC GetSpinOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoOpComments
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
ckG95 MoveX MoveZ
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat? AND Drilling?
IF Dwell?
SeqLabC 'G4F' Dwell# EOL
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC
IF LAST ThreadFeat?
Rapid
ELSE
RapidC
END
MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC ckG95 MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC
IF LAST ThreadFeat?
{ G33 is modal }
ELSE
'G33'
END
MoveXC MoveZC
IF Taper?
'I' MUL# DIV# Num#('1') Thread# DIV# Taper# FinishZInc#
END
ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
IF LAST Threading?
Rapid
ELSE
RapidC
END
END
RETURN

GetToolChng:
IF Flag?('2')
ToolChng
ELSE
'M26'
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
XsAreRadii
SetMaxRPM('4000')
SetMinRPM('30')
SetMaxFeed('500')
SetFlagF('1') { G95 output }
SetFlagF('2') { tools 2, 3, 5 or 6 }
SetFlagF('11') { Tool Center Output }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' OptCyc1 - when put in the At Op Start box in the First Operation' EOL
' will cause the program to output coordinates to the' EOL
' center of the tool nose radius.' EOL
END
EachOp {Start of post processing *********************}
IF NOT FirstOperation?
IF Equal? Tool# Num#('2')
SetFlag('2')
ELSE
IF Equal? Tool# Num#('3')
SetFlag('2')
ELSE
IF Equal? Tool# Num#('5')
SetFlag('2')
ELSE
IF Equal? Tool# Num#('6')
SetFlag('2')
ELSE
SetFlagF('2')
END
END
END
END
END
GetLCycle
IF FirstOperation?
'(' ProgramName$ ' *** FIRST TIME PRG. / PROVE OUT COMPLETELY ***' EOL
RestoreScale
SetHome
OpenSub
StockOff {.71.2}
' ' EOL
DoPostScript
IF OptCyc1?
SetFlag('11')
END
':?' Rapid Plane AbsValue 'G97' Approach StartSpeed GetSpinOn GetToolChng GearRange OpToolID ToolOfst EOL
SetFlagF('1')
IF UseComments?
SetScale('1')
IF ProgramNameComment?
'(MSG, ' ProgramName$ ')' EOL
END
IF ProgramComment?
'(MSG, ' ProgramComment$ ')' EOL
END
IF FormatNameComment?
'(MSG, FORMAT: ' FormatName$ ')' EOL
END
IF MovesComment?
'(MSG, OUTPUT IN ABSOLUTE INCHES)' EOL
END
IF TimeComment?
'(MSG, ' Date$ ' AT ' Time$ ')' EOL
END
RestoreScale
END
DoOpComments
ApproachSP
ELSE
IF NewTool? OR LAST ProgStop?

{Finish off last Operation}

StockOff {.62}
CheckRapid ckAutoClearToolTipOff
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
DoEndOpPS
IF NOT Flag?('2')
IF NotEqual? LAST Tool# NUm#('3')
SeqLabC LAST OpExitZCPC EOL
END
END
ckToolTipOk
IF ToolChangeAtHome?
SeqLabC NewHome EOL
END

{Start new Operation}

SeqLabC 'H00'
IF LAST ProgStop?
'M0'
ELSE
ProgStop
END
EOL
' ' EOL
':?' Rapid Plane AbsValue 'G97' Approach StartSpeed GetSpinOn GetToolChng GearRange OpToolID ToolOfst EOL
SetFlagF('1')
DoOpComments
DoPostScript
ApproachSP
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid ckAutoClearToolTipOff
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed?
IF SameTool? AND LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed EOL
END
ELSE
SeqLabC CSSOn 'G96' Speed 'R' StartPosX# EOL
END
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
ToolPath
ELSE
SetPass2
SeqLabC Feed FeedRate EOL
IF RoughContour?
SeqLabC '(BAR,'
IF ApproachFace?
'H1'
END
IF NOT AutoFinish?
'C1'
END
CutDepth XStkLeft ZStkLeft XSP ZSP ')' EOL
ELSE
IF RoughPatternShift?
SeqLabC '(CPY,'
IF ApproachFace?
'H1'
END
IF NOT AutoFinish?
'C1'
END
IF ApproachFace?
'D' ZCutDepth#
ELSE
'D' XCutDepth#
END
XStkLeft ZStkLeft XSP ZSP ')' EOL
END
END
SeqLabC Feed XSP ZSP FeedRate EOL
ToolPath
SeqLabC '(ENC)' EOL
END
ELSE
IF Threading?
SeqLabC '(THD,' CutDepth
IF SingleEdgeCut?
'A' InFeedAngle#
ELSE
'A0'
END
'R' ADD# CycleStartXRadius#
IF ApproachOD?
Num#('.05')
ELSE {Approach ID}
Num#('-.05')
END
XatFinZ ZSP ')' EOL
SeqLabC LCycle
IF Chamfer?
ThrdHeight {move to major diameter. force auto 45Ä„ pullout}
END
IF Taper?
XAtFinZ FinZ 'I' MUL# DIV# Num#('-1') Thread# DIV# Taper# FinishZInc#
ELSE
FinZ
END
ThrdLead EOL
SeqLabC '(ENC)' EOL
IF AutoFinish?
SeqLabC Rapid XatFinZ ZSP EOL
SeqLabC LCycle
IF Chamfer?
ThrdHeight {move to major diameter. force auto 45Ä„ pullout}
END
FinZ ThrdLead EOL
SeqLabC RapidC 'X' CycleStartXRadius# EOL
SeqLabC ZCSP EOL
END
ELSE
IF Drilling?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
SeqLabC RLevel EOL
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
ckAutoClearToolTipOff
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' ADD# FinishXRadius# Taper# EOL
SeqLabC 'G33'
IF Taper?
XatFinZ FinZ 'I' MUL# DIV# Num#('-1') Thread# DIV# Taper# FinishZInc# ThrdLead EOL
ELSE
FinZ ThrdLead EOL
END
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC ckAutoClearToolTipOff
IF CannedCycle?
Rapid
ELSE
IF Threading?
Rapid
ELSE
RapidC
END
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
DoEndOpPS
SeqLabC OpExitZCPC EOL
ckToolTipOk
IF ToolChangeAtHome?
SeqLabC FirstHome EOL
END
SeqLabC 'H00' EOP EOL
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
'(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS)' EOL
END
IF FileFeetComment?
'(MSG, FILE LENGTH: ' FileFeet# ' FEET)' EOL
END
IF FileMetersComment?
'(MSG, FILE LENGTH: ' FileMeters# ' METERS)' EOL
END
END
Post
ASCII('00') EOL
Close
Retag
ÍÍÍ