{6/5/89, changed tool path to force feed on first TP move after a tool change,added Metric, WFG}

{6/28/89
Copied & modified; Fanuc 10T-MS [-] L001.60, for Lawrence Berkley.
Machine is a Gidding & Lewis Horizantal Turret Lathe with NumriPath 800-L control.
Jim Radcliffe}

{12/18/89
Copied & modified: G & L 800 L111.55
For: Armco
Changed gear range from M41 & M42 to M40 & M41 changeover at 500 & 1200 max.
Unconditional axis calls for arcs.
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{8/31/90
Updated: G & L 800 [AS] L140.62 to .71 format
All ID & Threading & Drilling operations get M03, all else get M04.
Change EOP to M30.
Jim Radcliffe}

{3/27/98
Initial: G & L 800 [AS] L140.85
Created: G & L 800 [AS] L140.85.1
ForUser: Armco
Control: ????
Machine: ????
Develop: ComPost2 1.1b3, Virtual Gibbs 4.24
Comment: Modified per marked up readout from Benjamin Staff
Update corrections.
Changed ArcIJC to ArcIJ in FormatArc to output I/K even if equal to zero.
Major rewrite to beginning of tools per instruction.
Added SpinOff and CoolOff to end of tools.
Moved output of CoolOn to first feed move.
Created ckCoolOn sub with Flag#1 to control output and called on feed lines.
Updated per Fanuc 10T MS [-] L001.85.01.02.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '0.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '##^0'
#5 = '##.######;0.'
#6 = '###0'
#7 = '#'
#8 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(CycleStartZ#,2)
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Dwell#,4)
FORMAT(FeedTapIPR#,5)
FORMAT(SpeedSFPM#,6)
FORMAT(RapidF#,7)
FORMAT(ToolOffset#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

ckCoolOn:
IF NOT EmptyLine?
IF NOT Flag?('1')
CoolOn
SetFlag('1')
END
END
RETURN

GetSpinOn:
IF ApproachID? OR IF Drilling? OR IF Threading?
SpinOn
ELSE
InverseSpinOn
END
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC ckCoolOn
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC EOL
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
RapidF# { RapidF# Forces FeedRate }
SetFlagF('1')
IF ApproachOD?
ThisOpEntryXCP AppMove
ELSE
IF ApproachID?
XOpCD AppMove
ELSE {ApproachFace}
StockOnNoCan XSP AppMove
END
END
IF ConstantSurfaceFeed?
CSSOn MaxRPM 'C' SpeedSFPM#
ELSE
CSSOff Speed
END
OpToolID 'H' ToolOffset# GetSpinOn GearRange
RETURN

CheckOffset: {with gear ranges}
SeqC
IF LAST ProgStop?
CoolOff SpinOff
ELSE
IF CoolOff? AND LAST NOT CoolOff?
CoolOff
END
IF NewGear?
SpinOff
END
END
EOL
DoEndOpPS
SeqC
IF NewToolOffset?
'H00'
END
IF LAST ProgStop?
'M0'
END
EOL
DoOpComments
DoPostScript
SeqC
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
MaxRPM 'C' SpeedSFPM#
ELSE
IF NotEqual? MaxRPM# LAST MaxRPM#
MaxRPM 'C' SpeedSFPM#
END
END
ELSE
CSSOn MaxRPM 'C' SpeedSFPM#
END
ELSE
IF LAST ConstantSurfaceFeed?
CSSOff Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
END
END
IF NewToolOffset?
'H' ToolOffset#
END
IF LAST ProgStop?
GetSpinOn
ELSE
IF NewGear?
GetSpinOn
END
END
IF NewGear?
GearRange
END
EOL
SeqC
IF LAST ProgStop?
SetFlagF('1')
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SetFlagF('1')
END
END
EOL
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC 'G04F20' EOL
ELSE
IF Dwell?
SeqC 'G04F' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC
IF LAST ThreadFeat?
Rapid
ELSE
RapidC
END
MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC CkCRC FeedC MoveXC MoveZC FeedRateC ckCoolOn EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC ckCoolOn EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G32' MoveXC MoveZC ThrdLead ckCoolOn EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
IF LAST Threading?
Rapid
ELSE
RapidC
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
XsAreRadii
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' )' EOL
END
END
RestoreScale
OpenSub
StockOff
SetHome
DoOpComments
DoPostScript
Plane
Seq AbsOrInc Rapid Home 'H00' EOL
SeqC Approach EOL
ApproachSP
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
END
SeqC LAST OpExitZCPC CoolOff SpinOff EOL
DoEndOpPS
SeqC NewHome 'H00'
IF ProgStop?
'M00' EOL
ELSE
ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Plane
Seq AbsOrInc Rapid Approach EOL
ApproachSP
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle? {tapping is the only canned cycle on this machine}
StockOff
IF Drilling?
SeqC LCycle ZDepth 'K' CycleStartZ# 'R' CycleStartZ# 'E' FeedTapIPR# ('.9') EOL
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqC RapidC ZOpECPC EOL
ELSE
SeqC RapidC XOpECDC EOL
END
ApproachSP
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC RapidC XSPC ZSPC EOL
SeqC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqC 'X' MUL# Num#('1') ADD# FinishXRadius# Taper# EOL
SeqC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqC Rapid XSP EOL
SeqC ZSP EOL
END
END
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
IF Threading?
Rapid
ELSE
RapidC
END
END
IF ApproachOD?
SeqC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC EOL
END
END
SeqC OpExitZCPC CoolOff SpinOff EOL
DoEndOpPS
SeqC FirstHome 'H00' ProgStop EOL
SeqC EOP EOL
Post
EOR EOL
Close
IF UseComments?
Reopen
SetScale('1')
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END