{Change Comments ***********************************************************}

{for Maury Microwave, by WFG , 5/30/88, Citizen Cincom F12-Fanuc 3TA, from KiaMaster}
{ no G97/G96 for CSS }
{2 turrets, tools 1-9 turret1, tools 21-29 turret 2}
{collet in Z+ direction}

{ 11/3/88 }
{ originaly Fan 3TA Cincom F12 L063.54 }
{ for Maury Microwaves' Citizen F20 lathe with Fanuc 3TC control }
{ 2 turrets, tools 11-15 turret 1, tools 21-25 turret 2 }
{ changed X.55 in literal face off and cut-off sequence's to XCP
changed Z litteral in cut-off to ZStockMin#, also using T2100
instead of T1100 }
{ modified pretooling operations to include; '00', 'T0' or 'T2100' }
{ using tool and offset numbers for minimum 'N' numbers }
{ not using G50 presets, use only sub-routines if an ID operadtion }
{ Jim Radcliffe }

{12/2/88
Added parts cather in & out codes.
Changed X-.12 in literal face & cut-off sequences to X.15.
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{11/23/96, Updated Fanuc 3TC Cincom F20 L081.58 to .85 format per Fanuc 10T MS [-] L001.85.01.02, JR}

{Prog Numeric Format Definitions *******************************************}

#1 = '0.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '#.######;0.'
#5 = '#'
#6 = '00'
#7 = '####^####'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(ToolOffsetXRadius#,2)
FORMAT(ToolOffsetZ#,2)
FORMAT(TurretX#,2)
FORMAT(ZStockMin#,2)
FORMAT(Dwell#,2)
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(FeedIPR#,4)
FORMAT(RapidF#,5)
FORMAT(ToolOffsetLess20#,6)
FORMAT(ToolOffset#,6)
FORMAT(Peck#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP 'T' ToolOffset#
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid 'G99' RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
END
DoOpComments
DoPostScript
SeqLabC CSSOff
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
CalcRPM1
END
ELSE
CalcRPM1
END
ELSE
IF LAST ConstantSurfaceFeed?
Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
END
END
IF NewToolOffset?
SeqLabC 'T' ToolOffset# EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling? AND Dwell?
SeqLabC 'G4X' Dwell# EOL
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC
IF LAST ThreadFeat?
Rapid
ELSE
RapidC
END
MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
IF LAST Threading?
Rapid
ELSE
RapidC
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
NegateZ
PosSideLathe
ReverseXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1 EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff
SetHome

SeqLabC 'G68' EOL {st turret 2, tool 21 is in pos}
SeqLabC 'G50X-.15Z-.02' EOL {preset position at prog end}
SeqLabC 'M6' EOL {close collet}
SeqLabC 'M3S4000' EOL
IF NOT ToolOver?('20') {using turret 1}
SeqLabC OpToolID '00' EOL {OP1 tool call}
END
SeqLabC 'G0' XCP EOL
SeqLabC 'Z0T01'EOL
SeqLabC 'G99G1X-.15F.001' EOL {face part with tool 21}
SeqLabC 'G0' XCP 'Z-.02' EOL

DoOpComments
DoPostScript
Plane

IF NOT ToolOver?('20') {using turret 1, tool already in pos}
IF LastTool?
SeqLabC 'T2100' EOL
ELSE
SeqLabC PreToolOver('20')
IF NOT EmptyLine?
'00' EOL {set turret 2 tool for next use and cancel offset}
ELSE
'T0' EOL {cancel offset if no next tool over 20}
END
END
'N' Tool# ToolOffset# 'G69' EOL {set turret 1 for OP 1 use}
ELSE
SeqLabC PreToolUnder('20')
IF NOT EmptyLine?
'00' EOL
ELSE
'T0' EOL {cancel offset if no next tool under 20}
END
IF ToolOver?('21') {OP 1 tool is not tool 21}
SeqLabC OpToolID '00' EOL {new turret 2, new tool}
SeqLabC 'G4X1.' EOL {dwell if same turet}
END
'N' Tool# ToolOffset# EOL
END

SeqLabC SpeedC EOL
IF Drilling? OR ApproachID?
SeqLabC 'M98P9091' EOL
END
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC NewHome EOL
END
IF LAST Drilling? OR LAST ApproachID?
SeqLabC 'M98P9090' EOL
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript

IF LAST ToolOver?('20')
IF ToolOver?('20')
SeqLabC OpToolID '00' EOL {same turret 2}
SeqLabC 'G4X1.' EOL {dwell if same turet}
'N' Tool# ToolOffset# EOL
ELSE
IF LastTool?
SeqLabC 'T2100' EOL
ELSE
SeqLabC PreToolOver('20')
IF NOT EmptyLine?
'00' EOL {set turret 2 for next use and cancel offset}
ELSE
'T0' EOL {cancel offset if no next tool over 20}
END
END
'N' Tool# ToolOffset# 'G69' EOL {use turret 1}
END
ELSE
IF ToolOver?('20')
SeqLabC PreToolUnder('20')
IF NOT EmptyLine?
'00' EOL {set turret 1 for next use and cancel offset}
ELSE
'T0' EOL {cancel offset if no next tool under 20}
END
'N' Tool# ToolOffset# 'G68' EOL {use turret 2}
ELSE
IF LastTool?
SeqLabC 'T2100' EOL
ELSE
SeqLabC OpToolID '00' EOL {same turret 1}
SeqLabC 'G4X1.' EOL {dwell if same turet}
END
'N' Tool# ToolOffset# EOL
END
END

SeqLabC SpeedC EOL
IF Drilling? OR ApproachID?
SeqLabC 'M98P9091' EOL
END
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle CutDepth 'R.01' EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove ZSP EOL
SeqLabC XSP EOL
ELSE
SeqLab StepMove XSP EOL
SeqLabC ZSP EOL
END
ELSE
IF RoughPatternShift?
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF SingleEdgeCut?
SeqLabC 'G76' XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead EOL
ELSE
SeqLabC 'G92X' FirstMoveEPX# FinZ ThrdLead EOL
SimpleRough
IF AutoFinish?
SeqLabC XatFinZ EOL
END
END
ELSE
IF Drilling?
SeqLabC LCycle ZDepth 'Q' Peck# Retract FeedRate EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
SeqLabC RLevel EOL
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
IF Threading?
Rapid
ELSE
RapidC
END
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqLabC FirstHome EOL
END
IF Drilling? OR ApproachID?
SeqLabC 'M98P9090' EOL
END
IF ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

IF UseComments?
IF OperationComment?
'( CUT-OFF SEQUENCE )' EOL
END
IF ToolTypeComment? OR ToolComment?
'( TOOL 11: .060 WIDE PART-OFF TOOL )' EOL
END
END

IF NOT ToolOver?('20') {last tool under 20}
SeqLabC 'T0' EOL {cancel offset, tool 21 is in pos}
'N2116' 'G68' EOL {set turrt 2 for tool 21}
ELSE
IF ToolOver?('21') {last tool over 20 and over 21}
SeqLabC 'T2100' EOL {same turret 2, new tool 21}
SeqLabC 'G4X1.' EOL {dwell 1 sec. if same turret}
'N2116' EOL
ELSE
SeqLabC 'T0' EOL {cancel offset, for same tool new offset}
'N2116' EOL
END
END

SeqLabC 'G0' XCP 'Z' ZStockMin# 'T16' EOL {X clear, Z cutoff position}
SeqLabC 'M32' EOL {parts cather in}
SeqLabC 'G1X-.15F.0008' EOL {cut-off}
SeqLabC 'M33' EOL {parts cather out}
SeqLabC 'M5' EOL {spindle off}
SeqLabC 'G4X1.0' EOL {dwell 1 sec.}
SeqLabC 'M7' EOL {open collet}
SeqLabC 'G0X-.15Z-.02T0' EOL {barfeed}
SeqLabC 'M2' EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END