{ 10/24/88, WFG }
{From the Bridgeport IIA M1131.54 }
{ first tool not in spindle }

{12/1/89, Updated: Bridgeport IIA (HAC) M200.57, JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{6/14/93, Updated BP IIA (HAC) M200.62 to .81 format, JR}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '+####.####;0.'
#7 = '####.####;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(ZDepth#,6)
FORMAT(TrackZ#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF MultipleParts? AND SubComment?
'( PART ' Tag# ' )' EOL
END
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
Seq 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
Seq 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
Seq 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
Seq 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
Seq PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
Seq EndOpPS EOL
PSStuff
NextPS
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

StdRapid:
IF XMove? OR YMove? OR ZMove?
Seq RapidC MoveXYZC EOL
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
Seq FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
Seq FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
Seq FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

StdArc:
IF NOT XYPlane?
Seq PLANE EOL
END
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
Seq FormatArc ArcFeedC EOL
DecelMove2
END
Seq FormatArc DecelFeed EOL
ELSE
Seq FormatArc ArcFeedC EOL
END
NEXTQuadrant
RETURN

ToolPath2: {for AutoCycle element moves}
EACHFeat
IF RapidFeat?
IF LastFeat?
Seq CRCOffC RapidC MoveXYZC EOL
ELSE
StdRapid
END
ELSE
IF LineFeat?
IF LastFeat?
Seq CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
Seq FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

EntryMove:
IF FeedEntry?
Seq FeedC ZInC FeedEntC EOL
ELSE
Seq RapidC ZInC EOL
END
RETURN

CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
Seq IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
Seq RapidC PRIME ZCP2 EOL
END
NextRep
Seq AbsOrInc RapidC ZCP2 EOL
ELSE
EntryMove
ToolPath2
Seq AbsOrInc RapidC ZCP2 EOL
END
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

DoPeck:
IF GreaterThan? SUB# Recall# Num#('8') Peck# SPZ# {IF OldZ - Peck# > Depth}
Save# Num#('8') SUB# Recall# Num#('8') Peck# {Save#1 = OldZ - Peck# = NewZ}
Seq Feed ' Z' TrackZ# Recall# Num#('8') FeedEntC EOL {move to NewZ}
IF PeckFullRetract?
Seq Rapid ZCP2 EOL {move to CP2}
END
Seq RapidC ' Z' TrackZ# ADD# Recall# Num#('8') Retract# EOL {move to RetractZ}
END
RETURN

DoLastPeck: {OldZ - Peck# ² Depth}
Seq Feed ' Z' TrackZ# SPZ# FeedEntC EOL {move to Depth}
IF RetractToCP1?
Seq Rapid ZCP1 EOL {move to CP1}
ELSE
Seq Rapid ZCP2 EOL {move to CP2}
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
Seq MoveSXYC EOL
CutAutoCycle
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
Seq MoveSXYC EOL
IF Peck?
Seq ZCP2C EOL
Save# Num#('8') ClearancePlane2#
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoLastPeck
END
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
NEXTFeat
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

ToolChange:
EachMonoToolStep('12')
Seq ' M64' EOL
NextMonoToolStep
RETURN

DoOp:
IF FirstOperation?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
CoolOff EOL
Seq ' G80 M60' EOL
END
DoOpComments
ELSE
EOL
DoOpComments
Seq Plane AbsValue Preset Home OpToolID ToolChng EOL
DoPostScript
Seq Speed SpinOn EOL
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
Seq StrtPos EOL
ELSE
Seq Rapid StrtPos CoolOn EOL
Seq ' M67' EOL
Seq ' G92' ZCP1 EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
{only need to set up for tool change on 1st part}
ELSE
CoolOff EOL
Seq ' G80 M60' EOL
DoEndOpPS
Seq RapidC ZCP1C EOL
Seq Home EOL
IF LAST ProgStop?
Seq ' M0' EOL
ELSE
Seq ProgStop EOL
END
END

{Start new Operation}

IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
CoolOff EOL
Seq ' G80 M60' EOL
END
DoOpComments
ELSE
EOL
DoOpComments
Seq PlaneC AbsValue Preset Home OpToolID ToolChng EOL
DoPostScript
ToolChange
Seq Speed SpinOn EOL
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
Seq StrtPos EOL
ELSE
Seq Rapid StrtPos CoolOn EOL
Seq ' M67' EOL
Seq ' G92' ZCP1 EOL
END
ELSE
IF SameTool?
EOL
DoEndOpPS
IF LAST ProgStop?
Seq CoolOff EOL
Seq ' G80 M60' EOL
Seq ' M0' EOL

{Start new Operation}

GetStartOfSameTool
Seq PlaneC AbsOrInc Rapid StrtPos CoolOn EOL
Seq SpeedC SpinOn EOL
Seq ' M67' EOL
Seq ' G92' ZCP1 EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
Seq CoolOff EOL
END

{Start new Operation}

GetStartOfSameTool
Seq PlaneC AbsOrInc Rapid StrtPos EOL
Seq SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
Seq CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
Seq ZCP2C EOL
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
EACHRep
DoSubComment
IF NOT FirstCycle?
Seq Connect StrtPos EOL
IF NOT FeedConnect?
Seq ZCP2C EOL
END
END
END
END
IF NOT AutoCycle?
EntryMove
END
ToolPath
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
Seq CRCOffC
IF NOT FeedConnect?
RapidC PRIME ZCP3C
END
EOL
NEXTRep
END
END
Seq CRCOffC RapidC ZCP3C
ELSE
IF Drilling?
Seq ZCP2C EOL
IF Repeats?
EACHRep
DoSubComment
IF NOT FirstCycle?
Seq StrtPos EOL
END
END
IF NOT Peck?
GetCycle
Seq Cycle StrtPos ' Z' ZDepth# FeedEnt EOL
END
ToolPath
Seq ' G80' EOL
IF Repeats?
NEXTRep
END
Seq RapidC ZCP3C
END
END
RETURN

FinishLastOp:
Seq CoolOff EOL
Seq ' G80 M60' EOL
DoEndOpPS
Seq RapidC ZCP1C EOL
IF ToolChangeAtHome?
Seq AbsOrInc FirstHome EOL
END
EachFirstMonoToolStep('12')
Seq ' M64' EOL
NextMonoToolStep
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart? {no tool change after doing last part}
IF ProgStop?
Seq ' M0' EOL
ELSE
Seq ProgStop EOL
END
ELSE
Seq EOP EOL
END
RETURN

DoToolsOps:
EachOp
IF GTEqual? Operation# Recall# Num#('1') AND LTEqual? Operation# Recall# Num#('2')
{Tools1stOp ² op ² ToolsLastOp}
DoOp
END
NextOp
RETURN

NextTools1stOp:
SetNextToolOp Operation#
RETURN

GetToolsOps:
EachOp
IF Equal? Operation# Recall# Num#('1') {if op = Tools1stOp}
IF GreaterThan? NextTools1stOp Recall# Num#('1') {if NextTools1stOp is greater Tools1stOp}
Save# Num#('2') SUB# NextTools1stOp Num#('1') {ToolsLastOp becomes NextTools1stOp less 1}
ELSE {else}
Save# Num#('2') Recall# Num#('3') {ToolsLastOp becomes ncCAMsLastOp}
END
END
NextOp
RETURN

DoTool:
IF NOT Flag?('1')
GetToolsOps
EachPart
TagInc
DoToolsOps
NextPart
IF LessThan? Recall# Num#('2') Recall# Num#('3') {if ToolsLastOp < ncCAMsLastOp}
Save# Num#('1') ADD# Recall# Num#('2') Num#('1') {Tools1stOp becomes NextTools1stOp}
ELSE {else}
SetFlag('1') {set DoneFlag}
END
TagInit
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetFlagF('1') {done flag}
ReverseXZArcs
NoIJKSigns
SetFlood
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( MAKE SURE THAT TURRET #1 IS LOADED AND AT POSITION #1 )' EOL
END
END
OpenSub
RestoreScale
END
NextOp
IF MultipleParts?
IF AllToolsOnePart?
EachPart
TagInc
EachOp
DoOp
NextOp
FinishLastOp
NextPart
ELSE
IF OneToolAllParts?
EachOp
IF FirstOperation?
Save# Num#('1') Operation# {ncCAMs1stOp becomes Tools1stOp}
END
IF LastOp?
Save# Num#('3') Operation# {save ncCAMsLastOp}
END
NextOp
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
FinishLastOp
END
END
ELSE
EachOp
DoOp
NextOp
FinishLastOp
END
EOR EOL
CloseSub
Post2
IF UseComments?
SetScale('1')
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Close