{Change Comments ***********************************************************}

{7/7/95, Updated for Catalyst v2.20 per Fanuc 6M M001.10 Format, DWB}
{7/18/95, Added IF NOT LastFeat? at CkCRC sub, DWB}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{7/12/96
Modified: Fanuc 6M M001.12
Created: Fanuc 6M M001.13.1
For: Gibbs & Associates
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.05C/Compost 4.21.37/1.0a
Updated to .13 version.
DWB}

{10/2/96, updated to .14 format per Fanuc 6M (FW) B001.14, MPK}

{11/22/96
Versions: Catalyst v3.23C/Compost 4.21.37/v1.0b1
.14 Additions:
Deleted Flag(2) for CRCOffsetC at ckCRC and ckCRCNum subs and at setup and initializations.
Added NOT LastFeat? AND Equal? SPZ# EPZ# condition at ckCRCNum sub.
Moved contents of FormatLine back to ToolPath LineFeat.
Modified WorkFixtureOffset logic.
Added Flag(2) for WFOStuff at setup and initializations.
Added SetFlag(2) for EquallySpacedOffsets at OpenMP sub.
Added WFONum sub.
Rewrote logic at WFOStuff sub.
Added EOL to NewWFO MP WFOStuff sub Warning.
Deleted SeqC and EOL at WFOStuff sub.
Added Flag(2) logic at start of EachOp/NextOp Loop.
Moved WFOStuff after MP-OTAP-FU condition at FirstOperation and NewTool.
Added WFOStuff for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added AbsOrInc Rapid to StrtPos block for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added SeqC and EOL at WFOStuff calls at GetStartOfSameTool, FirstOperation and NewTool.
Added SetMaxFeed(12700) for Metric VNC files.
Moved Speed SpinOn after MP-OTAP-FU condition at FirstOperation and NewTool.
Added Speed SpinOn for MP-OTAP-ECP condition at FirstOperation and NewTool.
DWB}

{2/25/97
Modified: Fanuc 6M M001.14
Created: Fanuc 6M M001.15
For: Gibbs & Associates
Versions: Catalyst v3.30C/ComPost2 MSL 68K
Added Flag(5) to Suppress Redundant WFO for MultipleParts WorkFixtureOffsets programs.
Only concerns OneToolAllParts ExitClearancePlane situations.
DWB}

{5/7/98,
Initial : Fanuc 6M M001.15
Created: Fanuc 0M LM [HC] MV76.15
Customer: Harris Corp (Texas Offline), Duane Smith or Carlos 210/561-7300

***** CUSTOM FIXTURE OFFSET SUPPORT *****

*** SUPPORT 1 PART PROGRAMMING
*** SUPPORT MULTI PARTS with WORK FIXTURES and ONE TOOL ALL PARTS ONLY !!!

Changes to "Prog":

1. Changes to InitOp and FirstOp subs to match the customer output.
Moved Z-axis motion to FirstOp2 and X & Y to FirstOp3.
2. Changes to NewToolOp subs to match the customer output.
Moved Z-axis motion to NewToolOp4 and X & Y to NewToolOp5.
3. Changes to SameToolOp subs to match the customer output.
4. Changes to End subs to match the customer output.
5. Changed motions to Tool Change to be included in the customer's P7050 sub.
6. Changed program ID address from O to : and added a space line.
7. Added SetProgNum('8000').
8. Removed all calls to WFOStuff and added G[53+#1].
9. In OpenMP sub, removed EachWFO NextWOF loop (execute it only 1 time).
10. In CloseMP sub, removed WFO1 (G54) output.
12. Removed MPallTools1P sub execution and added a warning.
13. In MP1ToollAllPfu sub, added IF WorkFixtureOffsets? check and if not
(implies equally spaced), added a warning.
14. In MP1ToollAllPfu sub, added OfstOn motion after OpenMP and OfstOff before CloseMP.
Also Moved OpenMP one step down and CloseMP one step up.
15. In MP1ToollAllPXcp sub, added IF WorkFixtureOffsets? check and if not
(implies equally spaced), added a warning.
16. In MP1ToollAllPXcp sub, moved OpenMP one step up. Also Removed FirstOp2 and
NewToolOp4 subs after OpenMP.
JHE}


{Prog Numeric Format Definitions ********************************}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)

