{Change Comments ***********************************************************}

{9/22/95, Updated Dynapath Delta 20 MT M779.81.3 to .85 format per Dynapath 20M Conv[RB] M617.85, JR}

{11/2/95
Modified: Dynapath Delta 20 MT M779.85
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.08/Catalyst v2.28.04/Compost 4.21.33/1.0a
Various necessary minor changes, too numerous to list due to time constraints.
DWB}

{3/13/96
Initial: Dynapath Delta 20 MT M779.85.1
Created: Dynapath Delta 50 MT Mxxx.86
ForUser: Micron Tech
Control: Dynapath Delta 50
Machine: ????
Develop: ComPost 4.21.34, Catalyst68K v3.02.02C
Comment: New Processor per conversation with Brian Kramer at Micron Tech
Added Coolant. Added automatic tool changer and tool offsets.
Updated to .86 format.
Jim Radcliffe}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{4/24/96
Initial: Dynapath 50M [MT] M963.89
Created: Dynapath 50M [MT] M963.89.1
ForUser: Micron Technology, Inc.
Develop: ComPost 4.21.34, Catalyst68K v3.02.13C
Comment: Modified per faxes from Brian Kramer.
Added Rigid Tapping.
Tested reported bad F and L commands.
Jim Radcliffe}

{1/31/97,
Initial: Dynapath 50M [MT] M963.89.1
Created: Dynapath 50M [AA] MY17.89
For: Advanced Air Intl.
Modified Drill cycles per customer fax of manual.
Modified subroutine calls to put a ',' between F and L words,
Modified subroutine loops to output multiple calls instead of a loop function, MPK}

