{Change Comments ***********************************************************}

{2/7/91
Copied & modified: Fanuc 6M M001.76.1
For: Teleflex
Machine: Mori Seiki MV 40
Control: Yasnac MX1
First Tool In Spindle.
Move Speed to saftey start block.
Suppress WFO output to MP & PostScript.
Move SpinOn to OfstOn line.
Add literal sub calls to P9101 & P8001.
Add PreTool.
Replace Home stuff will literal sub call to P9101.
Supress tool comments on SameTool operations.
Delete DrillCP command.
Delete StrtPos from drill cycle line.
Add to operation comments.
Unconditional ZCP3 after drilling.
Jim Radcliffe}

{4/3/91
Updated: Yasnac MX1 MS MV40 M398.76.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
Did not verify, thus version .79
DWB}

{6/15/94
Updated: Yasnac MX1 MS MV40 M398.79
For: Gibbs & Associates per Strom Mfg
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.22
Updated to Version 4.2 per Fanuc 6M M001.81.2d Format.
Corrected FORMAT5 from '########;0' to '#######0'.
Corrected FORMAT6 for Dwell# from '####^###;' to '####^##0'.
Added RestoreScale Sub per 4-Axis Post Processor.
Added FIFO? at FinishSub1, AutoCycCutSub2, ZonlyRepAutoCycle subs and end of IF Milling.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added variable Drill depths at ToolPath PointFeat.
Moved UnSkipZ from FinishSub1 to ZOnlyRep where SkipZ is set.
Added IF NOT LastTool? for PreTool at FirstOperation.
Added TrackZNO# SPZ# at IF Drilling? section to allow for conditionality of MoveSXYZC command.
DWB}

{6/27/94
Copied: Yasnac MX1 MS MV40 M398.81.2
Created: Yasnac MX1 MVJr [SM] M671.81.2
For: Strom Mfg
Versions: Catalyst v2.05.16L/Compost 4.21.22
Changes made per Michael Strom, G-Code list, M-Code list and hardcopy sample program.
Changed G28 to G49 for Tool Length Offset Cancel in Compost Commands 5 dialog.
Added TrackY# to FORMAT#4.
Added Sequence# to FORMAT#5.
Added NextTool# to FORMAT#5.
Added ToolOffset# to FORMAT#5.
Added CRCOffset# to FORMAT#5.
Deleted suppression of SameTool ToolComments at DoOpComments sub.
Added 'M11/M10' for PostScript FourthDegree# UnClamp/Clamp at PSStuff sub.
Added special output of CRCOffset# at CkCRC sub.
Deleted CRCOffsetC 3 places at StdLine sub.
Added call to CkCRC at ToolPath RapidFeat.
Added full WorkFixtureOffset support at WFOStuff sub.
Added condition to output NewWFO warning for WorkFixtureOffset MultipleParts at WFOStuff sub.
Changed all occurances of DrillOff command to literal 'G80'.
Added literal '#116=0' at FirstOperation.
Added literal 'GOTO' Sequence# at FirstOperation.
Added blank line prior to DoOpComments at FirstOperation
Added Seq ' ' to DoOpComments call at FirstOperation and NewTool.
Modified Safe Start block and moved to follow DoPostScript call at FirstOperation and NewTool.
Moved Speed after WFOStuff call at FirstOperation and NewTool.
Moved SpinOn from OfstOn block to Speed block at FirstOperation and NewTool.
Deleted literal sub calls to P9101 & P8001 for Teleflex per 2/7/91 notes.
Moved PreTool to StrtPos block at FirstOperation and NewTool.
Changed PreTool to literal 'T[' NextTool# '+#116]' at FirstOperation and NewTool.
Moved CoolOn to OfstOn block at FirstOperation, NewTool and SameTool.
Changed OfstOn to literal 'G43' ZCP1 'H[' Tool# '+#116]' at FirstOperation, NewTool and SameTool.
Moved IncValue OfstOff after CoolOff block at NewTool and end of Prog.
Moved CoolOff to OfstOff block at NewTool, SameTool and end of Prog.
Changed OfstOff to literal 'G28Z2.' at NewTool, SameTool and end of Prog.
Deleted SpinOff at NewTool and end of Prog.
Added ToolChangeAtHome at NewTool and end of Prog.
Added literal 'G52', Return to Reference Coordinate System to ToolChangeAtHome at NewTool and end of Prog.
Deleted IF ToolChangeAtHome condition to output Home/FirstHome at NewTool and end of Prog.
Changed Home/FirstHome to literal 'Y' TrackY# Num#('-4') at NewTool and end of Prog.
Added DrillCP at IF Drilling.
Switched FromCP and Cycle commands to Drill Cycle Block at IF Drilling.
Added StrtPos to Canned Drilling block at IF Drilling.
Changed ZCP3 to ZCP3C at IF Drilling.
Deleted StrtPos from Drill Cycle Block at IF Drilling.
Moved ToolChng to follow ProgStop at end of Prog.
Added condition to output ToolChng IF NOT FirstTool at end of Prog.
Added literal 'Y' TrackY# Num#('0') for Pallet Changing at end of Prog.
DWB}

