LJMP start
ORG 0BH
INC R4
CLR TCON.5
RETI
ORG 100H

;Stale uzywane w programie
start: MOV 10H,#0EEH ;Przeniesienie odpowiednich pozycji do adresow
MOV 11H,#028H ;odpowiadajacych wyswietlanym cyfrom
MOV 12H,#0CDH
MOV 13H,#06DH
MOV 14H,#02BH
MOV 15H,#067H
MOV 16H,#0E7H
MOV 17H,#02CH
MOV 18H,#0EFH
MOV 19H,#06FH
MOV R4,#00H ;licznik przepelnien T0
MOV SP,#040H ;Stos
MOV IE,#082H ;wlaczenie przerwania od T0

;poczatek programu - pikanie
MOV P0,#00001111B
LCALL delay
MOV P0,#00010000B
LCALL delay
MOV P0,#00001111B
LCALL delay
MOV P0,#00010000B

MOV TMOD,#01H
SETB TCON.4 ;wlaczenie licznika

;1 Dioda
MOV A,#00000001B
MOV P0,A
LCALL delay ;pikniecie
LCALL guz

MOV R7,#9
los: MOV A,TL0
ANL A,#03H
CJNE A,#00,zero
MOV A,#01B
LJMP wys
zero: CJNE A,#01,jeden
MOV A,#010B
LJMP wys
jeden: CJNE A,#02,dwa
MOV A,#0100B
LJMP wys
dwa: MOV A,#01000B
wys: MOV P0,A
LCALL delay ;pikniecie
LCALL guz
DJNZ R7, los

CLR TCON.4 ;zatrzymanie licznika

dzieje: ;operacje wyswietlania czasu
;wyliczenie liczby sekund
MOV A,R4
MOV B,#61
DIV AB
MOV R5,B
MOV B,#4
MUL AB
MOV R3,A
MOV A,R5
MOV B,#4
MUL AB
MOV B,#61
DIV AB
ADD A,R3
MOV R3,A
;wyliczenie dziesietnych i setnych
MOV A,B
MOV B,#3
MUL AB
MOV B,#2
DIV AB
MOV B,#10
DIV AB
MOV R2,A
MOV R1,B
;R1-setne
;R2-dziesietne
;R3-sekundy

;poprawki adresow na kody wyswietlacza
MOV A,#10H
ADD A,R1
MOV R1,A

MOV A,#10H
ADD A,R2
MOV R2,A

MOV A,#10H
ADD A,R3
MOV R3,A

MOV P0,#00010000B
wyswie: MOV A,R3
MOV R0,A
CLR P0.7 ;wylacz setne
MOV P2,#00
MOV P2,@R0
SETB P2.4
SETB P0.5 ;wlacz sekundy
MOV R4,#50
DJNZ R4,$
MOV A,R2
MOV R0,A
MOV P2,#00
CLR P0.5 ;wylacz sekundy
MOV P2,@R0
SETB P0.6 ;wlacz dziesietne
MOV R4,#50
DJNZ R4,$
MOV A,R1
MOV R0,A
MOV P2,#00
CLR P0.6 ;wylacz dziesietne
MOV P2,@R0
SETB P0.7 ;wlacz setne
MOV R4,#50
DJNZ R4,$
LJMP wyswie

delay: MOV R6,#201
trzy: MOV R5,#248
raz: DJNZ R5,raz
DJNZ R6,trzy
RET

guz: SETB P0.4
ORL A,#11110000B
XRL A,#00001111B
CJNE A,P1,$
RET