{Change Comments ***********************************************************}

{9/23/88
Copied & modified: Okuma OSP 3000-LC20 L049.51.
For: Shultz
Machine only has one turret, no need to call for or see tool# for 2nd turret.
Deleted ToolOver20? stuff added conventional OpToolID stuff.
Deleted G95's.
Changed form to trailing zero's, always 4 places.
Added spaces between codes.
Jim Radcliffe}

{Jim & Bill worked on Canned cycles 9/29}

{5/9/89
Copied & modified: Okuma OSP 3000-LB20 L067.56.
For: Petes Workshop
Machine is an Okuma with OSP5000 LB15 control.
New 1st line of program with End of Record code.
Change format to use decimal points.
Modified canned cycles.
Jim Radcliffe}

{9/27/89, updated & added PostScript to Okuma OSP 5000 LB15 L103.55, JR}
{3/15/90, Updated: Okuma OSP 5000 LB15 L103.61 to .69.3 format, JR}

{3/15/90
Copied & modified: Okuma OSP 5000 LB15 L103.69
For: Rollason
Add 2 blank lines at start of prog. NOTE: The ReTag command removes empty lines.
Move CoolOn to Approach sub.
Add 'VLMON' & 'M215' stuff for load monitor.
Add 'D' to drilling FI-RO cycle.
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/7/90, Updated: Okuma OSP 5000LG L147.70 to .71 format & R format arcs, JR}

{10/19/90
Copied & modified: Okuma OSP 5000LG L147.71.2
Updated to Version 3.2 per Fanuc 10T MS [-] L001.71.3 Format.
Added Rapid Home to be first line of output.
Changed SeqLabC at safe start blocks to be 'N' Tool#.
Added 'G97S' CalcEPRPM# to end of last operation.
Added format for CalcEPRPM# to format definitions in prog.
Changed CutDepth output button in Rough-Contour-Turning from radius to diameter in form.
Added CoolantOff in NewTool.
Modified RoughContour cycle to output 'G82' for ApproachFace, and 'G81' for ApproachOD/ID.
Modified format for finish allowance 'U' to always be positive for RoughContour in form.
Modified RFormatArc lable to be 'L' and forced MoveX MoveZ to be non-conditional in FormatArc.
Deleted FirstFeed sub and added Feed and FeedRate to last line of Approach sub.
DWB}

{11/7/90
Copied & modified: Okuma OSP 5000LG L147.71.2
Moved 'N' Tool# from 'G97' line to NewHome line in NewTool.
Changed 'K' address to 'L' for PeckFullOut withdraw amount.
DWB}