{6/27/94
Copied: Yasnac MX1 MVJr [SM] M671.81.2
Created: Yasnac MX1 MV40 [SM] M672.81.2
For: Strom Mfg
Versions: Catalyst v2.05.16L/Compost 4.21.22
Changes made per Michael Strom, G-Code list, M-Code list and hardcopy sample program.
Changed Sub Label Repeat Address from L to K in Compost Strings 2 Dialog.
Added support of Rigid Tap Cycle.
Added OptCyc1F at PSInit.
Added test for Drilling AND Tap AND OptCyc1 to output literal 'M29' instead of SpinOn at
FirstOperation, NewTool and SameTool.
Added Repeats# to FORMAT#5.
Changed RepCycs to Repeats# at StdSub sub.
Changed Parts to Parts# 2 places at OpenMP sub.
Changed ProgID1 to ':' Program# at FirstOperation.
Deleted AbsOrInc Rapid 'G52Y' TrackY# Num#('-4') at NewTool and end of Prog.
Deleted literal 'Y' TrackY# Num#('0') for Pallet Changing at end of Prog.
DWB}

{1/25/96
Copied: Yasnac MX1 MVJr [SM] M671.81.2
Created: Yasnac MX1 MV40 [SM] M672.81.3
For: Strom Mfg
Changes made per Michael Strom,
Added Custome Header as per customer fax
Forced Program name output with no coments
Added tool list output as per customer fax
Added custome tool chance code as per custmer fax
JM}

{2/9/96, Updated .81 version to .84, MPK}

{3/4/96
Copied: Yasnac MX1 MV40 [SM] M672.84
Created: Yasnac MX1 MV40 [SM] M672.84.1
For: Strom Mfg
Added Tool in spindle line.
Removed User editable coments
Moved Origin Coment to top of program.
Moved Origin Coment to top of program after Program #
JM}

{3/15/96,
Initial: Yasnac MX1 MV40 [SM] M672.84.1
Created: Yasnac MX1 MV40 [SM] C672.11
Updated to support Adv Mill, MPK}

