{Change Comments ***********************************************************}

{12/4/96,
Modified: LongHand (PW) C001.12b
Created: LongHand (PW) C001.12c
Added .14 Additions:
NOTE: These changes have not been compiled yet.
Changed FORMAT#2 from ###.###;0. to #####.###;0. at Prog Numeric Format Definitions.
Changed FORMAT#3 from *###.###;0. to *#####.###;0. at Prog Numeric Format Definitions.
Deleted Flag(1) for CRCOffsetC at ckCRC and ckCRCNum subs and at setup and initializations.
Added NOT LastFeat? AND Equal? SPZ# EPZ# condition at ckCRCNum sub.
Moved contents of FormatLine back to ToolPath LineFeat.
Deleted version comments.
Simplified ExitMove sub.
Deleted OpenMP and CloseMP commands.
Simplified EndPartSub sub.
Modified WorkFixtureOffset logic.
Added Flag(1) for WFOStuff at setup and initializations.
Added WFONum sub.
Rewrote logic at WFOStuff sub.
Added EOL to NewWFO MP WFOStuff sub Warning.
Deleted SeqC and EOL at WFOStuff sub.
Added Flag(1) logic at start of EachOp/NextOp Loop.
Moved WFOStuff after MP-OTAP-FU condition at FirstOperation and NewTool.
Added WFOStuff for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added AbsOrInc Rapid to StrtPos block for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added SeqC and EOL at WFOStuff calls at GetStartOfSameTool, FirstOperation and NewTool.
Moved Speed SpinOn after MP-OTAP-FU condition at FirstOperation and NewTool.
Added Speed SpinOn for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added SetMaxFeed(12700) for Metric VNC files.
DWB}

{3/13/97,
Modified: LongHand (PW) C001.12c
Created: LongHand (PW) C001.12d
Added TrackXNO# to FORMAT#4 at Prog Numeric Format Definitions.
Added TrackYNO# to FORMAT#4 at Prog Numeric Format Definitions.
Added IF FirstOperation? OR EquallySpacedOffsets? condition at MPallTools1P sub.
Post was not outputting WFOStuff for NewTool Operations during MP-ESO-OPAT condition.
Deleted IF WorkFixtureOffsets? condition at DoNewPart sub.
Post was not outputting WFOStuff for NewPart during MP-ESO-OTAP condition.
Deleted all occurances of TagInit, TagInc and Tag#.
Replaced with PartNum# for better WFO handling.
DWB}

{4/17/97,
Modified: LongHand (PW) C001.12d
Created: LongHand (PW) C001.12e
Added SetPass1 at OpGuts IF Milling AND IF AutoCycle.
This fixed problem with returning to FirstHome at end of prog when final Operation consisted of
NoRepAutoCycle or XYZRepAutoCycle types.
ZonlyRepAutoCycle type did not seem to create this problem.
DWB}

{7/15/97
Modified: LongHand (PW) C001.12e
Created: LongHand (PW) C001.12f
For: Gibbs & Associates
Versions: Catalyst v3.35C/ComPost2 MSL 68K
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.10/ComPost2 MSL 68K
Versions: ncCad 4.33.02/ncEDM 4.33.01/ncPost 4.33.10/ComPost2 MSL 68K
Versions: ncCad 4.33.02/ncMAT 4.21.19/ncPost 4.33.10/ComPost2 MSL 68K
Improved handling of MultipleParts OneToolAllParts Output.
Rewrote MPLoop sub.
Simplified logic for handling OneToolAllParts situations.
No more need to keep track of Current Tool FirstOp, CurrentOp and LastOp.
Only using Vars(1) and (2).
Var(3) and Flags(2) and (3) no longer needed.
Deleted Var(3), NextToolOp# at ProgStart.
Deleted Flags(2) and (3) at ProgStart.
Deleted DoParts sub.
No longer necessary.
Deleted GetToolFirstOp sub.
No longer necessary.
Deleted GetToolLastOP sub.
No longer necessary.
Changed Var(8) to Var(3), LongHand Pecking at DoPeck, DrillFeature and ProgStart.
Changes made per Fanuc 6M NoSubs M877.89.1:
Fixed bug during MultipleParts AllToolsOnePart Output.
Commented out NOT FirstPart call to InitOp at MPallTools1P.
Was causing ncPost to beep and issue a series of alerts at start of additional Parts.
Problem disappeared if output was aborted and restarted, second processing of output, or
processing of output after any other MultipleParts/NoMPs situations.
Added FirstPart AND FirstOperation condition for calling InitOp at MPLoop sub.
Fixed MultipleParts WorkFixtureOffset bug.
Rewrote MPLoop sub.
Changed EachPart/NextPart loop to EachWFO/NextWFO loop.
EachPart/NextPart loop was causing coordinates of additional Parts to be affected by any
values entered into invisible EquallySpacedOffsets Edit Fields.
Deleted BadMPWFOReport sub and calls to same.
Deleted output comment regarding MultipleParts WorkFixtureOffsets and values in
EquallySpacedOffsets Edit Fields.
Rewrote XYZRepAutoCycle sub.
No longer necessary to Track Tool between Parts.
Added RapidC Move to StrtPos and ZCP2C inside of EachRep/NextRep loop just prior to
EACHFeat/NEXTFeat Loop.
Deleted TrackNo# FORMULAs of Vars(4) through (6).
Added CRCOffC and call to ExitMove inside of EachRep/NextRep loop just after EACHFeat/NEXTFeat
Loop.
Added SetSRSubMove at end of AutoCycCutSub2.
Deleted Vars(6) and (7) at end of ToolPath.
Deleted Vars(4) through (7) at ProgStart.
DWB}

