{Change Comments ***********************************************************}

{6/12/91,
Copied and Modified: Fanuc 10T MS [-] L001.80
For: Keystone Steel & Wire
Machine: Steel Mill Lathe, retrofit.
Control:Allen Bradley Series 9/240.
All normal Fanuc Canned Cycles are supported, including FIDFO and Left-Handed Tapping.
DWB}

{9/24/96, updated to .85 format, MPK}

{4/10/97,
Initial: AB Series 9/240 L218.85
Created: AB Series 9/240 [AS] Lxxx.85
For: Avant systems
Modified Tool Changes, added M6,
added output of G54 after tool change,
deleted preset (G92) lines,
modified output of feed rate for canned threading (G78 cycle), E word in output is now TPI,
reversed M3/M4,
Reversed G2/G3,
changed post to output in dia,
changed output of G7 at program beginning to G8 (indicates diameter programming), MPK}


{20Nov97
Original: AB Series 9/240 [AS] L578.85
Created: AB Series 9/240 [AS] L578.85.1
For: Avant systems
Changes made per: Nick Lupfer
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Changed M3 to M4 and viceversa in MachSpec
Changed Literal 'G54' to 'G55' in FirstOperation and NewTool
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0'
#3 = '########;0'
#4 = '#####.###;0'
#5 = '##.###;0'
#6 = '###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Dwell#,4)
FORMAT(FeedIPR#,5)
FORMAT(DIV#,5) {canned threading feedrate}
FORMAT(CalcEPRPM#,6)
FORMAT(FeedContour#,4)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

Approach: { NOT FOR TAILSTOCK.8 }
StockOff
IF NOT SameTool?
SeqLabC Rapid
IF ApproachOD?
ThisOpEntryXCP
ELSE
IF ApproachID?
XOpCD
ELSE {ApproachFace}
StockOnNoCan XSP StockOff
END
END
ThisOpEntryZCP CoolOn EOL
END
IF ApproachOD?
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
SeqLabC Feed StockOnNoCan XSPC FeedRate EOL
ELSE
IF ApproachID?
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
SeqLabC Feed StockOnNoCan XSPC FeedRate EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
SeqLabC Feed StockOnNoCan ZSPC FeedRate EOL
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
SeqLabC SpeedC EOL
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed EOL
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed EOL
ELSE
SeqLabC SpeedC EOL
END
END
IF LAST ProgStop?
SeqLabC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC:
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G94G4P2.' EOL
SeqLabC 'G95' Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G94G4P' Dwell# EOL
'G95'
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid1:
CRCOffC
IF LAST NOT ApproachID?
IF LAST CannedCycle?
IF LAST Drilling?
IF LAST Tap?
Rapid
ELSE
IF LAST NOT AutoFinish?
Rapid
END
END
ELSE
Rapid
END
ELSE
RapidC
END
END
RETURN

CheckRapid2:
IF CannedCycle?
IF Drilling?
IF Tap?
Rapid
ELSE
IF NOT AutoFinish?
Rapid
END
END
ELSE
Rapid
END
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
ReverseXZArcs
SetMaxRPM('3500')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff
SetHome
DoOpComments
DoPostScript
Plane
SeqLab AbsOrInc EOL
SeqLabC 'G8' EOL { Output to be in diameter values }
SeqLabC 'G95' EOL { Feed per revolution mode }
SeqLabC OpToolID LatheOffset ToolChng EOL
SeqLabC 'G55' EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff
CheckRapid1
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
SeqLabC NewHome LOfstOff '00' EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLab OpToolID LatheOffset ToolChng EOL
SeqLabC 'G55' EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF SameTool?

{Start new Operation}

DoOpComments
StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid1
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid1
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC XOpECDC EOL
ELSE {around}
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL {around}
END
IF ApproachID?
IF LAST NOT ApproachID?
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC ZOpECPC EOL
ELSE
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
Approach
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle XatFinZ
IF ApproachFace?
'Z' FirstMoveEPZ#
ELSE
FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
IF RoughContour?
SetPass2
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
SeqLab StepMove StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G72' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G72' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
END
END
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC 'M23' EOL
END
IF NOT ConstantVolumeCut? AND NOT SingleEdgeCut?
SeqLabC 'G21X' FirstMoveEPX# FinZ XTapAtZ ThrdLead EOL
SimpleRough
SeqLabC XatFinZ EOL
IF AutoFinish?
SeqLabC XatFinZ EOL
END
ELSE
SeqLabC LCycle XatFinZ FinZ ThrdHeight CutDepth 'E' DIV# Num#('1') FeedContour# {feedrate must be expressed as TPI}
IF SingleEdgeCut?
ToolAngle
ELSE
'A0'
END
CutMethod XTapAtZ EOL
IF AutoFinish?
SeqLabC 'G21' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
END
IF Chamfer?
SeqLabC 'M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC
IF CWSpindle?
LCycle { Right-Hand Thread }
ELSE
'G84.1' { Left-Hand Thread }
END
ZDepth RLevel Dwell 'F' FeedIPR# EOL
SeqLabC DrillOff EOL
ELSE
IF FIFO? AND Dwell?
SeqLabC 'G89' ZDepth RLevel Peck 'P' Dwell# FeedRate EOL
ELSE
SeqLabC LCycle ZDepth RLevel Peck Dwell FeedRate EOL
END
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
'G95'
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqLabC RapidC StrtPos EOL
ToolPath
END
END
END
IF Drilling? AND Tap? AND NOT CannedCycle?
SeqLabC SpinOff EOL
SeqLabC 'G94G4P2.' EOL
SeqLabC 'G95' Speed SpinOn EOL
END
IF ApproachID?
CheckRapid2
SeqLabC XOpECDC EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF NOT ApproachID?
CheckRapid2
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqLabC FirstHome OpToolID '00' SpinOff EOL
SeqLabC UnTool '00' EOL
IF ProgStop?
SeqLabC 'M0' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END