{Change Comments ***********************************************************}

{6/16/93
Copied & modified: Fanuc 0M [R&S] M565.81.2
For: Modo
Machine: Router
Control: Fanuc 0M
Updated to Version 4.1 per Fanuc 6M M001.81.3 Format.
Deleted WorkFixtureOffset support.
Added CkProgNum sub called at FirstOperation.
Customer uses subroutines P1 to P4 and P11 to P14 based on controlling Tool# and which contain:
G92 X####.#### Y####.#### Z####.####
M99
Added ToolTable, ClampTools and MainTool subs, called at FirstOperation, NewTool and SameTool.
T1 to T4 are router bits and can be used in any combination.
T11 to T14 are drill bits and can be used in any combination.
Offsets 1 to 30 are used to control different combinations for either range.
Changed CRCOffsetC to ' D' Recall# Num#('1') at StdLine.
Added CkCRC sub to output output ' D' Recall# Num#('1') only when needed.
Deleted ResetCRCNum at ToolPath.
Deleted ArcIJC at FormatArc, forcing ArcRC.
Changed SetMaxRPM('10000') to SetMaxRPM('20000') at setup and initializations.
Added literal ' G20', Inch Mode, to safe start block at FirstOperation and NewTool.
Deleted ToolChng at FirstOperation and NewTool.
Deleted Coolant support.
Moved Speed SpinOn to StrtPos block at FirstOperation and NewTool.
Changed OfstOn to ZCP1 at FirstOperation, NewTool and SameTool.
Moved ZCP1 to StrtPos block at FirstOperation, NewTool and SameTool.
Added Rapid ' X0 Y0' at NewTool, prior to OfstOff block.
Moved SpinOff to IncValue OfstOff at NewTool, SameTool and end of prog.
Deleted ToolChangeAtHome at NewTool and end of Prog.
Added literal ' G28 X0 Y0' at end of Prog.
Added Preset ' X0 Y0 Z0' at end of Prog.
Added AbsOrInc at end of Prog.
Added SetLineStrtChr('
') and Retag at end of Prog.
This is ASCII('10') which is needed for proper loading into IBM application.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Recall#,5)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

CkProgNum:
IF LessThan? Program# Num#('15')
' ' EOL
' ( NOTE: You have entered Program# ' Program# '. )' EOL
' ( The main program, and any subroutines may cause conflicts with )' EOL
' ( the Tool Preset Subroutines P1, P2, P3, P4, P11, P12, P13 and P14. )' EOL
' ( It is recommended that you enter Program# 15 or greater. )' EOL
' ' EOL
END
RETURN

ToolTable:
Save# Num#('1') Num#('0')
Save# Num#('2') Num#('0')
Save# Num#('3') Num#('0')
Save# Num#('4') Num#('0')
IF GreaterThan? Tool# Num#('30')
' ' EOL
'( NOTE: You have selected Tool# ' Tool# ' )' EOL
'( which is outside of the Tool Table Range. )' EOL
'( It is recommended that you select a Tool between 1 and 30. )' EOL
'( 1 = T1 )' EOL
'( 2 = T2 )' EOL
'( 3 = T3 )' EOL
'( 4 = T4 )' EOL
'( 5 = T1 T2 )' EOL
'( 6 = T1 T3 )' EOL
'( 7 = T1 T4 )' EOL
'( 8 = T2 T3 )' EOL
'( 9 = T2 T4 )' EOL
'( 10 = T3 T4 )' EOL
'( 11 = T11 )' EOL
'( 12 = T12 )' EOL
'( 13 = T13 )' EOL
'( 14 = T14 )' EOL
'( 15 = T11 T12 )' EOL
'( 16 = T11 T13 )' EOL
'( 17 = T11 T14 )' EOL
'( 18 = T12 T13 )' EOL
'( 19 = T12 T14 )' EOL
'( 20 = T13 T4 )' EOL
'( 21 = T1 T2 T3 )' EOL
'( 22 = T1 T2 T4 )' EOL
'( 23 = T1 T3 T4 )' EOL
'( 24 = T2 T3 T4 )' EOL
'( 25 = T1 T2 T3 T4 )' EOL
'( 26 = T11 T12 T13 )' EOL
'( 27 = T11 T12 T14 )' EOL
'( 28 = T11 T13 T14 )' EOL
'( 29 = T12 T13 T14 )' EOL
'( 30 = T11 T12 T13 T14 )' EOL
' ' EOL
ELSE
IF GTEqual? Tool# Num#('1')
IF LTEqual? Tool# Num#('4')
Save# Num#('1') Tool#
END
END
IF Equal? Tool# Num#('5')
Save# Num#('1') Num#('1')
Save# Num#('2') Num#('2')
END
IF Equal? Tool# Num#('6')
Save# Num#('1') Num#('1')
Save# Num#('2') Num#('3')
END
IF Equal? Tool# Num#('7')
Save# Num#('1') Num#('1')
Save# Num#('2') Num#('4')
END
IF Equal? Tool# Num#('8')
Save# Num#('1') Num#('2')
Save# Num#('2') Num#('3')
END
IF Equal? Tool# Num#('9')
Save# Num#('1') Num#('2')
Save# Num#('2') Num#('4')
END
IF Equal? Tool# Num#('10')
Save# Num#('1') Num#('3')
Save# Num#('2') Num#('4')
END
IF GTEqual? Tool# Num#('11')
IF LTEqual? Tool# Num#('14')
Save# Num#('1') Tool#
END
END
IF Equal? Tool# Num#('15')
Save# Num#('1') Num#('11')
Save# Num#('2') Num#('12')
END
IF Equal? Tool# Num#('16')
Save# Num#('1') Num#('11')
Save# Num#('2') Num#('13')
END
IF Equal? Tool# Num#('17')
Save# Num#('1') Num#('11')
Save# Num#('2') Num#('14')
END
IF Equal? Tool# Num#('18')
Save# Num#('1') Num#('12')
Save# Num#('2') Num#('13')
END
IF Equal? Tool# Num#('19')
Save# Num#('1') Num#('12')
Save# Num#('2') Num#('14')
END
IF Equal? Tool# Num#('20')
Save# Num#('1') Num#('13')
Save# Num#('2') Num#('14')
END
IF Equal? Tool# Num#('21')
Save# Num#('1') Num#('1')
Save# Num#('2') Num#('2')
Save# Num#('3') Num#('3')
END
IF Equal? Tool# Num#('22')
Save# Num#('1') Num#('1')
Save# Num#('2') Num#('2')
Save# Num#('3') Num#('4')
END
IF Equal? Tool# Num#('23')
Save# Num#('1') Num#('1')
Save# Num#('2') Num#('3')
Save# Num#('3') Num#('4')
END
IF Equal? Tool# Num#('24')
Save# Num#('1') Num#('2')
Save# Num#('2') Num#('3')
Save# Num#('3') Num#('4')
END
IF Equal? Tool# Num#('25')
Save# Num#('1') Num#('1')
Save# Num#('2') Num#('2')
Save# Num#('3') Num#('3')
Save# Num#('4') Num#('4')
END
IF Equal? Tool# Num#('26')
Save# Num#('1') Num#('11')
Save# Num#('2') Num#('12')
Save# Num#('3') Num#('13')
END
IF Equal? Tool# Num#('27')
Save# Num#('1') Num#('11')
Save# Num#('2') Num#('12')
Save# Num#('3') Num#('14')
END
IF Equal? Tool# Num#('28')
Save# Num#('1') Num#('11')
Save# Num#('2') Num#('13')
Save# Num#('3') Num#('14')
END
IF Equal? Tool# Num#('29')
Save# Num#('1') Num#('12')
Save# Num#('2') Num#('13')
Save# Num#('3') Num#('14')
END
IF Equal? Tool# Num#('30')
Save# Num#('1') Num#('11')
Save# Num#('2') Num#('12')
Save# Num#('3') Num#('13')
Save# Num#('4') Num#('14')
END
END
RETURN

ClampTools:
SeqC SubCall ' P' Recall# Num#('1')
IF NotEqual? Recall# Num#('2') Num#('0')
' T' Recall# Num#('2')
END
EOL
IF NotEqual? Recall# Num#('3') Num#('0')
SeqC ' T' Recall# Num#('3') EOL
END
IF NotEqual? Recall# Num#('4') Num#('0')
SeqC ' T' Recall# Num#('4') EOL
END
RETURN

MainTool:
' T' Recall# Num#('1')
RETURN

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
IF NotEqual? Recall# Num#('1') Num#('0')
'( TOOL ' Recall# Num#('1') ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
ELSE
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF NotEqual? Recall# Num#('2') Num#('0')
'( TOOL ' Recall# Num#('2') ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF NotEqual? Recall# Num#('3') Num#('0')
'( TOOL ' Recall# Num#('3') ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF NotEqual? Recall# Num#('4') Num#('0')
'( TOOL ' Recall# Num#('4') ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
END
SeqC CRCOffC EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP: { EquallySpacedOffsets Only }
NewProg
SeqC SubCall CallLab RepLab Parts EOL
StartSub
RETURN

CloseMP:
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC ArcRC
RETURN

CkCRC:
CRCOnC
IF NOT EmptyLine?
' D' Recall# Num#('1')
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CkCRC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC CkCRC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CkCRC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
IF FeedConnect?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC Rapid ZCP2PlusInc EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('20000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
CkProgNum
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq Plane ' G20' CRCOff ' G80' EOL
ToolTable
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
ClampTools
SeqC Rapid AbsOrInc StrtPos ZCP1 MainTool Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC Rapid ' X0 Y0' EOL
SeqC IncValue OfstOff SpinOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
SeqC Rapid ' Z0' EOL
DoEndOpPS
IF LAST ProgStop?
SeqC ' M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

Seq Plane ' G20' CRCOff ' G80' EOL
ToolTable
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
ClampTools
SeqC Rapid AbsOrInc StrtPos ZCP1 MainTool Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
IF NewToolOffset? { New Combination, same as NewTool without move to Home }
SeqC IncValue OfstOff SpinOff EOL
SeqC Rapid ' Z0' EOL
SeqC ' M0' EOL

{Start new Operation}

Seq Plane ' G20' CRCOff ' G80' EOL
ToolTable
GetStartOfSameTool
ClampTools
SeqC Rapid PlaneC AbsOrInc StrtPos ZCP1 MainTool SpeedC SpinOn EOL
ELSE
SeqC IncValue OfstOff SpinOff EOL
SeqC ' M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqC Rapid PlaneC AbsOrInc StrtPos ZCP1 SpeedC SpinOn EOL
END
ELSE
IF NewToolOffset? { New Combination, same as NewTool without move to Home }
SeqC IncValue OfstOff SpinOff EOL
SeqC Rapid ' Z0' EOL

{Start new Operation}

Seq Plane ' G20' CRCOff ' G80' EOL
ToolTable
GetStartOfSameTool
ClampTools
SeqC Rapid PlaneC AbsOrInc StrtPos ZCP1 MainTool SpeedC SpinOn EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC Rapid PlaneC AbsOrInc StrtPos SpeedC EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
SeqC CRCOffC EOL
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC Rapid AbsOrInc StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
TrackZNO# FIRST SPZ# {.81.2}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC ' G80' EOL
IF Repeats?
FinishSubG92
END
SeqC RapidC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC IncValue OfstOff SpinOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqC ' G28 X0 Y0' EOL
SeqC Preset ' X0 Y0 Z0' EOL
SeqC AbsOrInc EOL
IF ProgStop?
SeqC ' M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
SetLineStrtChr('
')
Retag
SetLineStrtChr('')
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'
( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'
( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'
( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END