{8/7/97,
Modified: LongHand (PW) C001.12f
Created: LongHand (PW) C001.12g
Changed Flag(1) to Flag(2).
Final changes to correct MultipleParts AllToolsOnePart Output bug.
Placed IF ToolChangeAtHome? SetHome logic inside EachOp/IF FirstOperation?/NextOp loop at InitOp
sub.
Deleted InitOp calls at MPallTools1P, MP1ToollAllPfu, MP1ToollAllPXcp, NoMPs and MPLoop subs.
Added InitOp call following ProgStart call at Start of executable Prog, Top Level.
Other Fine Tuning Modifications.
Deleted OpenSub command at InitOp sub.
Deleted LoadFeat Home code at NewToolOp2 sub.
Changed MoveXY to PRIME Home at NewToolOp2 sub.
Moved WFOStuff call from SameToolOp3 sub to SameToolOp2 sub.
Deleted LoadFeat FirstHome code at End2 sub.
Changed MoveXY to PRIME FirstHome at End2 sub.
Deleted Post command at End3 sub.
DWB}

{10/18/97,
Modified: LongHand (PW) C001.12g
Created: LongHand (PW) C001.12h
For: Gibbs & Associates
Versions: Catalyst v4.21.03(mac)/ComPost2 MSL 68K
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.10/ComPost2 MSL 68K
Added routines for Non-AutoCycle FeedConnect Repeats w/ ZMoves.
Routines needed to make sure that Tool clears floor of contour.
Added FlagF(3) at ProgStart.
Standard Initialization.
Added comparison bewteen FIRST SPZ# and final EPZ# at end of ToolPath.
Flag(3) set if Tool needs to move up to get to FIRST SPZ#.
Added Flag(3) test at ExitMove.
Flag(3) moves Tool up prior to StrtPos.
FlagF(3) leaves Tool at higher final EPZ#.
Also sets Flag(3) for EntryMove test to move Tool to ZIn following move to StrtPos.
Added Flag(3) EntryMove test at XYZRep.
Moves Tool to ZIn following move to StrtPos.
Added FlagF(3) at end of XYZRep.
Clears Flag(3) to avoid problems with future Operations.
DWB}

{11/12/97
Modified: LongHand (PW) C001.12h
Created: LongHand (PW) C001.12i
For: Gibbs & Associates
Versions: Catalyst v4.21.11(mac)/ComPost2 MSL 68K
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.10/ComPost2 MSL 68K
Eliminated all considerations regarding Non-AutoCycle ZShifting FeedConnect Repeats with ZMove.
Fanuc 6M M001.89 does not raise Tool for safety clearance and neither should this post.
User is responsible for making sure Tool will clear or should select Entry/Exit Connect.
Deleted all related changes made on 10/18/97.
Added condition to test for NOT EmptyLine at EntryMove sub.
This suppresses FeedEntC only block in case ZEndPoint of Previous Repeat equals ZStartPoint of
Next Repeat.
Deleted Move to ZInC for Non-AutoCycle FeedConnect Repeats with ZMoves at ExitMove sub, see 12/9/93.
Added IF NOT NoZMoves? condition at XYZRep sub.
Calls EntryMove sub.
Deleted FeedEntC on FeedC MoveSXYC block for additional FeedConnect Repeats at XYZRep sub.
DWB}

{1/15/98
Modified: LongHand (PW) C001.12i
Created: LongHand (PW) C001.12j
For: Gibbs & Associates
Versions: Catalyst v3.35C/ComPost2 1.1b3
Versions: Catalyst v4.21.30(mac)/ComPost2 1.1b3
Deleted SetSRSubMove at end of AutoCycCutSub2.
DWB}

{1/29/98
Updated: LongHand (PW) C001.12j
Created: LongHand (PW) C001.15
Updated for Catalyst v3.35C per LongHand M001.12j Format.
Added Var(4) for conditional SpeedC test at ProgStart sub.
Added Var(5) for conditional CS# test at ProgStart sub.
Added Flag(1) for conditional ProgStop test at ProgStart sub.
DWB}

