{Change Comments ***********************************************************}

{6/24/88}
{original program Bandit 1V M089.54}
{Deleted: Tool length offsets, Planes, Coolant}
{Modified: Z home, WFO's to if WorkFixtureOffsets?}
{Added: O code for program#}

{4/16/90
Copied & modified: Bandit IV AB (NA) M129.56
For: Hoegner Tool & Plastics
Machine: Bandit IV
Control: Allen Bradley
Updated to Version 3.2 per Fanuc 6M M001.71 Format
Changes made per customers request:
In Format:
Modified Rapid to output 'F0' rather than 'G0' in format.
In Prog:
Modified MoveXYZC at FormatArc to be non-conditional.
Modified cancellation of cutter radius compensation to occur before exiting to clearance plane.
Removed repeated StartPos from drill cycles.
At FirstOperation:
Deleted ProgID.
Deleted 'G99' literal.
Deleted Rapid 'X0Y0'.
Added startup G-codes.
Deleted Preset 'X0Y0'.
Added OpToolID to ZCP1.
At NewTool:
Modified 'G0Z0' to 'T0F0Z1.'
Added ToolChng.
After LastOp:
Modified 'G0Z0' to 'T0F0Z1.'
DWB}

{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{4/03/91
Modified: AB 7100 Hydratel M299.72
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)

{Prog Subroutines **********************************************************}

DoSubComment:
IF UseComments? AND SubComment?
'; SUB NUMBER: ' Program# EOL
END
RETURN

PSStuff:
IF Rotate?
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
ELSE
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
ELSE
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
ELSE
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
END
END
END
END
END
RETURN

DoPostScript:
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'; OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'; ' OperationComment$ EOL
END
IF WorkGroupComment?
'; ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'; TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'; ' ToolComment$ EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

EntryMove:
IF FeedEntry?
IF Repeats?
SeqC ZIn EOL
ELSE
SeqC Feed ZIn FeedEnt EOL
END
ELSE
SeqC RapidC ZIn EOL
END
IF CutterRadiusCompensation?
SeqC CRCOnC EOL
END
RETURN

StartSub:
OpenSub
EOR EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SubWarning
SeqC CallLab RepLab RepsLess1 EOL
StartSub
SeqC AbsOrInc EOL
SeqC Connect StrtPos FeedEntC EOL
RETURN

FinishSub1: {part 1}
IF CutterRadiusCompensation?
SeqC FeedC CRCOffC LastFeatExtend EOL
END
UnSkipZ
IF NOT FeedConnect?
SeqC RapidC ZCP3C EOL
END
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
EOR EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC 'G45' SetWFO EOL
SeqC CallLab EOL
IncWFO
NextWFO
ELSE
SeqC CallLab RepLab PartsLess1 EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
EOR EOL
CloseSub
SeqC 'G99' EOL
SeqC 'G45' WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
EOR EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveXY MoveZC ArcIJ
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC CRCOnC FeedC MoveXYZC DecelFeed EOL
ELSE
SeqC CRCOnC FeedC MoveXYZC FeedRateC EOL
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
SeqC MoveSXYC EOL
IF AutoCycle?
SeqC CallLab EOL
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
SeqC RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
IF WorkFixtureOffsets?
SeqC 'G45O' NewWFO# EOL
END
END
ELSE
IF NOT SameTool?
IF NeedWFO1? AND WorkFixtureOffsets?
SeqC 'G45O' NewWFO# EOL
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
SeqC StrtPosC EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF CutterRadiusCompensation?
SeqC FeedC CRCOffC LastFeatExtend EOL
END
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqC AbsOrInc EOL {.69 removed RapidC}
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL
END
SeqC EndSub EOL
EOR EOL
CloseSub
SetSRSubXY {restore tool position}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
StdSub
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
SetPass1 {for correct Z's}
EachCycle
IF FeedConnect?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC Rapid ZCP2PlusInc EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
SeqC Rapid ZCP2 EOL {.69}
END {.69}
SeqC EndSub EOL
EOR EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC StrtPos EOL
END
IF FeedConnect?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC Rapid ZCP2PlusIncC EOL {can't call for cycle =1}
{.69 added Rapid, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
SeqC CallLab EOL
NextCycle
StartSub
SkipZ
ToolPath
FinishSub1
SeqC EndSub EOL
EOR EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'; ' ProgramName$ EOL
END
IF ProgramComment?
'; ' ProgramComment$ EOL
END
IF FormatNameComment?
'; FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'; ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'; OUTPUT IN ' MoveType$ EOL
END
IF PartsComment?
'; PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'; FIRST TOOL NOT IN SPINDLE ' EOL
END
END
OpenSub
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqC AbsOrInc CRCOff 'G80G70G75G94' Plane EOL
DoPostScript
WFOStuff
SeqC SpinOn EOL
DoOpComments
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqC AbsOrInc EOL
END
CheckPass
SeqC Rapid StrtPos EOL
SeqC OpToolID ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?
{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
SeqC SpinOff EOL
SeqC 'T0F0Z1.' EOL
SeqC Rapid Home EOL
SeqC ToolChng EOL
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

SeqC PlaneC EOL
SeqC SpinOn EOL
DoOpComments
DoPostScript
WFOStuff
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqC AbsOrInc EOL
END
CheckPass
SeqC Rapid StrtPos EOL
SeqC OpToolID ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC SpinOff EOL
SeqC 'T0F0Z1.' EOL
SeqC 'M00' EOL

{Start new Operation}

DoOpComments
DoPostScript
SeqC PlaneC EOL
SeqC SpinOn EOL
WFOStuff
CheckPass
SeqC AbsOrInc EOL
SeqC Rapid StrtPos EOL
ELSE

{Start new Operation}

DoOpComments
DoPostScript
SeqC PlaneC EOL
WFOStuff
CheckPass
SeqC AbsOrInc EOL
SeqC Rapid StrtPos EOL
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
IF CutterRadiusCompensation?
SeqC FeedC CRCOffC LastFeatExtend EOL
END
END
IF NOT CutterRadiusCompensation?
SeqC 'G1' Rapid ZCP3 EOL
ELSE
SeqC RapidC ZCP3C EOL
END
ELSE
IF Drilling?
IF Repeats?
NewProg
SeqC CallLab RepLab RepsLess1 EOL
OpenSub
EOR EOL
DoSubComment
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
SeqC Cycle ZDepth RLevel
IF Dwell?
Dwell
END
IF Peck?
Peck FromCP FeedEnt
IF PeckChipBreaker?
'J*K*W' Retract 'U*'
END
ELSE
FromCP FeedEnt
END
EOL
ToolPath
SeqC 'G80' EOL
IF Repeats?
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
EOR EOL
CloseSub
SeqC Preset UnshftRC EOL
END
SeqC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
SeqC SpinOff EOL
SeqC 'F0T0Z1.' EOL
SeqC Rapid Home EOL
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
EOR EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'; FILE LENGTH: ' FileBytes# ' CHARACTERS ' EOL
END
IF FileFeetComment?
'; FILE LENGTH: ' FileFeet# ' FEET ' EOL
END
IF FileMetersComment?
'; FILE LENGTH: ' FileMeters# ' METERS ' EOL
END
Close
END