{Change Comments ***********************************************************}

{1/22/93
Copied & modified: Mitsubishi 320M M466.81.2
For: Paxton Engineering
Machine:
Control:
Changes made per Steve at Paxton Engineering.
Changed Sub Call Label from 'L' to 'P' in Forms Strings 2 dialog.
Changed Sub Repeat Label from 'P' to 'L' in Forms Strings 2 dialog.
Changed Program ID Label from 'L' to 'O' in Forms Strings 2 dialog.
Changed Call Sub from 'G22' to 'M98' in Forms Commands 3 dialog.
Changed Return From Sub from 'G23' to 'M99' in Forms Commands 3 dialog.
Changed End Program from 'M2' to 'M30' in Forms Commands 3 dialog.
Changed FORMAT for G Address from '00' to '#0' in Forms Default Formats dialog.
Changed FORMAT for M Address from '00' to '#0' in Forms Default Formats dialog.
Added EOR EOL at StartSub.
Activated UseSeparateSubCalls and SetMaxSeparateSubCalls at setup and initializations.
Changed SetMaxRPM value from 10000 to 8000 at setup and initializations.
Added Rapid AbsOrInc 'G49G28Z0' at FirstOperation, NewTool, SameTool and end of Prog.
Deleted literal 'G28Z' at NewTool, SameTool and end of Prog.
Deleted Rapid and Moved GetSpinOn at FirstOperation, NewTool, SameTool and end of Prog.
Deleted PreTool at FirstOperation and NewTool.
Added SpinOff at NewTool, SameTool and end of Prog.
Added OpToolID at NewTool.
Modified to output CRCOff and CoolOff on separate blocks.
Changed Rapid FirstHome to literal 'G30X0Y0' at end of Prog.
DWB}

{10/4/94
Modified: Mit Meldas 300 [PE] M548.81.2
For: Paxton
Changed SpeedC in GetSpinOn sub to Speed for FirstOp and NewTool.
Changed SpeedC to Speed on Drill Cycle Tap line.
Added OptCyc1 to futher descriminate the Tap cycle for Rigid Tapping.
The E value will be the TPI value of the tap.
Added literal ',R1' to denote rigid tapping.
Jim Radcliffe}

{9/28/95, Updated Mit Meldas 300 [PE] M548.81.3 to .85 format per Fanuc 6M M001.85.01.03, JR}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{5/21/96,
Initial: Mit Meldas 300 [PE] M548.89
Created: Mit Meldas 300 [PE] M548.89.1
Fixed Boolean Logic in SameTool, the statement IF LAST ProgStop? OR CoolOff? AND LAST NOT CoolOff?
used to determine whether or not to turn off coolonat in sametool and the equivalent statement to turn coolant on
do not evaluate properly, I broke them into an equivalent IF...ELSE statement that evaluates properly. MPK}

{6/18/96,
Initial: Mit Meldas 300 [PE] M548.89.1
Created: Mit Meldas 300 Mxxx.89
For: Keith & Co.
Changed to a 'first tool in spindle' post, changed G30 at program end to G28, removed EOR in StartSub, MPK}

{7/9/96,
Initial: Mit Meldas 50M Leadwell M134.89
Created: Mit Meldas 50M Leadwell M134.89.1
Modified Rigid Tap cycle: added Speed and Spin On on line before cycle call, eliminated 'E' word, added output of thread lead.
Changed tool offset cancel in NewTool (before OpComments) and End section: now calls G91 with G28, calls G90 after G28
blocks, moved 'G28X0Y0' into IF MultipleParts? AND OneToolAllParts? AND FullUp? conditions, MPK}

{9/17/96
Intial: Mit Meldas 50M Leadwell M134.89.1
Created: Mit Meldas 50M Mxxx.89
For: C-P Mfg.
Added pretooling,
Put OpToolID and ToolChng on separate lines in FirstOperation,
Put CoolOn and OfstOn on same line in FirstOp and NewTool,
Added M19 to Offset cancel line in NewTool and end section,
Added ToolChng before prog stop in NewTool,
Deleted Untool,
Put OpToolID and ToolChng on separate lines in and move to after saftey start block in NewTool,
Added Rapid 'Y9.' at program end before ToolChng,
MPK}