{5/15/98,
Updated: LongHand (PW) C001.15
Created: Fanuc 6M LH (PW) CV83.16
For: Gibbs & Associates
Versions: Catalyst v4.23.13(mac)/ComPost2 1.1b3
Corrected support for Linear ChangeCS.
Linear ChangeCS covers Multiple CSGroups in One Plane.
Post does not output CSWFOComments, G52Comments or G52Stuff for this situation.
IF AAxisAvail? OR BAxisAvail? does not automatically support this.
Deleted IF AAxisAvail? OR BAxisAvail? at DoCSComment.
Post retracts Tool at SameTool for this situation.
Retraction is only necessary for AChange OR BChange situations.
Changed ChangeCS? to AChange? OR BChange at SameToolOp1.
Changed ChangeCS? to AChange? OR BChange at SameToolOp3.
Simplified ClearCSOffset occurance.
ClearCSOffset occurs at 3 different places, including at the output of CSComments.
Discovered that CheckPass is a good place for all situations.
Deleted ClearCSOffset at CSG52, DoCSWFOComment and CSComments Procedures.
Added ClearCSOffset at CheckPass.
Moved IF FirstOperation? OR NewTool? OR ChangeCS? Boolean from CSG52 to G52Stuff.
Moved call to CSComments Procedure to inside IF UseComments? Boolean at DoOpComments.
To suppress when Comments are turned off.
Added AbsValueC, IncValueC and AbsOrIncC Procedures.
Simplifies readability of Prog.
Reduces redundancy of output.
Allows us to return to earlier versions
Improves upon earlier problem with incremental output of ShiftPC command at CloseMP while
allowing us to return to .85 OfstOff blocks.
AbsValueC called from AbsOrIncC.
IncValueC called from AbsOrIncC, DoAbsOrInc and DoDrillAbsOrInc.
IncValueC called for OfstOff Blocks at NewToolOp1, two places at SameToolOp1 and DoAbsOrInc.
AbsOrIncC called for ShiftPC Block at CloseMP.
AbsOrIncC called from DoAbsOrInc, DoDrillAbsOrInc and RestoreAbsOrInc.
AbsOrIncC called for Home Block at NewToolOp2.
AbsOrIncC called for FirstHome Block at End2.
Additional modifications.
Added CRCOffC at AutoCycCutSub2.
Corrects unique situation in ZonlyRepAutoCycle where one Operation is CRCLeft and LastFeat
is an ArcFeat followed by another Operation that is CRCRight.
CRCOffC did not get output at end of CRCLeft Operation and CRCOnC did not get output at start
of CRCRight Operation.
Oddly, CRCOnC only outputs if CRCOffC has been output, not if CRCSide changes.
Moved Boolean Test of Flag(3) at MP1ToollAllPfu and MP1ToollAllPXcp to MPLoop.
Added following Procedures:
NewPart1
Called at MPLoop.
Similar to SameTool1.
NewPart2
Called at MPLoop.
Similar to SameTool2.
NewPart3
Called at MPLoop.
Similar to SameTool3.
6/18/98
Changed to Lowercase Procedure Names.
Added comments to all SetFlag, SetFlagF and IF Flag statements.
Added Flag(6) to switch from B-Style to C-Style at progStart.
TRUE = B-Style Output, FALSE = C-Style Output.
Added Flag(7) to switch from local coordinates to uncompensated coordinates at progStart.
TRUE = Local WFO Coordinates, FALSE = D-Style Output.
Added pertinent comments at progStart.
Added IF Equal? NumOfCS# Num#('1') at progStart.
This is a standard 3 Axis - Output M-Style.
Changed literal 'G80' to DrillOff at end of IF Drilling.
Changed literal 'G80' to DrillOff at firstOp1 and newToolOp3.
To allow for change in FORM without having to recompile.
Changed SpeedC to Speed at for LAST ProgStop condition at sameToolOp3.
6/30/98
Deleted Gibbs System XYRepeat support.
Virtual only support ZShiftOnly Repeats.
Deleted CycleWarning procedure.
Added cutAutoCycle procedure.
Called for all AutoCycle Operations.
Supports NoRepeat and ZShiftOnly Repeats.
Replaces noRepAutoCycle and zonlyRepAutoCycle procedures
Deleted xYZRepAutoCycle procedure.
Changed XYZRep to ZOnlyRep.
Supports ZShiftOnly Repeats.
Moved LongDrillStuff from OpGuts to LongDrillStuff.
Rewrote OpGuts Procedure.
Deleted Drilling Repeats at IF Drilling.
Rewrote PostScript instructions at progStart.
7/22/98
Reverted back to Gibbs System XYRepeat support.
IF setup correctly, Virtual will support XShift and/or YShift Repeats for both Contour and
Patterns.
Rules for correct setup (as best as I understand at the moment).
Geometry CSGroup must be oriented to a plane that intersects CS#1 in a perpendicular direction.
Example, XZPlane and YZPlane, and any oriented rotation of either Plane around the XYPlane.
Any change in the ZPitch of the Origin will cause ZShiftOnly Repeat Operation.
Set Desired ZStep so that Operation will result in multiple passes.
NOTE: If correctly setup, ZStep would be misleading.
Step will be in line with depth axis of CSGroup.
Restored with slight modifications the xyRep Procedure.
Restored with slight modifications the xyRep Procedure.
Restored related code to OpGuts Procedure.
ZShiftOnly Contour Operations remain Full SepSub.
Any customer requesting G92 Style will require copying code from archives.
Deleted Deceleration from ToolPath LineFeat and ArcFeat.
There are plans to support this in the future through the use of Construction Tools in the
Virtual Process.
DWB}