{2/3/97,
Created: Dynapath 50M [AA] MY17.89.1
elimintaed us of G0s, was redundant,
Modified use tool offsets, now does not calls tool with '00' and in the next line calls another T word
which is the offset #, MPK}

{2/4/97,
Created: Dynapath 50M [AA] MY17.89.2
Fixed Tool Offsetoutput mistakenly left unmodified in NewTool, MPK}

{2/24/97
Created: Dynapath 50M [AA] MY17.89.3
deleted commas from sub output
changed SetStatusRapid to Rapid after drilling cycle, MPK}

{9/17/97
Initial: Dynapath 50M [AA] MY17.89.3
Created: Dynapath 50M LH [AA] MXXX.12
made longhand version,
MPK}

{9/23/97,
Initial: Dynapath 50M LH [AA] MW03.12
Created: Dynapath 50M LH [AA] MW03.12.1
added missing Get$ in ExitMove,
MPK
}

{12/23/98,
Initial: Dynapath 50M LH [AA] MW03.12.1
Created: Dynapath 50M LH [NP] MT68.12
For: National Presto

Changes to Prog:
1) ProgStart - Added SetMaxSeq('9999') command.
CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###.#;0'
#7 = '00'
#8 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(StartPosX#,4)
FORMAT(StartPosY#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(Retract#,4)
FORMAT(ToolDiameter#,4)
FORMAT(ADD#,4)
FORMAT(Recall#,5)
FORMAT(Tag#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(RapidF#,6)
FORMAT(DIV#,6)
FORMAT(Dwell#,6)
FORMAT(NewWFO#,7)
FORMAT(ToolOffset#,7)
FORMAT(RapidF#,8)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

Get$: { For conversational output }
IF NOT EmptyLine?
'$'
END
RETURN

TurnCRCOn:
IF CutterRadiusCompensation? AND NOT Flag?('2')
IF NOT LastFeat? AND NOT ZMove?
SetFlag('2')
Seq '(1)'
IF AutoCycle?
MoveSX '/' MoveSY '/'
ELSE
MoveSX MoveSY
END
CRCOff Get$ EOL
END
END
RETURN

TurnCRCOff:
IF CutterRadiusCompensation? AND Flag?('2')
SetFlagF('2')
Seq '(1)'
IF AutoCycle?
MoveX '/' MoveY '/'
ELSE
MoveXY
END
CRCOff Get$ EOL
END
RETURN

DoPartCycleComment:
IF MultipleParts? AND UseComments? AND SubComment?
Seq '(T) PART NO. ' Tag# Get$ EOL
END
RETURN

DoCycleComment:
IF UseComments? AND SubComment?
Seq '(T) CYCLE START ' Get$ EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
Seq '(T) OPERATION ' Operation# ' ' OperationType$ Get$ EOL
END
IF OperationComment?
Seq '(T) ' OperationComment$ Get$ EOL
END
IF WorkGroupComment?
Seq '(T) ' WorkGroupComment$ Get$ EOL
END
IF ToolTypeComment?
Seq '(T) TOOL# ' Tool# ' ' ToolDiameter# ' ' ToolType$ Get$ EOL
END
IF ToolComment?
Seq '(T) ' ToolComment$ Get$ EOL
END
RestoreScale
END
RETURN

BadMPWFOReport:
SetStatusOff
' ' EOL
'Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„' EOL
'Ä„ NOTE: Even though you have elected to Ä„' EOL
'Ä„ process this file using Multiple Ä„' EOL
'Ä„ Parts with Work Fixtures, there exist Ä„' EOL
'Ä„ non-zero values in the invisible, Ä„' EOL
'Ä„ Equally SpacedÉ fields, as follows: Ä„' EOL
'Ä„ Ä„' EOL
'*****************************************' EOL
IF NotEqual? PartShiftX# Num#('0')
' X axis shift = ' PartShiftX# EOL
END
IF NotEqual? PartShiftY# Num#('0')
' Y axis shift = ' PartShiftY# EOL
END
IF NotEqual? PartShiftZ# Num#('0')
' Z axis shift = ' PartShiftZ# EOL
END
'*****************************************' EOL
'Ä„ Ä„' EOL
'Ä„ Please reset these values to zero as Ä„' EOL
'Ä„ they affect the coordinate values Ä„' EOL
'Ä„ output, starting with Part# 2. Ä„' EOL
'Ä„ Thank You. Ä„' EOL
'Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„' EOL
' ' EOL
SetStatusOn
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC '(1)A' FourthDegree# Get$ EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC '(1)A' FourthDegree# Get$ EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC '(1)B' FifthDegree# Get$ EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC '(1)B' FifthDegree# Get$ EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
Seq PostScript Get$ EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
Seq EndOpPS Get$ EOL
PSStuff
NextPS
RETURN

EntryMove:
Seq
IF FeedEntry?
'(1)'
ELSE
'(0)'
END
ZIn
IF AutoCycle? { Implies Incremental }
'/'
END
IF FeedEntry?
FeedEnt
END
Get$ EOL
RETURN

ExitMove:
Seq
IF FeedConnect?
IF NOT AutoCycle?
IF NOT NoZMoves?
'(1)' ZIn FeedEntC
END
END
ELSE
CRCOffC
IF FIFO? { .81 }
'(1)'
ELSE
'(0)'
END
PRIME ZCP2
IF AutoCycle?
'/'
END
IF FIFO? { .81 }
FeedEntC
END
END
Get$ EOL
RETURN

ExitMove2:
IF FIFO?
'(1)' ZCP3C FeedEntC
ELSE
'(0)' ZCP3C
END
RETURN

GetPlane:
IF XYPlane?
IF NOT AutoCycle?
IF FirstFeat?
IF XMove? OR YMove?
'P0' { This is the default Plane select }
END
END
END
ELSE
IF XZPlane?
'P2'
ELSE {YZPlane}
'P1'
END
END
RETURN

CheckMove:
IF Drilling?
IF Flag?('1') AND NOT AbsValue? { AbsoluteMoves? = TRUE }
IF XMove?
MoveSX '/'
END
IF YMove?
MoveSY '/'
END
IF ZMove?
MoveSZ '/' {.80.01}
END
ELSE
MoveSXYZC {.80.01}
END
ELSE
IF AutoCycle? { Implies Incremental }
IF XMove?
MoveX '/'
END
IF YMove?
MoveY '/'
END
IF ZMove?
MoveZ '/'
END
ELSE
IF Flag?('1') AND NOT AbsValue? { AbsoluteMoves? = TRUE }
IF XMove?
MoveX '/'
END
IF YMove?
MoveY '/'
END
IF ZMove?
MoveZ '/'
END
ELSE
MoveXYZC
END
END
END
RETURN

CycleWarning:
{ NOTE: This Post Processor takes care of Z Clearance. }
RETURN

FormatArc:
GetPlane CheckMove
IF AutoCycle?
ArcI '/' ArcJ '/'
ELSE
IF Flag?('1') AND NOT AbsValue? { AbsoluteMoves? = TRUE }
ArcI '/' ArcJ '/'
ELSE
ArcIJ
END
END
IF ArcCW?
CWArc
ELSE
CCWArc
END
RETURN

ckCRC:
IF CutterRadiusCompensation? AND Flag?('2')
IF NOT LastFeat? AND NOT ZMove?
CRCOnC
END
END
RETURN

FormatLine:
GetPlane CheckMove ckCRC
RETURN

ckCRCNum:
{ Not supported }
RETURN

ToolPath:
EACHFeat
IF PointFeat? { Drilling Only }
IF NOT FirstFeat?
Seq '(0)' CheckMove Get$ EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
TurnCRCOn
IF CutterRadiusCompensation? AND Flag?('2')
Seq '(1)' FormatLine RapidFC Get$ EOL
ELSE
Seq '(0)' FormatLine Get$ EOL
END
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
TurnCRCOn
IF Decelerate?
IF RoomToDecel?
DecelMove1
Seq '(1)' FormatLine FeedRateC Get$ EOL
DecelMove2
END
Seq '(1)' FormatLine DecelFeed Get$ EOL
ELSE
Seq '(1)' FormatLine FeedRateC Get$ EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
Seq '(2)' FormatArc ArcFeedC Get$ EOL
DecelMove2
END
Seq '(2)' FormatArc DecelFeed Get$ EOL
ELSE
Seq '(2)' FormatArc ArcFeedC Get$ EOL
END
NEXTQuadrant
END
END
END
IF AutoCycle?
SetAbs
Save# Num#('6') SUB# EPX# CurOriginPosX#
Save# Num#('7') SUB# EPY# CurOriginPosY#
SetInc
END
IF LastFeat? { Exit Length Feature }
TurnCRCOff {.70}
END
END
NEXTFeat
RETURN

AutoCycCutSub1: {part 1}
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
IF Repeats? AND ZShiftOnly?
EntryMove
END
SetInc
Seq '(1)' 'P0X0./Y0./' Get$ EOL { AutoCycle dummy move to select correct Plane }
RETURN

AutoCycCutSub2: {part 2}
SetAbs
IF FIFO? {.81}
Seq '(1)' ZCP2 FeedEntC Get$ EOL
ELSE
Seq '(0)' ZCP2 Get$ EOL
END
SetSRSubXY {restore SR to 1st position value}
ReSetPass2 {restore for positioning moves}
RETURN

Milling:
EntryMove
ToolPath
RETURN

XYZRep:
CycleWarning
FindAnyZMoves
EachRep
DoCycleComment
IF FirstCycle?
EntryMove
ELSE
IF FeedConnect?
IF SPXMove? OR SPYMove?
Seq '(1)'
IF SPXMove?
MoveSX
END
IF SPYMove?
MoveSY
END
END
Get$ EOL
IF ZShiftOnly?
EntryMove
END
ELSE
IF SPXMove? OR SPYMove?
Seq '(0)'
IF SPXMove?
MoveSX
END
IF SPYMove?
MoveSY
END
END
Get$ EOL
IF FeedEntry?
Seq '(0)' ZCP2C Get$ EOL
END
EntryMove
END
END
ToolPath
ExitMove
NextRep
RETURN

NoRepAutoCycle:
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
Seq '(0)'
IF SPXMove?
MoveSX
END
IF SPYMove?
MoveSY
END
END
Get$ EOL
AutoCycCutSub1
Milling
AutoCycCutSub2
NEXTFeat
RETURN

XYZRepAutoCycle:
CycleWarning
EachRep
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
Seq '(0)'
IF SPXMove?
MoveSX
END
IF SPYMove?
MoveSY
END
END
Get$ EOL
SetAbs
Save# Num#('4') SPX#
Save# Num#('5') SPY#
SetInc
AutoCycCutSub1
Milling
AutoCycCutSub2
SetAbs
TrackXNO# ADD# Recall# Num#('4') Recall# Num#('6')
TrackYNO# ADD# Recall# Num#('5') Recall# Num#('7')
SetAbsOrInc
NEXTFeat
NextRep
RETURN

ZonlyRepAutoCycle:
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
Seq '(0)'
IF SPXMove?
MoveSX
END
IF SPYMove?
MoveSY
END
END
Get$ EOL
AutoCycCutSub1
EachRep
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc
Seq '(0)'
IF SPXMove?
MoveSX '/'
END
IF SPYMove?
MoveSY '/'
END
SetAbs
END
Get$ EOL
EntryMove
ELSE
SetAbs
ExitMove
IF SPXMove? OR SPYMove?
SetInc
Seq '(0)'
IF SPXMove?
MoveSX '/'
END
IF SPYMove?
MoveSY '/'
END
END
Get$ EOL
SetAbs
IF FeedEntry? AND NOT FIFO?
Seq '(0)' ZCP2 Get$ EOL
END
END
EntryMove
SetInc
END
ToolPath
NextRep
AutoCycCutSub2
NEXTFeat
RETURN

DrillStuff:
GetCycle
Seq '(0)' Cycle StrtPos ZDepth FeedEnt Peck
IF PeckChipBreaker?
'/Q'
END
Retract 'W' ClearancePlane2# {W word is the height that the tool begins to feed at, as well as the height to which peck full out retracts to}
'O' {O word is the Z value to which the quill retracts between holes}
IF RetractToCP1?
ClearancePlane1#
ELSE
ClearancePlane2#
END
Get$ EOL
TrackZNO# FIRST SPZ# {.81.2}
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

ProgStart:
InitProg
TagInit
SetAbs
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetMaxSeq('9999')
SetFlagF('2') { CutterRadiusCompensation }
IF PSComment? AND UseComments?
Seq '(T) PostScript:' Get$ EOL
Seq '(T) Literals: put between single or double quotes.' Get$ EOL
Seq '(T) Separate commands and literals with at least one space.' Get$ EOL
Seq '(T) A CR ( RETURN key ) will start a new line.' Get$ EOL
Seq '(T) Commands: may be capital and/or lower case letters. Separate commands with a space.' Get$ EOL
Seq '(T) EndOP -' Get$ EOL
Seq '(T) all literals and commands before an ENDOP command' Get$ EOL
Seq '(T) will appear at the beginning of the operation. All' Get$ EOL
Seq '(T) literals and commands after an ENDOP command will appear' Get$ EOL
Seq '(T) at the end of the operation.' Get$ EOL
Seq '(T) NewWFO(56), NWFO(56) -' Get$ EOL
Seq '(T) The Work Fixture Offset # you specify will be used for all following operations.' Get$ EOL
Seq '(T) Do not use with the ncPost multiple part option.' Get$ EOL
Seq '(T) 4thAxisCW(12.5), 4ACW(12.5) -' Get$ EOL
Seq '(T) generates a + A move of the value you specify' Get$ EOL
Seq '(T) 4thAxisCCW(22.5), 4ACCW(22.5) -' Get$ EOL
Seq '(T) generates a - A move of the value you specify' Get$ EOL
Seq '(T) 5thAxisCW(30), 5ACW(30) -' Get$ EOL
Seq '(T) generates a + B move of the value you specify' Get$ EOL
Seq '(T) 5thAxisCCW(22.5), 5ACCW(22.5) -' Get$ EOL
Seq '(T) generates a - B move of the value you specify' Get$ EOL
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
Plane { no output }
DoOpComments
DoPostScript
CheckPass
RETURN

OpGuts:
RapidF# { No Output }
IF Milling?
SeqC '(0)' ZCP2 Get$ EOL
IF AutoCycle?
IF Repeats?
IF ZShiftOnly?
ZonlyRepAutoCycle
ELSE
XYZRepAutoCycle
END
IF NOT FeedConnect?
SeqC ExitMove2 Get$ EOL
END
ELSE
NoRepAutoCycle
SeqC ExitMove2 Get$ EOL
END
ELSE { NOT AutoCycle }
IF Repeats?
XYZRep
ELSE
Milling
END
SeqC ExitMove2 Get$ EOL
END
ELSE
IF Drilling?
IF Repeats?
EachRep
DoCycleComment
IF FirstCycle?
DrillStuff
END
ToolPath
NextRep
ELSE
DrillStuff
ToolPath
END
SetDrillEndOpZ
Seq '(0)' Rapid ZCP3 Get$ EOL
END
END
RETURN

WFOStuff:
IF MultipleParts? AND WorkFixtureOffsets? AND NewWFO?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS AND WORK FIXTURE OFFSETS' Get$ EOL
ELSE
IF NewWFO?
'E' NewWFO#
ELSE
IF MultipleParts? AND WorkFixtureOffsets? AND NOT SameTool?
FORMAT(ADD#,7)
'E' ADD# NewWFO# SUB# Tag# Num#('1')
FORMAT(ADD#,4)
ELSE
IF NeedWFO1? AND NOT SameTool?
'E' NewWFO#
END
END
END
END
RETURN

ResetWFO:
IF WorkFixtureOffsets?
SeqC '(9)' WFO1 Get$ EOL
END
RETURN

InitOp:
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
Seq '(T) PROGRAM ' ProgramName$ Get$ EOL
END
IF FormatNameComment?
Seq '(T) FORMAT ' FormatName$ Get$ EOL
END
IF TimeComment?
Seq '(T) ' Date$ ' AT ' Time$ Get$ EOL
END
IF MovesComment?
Seq '(T) OUTPUT IN ABSOLUTE INCHES' Get$ EOL
END
IF PartsComment?
Seq '(T) PARTS PROGRAMMED ' Parts# Get$ EOL
END
IF StartToolComment?
Seq '(T) FIRST TOOL NOT IN SPINDLE' Get$ EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
Plane { no output }
DoPartCycleComment
DoOpComments
DoPostScript
Seq '(9)' ToolChng OpToolID Get$ EOL
Seq '(9)' SpinOn 'T' ToolOffset# WFOStuff Speed Get$ EOL
RETURN

FirstOp2:
RETURN

FirstOp3:
IF NOT CoolOff?
Seq '(9)' CoolOn Get$ EOL
END
CheckPass
IF Milling?
Seq '(0)' StrtPos SetStatusRapid Get$ EOL
Seq '(0)' ZCP1 Get$ EOL
END
RETURN

FirstOp3a: {can't XY position before WFO}
IF NOT CoolOff?
Seq '(9)' CoolOn Get$ EOL
END
CheckPass
IF Milling?
Seq '(0)' SetStatusRapid ZCP1 Get$ EOL
END
RETURN

NewToolOp1:
Seq '(9)' CoolOff Get$ EOL
RETURN

NewToolOp2:
DoEndOpPS
IF LAST ProgStop?
Seq '(9)' 'M0' Get$ EOL
ELSE
IF OptionalStops?
Seq '(9)' ProgStop Get$ EOL
END
END
RETURN

NewToolOp3: {Start new Operation}
Plane { no output }
DoPartCycleComment
DoOpComments
DoPostScript
Seq '(9)' ToolChng OpToolID Get$ EOL
Seq '(9)' SpinOn 'T' ToolOffset# WFOStuff Speed Get$ EOL
RETURN

NewToolOp4:
RETURN

NewToolOp5:
IF NOT CoolOff?
Seq '(9)' CoolOn Get$ EOL
END
CheckPass
IF Milling?
Seq '(0)' StrtPos SetStatusRapid Get$ EOL
Seq '(0)' ZCP1 Get$ EOL
END
RETURN

NewToolOp5a:
IF NOT CoolOff?
Seq '(9)' CoolOn Get$ EOL
END
CheckPass
IF Milling?
Seq '(0)' SetStatusRapid ZCP1 Get$ EOL
END
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
Seq '(9)' SpinOff Get$ EOL
Seq '(9)' 'M0' Get$ EOL
RETURN

SameToolOp2: {Start new Operation}
DoPartCycleComment
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
IF LAST ProgStop?
Seq '(9)' SpinOn OpToolID WFOStuff Speed Get$ EOL
IF Milling?
Seq '(0)' StrtPos SetStatusRapid Get$ EOL
Seq '(0)' ZCP1 Get$ EOL
END
ELSE
IF NewToolOffset?
Seq '(SetStatusRapid9)T' ToolOffset# WFOStuff
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
Get$ EOL
IF Milling?
Seq '(0)' StrtPos SetStatusRapid Get$ EOL
Seq '(0)' ZCP1 Get$ EOL
END
ELSE
Seq
IF NewWFO?
'(9)' WFOStuff
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
IF EmptyLine?
'(9)'
END
Speed
END
Get$ EOL
IF Milling?
Seq '(0)' StrtPos SetStatusRapid Get$ EOL
END
END
END
RETURN

End1:
Seq '(9)' CoolOff Get$ EOL
RETURN

End2:
DoEndOpPS
IF LAST ProgStop?
Seq '(9)' 'M0' Get$ EOL
ELSE
IF OptionalStops?
Seq '(9)' ProgStop Get$ EOL
END
END
RETURN

End3:
Seq '(9)' EOP Get$ EOL
CloseSub
Post2 {organize Subs into one program}
IF Flag?('4') { SubPrograms exist }
SetFlagF('4')
Seq '(9)' EOP Get$ EOL { This is required a second time, at end of all subs }
END
'END' EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'N9997(T) FILE LENGTH: ' FileBytes# ' CHARACTERS' Get$ EOL
END
IF FileFeetComment?
'N9998(T) FILE LENGTH: ' FileFeet# ' FEET' Get$ EOL
END
IF FileMetersComment?
'N9999(T) FILE LENGTH: ' FileMeters# ' METERS' Get$ EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
IF FirstOperation?
IF FirstPart?
InitOp
END
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
IF FirstOperation?
IF FirstPart?
InitOp
FirstOp1
FirstOp2
OpenMP
FirstOp3
END
ELSE
IF NewTool?
IF FirstPart?
NewToolOp1
CloseMP
ResetWFO
NewToolOp2
NewToolOp3
NewToolOp4
OpenMP
NewToolOp5
END
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
IF FirstOperation?
IF FirstPart?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
END
ELSE
IF NewTool?
IF FirstPart?
CloseMP
NewToolOp1
ResetWFO
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
END
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

NoMPs: {no multiple parts}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MasterSub:
IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END
RETURN

EndPartSub:
{End of program ************************************************************}

{finish last operation}
IF MultipleParts?
IF AllToolsOnePart?
End1
End2
CloseMP
ELSE {implied OneToolAllParts?}
IF FullUp?
End1
CloseMP
ResetWFO
End2
ELSE {implied ExitClearancePlane?}
CloseMP
End1
ResetWFO
End2
END
END
ELSE {NoMPs}
End1
End2
END
RETURN

DoNewPart:
IF NOT FirstPart?

{Finish off last Part}

IF FullUp?
Seq '(0)' SetStatusRapid ZCP1 Get$ EOL
END
{DoEndOpPS}

{Start new Part}

DoPartCycleComment
DoOpComments
DoPostScript
SeqC '(9)' WFOStuff EOL
CheckPass
IF Milling?
Seq '(0)' StrtPos SetStatusRapid Get$ EOL
END
END
RETURN

DoParts:
TagInit
EachPart
TagInc
EachOp
IF AllToolsOnePart?
MasterSub
ELSE { OneToolAllParts }
IF GTEqual? Operation# Recall# Num#('1') { Tool First Op }
IF LTEqual? Operation# Recall# Num#('2') { Tool Last Op }
IF Equal? Operation# Recall# Num#('1') { Tool First Op }
DoNewPart
END
MasterSub
END
END
END
NextOp
IF AllToolsOnePart?
EndPartSub
END
NextPart
RETURN

GetToolFirstOp:
Save# Num#('2') Recall# Num#('1')
RETURN

GetToolLastOP:
EachOp
IF Equal? Operation# Recall# Num#('2')
Save# Num#('2') ADD# Operation# Num#('1')
IF NewTool?
IF Equal? Recall# Num#('1') Recall# Num#('3')
Save# Num#('2') Operation#
ELSE
IF NotEqual? Recall# Num#('1') SUB# Recall# Num#('2') Num#('1')
Save# Num#('2') SUB# Operation# Num#('1')
END
END
END
END
NextOp
RETURN

MPLoop:
IF AllToolsOnePart?
DoParts
ELSE { OneToolAllParts }
GetToolFirstOp
IF LTEqual? Recall# Num#('1') Recall# Num#('3')
GetToolLastOP
DoParts
Save# Num#('1') ADD# Recall# Num#('2') Num#('1') { Next Tool First Op }
END
END
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF WorkFixtureOffsets?
{'NOTE: This Post Processor does not support Work Fixture Offsets for Multiple Parts.' EOL
'Therefore, the output will be controlled by the following values that are' EOL
'already entered in Equally Spaced Offsets Edit Fields:' EOL
'X' PartShiftX# ' Y' PartShiftY# ' Z' PartShiftZ# EOL
'It is recommended that you change your selection to Equally Spaced Offsets.' EOL}
IF NotEqual? PartShiftX# Num#('0')
BadMPWFOReport
ELSE
IF NotEqual? PartShiftY# Num#('0')
BadMPWFOReport
ELSE
IF NotEqual? PartShiftZ# Num#('0')
BadMPWFOReport
END
END
END
END
EachOp
IF FirstOperation?
Save# Num#('1') Operation#
ELSE
IF LastOp?
Save# Num#('3') Operation#
END
END
NextOp
MPLoop
IF OneToolAllParts?
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
EndPartSub
ELSE
ResetWFO
END
ELSE
EachOp
MasterSub
NextOp
EndPartSub
END
End3