{10/16/96
Intial: Mit Meldas 50M [CP] MZ37.89
Created: Mit Meldas 50M [CP] MZ37.89.1
For: C-P Mfg.
Added literal line 'G80G49G20' at program beginning,
Added tool offset cancel line before first tool change,
Changed G28 after first tool change to Rapid AbsOrInc G49 G80,
Changed clearing of offsets after toolchange to 'IncValue OfstOff',
Changed literal 'G28Z0's to OfstOff in FirstOp and NewTool,
Removed M19 command from OfstOff line before tool changes,
Put ToolChng after ProgStop in NewTool,
Put GetSpinOn on it own line in FirstOp and NewTool,
added saftey start line Rapid AbsOrInc G49G80 after tool changes,
deleted literal 'G28X0Y0' at program end,
added literal 'X0Y0' to AbsOrInc line at program end,
MPK}

{6/30/98,
Initial : Mit Meldas 50M [CP] MZ37.89.1
Created: Mit Meldas 50M [DC] MU33.89
Customer: Dicoa Company, Bill Donovan 800/425-9910

Changes to "Prog":

1. Removed all G49 output and removed G20 at tape start.
2. Removed Seq from ToolComment$.
3. Moved OpToolID (T_) to ToolChng (M6) block and removed PreTool output.
4. Added FromCP (G98/99) to canned cycle blocks and G80 to cancel the cycles.
Also force the output of ZCP3 with the G80 block.
5. For Rigid Tapping, moved R1 to be the last code in the line.
6. Added format to TrackZNO#.
JHE}

{7/2/98,
Initial : Mit Meldas 50M [DC] MU33.89
Created: Mit Meldas 50M [DC] MU33.89.1
Customer: Dicoa Company, Bill Donovan 800/425-9910

Changes to "Prog":

1. Removed all calls to GetSpinOn sub and added Speed SpinOn block before
the X & Y motion block.
JHE}

