{Change Comments ***********************************************************}

{5/24/93
created initial NoSubs Processor to .81 format
FIFO stuff not supported
variables: 1 = tools 1st op; 2 = tools last op; 3 = ncCAMs last op
Jim Radcliffe}

{7/29/93, v.81.1, added FIFO handling, JR}
{8/3/93, v.81.2, SameTool WFO, RapidF#, additional FIFO handling, JR}

{1/21/94
Copied & modified: Fanuc 6M NoSubs M001.81.2
For: CNCCS / Goddard Enterprises
Machine: Proto Plus
Added semi-colon, ascii 59, to MachSpec for output with EOL.
Changed MachSpec labels I, J, K to XC, YC, ZC and Booleans to use Absolute Arc Centers.
Changed to unconditional G code output and all drill positions get a G0.
FeedC -> Feed
RapidC -> Rpid
CWArcC -> CWArc
CCWArcC-> CCWArc
Jim Radcliffe}

{2/21/94
Modified: Prototrak Plus M623.81.2
For: CNCCS / Goddard Enterprises
Control has no Z drive. When it reads a G0 it stops for Manual Operation.
Cutter Comp needs to be Contour which is not available in Virtual.
The D value shuold be the diameter of the tool and cannot be a negative value.
I am using a value of .0005 for the D value for the time being here until
the we can properly post contour values from virtual.
Cutter comp is not turned off on the last feature or at the end of the operation.
We set it at the beginning to be either CRCOn or CRCOff.
Jim Radcliffe}

{3/5/94, created .81.4, corrected unconditional G code output in StdLine, JR}
{4/14/94, created .81.5, arcs stop on quads when doing full 360 deg circle, JR}

{3/14/95
Modified: Prototrak Plus M623.81.5
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Catalyst v2.14.30/Compost 4.21.27
Changes made per Pete Jackson.
Added SetLineStrtChr('
') at FirstOperation.
This is ASCII('10') which is needed for proper loading into IBM application.
DWB}

{6/16/95
Copied: Prototrak Plus M623.81.2
Created: Prototrak Plus [PE] M808.81.2
For: Perkin Elmer
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.14.40/Compost 4.21.29
Changes made per Tom Donaldson of Murtaugh.
Added IF SPXMove? OR SPYMove? condition at IF Milling?
Changed Connect command to Rapid command in IF SPXMove? OR SPYMove? condition at IF Milling?
DWB}

{6/16/95
Modified: Prototrak Plus [PE] M808.81.2
For: Perkin Elmer
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.14.40/Compost 4.21.29
Changes made per Jeff Myers.
Deleted SetLineStrtChr('
') at FirstOperation, see 3/14/95.
This was added due to a bug in the Communications Software.
Jeff said the post wouldn't DOS wash when it encountered the first block containing the LF.
He said the software will be fixed in the 2.20 version.
DWB}

{8/9/95, No changes made to update to .85 format, renamed and recompiled, JR}

{8/16/95
Initial: Prototrak Plus [PE] M808.85
Created: Prototrak Plus [PE] M808.85.01
Comment: Added ASCII 10 to MachSpec EOL.
Gives it the same output as M623 except:
The line feed is at the end of the line instead of the beginning
The SPXMove? OR SPYMove? stuff added on 6/16/95 obviously for repeat Z operations!
Jim Radcliffe}

{9/11/95
Initial: Prototrak Plus [PE] M808.85.01
Created: Prototrak Plus [PE] M808.85.02
Comment: Corrected repeat operations.
Deleted the SPXMove? OR SPYMove? descrimination of Rapid StrtPos in Milling Repeats.
Regardless of selection, feed connect or entry exit connect, we need to output a G0
to stop the machine for positioning on Z!
Jim Radcliffe}

{2/12/96, Updated .85 number to .86, no changes necessary, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '#;'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF MultipleParts? AND SubComment?
'( PART ' Tag# ' )' EOL
END
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

FormatArc:
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveXYZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

HandleCRC:
IF NOT Flag?('2')
SetFlag('2')
IF CutterRadiusCompensation?
CRCOn 'D.0005'
ELSE
CRCOff
END
END
RETURN

StdRapid:
IF XMove? OR YMove?
SeqC Rapid MoveXYZC HandleCRC EOL
END
RETURN

StdLine:
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC Feed MoveXYZC HandleCRC FeedRateC EOL
DecelMove2
END
SeqC Feed MoveXYZC HandleCRC DecelFeed EOL
ELSE
IF XMove? OR YMove?
SeqC Feed MoveXYZC HandleCRC FeedRateC EOL
END
END
RETURN

DoArc:
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc HandleCRC ArcFeedC EOL
DecelMove2
END
SeqC FormatArc HandleCRC DecelFeed EOL
ELSE
SeqC FormatArc HandleCRC ArcFeedC EOL
END
RETURN

StdArc:
IF FullArc?
EACHQuadrant
DoArc
NEXTQuadrant
ELSE
DoArc
END
RETURN

ToolPath2: {for AutoCycle element moves}
EACHFeat
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

EntryMove:
SeqC ZInC EOL
RETURN

CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
SeqC PRIME ZCP2 EOL
END
NextRep
ELSE
EntryMove
ToolPath2
END
SeqC AbsOrInc ZCP2 EOL
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
SetFlagF('2') { set to flag that CRC needs to be handled }
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
SeqC Rapid MoveSXYC EOL
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
CutAutoCycle
ELSE
IF NOT FirstFeat?
SeqC Rapid MoveSXYZC EOL {.80.01}
END
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqC 'G' NewWFO# EOL
END
END
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
WFOStuff
CheckPass
RETURN

DoOp:
IF FirstOperation?
Plane { no output }
CheckPass
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
SeqC CoolOff EOL
SeqC IncValue OfstOff EOL
END
DoOpComments
SeqC Rapid StrtPos EOL
ELSE
DoOpComments
DoPostScript
WFOStuff
Seq Rapid StrtPos OpToolID EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
{only need to set up for tool change on 1st part}
ELSE
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
END

{Start new Operation}

Plane { no output }
CheckPass
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
SeqC CoolOff EOL
SeqC IncValue OfstOff EOL
END
DoOpComments
SeqC Rapid StrtPos EOL
ELSE
DoOpComments
DoPostScript
WFOStuff
Seq Rapid StrtPos OpToolID EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC Rapid StrtPos OpToolID EOL
ELSE
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC Rapid StrtPos OpToolID EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC Rapid StrtPos EOL
END
END
END
END
END

{ Common Point for All Operations }

ResetCRCNum {call here to reset for each new operation only, call in tool path to reset for each repeat in an operation}
RapidF# {forces the output of a conditional feedrate for each operation}

IF Milling?
SeqC ZCP2C EOL
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
EACHRep
DoSubComment
IF NOT FirstCycle?
SeqC Rapid StrtPos EOL
IF NOT FeedConnect?
SeqC ZCP2C EOL
END
END
END
END
IF NOT AutoCycle?
EntryMove
END
ToolPath
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
SeqC
IF NOT FeedConnect?
PRIME ZCP3C
END
EOL
NEXTRep
END
END
SeqC ZCP3C EOL
ELSE
IF Drilling?
IF Repeats?
EACHRep
DoSubComment
END
GetCycle
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC DrillOff EOL
IF Repeats?
NEXTRep
END
SeqC ZCP3C EOL
END
END
RETURN

FinishLastOp:
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqC Rapid FirstHome EOL
END
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart? {no tool change after doing last part}
IF ProgStop?
SeqC 'M0' EOL
END
ELSE
EOP EOL
END
RETURN

DoToolsOps:
EachOp
IF GTEqual? Operation# Recall# Num#('1') AND LTEqual? Operation# Recall# Num#('2')
{Tools1stOp ² op ² ToolsLastOp}
DoOp
END
NextOp
RETURN

NextTools1stOp:
SetNextToolOp Operation#
RETURN

GetToolsOps:
EachOp
IF Equal? Operation# Recall# Num#('1') {if op = Tools1stOp}
IF GreaterThan? NextTools1stOp Recall# Num#('1') {if NextTools1stOp is greater Tools1stOp}
Save# Num#('2') SUB# NextTools1stOp Num#('1') {ToolsLastOp becomes NextTools1stOp less 1}
ELSE {else}
Save# Num#('2') Recall# Num#('3') {ToolsLastOp becomes ncCAMsLastOp}
END
END
NextOp
RETURN

DoTool:
IF NOT Flag?('1')
GetToolsOps
EachPart
TagInc
DoToolsOps
NextPart
IF LessThan? Recall# Num#('2') Recall# Num#('3') {if ToolsLastOp < ncCAMsLastOp}
Save# Num#('1') ADD# Recall# Num#('2') Num#('1') {Tools1stOp becomes NextTools1stOp}
ELSE {else}
SetFlag('1') {set DoneFlag}
END
TagInit
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetFlagF('1') {done flag}
ReverseXZArcs
InitWFONum
SetFlood
SkipZ
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
ProgID1 'G20' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
END
NextOp
IF MultipleParts?
IF AllToolsOnePart?
EachPart
TagInc
EachOp
DoOp
NextOp
FinishLastOp
NextPart
ELSE
IF OneToolAllParts?
EachOp
IF FirstOperation?
Save# Num#('1') Operation# {ncCAMs1stOp becomes Tools1stOp}
END
IF LastOp?
Save# Num#('3') Operation# {save ncCAMsLastOp}
END
NextOp
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
FinishLastOp
END
END
ELSE
EachOp
DoOp
NextOp
FinishLastOp
END
EOR EOL
CloseSub
Post2
IF UseComments?
SetScale('1')
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Close