{Change Comments ***********************************************************}

{8/16/95,
Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85.01 Format.
DWB}

{1/9/97
Updated & Modified: Okuma OSP 5000 LB15 L103.85m
Created: Okuma OSP 5000 LB15 L103.85.1m
For: Gibbs & Associates
Versions: Catalyst v3.25C/Compost 4.21.37/v1.0b4
Updated for Catalyst v3.25C per Fanuc 10T MS [-] L001.85.02a Format.
Added SetMaxFeed(12700) condition for Metric Files at setup and initializations.
Changed bad SetScale argument from 2.54 to 25.4 at RestoreScale sub.
DWB}

{1/9/97
Copied: Okuma OSP 5000 LB15 L103.85.1m
Created: Okuma OSP 5000 LB15 L553.85m
For: Fructus/Stršmsholmen
Versions: Catalyst v3.25C/Compost 4.21.37/v1.0b4
Changes made per Mikael Bagge of Fructus and sample file.
Customer requested U, stock threading value added to Canned Threading block
Added LastCutXRadius# to FORMAT#2 at Prog Numeric Format Definitions.
Added ' U' LastCutXRadius# at CannedCycle Threading.
Customer requested change to output of Dwell Address for manual Drilling Operations.
Changed literal ' G4 P2000' to ' G4 F.4' at ToolPath Drilling Tap.
Changed literal ' G4 P' to ' G4 F' at ToolPath Drilling Dwell.
Changed literal ' G4 P2000' to ' G4 F.4' for Drilling AND Tap Booleans at end of Non CannedCycle.
Customer requested G96 at ToolChng position.
Changed CSSOff ' G97' to CSSOn ' G96' for ConstantSurfaceFeed at FirstOperation and NewTool.
Deleted CSSOff ' G97' CalcRPM2 for LAST ConstantSurfaceFeed Boolean at NewTool.
Deleted CSSOn ' G96' Speed for ConstantSurfaceFeed AND NOT SameTool Booleans at common point.
Deleted CSSOff ' G97' CalcRPM2 for ConstantSurfaceFeed Boolean at end of Prog.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '+#####.###;0'
#3 = '#######0'
#4 = '###.##;0'
#5 = '#####.###;0'
#6 = '###0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(XCutDepth#,2)
FORMAT(ZCutDepth#,2)
FORMAT(LastCutXRadius#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(Peck#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
CSSOff
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF LAST ProgStop?
CSSOn ' G96' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
CSSOn ' G96' Speed
END
END
ELSE
SeqLabC Preset MaxRPM EOL
CSSOn ' G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
' G97' Speed
ELSE
IF LAST ProgStop?
' G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
' G97' Speed
END
END
END
END
IF LAST ProgStop?
SeqLabC {SpeedC} SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC {SpeedC} EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC ' G4 F.4' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC ' G4 F' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC ' G33' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC Rapid
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('500')
ELSE
SetMaxFeed('100')
END
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
'$' ProgramName$ '.MIN' EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE METERS )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
IF ConstantSurfaceFeed?
SeqLab Preset MaxRPM EOL
SeqLabC Rapid CSSOn ' G96'
ELSE
SeqLab Rapid CSSOff ' G97'
END
Speed OpToolID LatheOffset SpinOn CoolOn ' M42' EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
SeqLabC NewHome
IF LAST ProgStop?
' M0'
ELSE
ProgStop
END
EOL

{Start new Operation}

DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
SeqLab Preset MaxRPM EOL
SeqLabC Rapid CSSOn ' G96'
ELSE
SeqLab Rapid CSSOff ' G97'
END
Speed OpToolID LatheOffset SpinOn CoolOn ' M42' EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF NOT RoughSimple?
TagInc
SetPass2
IF RoughContour?
SeqLabC ' G85 NÅ‚' Tag#
IF ApproachFace?
' D' ZCutDepth#
ELSE
' D' XCutDepth#
END
FeedRate XStkLeft ZStkLeft EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab ' G82' EOL
ELSE
SeqLab ' G81' EOL
END
ELSE
IF RoughPatternShift?
SeqLabC ' G86 NÅ‚' Tag#
IF ApproachFace?
' D' ZCutDepth#
ELSE
' D' XCutDepth#
END
FeedRate XStkLeft ZStkLeft EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab ' G82' EOL
ELSE
SeqLab ' G81' EOL
END
END
END
SeqLabC StepMove StrtPos EOL
ToolPath
SeqLabC ' G80' EOL
IF AutoFinish?
SeqLabC ' G87 NÅ‚' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?

{ G72 Face Threads modification would require changes to XTapAtZ command with W Address }

SeqLabC ' G71' XatFinZ FinZ XTapAtZ
IF SingleEdgeCut?
ToolAngle
ELSE
' B0'
END
CutDepth ThrdHeight ' U' LastCutXRadius# ThrdLead ' M32'
IF ConstantVolumeCut?
' M75'
ELSE
' M74'
END
IF Chamfer?
' M23'
ELSE
' M22'
END
EOL
IF AutoFinish?
SeqLabC ' G33' XatFinZ FinZ XTapAtZ ThrdLead EOL
SeqLabC Rapid XCSP EOL
SeqLabC ZCSP EOL
END
ELSE
IF Drilling?
SeqLabC
IF Tap? AND NOT CWSpindle?
' G78'
ELSE
LCycle
END
XCSP ZDepth Peck Retract
IF PeckFullRetract?
' L' Peck#
END
FeedRate Dwell EOL
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC ' X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC ' G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC ' G4 F.4' EOL
SeqLabC Speed SpinOn EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC Rapid
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
SeqLabC FirstHome
IF ProgStop?
' M0'
ELSE
ProgStop
END
EOL
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END