{Change Comments ***********************************************************}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{1/11/91, Updated "Fanuc 0T Miyano (1) L057.54" to ".71", JR}

{2/12/91
Copied & modified: Fanuc 0T Miyano (1) L057.71
For: Gibbs & Associates
Machine: Miyano
Control: Fanuc 0T
Updated to Version 3.2 per Fanuc 10T MS [-] L001.71.4 Format.
DWB}

{8/9/95, Updated Fanuc 0T Miyano (1) L057.71.4 to .85 format per Fanuc 10T MS [-] L001.85.01, JR}

{
Format: Mit Meldas 50L Lxxx.85
4/26/96
Changed Thread canned cycle to match manual
TH}

{8/1/96,
Initial: Mitsubishi Meldas 50L L447.85
Created: Mit Meldas 50L [PEP] Lxxx.85
Made RapidC home positioning line in FirstOperation? unconditional
Added literal 'G54' to AppMove that outputs when FirstOperation? is true
MPK}

{2/28/97,
Initial: Mit Meldas 50L [PEP] L492.85
Created: Mit Meldas 50L [PEP] L492.85.1
added literal R retract value to G71 cycle,
modifed output of start pos for G71 cycle so X and Z values are not on the same line,
MPK}

{4/14/97,
Initial: Mit Meldas 50L [PEP] L492.85.1
Created: Mit Meldas 50L [PEP] L492.85.2
Modified lathe drill cycles, deleted PeckPR cycle, added FIRO, PeckFO, Bore cycle, and changed tap all
per manual.
Moved lines that force sequence number to before op comments in FirstOp and NewTool, MPK}

