{Change Comments ***********************************************************}

{10/03/95
Modified: Cin Acr 850 TC [IM] L289.82.2
For: Illiana Machine
Control: Acramatic 850 TC
Machine: Cincinnati Milicron Cinturn 18" Universal Turning Center
For Metric CAM Doc.:
Fixed first line output to output X and Z in Inches.
Calculated correct Start RPMS and SFPM from Surface Meters per Minute.
Reset scale to output correct tool angle in threading.
Changed threading cycle from 'G76' to 'G33' per Illiana.
-MPS}

{10/10/95, Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format, MPS}

{Prog Numeric Format Definitions *******************************************}

#1 = '0.00'
#2 = '##.#0'
#3 = '###.0###;0'
#4 = '+#.0###;0'
#5 = '#####0'
#6 = '0000'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,2)
FORMAT(StartPosX#,3)
FORMAT(CycleStartXRadius#,3)
FORMAT(ADD#,3)
FORMAT(NewHomeX#,3)
FORMAT(NewHomeZ#,3)
FORMAT(FirstHomeX#,3)
FORMAT(FirstHomeZ#,3)
FORMAT(HomeX#,3)
FORMAT(XCutDepth#,4)
FORMAT(ZCutDepth#,4)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Program#,6)
FORMAT(RapidF#,7)
FORMAT(MUL#,7)

{Prog Subroutines **********************************************************}

SetScaleMMorInch:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
ELSE
SetScale('1')
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLabC '(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLabC '(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLabC '(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLabC '(MSG, TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLabC '(MSG, ' ToolComment$ ' )' EOL
END
SetScaleMMorInch
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ODApproachSP:
IF CannedCycle? AND Threading?
{back off 2 threads from start point}
SeqLabC StockOnNoCan ' Z' ADD# CycleStartZ# MUL# NUM#('2') DIV# NUM#('1') Thread# EOL
ELSE
SeqLabC StockOnNoCan ZSPC EOL
END
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

IDApproachSP:
IF CannedCycle? AND Threading?
{back off 2 threads from start point}
SeqLabC StockOnNoCan ' Z' ADD# CycleStartZ# MUL# NUM#('2') DIV# NUM#('1') Thread# EOL
ELSE
SeqLabC StockOnNoCan ZSPC EOL
END
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN

AppMove:
ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP StockOff AppMove EOL
FaceApproachSP
END
END
RETURN

GetSpinOn:
IF CWSpindle?
IF CoolOff?
' M3'
ELSE
' M13'
END
ELSE
IF CoolOff?
' M4'
ELSE
' M14'
END
END
RETURN

DoMMorInchSpeed:
IF Metric? {CAM file is in Metric, tools and tool path}
{Calculate SFPM converting SMPM to SFPM this is an english post}
' S' MUL# SpeedSFPM# Num#('3.280839895') {(1000 MM/25.4)/12 Inches}
ELSE
Speed
END
RETURN

StartSpeed:
CSSOff
IF ConstantSurfaceFeed?
IF Metric?
{Calculate RPM converting SMPM to SFPM for inch dia. this is an english post}
' S' MUL# CalcRPM1# Num#('83.333333333') {1000 MM/12 Inches}
ELSE
CalcRPM1
END
ELSE
Speed
END
RETURN

CheckOffset:
IF LAST ProgStop?
SeqLabC ' M0' EOL
':?' Rapid Plane ' G95' ' G97' ' F.05' StartSpeed OpToolID GetSpinOn GearRange EOL
DoPostScript
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
ELSE
IF NewGear?
SeqLabC SpinOff EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
{tool offsets not used in this processor}
END
IF NewGear?
SeqLabC GearRange EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
SeqLabC DoMMorInchSpeed EOL
ELSE
SeqLabC Preset MaxRPM EOL
{set in main after StrtPos}
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' Speed EOL
ELSE
SeqLabC SpeedC EOL
END
END
IF NewGear?
SeqLabC GetSpinOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveX MoveZ
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat? AND Drilling?
IF Dwell?
SeqLabC ' G4 F' Dwell# EOL
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC ' G33' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
CRCOffC Rapid
ELSE
CRCOffC RapidC
END
RETURN

GoNewHome:
IF ToolOver?('10') AND LAST NOT ToolOver?('10') {lower to upper turret index}
' X' NewHomeX# ' Z' ADD# Num#('20.0') NewHomeZ#
ELSE
IF NOT ToolOver?('10') AND LAST ToolOver?('10') {upper to lower turret index}
' X' ADD# Num#('13.0.') NewHomeX# ' Z' NewHomeZ#
ELSE {index on same turret}
NewHome
END
END
RETURN

GoFirstHome:
IF FIRST ToolOver?('10') AND NOT ToolOver?('10') {lower to upper turret index}
' X' FirstHomeX# ' Z' ADD# Num#('20.0') FirstHomeZ#
ELSE
IF NOT FIRST ToolOver?('10') AND ToolOver?('10') {upper to lower turret index}
' X' ADD# Num#('13.0.') FirstHomeX# ' Z' FirstHomeZ#
ELSE {index on same turret}
FirstHome
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
XsAreRadii
SetMaxRPM('1600')
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EACHOp
TagInc
GetLCycle
IF FirstOperation?
SetHome
SetScaleMMorInch
':?' Rapid Plane ' G95' ' G97' Home ' F.05' StartSpeed OpToolID ToolChng GetSpinOn GearRange EOL
SeqLabC '(MSG,' Program# '81 )' EOL {the 81 refers to customers machine number}
IF UseComments?
SetScale('1')
IF ProgramNameComment?
SeqLabC '(MSG, ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqLabC '(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLabC '(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF MovesComment?
SeqLabC '(MSG, OUTPUT IN ABSOLUTE INCHES )' EOL
END
IF TimeComment?
SeqLabC '(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
SetScaleMMorInch
END

OpenSub
StockOff {.71.2}
DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn ' G96 R' HomeX# DoMMorInchSpeed EOL
END
Approach
ELSE
IF NewTool?
StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC CoolOff EOL
SeqLabC LAST OpExitZCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC CoolOff EOL
SeqLabC LAST OpExitZCPC EOL
ELSE
SeqLabC LAST OpExitZCPC CoolOff EOL
END
END
DoEndOpPS
IF CWSpindle? AND LAST NOT CWSpindle?
SeqLabC CSSOff ' G97' GoNewHome ' S125' EOL
ELSE
IF NOT CWSpindle? AND LAST CWSpindle?
SeqLabC CSSOff ' G97' GoNewHome ' S125' EOL
ELSE
IF NewGear?
SeqLabC CSSOff ' G97' GoNewHome ' S125' EOL
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' GoNewHome CalcRPM2 EOL
ELSE
SeqLabC GoNewHome EOL
END
END
END
END

{Start new Operation}

DoOpComments
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
SeqLabC ProgStop EOL
END
':?' Rapid Plane ' G95' ' G97' Home ' F.05' StartSpeed OpToolID ToolChng GetSpinOn GearRange EOL
DoPostScript
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn ' G96 R' HomeX# DoMMorInchSpeed EOL
END
Approach
ELSE
IF SameTool? {.62}
DoEndOpPS

{Start new Operation}

DoOpComments
StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed?
IF SameTool?
IF LAST ProgStop?
SeqLabC CSSOn ' G96 R' StartPosX# DoMMorInchSpeed EOL
ELSE
IF LAST NOT ConstantSurfaceFeed?
SeqLabC CSSOn ' G96 R' StartPosX# DoMMorInchSpeed EOL
END
END
END
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughContour?
SetPass2
SeqLabC Feed Feedrate EOL
SeqLabC '(BAR,'
IF ApproachFace?
' H1'
END
IF NOT AutoFinish?
' C1'
END
CutDepth XStkLeft ZStkLeft XSP ZSP ')' EOL
SeqLabC Feed XSP ZSP FeedRate EOL
ToolPath
SeqLabC '(ENC)' EOL
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC Feed Feedrate EOL
SeqLabC '(CPY,'
IF ApproachFace?
' H1'
END
IF NOT AutoFinish?
' C1'
END
IF ApproachFace?
' D' ZCutDepth#
ELSE
' D' XCutDepth#
END
XStkLeft ZStkLeft XSP ZSP ')' EOL
SeqLabC Feed XSP ZSP FeedRate EOL
ToolPath
SeqLabC '(ENC)' EOL
END
END
ELSE
IF Threading?
SeqLabC '(THD,' CutDepth
IF SingleEdgeCut?
SetScale('1') {We Don't Scale angles, metric angles are similar to english angles}
ToolAngle
SetScaleMMorInch {Set correct scale}
ELSE
' A0'
END
' R' ADD# CycleStartXRadius#
IF ApproachOD?
Num#('.05')
ELSE {Approach ID}
Num#('-.05')
END
XatFinZ ZSP ')' EOL
SeqLabC LCycle
IF Chamfer?
ThrdHeight {move to major diameter. force auto 45Ą pullout}
END
FinZ ThrdLead EOL
SeqLabC '(ENC)' EOL
IF AutoFinish?
SeqLabC Rapid XatFinZ ZSP EOL
SeqLabC LCycle
IF Chamfer?
ThrdHeight {move to major diameter. force auto 45Ą pullout}
END
FinZ ThrdLead EOL
SeqLabC RapidC ' X' CycleStartXRadius# EOL
SeqLabC ZCSP EOL
END
ELSE
IF Drilling?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
SeqLabC RLevel EOL
END
ELSE
IF Grooving?
SeqLab StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? AND NOT Drilling?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqLabC RapidC StrtPos EOL
ToolPath
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CannedCycle?
CRCOffC Rapid
ELSE
CRCOffC RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC CoolOff EOL
SeqLabC OpExitZCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC CoolOff EOL
SeqLabC OpExitZCPC EOL
ELSE
SeqLabC OpExitZCPC CoolOff EOL
END
END
DoEndOpPS
SeqLabC CSSOff ' G97' GoFirstHome ' S125' EOL
SeqLabC UnTool ToolChng EOP EOL
IF UseComments?
SetScale('1')
IF FileBytesComment?
SeqLabC '(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
SeqLabC '(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
SeqLabC '(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Post
Close
Retag