{8/18/98,
Initial : Fanuc 6M LH (FW) CV83.16
Created: Fanuc 0M LW LH [RI] CU58.16
Machine: Leadwell 500 Horizontal Machining Center
Customer: Rehmann Industries, Bob Rehmann or Jim Helvey 810/774-2220

Changes to "Form":

1. Under Default Formats, changed D, G, H, M, & T Format to #00

Changes to "Prog":

1. Changed work fixture offset call from G54 thru G59 to M98P3001 thru M98P3999
for PalletIn(1) and M98P4001 thru M98P4999 for PalletIn(2).
2. Changed max WFO from 6 to 999.
3. Added SetPalletIn('1').
4. Changed FirstOp1, 2, and 3 to match the customer spec.
5. Changed NewToolOp1, 2, 3, 4, and 5 to match the customer spec.
6. Changed SameToolOp1, 2, and 3 to match the customer spec.
7. Changed End1 and 2 to match the customer spec.
8. Added M29 output for Rigid Tapping.
9. Added clamp/unclamp codes and switched the output of A and B.
10. Added Save#('11') & 12 for the current rotary location.
If rotary not at zero before pallet change or at program End,
move it to A0 or B0 by new sub, moveRotaryHome.
11. Added PalletOutF and IF PalletOut? at End3 to output M60.
12. Added IF PalletIn? at NewToolOp3 to output pallet change sequence.
13. Updated PostScript to the use of Pallets.
JHE}