{4/15/97,
Initial: Mit Meldas 50L [PEP] L492.85.2
Created: Mit Meldas 50L [PEP] L492.85.3
Deleted all remaining entries in TE boxes for PeckPR in Lathe drill cycles, R word for G76 threading cycle no
outputs LastCutXRadius#, MPK}

{4/15/97,
Initial: Mit Meldas 50L [PEP] L492.85.3
Created: Mit Meldas 50L [PEP] L492.85.4
Replaced space between 'OPERATION' and Operation# in DoOpComments with an underscore, MPK}

{5/5/97,
Initial: Mit Meldas 50L [PEP] L492.85.4
Created: Mit Meldas 50L [PEP] L492.85.5
modified CheckOffset sub to not output redundant S words, MPK}

{2Jul97
Original: Mit Meldas 50L [PEP] L492.85.5
Created: Mit Meldas 50L [PEP] L492.85.6
For: Precision Enhanced Products
Changes made per: Robert Morelli
Moved 'G54' from AppMove to FirstOperation
Changed Literal 'R0' in Drill-Cycle to RLevel
Added R-word to Drill Cycles in MachSpec
Charles Winston}

{15Sep97
Original: Mit Meldas 50L [PEP] L492.85.6
Created: Mit Meldas 50L [PEP] L492.85.7
For: Precision Enhanced Products
Changes made per: Robert Morelli
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Added Formats for SUB#, DIV#, ThreadStarts, Recall# and Thread# in Prog Numeric Format
Definitions
Added Multiple-Start Threading Canned Cycle at IF Threading supported by the following
subs, ThreadsPerInch#, Pitch#, IncrementalPitch#, ThreadStart and DoNumThreadStarts

*** WARNING *** When doing Multiple Start Threads, Virtual incorrectly scales the
Thread# and ThrdLead commands These are rescaled in the ThreadsPerInch#
& Pitch# Subs. This post will NOT work if this bug is fixed.
Charles Winston}

{30Sep97
Original: Mit Meldas 50L [PEP] L492.85.7
Created: Mit Meldas 50L [PEP] L492.85.8
For: Precision Enhanced Products
Changes made per: Robert Morelli
Changed IncrementalPitch# to Pitch# in ThreadStart sub
Changed Pitch# to the inverse of Thread# in ThreadStart sub
In ThreadStart, added a Rapid and an incremental Z move, ( from SPZ# away from the part ),
between succesive thread starts, and a Boolean to suppress its output after the
last pass. ( Note: Moved away from the part because its safer. )
In DoNumThreadStarts added a Rapid and an incremental Z move, ( from SPZ# away from
the part ), after the First thread pass, and a Boolean to suppress its output if
its only a Single Start Thread.
Added Save# SPZ# Num#('8') to store the Z-start of the Canned Cycle at IF Threading
Added FORMAT#9 and changed Recall# and DIV# from FORMAT#2
Charles Winston}

{4Oct97
Original: Mit Meldas 50L [PEP] L492.85.8
Created: Mit Meldas 50L [PEP] L492.85.9
For: Precision Enhanced Products
Changes made per: Robert Morelli
Added FORMAT#10 and changed DIV# at Prog Numeric Format Definitions
Note: customer requires 5 dec. pl. for the FeedRate in his Threading Canned Cycle.
Changed SeqLab to SeqlabC for Plane CRCOff 'G64G54' in FirstOperation.
Changed SeqLabC to Seqlab for Rapid Home in FirstOperation.
Added Boolean to output a ProgStop in FirstOperation.
Charles Winston}

{6/29/98,
Initial : Mit Meldas 50L [PEP] L492.85.9
Created: Mit Meldas 50L [DC] L743.85
Customer: Dicoa Company, Bill Donovan 800/425-9910

Changes to "Prog":

1. Added FORMAT #3 for Tag# to eliminate the output of . blocks after G71.
2. At tape start, removed G64 and added G0, G80, G97, & G99.
3. Moved M0/M1 block to be the 2nd block.
4. Removed OpToolID '00' output in M3 blocks and OpToolID LatheOffset in M8 blocks.
Also removed tool output before tool change with the motion Home.
5. Added OpToolID to the Home block.
6. At tape end, removed the output of the 1st tool.
7. Added part catcher ON (M70) and OFF (M74) when CutOff? is true.
JHE}

{7/2/98,
Initial : Mit Meldas 50L [DC] L743.85
Created: Mit Meldas 50L [DC] L743.85.1
Customer: Dicoa Company, Bill Donovan 800/425-9910

Changes to "Prog":

*** NON STANDARD SUPPORT FOR TOOLS NUMBER 11 AND UP ***

1. Added getSideLathe sub. For tools 1 thru 10 output +X and for the rest, -X.
For tools 11 and up, reverse G2/G3 output.
2. Added a call to getSideLathe before every tool change.
3. Added getSpinOn sub. For tools 11 and up, reverse spindle direction.
4. Changed all the SpinOn to getSpinOn sub call.
5. Added getInverseSpinOn sub. For tools 11 and up, reverse spindle for exit tapping.
6. Changed InverseSpinOn to getInverseSpinOn sub call.
7. Added getSpinOff sub. When changing from tools 1-10 to 11-20 or vise-versa,
stop the spindle.
8. Added a call to getSpinOff before NewTool.
JHE}

{7/14/98,
Initial : Mit Meldas 50L [DC] L743.85.1
Created: Mit Meldas 50L [DC] L743.85.2
Customer: Dicoa Company, Bill Donovan 800/425-9910

Changes to "Prog":

1. Changed back all the getSpinOn to SpinOn.
2. Changed back getInverseSpinOn to InverseSpinOn.
3. Changed getSpinOff sub logic. When changing from CW to CCW spindle direction
or vise-versa, stop the spindle.
4. For Tapping, changed dwell from 2 sec to 0.5 and 1.0 sec.
JHE}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '#'
#8 = '00'
#9 = '##0.00##;0.'
#10 = '##0.00###;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(FirstMoveEPZ#,2)
FORMAT(LastCutXRadius#,2)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(SUB#,2)
FORMAT(Thread#,2)
FORMAT(FinishZ#,2)
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Tag#,3) {Added - JHE}
FORMAT(Dwell#,4)
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(SpringPasses#,8)
FORMAT(ThreadStarts#,6)
FORMAT(InFeedAngle#, 8)
FORMAT(Recall#, 9)
FORMAT(DIV#, 10)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

getSideLathe:
{if tool number greater than 10, output -X & reverse G2/3}
IF GreaterThan? Tool# Num#('10')
NegSideLathe
ReverseXZArcs
ELSE
PosSideLathe
StandardXZArcs
END
RETURN

getSpinOff: {Changed logic - JHE}
{if changing from CW to CCW spindle direction or vise-versa, stop the spindle}
IF CWSpindle? AND LAST NOT CWSpindle?
SeqLabC SpinOff EOL
END
IF NOT CWSpindle? AND LAST CWSpindle?
SeqLabC SpinOff EOL
END
{*** Removed - JHE 7/14
{if changing from tools 1-10 to 11-20 or vise-versa, stop the spindle}
IF GreaterThan? Tool# Num#('10')
IF LessThan? LAST Tool# Num#('11')
SeqLabC SpinOff EOL
END
ELSE
IF GreaterThan? LAST Tool# Num#('10')
SeqLabC SpinOff EOL
END
END ***}
RETURN

getSpinOn: {Removed all calls to this sub - JHE 7/14}
{if tool number greater than 10, reverse the spindle direction of rotation}
IF GreaterThan? Tool# Num#('10')
InverseSpinOn
ELSE
SpinOn
END
RETURN

getInverseSpinOn: {Removed all calls to this sub - JHE 7/14}
{if tool number greater than 10, reverse the spindle direction for exit tapping}
IF GreaterThan? Tool# Num#('10')
SpinOn
ELSE
InverseSpinOn
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION_' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn {Removed OpToolID LatheOffset - JHE}
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
{*** Removed this check and output - JHE
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END ***}
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed
END
END
END
IF LAST ProgStop?
SpinOn EOL
SeqLabC CoolOn EOL
ELSE
EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P500' EOL {Changed from 2000 - JHE 7/14}
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

ThreadsPerInch#:
MUL# ThreadStarts# Thread#
RETURN

Pitch#:
DIV# NUM#('1') ThreadsPerInch#
RETURN

IncrementalPitch#:
DIV# Pitch# ThreadStarts#
RETURN

ThreadStart:
IF GreaterThan? Recall# NUM#('9') NUM#('0')
SeqLabC LCycle XatFinZ
Save# NUM#('10') ADD# Recall# NUM#('10') Pitch#
'Z' Recall# NUM#('10') XTapAtZ CutMethod ThrdHeight CutDepth 'F' DIV# NUM#('1') Thread# EOL
IF NotEqual? Recall# NUM#('9') NUM#('1')
Save# NUM#('8') ADD# Recall# NUM#('8') Pitch#
SeqLabC Rapid 'Z' Recall# NUM#('8') EOL
END
END
Save# NUM#('9') SUB# Recall# NUM#('9') NUM#('1') {counter}
RETURN

DoNumThreadStarts: { for Single or Multiple Start Threads }
Save# NUM#('9') ThreadStarts#
Save# NUM#('10') FinishZ#
SeqLabC LCycle XatFinZ 'Z' FinishZ# XTapAtZ CutMethod ThrdHeight CutDepth 'F' DIV# NUM#('1') Thread# EOL
IF NotEqual? Recall# NUM#('9') NUM#('1')
Save# NUM#('8') ADD# Recall# NUM#('8') Pitch#
SeqLabC Rapid 'Z' Recall# NUM#('8') EOL
END
Save# NUM#('9') SUB# Recall# NUM#('9') NUM#('1') { Reduce the counter by 1 at the start }
ThreadStart ThreadStart ThreadStart ThreadStart ThreadStart
ThreadStart ThreadStart ThreadStart ThreadStart ThreadStart
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
getSideLathe {Added this sub call - JHE 7/2}
RestoreScale
OpenSub
StockOff
SetHome
SeqLabC Plane Rapid CRCOff 'G80G97G99G54' EOL
{Removed G64, added Rapid, G80, G97=Constant RPM, & G99=IPR feed - JHE}
IF ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
DoOpComments
DoPostScript

SeqLab Rapid Home OpToolID EOL {Added OpToolID - JHE}
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL {Removed OpToolID '00' - JHE}
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff
IF LAST CutOff?
SeqLabC 'M74' EOL {Added, part catcher OFF - JHE}
END
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
SeqLabC Home EOL {Removed LOfstOff '00' - JHE}
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation, NewTool}

getSideLathe {Added this sub call - JHE 7/2}
DoOpComments
DoPostScript
getSpinOff {Added this sub call - JHE 7/2}
SeqLab RapidC Home OpToolID EOL {Added OpToolID - JHE}
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL {Removed OpToolID '00' - JHE}
Approach
ELSE
IF SameTool?

{Start new Operation, SameTool}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
IF CutOff?
SeqLabC 'M70' EOL {Added, part catcher ON - JHE}
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle CutDepth 'R.020' {Retract value} EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC FeedC 'X' SPX# EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC FeedC 'Z' SPZ# EOL
END
ELSE
IF RoughPatternShift?
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
Save# Num#('8') SPZ#
SeqLabC LCycle 'P' SpringPasses# '00' InFeedAngle# 'R' LastCutXRadius# EOL
DoNumThreadStarts { For Single or Multiple Start Threads }
ELSE
IF Drilling?
SeqLabC LCycle ZDepth RLevel Dwell Peck FeedRate 'K1' EOL
SeqLabC DrillOff EOL
SeqLabC Rapid ZSP EOL
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P1000' EOL {Changed from 2000 - JHE 7/14}
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CutOff?
SeqLabC 'M74' EOL {Added, part catcher OFF - JHE}
END
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqLabC FirstHome SpinOff EOL {Removed OpToolID '00' - JHE}
{SeqLabC UnTool '00' EOL} {Removed - JHE}
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END