{3/25/96, Tested ZOnlyRepAutoCycle, Changed version # to .12, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '*#####.##;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(TrackY#,4)
FORMAT(ToolDiameter#,4)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(Sequence#,5)
FORMAT(NextTool#,5)
FORMAT(ToolOffset#,5)
FORMAT(CRCOffset#,5)
FORMAT(Repeats#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Dwell#,6)
FORMAT(CSOffsetA#,7)
FORMAT(CSOffsetB#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END

'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL

IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

CSWFO:
'G' ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CalcCSWFO: {(iPart-1)*NumOfCS#)}
'G' ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CSAngleA:
IF AAxisAvail?
SeqC 'M11' EOL { UnClamp }
'A' CSOffsetA#
SeqC 'M10' EOL { Clamp }
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
'B' CSOffsetB#
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

DoCSWFOComment:
'( CS#' CS# ' - ' CSComment$ ' )' EOL
'( ' CalcCSWFO '= X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' )' EOL
RETURN

PSInit:
MasterOpF
CallMasterOpF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab RepLab Repeats# EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

OpenMP:
IF WFOCS?
NewProg
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO EOL
SeqC SubCall CallLab RepLab Parts# EOL
IncWFO
NextWFO
ELSE
SeqC SubCall CallLab RepLab Parts# EOL
END
StartSub
END
RETURN

CloseMP:
IF WFOCS?
SeqC EndSub EOL
CloseSub
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqC CalcCSWFO EOL
SeqC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
ClearCSOffset
IncWFO
NextWFO {simple NextPart}
ELSE
LastWFO
EachWFO {simple eachPart}
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqC CalcCSWFO EOL
SeqC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
ClearCSOffset
DecWFO
NextPrevWFO {simple NextPart}
END
IF Flag?('4')
ToggleIncDecWFO
END
ELSE
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
END
RETURN

SubCSMP:
IF WFOCS?
IF ChangeCS?
SeqC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF LastFeat?
CRCOffC
ELSE
CRCOnC
IF NOT EmptyLine?
'D[' CRCOffset# '+#116]' { CRCOffsetC }
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
IF LastFeat?
CRCOffC
END
SeqC DoAbsOrInc RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 2}
SetFlag('3') {True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP}
SetFlag('4') {True = toggle between incrementing/decrementing WFO's }
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('6')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to non-WFO output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('6') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to non-WFO output. )' EOL
END
END
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
SeqC FromCP Cycle ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF CallMasterOp?
SeqC SubCall 'P' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

NotSameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
SeqC CSWFO EOL
ELSE
SeqC 'G' NewWFO# EOL
END
ClearCSOffset
ELSE
IF NeedWFO1?
SeqC 'G' NewWFO# EOL
END
END
RETURN

SameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
SeqC CSWFO EOL
END
ClearCSOffset
END
RETURN

InitOp:
IF FirstOperation?
EOR EOL
':' Program#
' ( ' ProgramName$ ' )'
' ' EOL
'( ' ProgramComment$ ' )' EOL
{CUSTOM COMENTS A PER CUSTOMER}
'#100=1 (NUMBER OF VICES)'EOL
'#102=0 (STARTING VICE, VICES AR NUMBERS 0,1,2...ECT)'EOL
'#106=XX.XXX (INITAL X G54 POSITION FROM X DATUM)'EOL
'#107=XX.XXX (INITAL Y G54 POSITION FROM Y DATUM)'EOL
'#108=XX.XXX (INITAL X G55 POSITION FROM X DATUM)'EOL
'#109=XX.XXX (INITAL Y G55 POSITION FROM Y DATUM)'EOL
'#110=#506 (DISTANEC BETWEEN VICES)'EOL
'#116=0 (HEIGHT AND DIAMETER ADJUST)'EOL
'GOTO1'EOL
EOL
EOL

EachTool {tool loop to give a list of tools in program header}
'(T' TLNum# ' ' TLToolComment$ ')' EOL
NextTool
EOL

IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
' ' EOL
Seq ' ' DoOpComments EOL
DoPostScript
RETURN

FirstOp2:
'T[' Tool# '+#116]' EOL
'M6' EOL
SeqC Plane CRCOff 'G80' AbsOrInc Rapid EOL
'#101=#102(SET STARTING VICE POSITTION)' EOL {custom tool change for STROM}
'WHILE[#101LT#100]D01' EOL
'G65P9500V#101D110 (SETS POSITIONING FOR MACHINED PART)' EOL
SeqC Speed
IF Drilling? AND Tap? AND OptCyc1?
'M29' { Rigid Tap Cycle }
ELSE
SpinOn
END
EOL
RETURN

FirstOp3:
CheckPass
SeqC AbsOrInc Rapid StrtPos
IF NOT LastTool?
'T[' NextTool# '+#116]' { PreTool }
END
EOL
SeqC CSAngleA CSAngleB EOL
SeqC 'G43' ZCP1 'H[' ToolOffset# '+#116]' CoolOn EOL { OfstOn }
END
RETURN

FirstOp3a:
CheckPass
IF NOT LastTool?
'T[' NextTool# '+#116]' { PreTool }
END
EOL
SeqC 'G43' ZCP1 'H[' ToolOffset# '+#116]' CoolOn EOL { OfstOn }
END
RETURN

NewToolOp1:
'#101=#101+1' EOL
'END1' EOL
SeqC IncValue 'G28Z2.' CoolOff EOL { Return to Reference Point }
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
RETURN

NewToolOp2:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
SeqC ToolChng EOL
Seq ' ' DoOpComments EOL
DoPostScript
RETURN

NewToolOp4:
'T[' Tool# '+#116]' EOL
'M6' EOL
SeqC Plane CRCOff 'G80' AbsOrInc Rapid EOL
'#101=#102(SET STARTING VICE POSITTION)' EOL {custom tool change for STROM}
'WHILE[#101LT#100]D01' EOL
'G65P9500V#101D110 (SETS POSITIONING FOR MACHINED PART)' EOL
SeqC Speed
IF Drilling? AND Tap? AND OptCyc1?
'M29' { Rigid Tap Cycle }
ELSE
SpinOn
END
EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
RETURN

NewToolOp5:
CheckPass
SeqC AbsOrInc Rapid StrtPos 'T[' NextTool# '+#116]' EOL { PreTool }
SeqC CSAngleA CSAngleB EOL
SeqC 'G43' ZCP1 'H[' ToolOffset# '+#116]' CoolOn EOL { OfstOn }
RETURN

NewToolOp5a:
CheckPass
SeqC 'T[' NextTool# '+#116]' EOL { PreTool }
SeqC 'G43' ZCP1 'H[' ToolOffset# '+#116]' CoolOn EOL { OfstOn }
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC IncValue 'G28Z2.' CoolOff EOL { Return to Reference Point }
SeqC SpinOff EOL
SeqC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset? OR ChangeCS?
SeqC IncValue 'G28Z2.' EOL { Return to Reference Point }
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3:
DoEndOpPS
IF LAST ProgStop?
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC
IF Drilling? AND Tap? AND OptCyc1?
'M29' { Rigid Tap Cycle }
ELSE
SpinOn
END
EOL
SeqC CSAngleA CSAngleB EOL
SeqC 'G43' ZCP1 'H[' ToolOffset# '+#116]' CoolOn EOL { OfstOn }
ELSE
IF NewToolOffset?
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
SeqC CSAngleA CSAngleB EOL
SeqC 'G43' ZCP1 'H[' ToolOffset# '+#116]' EOL { OfstOn }
ELSE
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
SeqC CSAngleA CSAngleB EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

End1:
SeqC IncValue 'G28Z2.' CoolOff EOL { Return to Reference Point }
RETURN

End2:
DoEndOpPS
IF NOT Equal? CSOffsetA# Num#('0') OR NOT Equal? CSOffsetB# Num#('0')
IF AAxisAvail?
SeqC CSAngleA
END
IF BAxisAvail?
SeqC CSAngleB
END
EOL

SeqC 'G92'
IF AAxisAvail?
'A0'
END
IF BAxisAvail?
'B0'
END
EOL
END
IF ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
IF NOT FirstTool?
SeqC ToolChng EOL
END
RETURN

End3:
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
OpenMP
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
OpenMP
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3a
OpenMP
SeqC StrtPos EOL
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5a
OpenMP
SeqC StrtPos EOL
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
NotSameToolWFO
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NotSameToolWFO
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolWFO
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, top level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END