{Prog Numeric Format Definitions ****************************}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,3)
FORMAT(CSOffsetB#,3)
FORMAT(ToolDiameter#,4)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackXNO#,4)
FORMAT(TrackYNO#,4)
FORMAT(TrackZNO#,4)
FORMAT(TrackZ#,4)
FORMAT(Recall#,5)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(PartNum#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)

{Prog Subroutines *************************}

restoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

cSPartNum#:
ADD# CS# MUL# NumOfCS# SUB# PartNum# Num#('1')
RETURN

cSWFO:
IF Equal? Pallet# Num#('1') {Added this check - JHE}
'M98P' ADD# CSPartNum# Num#('3000') {Changed from 'G' and '53' - JHE}
ELSE
'M98P' ADD# CSPartNum# Num#('4000')
END
RETURN

wFO:
IF Equal? Pallet# Num#('1') {Added this check - JHE}
'M98P' ADD# PartNum# Num#('3000') {Changed from 'G' and '53' - JHE}
ELSE
'M98P' ADD# PartNum# Num#('4000')
END
RETURN

moveRotaryHome: {Added this sub routine - JHE}
IF AAxisAvail?
IF NotEqual? Recall# Num#('11') Num#('0')
SeqC 'M22' EOL
SeqC AbsValue Rapid 'B0.' EOL
SeqC 'M21' EOL
END
END
IF BAxisAvail?
IF NotEqual? Recall# Num#('12') Num#('0')
SeqC 'M22' EOL
SeqC AbsValue Rapid 'A0.' EOL
SeqC 'M21' EOL
END
END
RETURN

wFOStuff:
IF Flag?('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF NOT SameTool?
IF WFOCS?
cSWFO
ELSE
IF MultipleParts? AND WorkFixtureOffsets?
wFO
ELSE
wFO {Changed from WFO1 - JHE}
END
END
ELSE
IF WFOCS?
IF ChangeCS?
cSWFO
END
END
END
END
SetFlagF('2') { Do not output WFO second time wFOStuff is called for MP-WFO-OTAP-ECP }
RETURN

cSG52:
SeqC 'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
RETURN

g52Stuff:
IF Flag?('7') AND NOT WFOCS?
IF FirstOperation? OR NewTool? OR ChangeCS?
IF MultipleParts?
IF WorkFixtureOffsets?
cSG52
END
ELSE
cSG52
END
END
END
RETURN

doCSComment:
'( CS#' CS# ' - ' CSComment$ ' )' EOL
RETURN

doCSWFOComment:
IF FirstOperation? OR NewTool? OR ChangeCS?
'( ' cSWFO ' = X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ#
IF Flag?('6') { TRUE = B-Style Output, FALSE = C-Style Output }
IF AAxisAvail?
' B' CSOffsetA#
END
IF BAxisAvail?
' A' CSOffsetB#
END
END
' )' EOL
END
RETURN

cSComments:
doCSComment
IF WFOCS?
doCSWFOComment
END
RETURN

doPartCycleComment:
IF MultipleParts? AND UseComments? AND SubComment?
'( PART NO. ' PartNum# ' )' EOL
END
RETURN

doCycleComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

doOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
restoreScale
cSComments
END
RETURN

cSAngleA:
IF AAxisAvail?
IF Flag?('6') AND WFOCS? { TRUE = B-Style Output, FALSE = C-Style Output }
'B0.'
ELSE
SeqC 'M22' EOL {unclamp rotary - JHE}
SeqC AbsValue Rapid 'B' CSOffsetA# EOL {yes, output 'B' - JHE}
SeqC 'M21' EOL {clamp rotary - JHE}
END
END
Save# Num#('11') CSOffsetA#
RETURN

cSAngleAC:
IF AChange?
cSAngleA
END
RETURN

cSAngleB:
IF BAxisAvail?
IF Flag?('6') AND WFOCS? { TRUE = B-Style Output, FALSE = C-Style Output }
'A0.'
ELSE
SeqC 'M22' EOL {unclamp rotary - JHE}
SeqC AbsValue Rapid 'A' CSOffsetB# EOL {yes, output 'A' - JHE}
SeqC 'M21' EOL {clamp rotary - JHE}
END
END
Save# Num#('12') CSOffsetB#
RETURN

cSAngleBC:
IF BChange?
cSAngleB
END
RETURN

pSInit:
NewWFOF
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

pSStuff:
RETURN

doPostScript:
pSInit
EachPS
SeqC PostScript EOL
pSStuff
NextPS
RETURN

doEndOpPS:
pSInit
EachEOPS
SeqC EndOpPS EOL
pSStuff
NextPS
RETURN

pRIMEZCP2:
IF Flag?('7')
PRIME ZCP2
ELSE
'Z' TrackZ# ADD# CSOffsetZ# PRIME ClearancePlane2#
END
RETURN

LoadpRIMEZCP2:
IF Flag?('7')
LoadFeat Num#('0') Num#('0') PRIME ClearancePlane2#
ELSE
LoadFeat Num#('0') Num#('0') ADD# CSOffsetZ# PRIME ClearancePlane2#
END
RETURN

entryMove:
IF FeedEntry?
SeqC FeedC ZInC
IF NOT EmptyLine? { Mostly for FeedConnect ZShiftOnly with ZMove }
FeedEntC
END
EOL
ELSE
SeqC RapidC ZInC EOL
END
RETURN

exitMove:
IF NOT FeedConnect?
CRCOffC
IF FIFO?
FeedC pRIMEZCP2 FeedEntC
ELSE
RapidC pRIMEZCP2
END
END
RETURN

exitMove2:
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
RETURN

absValueC:
IF NOT AbsValue?
AbsValue
END
RETURN

incValueC:
IF AbsValue?
IncValue
END
RETURN

absOrIncC:
IF AbsoluteMoves?
absValueC
ELSE
incValueC
END
RETURN

formatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
RETURN

toolPath:
EACHFeat
IF PointFeat? { Drilling Only }
SeqC MoveSXYZC EOL
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
SeqC formatArc ArcFeedC EOL
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

autoCycCutSub1: {part 1}
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
IF Repeats? AND ZShiftOnly?
entryMove
END
SeqC IncValue EOL
RETURN

autoCycCutSub2: {part 2}
SeqC AbsOrInc CRCOffC
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
EOL
SetSRSubXY {restore SR to 1st position value}
ReSetPass2 {restore for positioning moves}
RETURN

milling:
entryMove
toolPath
RETURN

xyRep:
FindAnyZMoves
EachRep
DoCycleComment
IF FirstCycle?
EntryMove
ELSE
CRCOffC
IF FeedConnect?
IF SPXMove? OR SPYMove?
SeqC FeedC MoveSXYC EOL
END
IF NOT NoZMoves?
EntryMove
END
ELSE
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
IF FeedEntry?
SeqC ZCP2C EOL
END
EntryMove
END
END
ToolPath
SeqC ExitMove EOL
NextRep
RETURN

xyRepAutoCycle:
EachRep
DoCycleComment
IF NOT FirstCycle?
IF FIFO?
Rapid
END
SeqC RapidC StrtPos EOL
IF NOT FeedConnect?
SeqC ZCP2C EOL
END
END
EACHFeat
IF NOT FirstFeat?
DoCycleComment
END
IF SPXMove? OR SPYMove?
IF FIFO?
Rapid
END
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
Milling
AutoCycCutSub2
NEXTFeat
SeqC CRCOffC
LoadpRIMEZCP2
IF ZMove?
ExitMove
END
EOL
NextRep
RETURN

cutAutoCycle:
EACHFeat
doCycleComment
IF SPXMove? OR SPYMove?
IF FIFO?
Rapid
END
SeqC RapidC MoveSXYC EOL
END
autoCycCutSub1
IF Repeats?
IF ZShiftOnly?
EachRep
IF NOT FirstCycle?
IF FeedConnect?
doCycleComment
IF SPXMove? OR SPYMove?
SeqC FeedC MoveSXYC FeedEntC EOL
END
AbsOrInc
ELSE
SeqC AbsOrInc exitMove EOL
doCycleComment
IF SPXMove? OR SPYMove?
SeqC IncValue RapidC MoveSXYC EOL
AbsOrInc
END
IF FeedEntry? AND NOT FIFO?
SeqC RapidC ZCP2 EOL
END
END
entryMove
SeqC IncValue EOL
END
toolPath
NextRep
END
ELSE
milling
END
autoCycCutSub2
NEXTFeat
RETURN

zOnlyRep:
EachRep
doCycleComment
IF NOT FirstCycle?
CRCOffC
IF SPXMove? OR SPYMove?
IF FeedConnect?
FeedC
ELSE
RapidC
END
SeqC MoveSXYC EOL
END
IF FeedEntry? AND NOT FeedConnect?
SeqC ZCP2C EOL
END
END
entryMove
toolPath
SeqC exitMove EOL
NextRep
RETURN

longDrillStuff:
SeqC DrillCP EOL
GetCycle
SeqC StrtPosC EOL
toolPath
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
SeqC RapidC ZCP3C EOL
END
RETURN

drillStuff:
SeqC DrillCP EOL
GetCycle
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
TrackZNO# FIRST SPZ# {.81.2}
RETURN

setDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

checkPass: {use the correct StrtPos}
IF AutoCycle?
SetPass2
ELSE
SetPass1
END
IF Flag?('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
ClearCSOffset
END
RETURN

opGuts:
ResetCRCNum
RapidF# { No Output }
IF Milling?
SeqC ZCP2C EOL
IF AutoCycle?
IF Repeats?
IF ZShiftOnly?
cutAutoCycle
ELSE
xyRepAutoCycle
END
IF NOT FeedConnect?
SeqC exitMove2 EOL
END
ELSE
cutAutoCycle
SeqC exitMove2 EOL
END
SetPass1
ELSE { NOT AutoCycle }
IF Repeats?
IF ZShiftOnly?
zOnlyRep
ELSE
xyRep
END
ELSE
milling
END
SeqC CRCOffC exitMove2 EOL
END
ELSE
IF Drilling?
drillStuff
toolPath
setDrillEndOpZ
SeqC DrillOff Rapid ZCP3 EOL
END
END
RETURN

progStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
Save# Num#('1') Num#('0') { MultipleParts Current Tool FirstOp# }
Save# Num#('2') Num#('0') { MultipleParts ToolOp# Counter }
Save# Num#('3') Num#('0') { LongHand PeckCycle }
SetFlagF('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
SetFlag('3') { Incrementing WFOs in effect }
SetFlag('4') { This post supports IncWFO/DecWFO }
SetFlagF('6') { TRUE = B-Style Output, FALSE = C-Style Output }
SetFlag('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
IF PSComment? AND UseComments?
'Utility Data:' EOL
' At Op Start: All literals and commands will appear at the beginning of the operation.' EOL
' At Op End: All literals and commands will appear at the end of the operation.' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' ' EOL
'Palletin(1) or PIN(1) with first tool (default): ' EOL
' Output fixture offset from 3001. ' EOL
'Palletin(2) or PIN(2) with first tool: ' EOL
' Output fixture offset from 4001. ' EOL
'PIN(1) or PIN(2) with any other tool: ' EOL
' Output pallet change sequence and switch fixture offset numbers. ' EOL
'PalletOut or POUT with last operation: ' EOL
' Output pallet change sequence before program end. ' EOL
END
IF Flag?('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
IF Equal? NumOfCS# Num#('1') { 3 Axis Part - Output M-Style }
SetFlagF('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
ELSE
IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('999') {Changed from 6 - JHE}
SetWFOCS { use WFO for CS changes }
ELSE
SetFlagF('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to '
IF Flag?('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
'G52'
ELSE
'non-wfo'
END
' style output. )' EOL
END
END
ELSE
SetFlagF('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
END
ELSE
IF LTEqual? NumOfCS# Num#('999') {Changed from 6 - JHE}
SetWFOCS { use WFO for CS changes }
ELSE
SetFlagF('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to '
IF Flag?('7') { TRUE = Local WFO Coordinates, FALSE = D-Style Output }
'G52'
ELSE
'non-wfo'
END
' style output. )' EOL
END
END
END
END
END
RETURN

initOp:
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
EachOp
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
END
NextOp
SetPalletIn('1') {Added - JHE}
PalletOutF {Added - JHE}
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL {Removed NOT - JHE}
END
END
restoreScale
PalletInF {Added - JHE}
RETURN

firstOp1:
Seq Plane 'G20' CRCOff EOL {Added G20 - JHE}
SeqC DrillOff AbsOrInc EOL {Added AbsOrInc - JHE}
{SeqC OpToolID EOL} {Removed - JHE}
{SeqC ToolChng EOL} {Removed - JHE}
doPartCycleComment
doPostScript
doOpComments
RETURN

firstOp2:
SeqC wFOStuff EOL
g52Stuff
cSAngleA cSAngleB {Moved rotary to here - JHE}
checkPass
SeqC PreTool AbsOrInc Rapid StrtPos Speed SpinOn EOL {Added PreTool - JHE}
RETURN

firstOp3:
SeqC AbsOrInc OfstOn EOL
SeqC CoolOn EOL
IF RigidTap?
SeqC 'M29' EOL {Added - JHE}
END
RETURN

newToolOp1:
SeqC incValueC OfstOff EOL
SeqC 'G28X0.Y0.' EOL {Added this line - JHE}
SeqC AbsValue EOL
SeqC CoolOff EOL {Moved to here - JHE}
RETURN

newToolOp2:
doEndOpPS
{*** Removed motion home and spindle off - JHE
IF ToolChangeAtHome?
SeqC absOrIncC Rapid PRIME Home SpinOff EOL
ELSE
SeqC SpinOff EOL
END ***}
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

newToolOp3: {Start new Operation}
{Seq Plane CRCOff DrillOff EOL} {Removed - JHE}
{SeqC OpToolID EOL} {Removed - JHE}
Seq ToolChng EOL
doPartCycleComment
doPostScript
doOpComments
IF PalletIn? {Added pallet changed - JHE}
moveRotaryHome
SeqC 'M00' EOL
SeqC 'M60' EOL
SeqC 'M00' EOL
Seq ' (START NEW PALLET)' EOL
SeqC DrillOff EOL
SeqC IncValue OfstOff EOL
SeqC 'G28X0.Y0.' EOL
SeqC AbsValue EOL
PalletInF
END
RETURN

newToolOp4:
SeqC wFOStuff EOL
g52Stuff
cSAngleA cSAngleB
checkPass
SeqC PreTool AbsOrInc Rapid StrtPos Speed SpinOn EOL
RETURN

newToolOp5:
SeqC AbsOrInc OfstOn EOL
SeqC CoolOn EOL
IF RigidTap?
SeqC 'M29' EOL {Added - JHE}
END
RETURN

sameToolOp1:
doEndOpPS
IF LAST ProgStop?
SeqC incValueC OfstOff EOL
SeqC AbsValue EOL
SeqC CoolOff EOL
SeqC SpinOff EOL
SeqC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset? OR AChange? OR BChange?
SeqC incValueC OfstOff EOL
SeqC AbsValue EOL
END
END
RETURN

sameToolOp2: {Start new Operation}
doPartCycleComment
doPostScript
doOpComments
checkPass
RETURN

sameToolOp3: {Start new Operation}
SeqC wFOStuff EOL
g52Stuff
IF LAST ProgStop?
cSAngleA cSAngleB
SeqC PlaneC AbsOrInc Rapid StrtPos Speed SpinOn EOL
SeqC AbsOrInc OfstOn EOL
SeqC CoolOn EOL
ELSE
cSAngleAC cSAngleBC
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
IF NewToolOffset? OR AChange? OR BChange?
SeqC AbsOrInc OfstOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

end1:
SeqC incValueC OfstOff EOL
SeqC 'G28X0.Y0.' EOL {Added this line - JHE}
SeqC AbsValue EOL {Added this line - JHE}
SeqC CoolOff EOL {Moved to here - JHE}
RETURN

end2:
doEndOpPS
{*** Removed moving home and spindle stop - JHE
IF FIRST ToolChangeAtHome?
SeqC absOrIncC Rapid PRIME FirstHome SpinOff EOL
ELSE
SeqC SpinOff EOL
END ***}
moveRotaryHome {Added - JHE}
SeqC ToolChng EOL {Added - JHE}
IF ProgStop?
SeqC 'M00' EOL
ELSE
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart?
SeqC ProgStop EOL
END
END
RETURN

end3:
IF PalletOut? {Added - JHE}
SeqC 'M00' EOL
SeqC 'M60' EOL
END
SeqC EOP EOL
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

mPallTools1P: {Multiple Parts, All Tools 1 Part}
IF FirstOperation? OR EquallySpacedOffsets?
SetFlag('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END
opGuts
RETURN

mP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
SetFlag('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END
opGuts
RETURN

mP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
SetFlag('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END
opGuts
RETURN

noMPs: {no multiple parts}
SetFlag('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END
opGuts
RETURN

masterSub:
IF MultipleParts?
IF AllToolsOnePart?
mPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
mP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
mP1ToollAllPXcp
END
END
ELSE
noMPs
END
RETURN

endPartSub:
{End of program ************************************************************}

{finish last operation}
end1
end2
RETURN

newPart1: {Finish off last Part}
IF FullUp?
SeqC incValueC OfstOff EOL
SeqC absValueC EOL
SeqC CoolOff EOL
END
{doEndOpPS}
RETURN

newPart2: {Start new Part}
sameToolOp2
RETURN

newPart3: {Start new Part}
SetFlag('2') { Need to output wFOStuff twice for MP-ESO-OTAP-ECP, once for all others }
SeqC wFOStuff EOL
g52Stuff
cSAngleA cSAngleB
SeqC PlaneC AbsOrInc Rapid StrtPos Speed EOL
IF FullUp?
SeqC OfstOn EOL
SeqC CoolOn EOL
END
RETURN

toggleIncDecWFO:
IF Flag?('3') { Incrementing WFOs in effect }
SetFlagF('3')
ELSE { Decrementing WFOs in effect }
SetFlag('3')
END
RETURN

mPLoop:
Save# Num#('2') Recall# Num#('1')
IF WorkFixtureOffsets?
IF Flag?('3') { Incrementing WFOs in effect }
NewWFO
ELSE
LastWFO
END
EachWFO
ELSE
EachPart
END
IF AllToolsOnePart?
EachOp
masterSub
NextOp
endPartSub
ELSE { OneToolAllParts }
EachOp
IF Equal? Operation# Recall# Num#('2') { Valid Tool Op }
IF FirstOperation? OR NewTool?
IF FirstPart? AND Flag?('3') { Incrementing WFOs in effect }
masterSub
ELSE
IF LastPart? AND NOT Flag?('3') { Decrementing WFOs in effect }
masterSub
ELSE
newPart1
newPart2
newPart3
opGuts
END
END
ELSE
masterSub
END
IF LastOp?
IF LastPart? AND Flag?('3') { Incrementing WFOs in effect }
Save# Num#('1') Num#('0')
ELSE
IF FirstPart? AND NOT Flag?('3') { Decrementing WFOs in effect }
Save# Num#('1') Num#('0')
END
END
Save# Num#('2') Recall# Num#('1')
ELSE
IF NEXT SameTool?
Save# Num#('2') NEXT Operation#
ELSE
IF LastPart? AND Flag?('3') { Incrementing WFOs in effect }
Save# Num#('1') NEXT Operation#
Save# Num#('2') Num#('0')
ELSE
IF FirstPart? AND NOT Flag?('3') { Decrementing WFOs in effect }
Save# Num#('1') NEXT Operation#
Save# Num#('2') Num#('0')
ELSE
Save# Num#('2') Recall# Num#('1')
END
END
END
END
END
NextOp
END
IF WorkFixtureOffsets?
IF Flag?('3') { Incrementing WFOs in effect }
IncWFO
NextWFO
DecWFO
ELSE { Decrementing WFOs in effect }
DecWFO
NextPrevWFO
IncWFO
END
IF Flag?('4') { This post supports IncWFO/DecWFO }
toggleIncDecWFO
END
ELSE
NextPart
END
RETURN

{Start of executable Prog, Top Level ***********************}

progStart {setup and initializations}
initOp

IF MultipleParts?
IF WorkFixtureOffsets?
{'NOTE: This Post Processor does not support Work Fixture Offsets for Multiple Parts.' EOL
'It is recommended that you change your selection to Equally Spaced Offsets.' EOL}
END
IF AllToolsOnePart?
mPLoop
ELSE
EachOp
IF FirstOperation?
Save# Num#('1') Operation#
END
NextOp
mPLoop mPLoop mPLoop mPLoop mPLoop
mPLoop mPLoop mPLoop mPLoop mPLoop
mPLoop mPLoop mPLoop mPLoop mPLoop
mPLoop mPLoop mPLoop mPLoop mPLoop
mPLoop mPLoop mPLoop mPLoop mPLoop
endPartSub
END
ELSE
EachOp
masterSub
NextOp
endPartSub
END
end3