{7/14/98,
Initial : Mit Meldas 50M [DC] MU33.89.1
Created: Mit Meldas 50M [DC] MU33.89.2
Customer: Dicoa Company, Bill Donovan 800/425-9910

Changes to "Prog":

1. Removed ToolChng (M6) output before every tool change.
2. Removed G0Y9. and ToolChng (M6) output before the program End.
JHE}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0'
#5 = '#######0'
#6 = '####^###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(FeedEntry#,4)
FORMAT(FeedTapIPR#,4)
FORMAT(TrackZNO#,4) {Added - JHE}
FORMAT(Program#,5) {.72}
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Div#,5)
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
{ ToolComment$ moved to FirstOperation and NewTool. }
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO EOL
SeqC SubCall CallLab RepLab OnePart EOL
IncWFO
NextWFO
ELSE
SeqC SubCall CallLab RepLab Parts EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXY MoveZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC RapidC MoveXYZC CRCOffsetC EOL
END
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
SeqC
ELSE
'G' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
'G' NewWFO#
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetSpinOn: {Removed all calls - JHE 7/2}
IF Drilling? AND Tap?
{ Speed is output on Drill Cycle line and SpinOn is not needed }
ELSE
IF SameTool? AND LAST NOT ProgStop?
SpeedC
ELSE
Speed SpinOn
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('8000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments?
'('
IF ProgramNameComment?
ProgramName$
END
')'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq Rapid Plane CRCOff 'G80' AbsOrInc EOL
{SeqC 'G80' EOL} {Removed G49 & G20, moved G80 to 1st block - JHE}
DoOpComments
{Seq '('} {Removed Seq from comment - JHE}
IF UseComments?
IF ToolComment?
'( ' ToolComment$ ' )' EOL
ELSE
'( No Tool Comment )' EOL
END
END
SeqC Rapid IncValue OfstOff EOL
SeqC ToolChng OpToolID EOL {Moved OpToolID to here - JHE}
SeqC Rapid 'G80' AbsOrInc EOL {Removed G49 - JHE}
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC WFOStuff EOL
OpenMP
CheckPass
SeqC Speed SpinOn EOL {Added this line - JHE 7/2}
SeqC AbsOrInc StrtPos EOL {Removed PreTool - JHE}
{SeqC GetSpinOn EOL} {Removed - JHE 7/2}
ELSE
CheckPass
SeqC Speed SpinOn EOL {Added this line - JHE 7/2}
SeqC WFOStuff StrtPos EOL {Removed PreTool - JHE}
{SeqC GetSpinOn EOL} {Removed - JHE 7/2}
END
SeqC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CRCOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC CoolOff EOL
SeqC Rapid IncValue OfstOff EOL { Clear Offsets }
SeqC AbsOrInc EOL
CloseMP
SeqC SpinOff EOL
ELSE
SeqC SpinOff EOL
SeqC CoolOff EOL
SeqC Rapid IncValue OfstOff EOL { Clear Offsets }
SeqC AbsOrInc EOL
END
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
{SeqC ToolChng EOL} {Removed - JHE 7/13}

{Start new Operation, NewTool}

SeqC PlaneC EOL
DoOpComments
{Seq '('} {Removed Seq from comment - JHE}
IF UseComments?
IF ToolComment?
'( ' ToolComment$ ' )' EOL
ELSE
'( No Tool Comment )' EOL
END
END
Seq Rapid IncValue OfstOff EOL
SeqC ToolChng OpToolID EOL {Moved OpToolID to here - JHE}
DoPostScript
SeqC Rapid 'G80' AbsOrInc EOL {Removed G49 - JHE}
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC WFOStuff EOL
OpenMP
CheckPass
SeqC Speed SpinOn EOL {Added this line - JHE 7/2}
SeqC AbsOrInc StrtPos EOL {Removed PreTool - JHE}
{SeqC GetSpinOn EOL} {Removed - JHE 7/2}
ELSE
CheckPass
SeqC Speed SpinOn EOL {Added this line - JHE 7/2}
SeqC WFOStuff StrtPos EOL {Removed PreTool - JHE}
{SeqC GetSpinOn EOL} {Removed - JHE 7/2}
END
SeqC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?

{Finish off last Operation}

SeqC CRCOff EOL
IF LAST ProgStop?
SeqC SpinOff EOL
SeqC CoolOff EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF LAST ProgStop? OR NewToolOffset?
SeqC Rapid AbsOrInc 'G28Z0' EOL {Removed G49 - JHE}
END
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
END

{Start new Operation, SameTool}

SeqC PlaneC EOL
DoOpComments
DoPostScript
CheckPass
IF LAST ProgStop?
SeqC Speed SpinOn EOL {Added this line - JHE 7/2}
SeqC WFOStuff Rapid StrtPos EOL
ELSE
SeqC WFOStuff RapidC StrtPos SpeedC EOL
END
{SeqC GetSpinOn EOL} {Removed - JHE 7/2}
IF LAST ProgStop?
SeqC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
IF LAST ProgStop? OR NewToolOffset?
SeqC OfstOn EOL
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
{*** Removed 3 lines - JHE 7/2
IF RigidTap?
SeqC Speed SpinOn EOL
END ***}
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract {Added FromCP - JHE}
IF Tap?
IF RigidTap?
Speed 'F' FeedTapIPR#('1') ',R1' EOL {Moved R1 to end of line - JHE}
ELSE
Speed 'E' FeedEntry# EOL
END
ELSE
FeedEnt EOL
END
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL {Added G80, removed C from ZCP3 - JHE}
IF Repeats?
FinishSubG92
END
{SeqC RapidC ZCP3C EOL} {Removed - JHE}
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CRCOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC CoolOff EOL
SeqC Rapid IncValue 'G28Z0M19' EOL { Clear Offsets }
CloseMP
SeqC AbsOrInc 'X0Y0'EOL
SeqC SpinOff EOL
ELSE
SeqC SpinOff EOL
SeqC CoolOff EOL
SeqC Rapid IncValue 'G28Z0M19' EOL { Clear Offsets }
SeqC AbsOrInc 'X0Y0'EOL
END
DoEndOpPS
{SeqC Rapid 'Y9.' EOL} {Removed - JHE 7/13}
{SeqC ToolChng EOL} {Removed - JHE 7/13}
IF ProgStop?
SeqC 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END