{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=T
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{1/10/94
Copied & odified: Fan 10M MS MVJr[¨] M050.81.2
For: Sunrise West
Machine: Comet 1250 VMC Machining Center
Control: Mitsubishi 330M
Versions: ncCad 4.32/ncCam 4.32/ncPost 4.32.01/Compost4.21.19
Changes made per conversation with Rike Miller at Sunrise West and sample program.
Added G43 to Tool Length Offset Enable in Composts Commands 5 Dialog.
Cosmetic changes to FirstOperation, NewTool and end of Prog.
Changed literal 'G30Y0.' to 'G30Z0.' at NewTool and end of Prog.
Customer says G30Y0. is normal for Horizontal machine, but his is a Verticle machine.
Deleted support of CutterRadiusCompensation.
Requested because customer uses Virtual and does not allow him to turn it off.
Deleted CRCOffC at FinishSub1 sub, RapidFeat and LineFeat at ToolPath, NewTool and end of
IF Milling.
Deleted CkCRC sub and call to same at StdLine.
Deleted CRCOffsetC at StdLine.
Deleted ResetCRCNum at ToolPath.
Changed to FIRST TOOL NOT IN SPINDLE at FirstOperation.
Deleted PreTool at FirstOperation and NewTool.
Deleted ToolChng handling of ToolOver(1) situation at end of Prog.
DWB}

{3/15/96, Updated to .84 version, MPK}
{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{8/6/96
Updated: Mit 330M Comet [SRW] M620.87
Created: Mit 330M Comet [SRW] M620.89
For: Gibbs & Associates/Riedel Machine Company
Machine:
Control:
Versions: Catalyst v3.05.03C/Compost 4.21.37/v1.0b1
Updated for Catalyst v3.05C per Fanuc 6M M001.89 Format
DWB}

{8/8/96
Copied: Mit 330M Comet [SRW] M620.89
Created: Mit 520AM Comet [RM] MZ18.89
For: Riedel Machine Company
Machine: Comet VMC500
Control: Mitsubishi Meldas 520AM
Versions: Catalyst v3.05.03C/Compost 4.21.37/v1.0b1
Changes made per Richard Riedel.
Added FORMAT#7, '#' at Prog Numeric Format Definitions.
Added DIV# to FORMAT#5 at Prog Numeric Format Definitions.
Added RapidF# to FORMAT#7 at Prog Numeric Format Definitions.
Added support of CutterRadiusCompensation at normal places.
Added condition to output Feed ZCP3 'F50.' RapidF# to CRCOff at FinishSub1 and IF Milling.
Deleted Flag(2) at ckCRC and ckCRCNum subs and at setup and initializations.
Moved CRCOffsetC from ckCRCNum sub to ckCRC sub.
Deleted contents of ckCRCNum sub and calls to same.
Modified startup code for FirstOperation, NewTool and SameTool.
Modified OfstOff block at NewTool, SameTool and end of Prog.
Added ckSpeed sub.
Suppresses Speed SpinOn for RigidTap Cycle.
Changed to FIRST TOOL IN SPINDLE at FirstOperation.
Added special codes for RigidTap Cycle support at IF Drilling.
Added UnTool ToolChng at end of Prog.
DWB}

{12Aug98
Original: Mit 520AM Comet [RM] MZ18.89
Created: Mit 520AM Comet [ABB] Mxxx.89
For: ABB, Columbus Ohio
Changes made per: David Batteiger
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Added Formatting for FeedTapIPR# in Prog Numeric Format Definitions
Added Speed to CkSpeed Sub for Rigid Tapping
Deleted AbsOrInc and added 'G91' to OffsetOff Line in FirstOperation, NewTool and SameTool
Added AbsOrInc to StartPos line in FirstOperation, NewTool and SameTool
Changed 'E', Inverse FeedTapIPR# to 'F' FeedTapIPR# for rigid Tapping and deleted Speed
Deleted Literal 'G30X0Y0' at End of Porg
Charles Winston}

{8/25/98
Initial: Mit 520AM Comet [ABB] MU61.89
Created: Mit 520AM Comet [ABB] MU61.89.1
Develop: ComPost2 1.1b3, Virtual Gibbs 4.24
Comment: Corrected per marked up readout from David Batteiger
Full Up Z move at end of program was being done in AbsOrInc.
Deleted AbsOrInc and added 'G91' as in previous post modification.
Jim Radcliffe}

{11/9/98
Initial: Mit 520AM Comet [ABB] MU61.89.1
Created: Mit 520A AS [RH] Mxxx.89
ForUser: RH Machine
Control: Mitsubishi 520A
Machine: Akira-Seiki SV100
Develop: Compost2 v1.6b8, Virtual 4.29.63
Comment: New processor per notes & marked up readout from Tom Donaldson
Modified saftey start line.
Moved tool change to saftey start line.
Modified OfstOff line & suppressed output at end of tools to output with MPFU only.
Added PreTool.
Changed 'F' FeedTapIPR# to 'E', Inverse FeedTapIPR# for RigidTap and added Speed
Deleted Speed from CkSpeed Sub for RigidTap
Added Literal 'G30X0Y0' at end of prog.
Changed formatter for Dwell to use decimal point.
Added extended WFOs. G54 thru G59 then G54.1P1 thru G54.1P48. Set 1 thru 54 in MachSpec!
Jim Radcliffe}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####.###;0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ClearancePlane3#,4)
FORMAT(ToolDiameter#,4)
FORMAT(FeedTapIPR#,4)
FORMAT(TrackZNO#,4)
FORMAT(DIV#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(ADD#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)

{Special WFO Subroutines ***************************************************}

CalcWFO#:
ADD# SUB# PartNum# Num#('1') NewWFO#
RETURN

WorkFixtureOffset:
IF GreaterThan? CalcWFO# Num#('6')
'G54.1P' ADD# CalcWFO# Num#('-6')
ELSE
'G' ADD# CalcWFO# Num#('53')
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF NOT EmptyLine?
Feed ZCP3 'F50.' RapidF#
ELSE
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO {simple eachPart}
SeqC WorkFixtureOffset EOL
SeqC SubCall CallLab RepLab OnePart EOL
IncWFO
NextWFO {simple NextPart}
ELSE
SeqC SubCall CallLab RepLab Parts EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC NewWFO WorkFixtureOffset EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC CRCOffsetC
END
END
RETURN

FormatLine:
DoAbsOrInc ckCRC FeedC MoveXYZC
RETURN

ckCRCNum:
{ Not Needed }
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatLine FeedRateC EOL
DecelMove2
END
SeqC FormatLine DecelFeed EOL
ELSE
SeqC FormatLine FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
IF AllToolsOnePart?
EOL
'*** WARNING ***' EOL
'DO NOT USE NEWWFO() WITH MULTIPLE PARTS ONE PART ALL TOOLS' EOL
SeqC
ELSE
IF SameTool?
EOL
'*** WARNING ***' EOL
'DO NOT USE NEWWFO() ON A SAME TOOL OPERATION WITH MULTIPLE PARTS' EOL
SeqC
ELSE
WorkFixtureOffset
END
END
ELSE
WorkFixtureOffset
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
WorkFixtureOffset
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

CkSpeed:
GetCycle
IF Drilling? AND RigidTap?
ELSE
IF FirstOperation? OR NewTool?
Speed SpinOn
ELSE { SameTool }
IF LAST ProgStop?
SpeedC SpinOn
ELSE
SpeedC
END
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(1), NWFO(1) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Value defaults to 1 for G54 output. Example: set value to 10 to get G54.1P4 output.' EOL
' Do not use with the Post multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
Seq Rapid AbsOrInc 'G49' CRCOff 'G28Z0' OpToolID ToolChng EOL
CheckPass
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC WFOStuff CkSpeed PreTool EOL
OpenMP
SeqC AbsOrInc Plane Rapid StrtPos EOL
ELSE
SeqC WFOStuff Plane StrtPos CkSpeed PreTool EOL
END
SeqC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC Rapid 'G49' 'G28Z0' EOL { OfstOff }
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Seq Rapid AbsOrInc 'G49' CRCOff 'G28Z0' OpToolID ToolChng EOL
CheckPass
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC WFOStuff CkSpeed PreTool EOL
OpenMP
SeqC AbsOrInc Plane Rapid StrtPos EOL
ELSE
SeqC WFOStuff Plane StrtPos CkSpeed PreTool EOL
END
SeqC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC Rapid 'G49' 'G28Z0' EOL { OfstOff }
SeqC SpinOff EOL
SeqC 'M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqC WFOStuff PlaneC AbsOrInc Rapid StrtPos CkSpeed EOL
SeqC OfstOn CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC Rapid 'G49' 'G28Z0' EOL { OfstOff }

{Start new Operation}

GetStartOfSameTool
SeqC WFOStuff PlaneC AbsOrInc Rapid StrtPos CkSpeed EOL
SeqC OfstOn EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC WFOStuff PlaneC AbsOrInc Rapid StrtPos CkSpeed EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
CRCOffC
IF NOT EmptyLine?
SeqC Feed ZCP3 'F50.' RapidF# EOL
ELSE
IF FIFO?
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
IF Tap? AND NOT CWSpindle?
'G74'
ELSE
Cycle
END
SeqC FromCP StrtPos ZDepth RLevel Dwell Peck Retract
IF RigidTap?
'E' DIV# Num#('1') FeedTapIPR#('1') Speed ',R1'
ELSE
FeedEnt
END
EOL
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC Rapid 'G49' 'G28Z0' EOL { OfstOff }
CloseMP
END
DoEndOpPS
IF ProgStop?
SeqC 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC 'G30X0Y0' EOL
SeqC UnTool ToolChng EOL
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END