{Change Comments ***********************************************************}

{5/23/89
Modified: BP Boss 1-6 M041.55
For: Lawrence Berkeley Labs
Changed FORMATs for XYZIJKPQR Addresses to 1 less decimal place.
Changed FORMAT for F Addresse to ##^0
NOTE: Post contains BPCRCStartPos/BPCRCEndPos scheme per BP Boss 1-6 M041.54.
Added Booleans to supress 2 co-Linear Blocks by skipping extra ncCAM line at ToolPath.
JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{8/17/93
Modified: BP Boss 5 M205.56
For: Lawrence Berkeley Labs
Changes made per request by Pete Jackson
Updated to Version 4.1 per Fanuc 6M M001.81.2 Format.
Used BP Boss 5 Series II M527.81.3
DWB}

{11/15/93
Modified: BP Boss 5 M205.81.2
For: Gibbs & Associates
Created metric version
Jim Radcliffe}

{12/20/93
Copied: BP Boss 5 M205.81.2m
Created: BP Boss 5 [McI] M616.81.2m
For: Gibbs & Associates/Keith McIver/Quentin Rowe/Britten Motorcycles
Changes made per request by Keith McIver for Quentin Rowe of Britten Motorcycles.
Changed General Default Format for Address F from ###^0 to ###0 in Mach Spec.
Set Arcs Stop On Quadrants to False in Mach Specs Booleans Dialog.
Changed ZCP2C to DrillCP at IF Drilling.
Added TrackZNO# ClearancePlane1# for RetractToCP1 at IF Drilling.
DWB}

{2/21/94
Modified: BP Boss 5 [McI] M616.81.2m
For: Britten MotorCycles
Machine: Bridgeport Series 1 Rigid Ram
Control: Bridgeport-Textron Boss 5 CNC
Versions: ncCad 4.32/ncCAM 4.32/ncPost 4.32.02/Compost 4.21.20
Changes made per Quentin Rowe and Keith McIver and Bridgeport Manual
Updated to Version 4.2 per Fanuc 6M M001.81.2d Format.
Changed FORMAT for Address F from '###0' to '##0' in Mach Spec Default Format Dialog.
Changed FORMAT for Address S from '####0' to '###0' in Mach Spec Default Format Dialog.
Deleted FORMATs for Addresses P and Q in Mach Spec Default Format Dialog.
Deleted M3, M4, M5, M8 and M9 from Mach Spec.
Changed FORMAT#4 from '#####.###;0.' to '####.###;0.' in Prog Numeric Format Definitions.
Changed FORMAT#7 from '*#####.###;0.' to '*####.###;0.' in Prog Numeric Format Definitions.
Added FORMAT#8 '+####.###;0.' in Prog Numeric Format Definitions.
Customer requested full support of 360Ä„ arcs.
Added literal G75, Multi-Quadrant Circular Interpolation code, at FirstOperation.
Manual states that G75 will generate any 2 Axis Arcs up to 360Ä„, all conditional adresses must be
output unconditionally, IJ Arc Centers to be Absolute coordinates, and non-XYPlane arcs to be
output Incrementally.
Set Use Absolute Arc Centers to TRUE in Mach Spec Booleans Dialog.
Set Arc Centers Have Polarity to FALSE in Mach Spec Booleans Dialog.
Added IncValue to XZPlane and YZPlane arcs at FormatArc sub.
Added booleans to break up 2 axis Arcs for all planes at FormatArc sub.
Deleted NoIJKSigns at setup and initializations.
Customer requested support of Helical Arcs.
Manual states that Helical Arcs can be generated through Incremental Polar Coordinate Loop.
Added SetArcSegmentAccuracy(.0002) at setup and initializations.
Added support of this for XYPlane Helical Arcs only.
Var(1) stores incremental MoveZ value.
Var(2) stores ArcAngle# value.
Var(3) stores incremental SegmentMoveZ value.
Var(4) stores SegmentArcAngle# value.
Var(5) stores number of Segments.
Var(6) modifies values of Var(3 and 4).
Added Recall# to Format#4 in Prog Numeric Format Definitions.
Added ArcI# to Format#8 in Prog Numeric Format Definitions.
Added ArcJ# to Format#8 in Prog Numeric Format Definitions.
Added following subs to support Helical Interpolation Incremental Polar Coordinate Loop.
NormalHelix sub uses EACHArcSegment/NEXTArcSegment loop for XZPlane and YZPlane Helical Arcs.
RoundUp sub adds .0005 to contents of Var(6).
RoundDown sub MULtiplies Var(6) by 1000, TRUNCates decimal portion and then MULtiplies Var(6) by
.001 to leave Var(6) carried only to 4 places without rounding.
StartHelix sub begins output and handling of XYPlane Helical Arcs.
HelixVars sub stores scheme 1 values into Vars(3, 4 and 6).
HelixVars2 sub stores scheme 2 values into Vars(3, 4 and 6).
RoundPolarA sub calls RoundDown sub for Var(3).
RoundPolarZ sub calls RoundDown sub for Var(4).
HelixBlock sub outputs Helical code for A and Z parameters.
LoopHelix sub outputs Helical code per manual.
BalanceHelix sub outputs remaining move to be made for A parameter at end of Helix.
EndHelix sub updates ncPost and returns to normal programming.
PolarHelix sub calls above mentioned subs and is called from ToolPath ArcFeat.
Added cancellation, reposition and redefinition of Canned Drilling Cycles that RetractToCP1 at
ToolPath PointFeat.
Added SetMaxRPM(4200) at setup and initializations.
Added SetMinRPM(60) at setup and initializations.
Changed SetMaxFeed from 500 to 812 at setup and initializations.
Added literal G71, Metric Mode, at FirstOperation.
Added Speed to ToolChng block at FirstOperation, NewTool and SameTool.
Customer requested this for operator benefit, even though machine is manual speed changer.
Changed all literal M00 to M0.
Changed DrillCP back to ZCP2C at IF Drilling per changes on 12/20/93.
Deleted TrackZNO# ClearancePlane1# for RetractToCP1 at IF Drilling per changes on 12/20/93.
Changed G04 to G4 at IF Drilling.
Added G89 FI-D-FO cycle at IF Drilling.
DWB}

{11/22/94
Modified: BP Boss 5 [McI] M616.81.3m
For: Britten MotorCycles
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.04/Compost 4.21.23
Changes made per Quentin Rowe and Keith McIver and fax and sample file.
Customer reported that G75 code, added on 2/21/94, caused G2/G3 arc commands to become non-modal.
Changed conditional CWArcC/CCWArcC to unconditional CWArc/CCWArc at FormatArc sub.
Customer requested support for Z2 parameter for Canned Peck Drilling Operations.
The Z2 parameter is, according to manual, the incremental distance for the first peck increment.
The customer suggested using the Retract/Clearance field of the General Info 1 Dialog.
Added Retract# to Format#4 at Prog Numeric Format Definitions.
Changed Retract command to 'Z' Retract# in Canned Drill Cycle block at ToolPath PointFeat and
IF Drilling, and moved in front of Peck Command.
Customer requested support of CutterRadiusCompensation for AutoCycles.
Added necessary code at AutoCycCutSub2 sub.
DWB}

{3/2/95
Modified: BP Boss 5 [McI] M616.81.4m
For: Britten MotorCycles
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Compost 4.21.27
Changes made per Quentin Rowe and fax.
Customer reported problem when doing incremental arcs.
Noted that we were forcing all AutoCycle and Non-XYPlane ArcIJ values are to be unsigned.
Manual on page 9-2 states that all ArcIJ values are to be signed
Deleted Format#8 '+####.###;0.' from Prog Numeric Format Definitions.
Changed ArcI# to Format#4 '####.###;0.' in Prog Numeric Format Definitions.
Changed ArcJ# to Format#4 '####.###;0.' in Prog Numeric Format Definitions.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.###;0.'
#5 = '#######0'
#6 = '###^#0'
#7 = '*####.###;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Recall#,4)
FORMAT(Retract#,4)
FORMAT(ArcI#,4)
FORMAT(ArcJ#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(SPZ#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'#' Program# EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
TagUp TagInc
SeqLabC CallLabB '²' Tag# RepLab RepCycs EOL
RETURN

StartPos:
IF CutterRadiusCompensation? AND NOT AutoCycle?
BPCRCStartPos
ELSE
StrtPos
END
RETURN

EndPos:
IF CutterRadiusCompensation? AND NOT AutoCycle?
CRCOffC BPCRCEndPos
END
RETURN

FinishSub1: {part 1}
IF FeedConnect?
IF CutterRadiusCompensation? AND NOT AutoCycle?
SeqLabC FeedC EndPos FeedEntC EOL
END
ELSE
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO?
SeqLabC FeedC EndPos ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC EndPos ZCP3C EOL
END
END
END
RETURN

FinishSubG92: {part 2}
SeqLab Preset ShiftRC EOL
'<' Tag# EOL
TagDown
SeqLabC Preset UnshftRC EOL
RETURN

OpenMP:
IF WorkFixtureOffsets?
' ' EOL
' ( Note - Post does not support MultipleParts with WorkFixtureOffsets. )' EOL
' ( Please change to EquallySpacedOffsets. )' EOL
' ' EOL
ELSE
TagUp TagInc
SeqLabC CallLabB '²' Tag# RepLab Parts EOL
END
RETURN

CloseMP:
IF NOT WorkFixtureOffsets?
SeqLab Preset ShiftPC EOL
'<' Tag# EOL
TagDown
SeqLabC Preset UnshftPC EOL
END
RETURN

NormalHelix:
EACHArcSegment
SeqLabC FeedC MoveXYZC ArcFeedC EOL
NEXTArcSegment
RETURN

RoundUp:
IF LessThan? Recall# Num#('6') Num#('0')
Save# Num#('6') SUB# Recall# Num#('6') Num#('.0005')
ELSE
IF GreaterThan? Recall# Num#('6') Num#('0')
Save# Num#('6') ADD# Recall# Num#('6') Num#('.0005')
END
END
RETURN

RoundDown:
Save# Num#('6') MUL# Recall# Num#('6') Num#('1000') { SegValue * 100 }
Save# Num#('6') TRUNC# Recall# Num#('6') { remove decimal portion leaving integer value }
Save# Num#('6') MUL# Recall# Num#('6') Num#('.001') { SegValue Ö .01, unrounded decimal value }
RETURN

StartHelix:
SeqLabC ArcR 'I' ArcI# 'J' ArcJ# EOL
SetAbs
SetStatusOff
Save# Num#('1') ArcAngle#
Save# Num#('6') Recall# Num#('1')
RoundUp
RoundDown
Save# Num#('1') Recall# Num#('6')
Save# Num#('2') SUB# EPZ# SPZ#
Save# Num#('6') Recall# Num#('2')
RoundUp
RoundDown
Save# Num#('2') Recall# Num#('6')
Save# Num#('3') Num#('0')
Save# Num#('4') Num#('0')
Save# Num#('5') Num#('0')
RETURN

HelixVars: { PolarCalcHelix }
Save# Num#('4') Num#('-.001') { ZMoveSeg }
Save# Num#('5') DIV# Recall# Num#('2') Recall# Num#('4') { NumSegs }
Save# Num#('3') DIV# ArcAngle# Recall# Num#('5') { ArcSeg }
RETURN

HelixVars2: { PolarSegHelix }
EACHArcSegment
IF Equal? ArcSeg# Num#('1')
Save# Num#('3') ArcAngle#
Save# Num#('4') SUB# EPZ# SPZ# { SPZ# needs FORMAT#4 }
END
NEXTArcSegment
Save# Num#('5') ArcSeg#
RETURN

RoundPolarA:
Save# Num#('6') Recall# Num#('3')
RoundDown
Save# Num#('3') Recall# Num#('6')
RETURN

RoundPolarZ:
Save# Num#('6') Recall# Num#('4')
RoundDown
Save# Num#('4') Recall# Num#('6')
RETURN

HelixBlock:
'A' Recall# Num#('3') 'Z' Recall# Num#('4')
RETURN

LoopHelix:
TagUp TagInc
FORMAT(Recall#,5)
SeqLabC CallLabB '²' Tag# RepLab Recall# Num#('5') EOL
FORMAT(Recall#,4)
IF AbsoluteMoves? AND NOT AutoCycle?
IncValue
END
SeqLab FeedC HelixBlock ArcFeedC EOL
'<' Tag# EOL
TagDown
RETURN

BalanceHelix:
Save# Num#('3') MUL# Recall# Num#('3') Recall# Num#('5')
Save# Num#('3') SUB# Recall# Num#('1') Recall# Num#('3')
Save# Num#('4') MUL# Recall# Num#('4') Recall# Num#('5')
Save# Num#('4') SUB# Recall# Num#('2') Recall# Num#('4')
IF NotEqual? Recall# Num#('3') Num#('0')
SeqLabC HelixBlock EOL
ELSE
IF NotEqual? Recall# Num#('4') Num#('0')
SeqLabC HelixBlock EOL
END
END
RETURN

EndHelix:
SetStatusOn
TrackXNO# EPX#
TrackYNO# EPY#
TrackZNO# EPZ#
IF AutoCycle?
SetInc
ELSE
SetAbsOrInc
IF AbsoluteMoves?
SeqLabC AbsValue EOL
END
END
RETURN

PolarHelix:
FORMAT(SPZ#,4)
StartHelix
HelixVars
RoundPolarA
RoundPolarZ
LoopHelix
BalanceHelix
EndHelix
FORMAT(SPZ#,7)
RETURN

FormatArc:
IF ArcCW?
CWArc
ELSE
CCWArc
END
IF AbsoluteMoves? AND NOT XYPlane?
IncValue
END
IF XYPlane?
MoveXY
ELSE
Plane
IF XZPlane?
MoveX
ELSE
MoveY
END
MoveZ
END
IF XYPlane? AND NOT AutoCycle?
ArcIJ
ELSE
'I' ArcI# 'J' ArcJ#
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate? AND NOT CutterRadiusCompensation?
IF RoomToDecel?
DecelMove1
SeqLabC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqLabC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC '=#' Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF RetractToCP1?
IF NOT FirstFeat?
SeqLabC Rapid ZCP1 EOL
SetStatusOff
SeqLabC MoveSXYC EOL
SetStatusOn
SeqLabC ZCP2 EOL
SeqLabC
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
MoveSXYC SetInc 'Z' SPZ# SetAbsOrInc
IF Peck?
'Z' Retract# Peck
END
FeedEnt EOL
END
ELSE
SeqLabC MoveSXYC
IF SPZMove? {.80.01}
TrackZNO# ClearancePlane2#
SetInc
'Z' SPZ#
SetAbsOrInc
END
EOL
END
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLabC RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqLabC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
IF XYPlane? AND ZMove?
PolarHelix
ELSE
IF XZPlane? AND YMove?
NormalHelix
ELSE
IF YZPlane? AND XMove?
NormalHelix
ELSE
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
IF AbsoluteMoves? AND NOT XYPlane?
SeqLabC AbsOrInc EOL
END
END
END
END
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
IF CutterRadiusCompensation?
SeqLabC CRCOnC 'X0.Y0.' EOL
END
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
IF CutterRadiusCompensation?
SeqLabC CRCOffC 'X0.Y0.' EOL
END
SeqLabC AbsOrInc EOL
ELSE
SeqLabC AbsOrInc
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
EOL
IF CutterRadiusCompensation?
IF AbsoluteMoves?
SeqLabC IncValue EOL
SeqLabC CRCOffC 'X0.Y0.' EOL
SeqLabC AbsOrInc EOL
ELSE
SeqLabC CRCOffC 'X0.Y0.' EOL
END
END
END
'$' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
IF CutterRadiusCompensation?
SeqLabC CRCOnC StrtPos EOL
END
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Connect StartPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
IF FeedConnect?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC Rapid ZCP2PlusInc EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
'=#' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLabC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqLabC Rapid ZCP2 EOL {.69}
END
END {.69}
'$' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF FirstCycle?
IF CutterRadiusCompensation?
SeqLabC CRCOnC StrtPos EOL
END
ELSE
SeqLabC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
'=#' Program# EOL
NextCycle
StartSub
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
IF NOT FeedConnect?
IF FIFO?
SeqLabC FeedC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
END
END
'$' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseYZArcs
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('4200')
SetMinRPM('60')
SetMaxFeed('812')
SetArcSegmentAccuracy('.0002')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR 'N1' Plane 'G71G75' AbsValue EOL { Metric, Multi-Quadrant Circular Interpolation }
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' MILLIMETERS )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLab Rapid Home OpToolID Speed ToolChng EOL
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC AbsOrInc Rapid StartPos ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StartPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

SeqLab AbsOrInc Rapid Home OpToolID Speed ToolChng EOL
SeqLabC Plane AbsValue EOL
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC AbsOrInc Rapid StartPos ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StartPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLabC ZCP1 EOL
SeqLabC 'M0' EOL
END

{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC AbsOrInc Rapid StartPos SpeedC EOL
END
END
END {common point for all operations}
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
NewProg
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
NewProg
ZonlyRep
SetFlag('1')
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
SetFlag('1')
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLabC FeedC
IF Flag?('1')
SetFlagF('1')
EndPos
END
ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC
IF Flag?('1')
SetFlagF('1')
EndPos
END
ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
SeqLabC ZCP2C EOL
GetCycle
IF Dwell?
SeqLabC 'G4/' Dwell# EOL
END
SeqLabC
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
StrtPos ZDepthAbs
IF Peck?
'Z' Retract# Peck
END
FeedEnt EOL
TrackZNO# FIRST SPZ# {.81.2}
ToolPath
TrackZNO# ClearancePlane2#
SeqLabC 'G80' EOL
IF Repeats?
FinishSubG92
END
SeqLabC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLabC AbsOrInc Rapid
IF FIRST ToolChangeAtHome?
FirstHome
END
IF ProgStop?
'M0' EOL
SeqLabC
END
IF MultipleParts? AND AllToolsOnePart?
EOL
CloseMP
SeqLabC
END
EOP EOL
'E' EOL
CloseSub
Post2 {organize Subs into one program}
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END