{4/3/96
Initial: Okuma OSP 5000LG L147.71.4
Created: Okuma OSP 5000LG LXXX.71
Added support for LAP programming, Only Line # output is at lines with OpToolID, Line# matches tool#, MPK}

{4/25/96
Initial: Okuma OSP 5000LG [PPM] L439.71
Created: Okuma OSP 5000LG [PPM] L439.85
Updated to .85 format per L001.85, eliminated M216 at program beginning and M215 at program end, MPK}

{1/13/97, created metric version, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '#####.###;0'
#3 = '#0'
#4 = '###.##;0'
#5 = '#.###;0'
#6 = '###0'
#7 = '+#####.###;0'
#8 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CycleStartX#,2)
FORMAT(FinishXDia#,2)
FORMAT(CycleStartZ#,2)
FORMAT(FinishZ#,2)
FORMAT(Peck#,2)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(Tag#,6)
FORMAT(XCutDepth#,7)
FORMAT(ZCutDepth#,7)
FORMAT(ZDepthInc#,7)
FORMAT(RapidF#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
'N' Tool# OpToolID LatheOffset LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn ' G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' Speed
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
ELSE
SeqLabC SpeedC EOL
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveX MoveZ ArcRC
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC ' G04 P' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedrateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedrateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC ' G33' MoveXC MoveZC XTapAtZ ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
StandardXZArcs
SetMaxRPM('3500')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
'$' ProgramName$ '.MIN' EOR EOL
' ' EOL
' ' EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
SeqLabC Rapid Home EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
'N' Tool# CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID LatheOffset LatheOffset SpinOn ' M42' EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' CalcRPM2 EOL
END
SeqLabC Rapid NewHome
IF ProgStop?
' M00'
ELSE
ProgStop
END
EOL

{Start new Operation}

DoOpComments
DoPostScript
Plane
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
'N' Tool# Rapid CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID LatheOffset LatheOffset SpinOn ' M42' EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}
StockOff
DoOpComments
IF Drilling? AND Tap?
' ( Need to ask about this. )' EOL
END
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
SeqLabC
IF ConstantSurfaceFeed? AND NOT SameTool?
CSSOn ' G96' Speed
END
IF NOT SameTool?
IF NOT CoolOff? OR LAST ProgStop?
CoolOn
END
END
EOL
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF ApproachFace?
SeqLabC Feed ' Z' FinishZ# EOL
SeqLabC ' X' FinishXDia# EOL
SeqLabC ' Z' CycleStartZ# EOL
SeqLabC Rapid ' X' CycleStartX# EOL
ELSE
SeqLabC Feed ' X' FinishXDia# EOL
SeqLabC ' Z' FinishZ# EOL
IF ApproachOD?
SeqLabC ' X' CycleStartX# EOL
SeqLabC Rapid ' Z' CycleStartZ# EOL
ELSE {ApproachID}
SeqLabC Rapid ' X' CycleStartX# EOL
SeqLabC ' Z' CycleStartZ# EOL
END
END
END
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle
IF ApproachFace?
' NFCEł' Tag# ' D' ZCutDepth#
ELSE
IF ApproachID?
' NBORł' Tag# ' D' XCutDepth#
ELSE
' NTRNł' Tag# ' D' XCutDepth#
END
END
FeedRate XStkLeft ZStkLeft EOL
'>' Tag# EOL

IF ApproachFace?
'NFCE? G82' EOL
ELSE
IF ApproachID?
'NBOR? G81' EOL
ELSE
'NTRN? G81' EOL
END
END
SeqLabC Rapid StrtPos EOL
ToolPath
SeqLabC ' G80' EOL
IF AutoFinish?
IF ApproachFace?
SeqLabC ' G87' 'NFACEł' Tag# EOL
ELSE
SeqLabC ' G87' 'NTURNł' Tag# EOL
END
END
ELSE
IF RoughPatternShift?
SeqLabC LCycle ' Nł' Tag#
IF ApproachFace?
' D' ZCutDepth#
ELSE
' D' XCutDepth#
END
FeedRate XStkLeft ZStkLeft EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab ' G82' EOL
ELSE
SeqLab ' G81' EOL
END
SeqLabC Rapid StrtPos EOL
ToolPath
SeqLabC ' G80' EOL
IF AutoFinish?
SeqLabC ' G87 Nł' Tag# EOL
END
END
END
END
ELSE
IF Threading?
SeqLabC LCycle XatFinZ FinZ XTapAtZ
IF ConstantVolumeCut?
ToolAngle
ELSE
' B0'
END
CutDepth ThrdHeight ThrdLead ' M32'
IF SingleEdgeCut?
' M75'
ELSE
' M74'
END
IF Chamfer?
' M23'
ELSE
' M22'
END
EOL
IF AutoFinish?
SeqLabC ' G33' XatFinZ FinZ XTapAtZ ThrdLead EOL
SeqLabC RapidC XCSP EOL
SeqLabC ZCSP EOL
END
ELSE
IF Drilling?
IF Tap?
IF CWSpindle?
LCycle { will output ' G77' }
ELSE
' G78'
END
SeqLabC XCSP ZDepth ' F' FeedIPR# EOL
ELSE
SeqLabC LCycle XCSP ZDepth
IF PeckFullRetract?
' L' CycleStartZ#
END
IF NOT Peck?
' D' ZDepthInc#
END
Peck FeedRate Dwell EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC ' G04 P' Dwell# EOL
END
IF NOT FIFO?
Rapid
END
SeqLabC ZSP EOL
END
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC ' G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
ELSE
IF Drilling?
IF NOT Tap?
SeqLabC FeedC ZDepth EOL
IF Dwell?
SeqLabC ' G04 P' Dwell# EOL
END
IF NOT FIFO?
Rapid
END
SeqLabC ZSP EOL
END
END
END
END
END
END
END
IF Drilling? AND Tap? AND NOT CannedCycle?
SeqLabC SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff ' G97 S' CalcEPRPM# EOL
END
SeqLabC FirstHome ProgStop EOL
SeqLabC EOP EOL
EOR EOL
Post
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END