{Prog Subroutines ***********************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

WFONum:
'G' NewWFO#
RETURN

WFOStuff: {Removed all calls to this sub - JHE}
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
WFONum
END
ELSE
IF Flag?('2')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
WFO1
ELSE
WFONum
END
ELSE
WFONum
END
END
END
END
SetFlagF('2')
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
' ' EOL {Added space line - JHE}
':' Program# EOL {Changed from SubID - JHE}
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
NewWFO
{EachWFO} {Removed loop, execute only 1 time - JHE}
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
{SeqC SetWFO EOL} {Removed this line - JHE}
END
SeqC SubCall CallLab EOL {Removed RepLab & OnePart - JHE}
IncWFO
{NextWFO}
ELSE
SeqC SubCall CallLab RepLab Parts EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
{SeqC WFO1 EOL} {Removed this line - JHE}
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

InitOp:
EOR EOL
':' Program# {Changed from ProgID1 - JHE}
IF UseComments? AND ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )'
END
EOL
SetProgNum('8000') {Added - JHE}
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
{SeqC Plane CRCOff 'G80' EOL} {Removed this line - JHE}
SeqC 'M200' EOL {Initialize control's default codes} {Added the next 12 lines - JHE}
{G01 G17 G40 G49 G54 G80 G90 G94 G98}
'#511=1. (# of vise stations needed to run parts)' EOL
'(set work coordinates)' EOL
SeqC Rapid Plane AbsValue EOL
SeqC 'G10L2P1 X0.0Y0.0Z0.0' EOL
SeqC 'G10L2P2 X0.0Y0.0Z0.0' EOL
SeqC 'G10L2P3 X0.0Y0.0Z0.0' EOL
SeqC 'G10L2P4 X0.0Y0.0Z0.0' EOL
SeqC 'G10L2P5 X0.0Y0.0Z0.0' EOL
SeqC 'G10L2P6 X0.0Y0.0Z0.0' EOL
SeqC IncValue OfstOff EOL
SeqC 'G28X0.Y0.' EOL
SeqC OpToolID ToolChng EOL {Added ToolChng - JHE}
{SeqC ToolChng EOL} {Moved up - JHE}
DoOpComments
DoPostScript
RETURN

FirstOp2:
{SeqC WFOStuff EOL} {Removed - JHE}
{SeqC Speed SpinOn EOL} {Moved to motion block - JHE}
CheckPass
SeqC Rapid AbsOrInc OfstOn Speed SpinOn EOL
SeqC CoolOn PreTool EOL {Added PreTool - JHE}
'#1=1.' EOL {Added next 3 lines - JHE}
'while[#1le#511]do1' EOL
'g[53+#1]' EOL
RETURN

FirstOp3:
SeqC Rapid StrtPos Speed EOL
RETURN

NewToolOp1:
'#1=#1+1.' EOL {Added next 3 lines - JHE}
'end1' EOL
SeqC 'M98P7050' EOL {motion to TC sub}
{M9}
{G0G28G80G91Z0.M5}
{G40G49G80D0H0G94}
{G28X0.Y0.}
{M99}
{SeqC CoolOff EOL} {Removed all codes - JHE}
{IF AbsoluteMoves?}
{ SeqC IncValue OfstOff EOL}
{ SeqC AbsValue EOL}
{ELSE}
{ SeqC OfstOff EOL}
{END}
RETURN

NewToolOp2:
DoEndOpPS
{IF ToolChangeAtHome?} {Removed all codes - JHE}
{ SeqC Rapid Home SpinOff EOL}
{ELSE}
{ SeqC SpinOff EOL}
{END}
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
{SeqC Plane 'G80' CRCOffC EOL} {Removed - JHE}
SeqC OpToolID ToolChng EOL {Added ToolChng - JHE}
{SeqC ToolChng EOL} {Moved up - JHE}
DoOpComments
DoPostScript
RETURN

NewToolOp4:
{SeqC WFOStuff EOL} {Removed - JHE}
{SeqC Speed SpinOn EOL} {Moved to motion block - JHE}
CheckPass
SeqC Rapid PlaneC AbsOrInc OfstOn Speed SpinOn EOL
SeqC CoolOn PreTool EOL {Added PreTool - JHE}
'#1=1.' EOL {Added next 3 lines - JHE}
'while[#1le#511]do1' EOL
'g[53+#1]' EOL
RETURN

NewToolOp5:
SeqC Rapid StrtPos Speed EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
{SeqC CoolOff EOL} {Moved to motion block - JHE}
IF AbsoluteMoves?
SeqC IncValue OfstOff CoolOff EOL {Added CoolOff - JHE}
SeqC AbsValue SpinOff EOL {Added SpinOff - JHE}
ELSE
SeqC OfstOff CoolOff EOL {Added CoolOff - JHE}
SeqC SpinOff EOL
END
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
{SeqC WFOStuff EOL} {Removed - JHE}
IF LAST ProgStop?
SeqC Rapid PlaneC AbsOrInc StrtPos Speed SpinOn EOL
SeqC OfstOn CoolOn EOL {Added CoolOn - JHE}
{SeqC CoolOn EOL} {Moved up - JHE}
ELSE
SeqC Rapid PlaneC AbsOrInc StrtPos SpeedC EOL
IF NewToolOffset?
SeqC OfstOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

End1:
'#1=#1+1.' EOL {Added next 3 lines - JHE}
'end1' EOL
SeqC 'M98P7050' EOL {Return Home sub}
{M9}
{G0G28G80G91Z0.M5}
{G40G49G80D0H0G94}
{G28X0.Y0.}
{M99}
{SeqC CoolOff EOL} {Removed all codes - JHE}
{IF AbsoluteMoves?}
{ SeqC IncValue OfstOff EOL}
{ SeqC AbsValue EOL}
{ELSE}
{ SeqC OfstOff EOL}
{END}
RETURN

End2:
DoEndOpPS
{IF FIRST ToolChangeAtHome?} {Removed next 5 lines - JHE}
{ SeqC Rapid FirstHome SpinOff EOL}
{ELSE}
{ SeqC SpinOff EOL}
{END}
IF ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL {Added this line - JHE}
END
RETURN

End3:
SeqC 'M60' EOL {Added, pallet change - JHE}
SeqC 'M98P7051' EOL {Return Home, Reset work coordinates to zero}
{M9}
{G0G28G80G91Z0.M5}
{G40G49G80D0H0G94}
{G28G91X0.Y0.}
{G90G10L2P1X0.Y0.Z0.}
{G10L2P2X0.Y0.Z0.}
{G10L2P3X0.Y0.Z0.}
{G10L2P4X0.Y0.Z0.}
{G10L2P5X0.Y0.Z0.}
{G10L2P6X0.Y0.Z0.}
{G92X0.Y0.Z15.7521}
{M99}
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
' ' EOL
'( warning: this post does not support one part all tools option. )' EOL
'( select one tool all parts option. )' EOL
' ' EOL
{{ {Removed this option - JHE}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
}}
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
IF WorkFixtureOffsets? {Added this check - JHE}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
OpenMP {Moved one step down - JHE}
FirstOp3
SeqC OfstOn EOL {Added this line - JHE}
ELSE
IF NewTool?
SeqC RapidC IncValue OfstOff EOL {Added this line - JHE}
SeqC AbsOrInc EOL {Added this line - JHE}
CloseMP {Moved one step up - JHE}
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
OpenMP {Moved one step down - JHE}
NewToolOp5
SeqC OfstOn EOL {Added this line - JHE}
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
SeqC RapidC IncValue OfstOff EOL {Added this line - JHE}
SeqC AbsOrInc EOL {Added this line - JHE}
CloseMP {Moved one step up - JHE}
End1 {End of program}
End2
End3
ELSE {implies equally spaced} {Added this warning - JHE}
' ' EOL
'( warning: this post does not support equally spaced option. )' EOL
'( select work fixtures option. )' EOL
' ' EOL
END
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
IF WorkFixtureOffsets? {Added this check - JHE}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
OpenMP {Moved one step up - JHE}
FirstOp3
{FirstOp2} {need StrtPos in Sub} {Removed this line - JHE}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
OpenMP {Moved one step up - JHE}
NewToolOp5
{NewToolOp4} {need StrtPos in Sub} {Removed this line - JHE}
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
ELSE {implies equally spaced} {Added this warning - JHE}
' ' EOL
'( warning: this post does not support equally spaced option. )' EOL
'( select work fixtures option. )' EOL
' ' EOL
END
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { WFOStuff }
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level **************************}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END