{Change Comments ***********************************************************}

{added separate sub call code and warning for not separate, 7/5/88 WFG}
{separate sub calls turned off in this post- 'UseSeparateSubCalls' commented out}
{ncPost3ż24 or better}
{added IF ToolChangeAtHome?, & SetHome 9/26/88 WFG}
{added PostScript commands 3/11/89 WFG}
{added PostScript command comments 5/9/89, WFG, use ncPost 3.10Ś9 or better}
{removed run time comments, 5/9/89, WFG}
{added "must be all capital letters when typed in" to Postscript Command comment, 5/17/89, JR}
{added metric, 6/5/89, WFG}
{suppressed first cycle StrtPos for sep subs,7/17/89 WFG}
{last tool now goes to FirstHome when finished, 7/26/89, WFG}
{changed to Sep Sub standard}
{.65, corrected Sep sub problem if 1st cut <> Z step, 9/14/89 WFG, requires ncPost 3.19Ś5}
{.66, added name comment to Prog ID # line, 10/30/89, WFG}
{.67, new prog commands, 11/20/89, WFG}
{*.68, AutoCycles and 3.2 support, 12/4/89, WFG (Good luck on the upgrades to other posts)}
{.69, corrected 2 repeat op/autocycle problems, 12/21/89, WFG}
{.70, added CRC to Autocycles, 12/30/89, wfg}
{.71, added InitProg, 4/11/90, wfg}
{.72, added reset flag PostScript commands, ResetCRCNum, & CoolOff?,see PostNotes #33,#34, 4/22/90, wfg}

{5/9/90
Copied & modified: Fanuc 6M M001.72
For: OSF America
Machine: Motion Master
Control: Allen Bradley Series B 8400/Bandit IV
Updated to Version 3.2 per Fanuc 6M M001.72 Format
DWB}

{6/28/90
Deleted all occurances of SpinOn, SpinOff, CoolOn and CoolOff.
Modified IJ and R arc center output, to output IJ when in Absolute, and R when in incremental.
DWB}

{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{4/03/91
Modified: AB 8400 (OSF)[Y] M309.73
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '###.####;0.'
#5 = '########;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(ClearancePlane3#,4)
FORMAT(ZDepth#,4)
FORMAT(EPZ#,4)
FORMAT(OriginShiftPX#,4)
FORMAT(OriginShiftPY#,4)
FORMAT(OriginShiftPZ#,4)
FORMAT(OriginShiftRX#,4)
FORMAT(OriginShiftRY#,4)
FORMAT(OriginShiftRZ#,4)
FORMAT(OriginUSPXCTP#,4)
FORMAT(OriginUSPYCTP#,4)
FORMAT(OriginUSPZCTP#,4)
FORMAT(OriginUSRXCTP#,4)
FORMAT(OriginUSRYCTP#,4)
FORMAT(OriginUSRZCTP#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}

{Prog Subroutines **********************************************************}

DoSubComment:
IF UseComments? AND SubComment?
'; SUB NUMBER: ' Program# EOL
END
RETURN

PSInit: {.72}
NewWFOF {reset NewWFO?}
RotateF {reset Rotate?}
RETURN

PSStuff: {revised.72}
{no Rotate stuff for this post}
RETURN

DoPostScript:
PSInit {reset flags from last Op, .72}
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit {reset PS flags, .72}
EachEOPS
SeqC EndOpPS EOL
NextPS
PSStuff
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'; OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'; ' OperationComment$ EOL
END
IF WorkGroupComment?
'; ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'; TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'; ' ToolComment$ EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

DoToolNum:
IF NOT ToolOver?('9')
OpToolID
ELSE
IF NOT ToolOver?('19')
'O1'
ELSE
IF NOT ToolOver?('29')
'O2'
ELSE
'O3'
END
END
END
RETURN

DoCylinderDown:
IF ToolOver?('1') AND NOT ToolOver?('2')
SeqC 'M39' EOL
ELSE
IF ToolOver?('2') AND NOT ToolOver?('3')
SeqC 'M41' EOL
ELSE
IF ToolOver?('4') AND NOT ToolOver?('5')
SeqC 'M43' EOL
ELSE
IF ToolOver?('5') AND NOT ToolOver?('6')
SeqC 'M45' EOL
ELSE
IF ToolOver?('14') AND NOT ToolOver?('15')
SeqC 'M43' EOL
ELSE
IF ToolOver?('15') AND NOT ToolOver?('16')
SeqC 'M45' EOL
ELSE
IF ToolOver?('24') AND NOT ToolOver?('25')
SeqC 'M39' EOL
SeqC 'M43' EOL
ELSE
IF ToolOver?('25') AND NOT ToolOver?('26')
SeqC 'M39' EOL
SeqC 'M45' EOL
ELSE
IF ToolOver?('34') AND NOT ToolOver?('35')
SeqC 'M41' EOL
SeqC 'M43' EOL
ELSE
IF ToolOver?('35') AND NOT ToolOver?('36')
SeqC 'M41' EOL
SeqC 'M45' EOL
END
END
END
END
END
END
END
END
END
END
RETURN

DoLastCylinderUp:
IF LAST ToolOver?('1') AND NOT LAST ToolOver?('2')
SeqC 'M40' EOL
ELSE
IF LAST ToolOver?('2') AND NOT LAST ToolOver?('3')
SeqC 'M42' EOL
ELSE
IF LAST ToolOver?('4') AND NOT LAST ToolOver?('5')
SeqC 'M44' EOL
ELSE
IF LAST ToolOver?('5') AND NOT LAST ToolOver?('6')
SeqC 'M46' EOL
ELSE
IF LAST ToolOver?('14') AND NOT LAST ToolOver?('15')
SeqC 'M44' EOL
ELSE
IF LAST ToolOver?('15') AND NOT LAST ToolOver?('16')
SeqC 'M46' EOL
ELSE
IF LAST ToolOver?('24') AND NOT LAST ToolOver?('25')
SeqC 'M40' EOL
SeqC 'M44' EOL
ELSE
IF LAST ToolOver?('25') AND NOT LAST ToolOver?('26')
SeqC 'M40' EOL
SeqC 'M46' EOL
ELSE
IF LAST ToolOver?('34') AND NOT LAST ToolOver?('35')
SeqC 'M42' EOL
SeqC 'M44' EOL
ELSE
IF LAST ToolOver?('35') AND NOT LAST ToolOver?('36')
SeqC 'M42' EOL
SeqC 'M46' EOL
END
END
END
END
END
END
END
END
END
END
RETURN

DoCylinderUp:
IF ToolOver?('1') AND NOT ToolOver?('2')
SeqC 'M40' EOL
ELSE
IF ToolOver?('2') AND NOT ToolOver?('3')
SeqC 'M42' EOL
ELSE
IF ToolOver?('4') AND NOT ToolOver?('5')
SeqC 'M44' EOL
ELSE
IF ToolOver?('5') AND NOT ToolOver?('6')
SeqC 'M46' EOL
ELSE
IF ToolOver?('14') AND NOT ToolOver?('15')
SeqC 'M44' EOL
ELSE
IF ToolOver?('15') AND NOT ToolOver?('16')
SeqC 'M46' EOL
ELSE
IF ToolOver?('24') AND NOT ToolOver?('25')
SeqC 'M40' EOL
SeqC 'M44' EOL
ELSE
IF ToolOver?('25') AND NOT ToolOver?('26')
SeqC 'M40' EOL
SeqC 'M46' EOL
ELSE
IF ToolOver?('34') AND NOT ToolOver?('35')
SeqC 'M42' EOL
SeqC 'M44' EOL
ELSE
IF ToolOver?('35') AND NOT ToolOver?('36')
SeqC 'M42' EOL
SeqC 'M46' EOL
END
END
END
END
END
END
END
END
END
END
RETURN

DoZCP1:
IF NOT ToolOver?('3')
ZCP1C
ELSE
IF NOT ToolOver?('6')
'U' ClearancePlane1#
ELSE
ZCP1 'U' ClearancePlane1#
END
END
RETURN

DoZCP2Type1:
IF NOT ToolOver?('3')
ZCP2C
ELSE
IF NOT ToolOver?('6')
'U' ClearancePlane2#
ELSE
ZCP2 'U' ClearancePlane2#
END
END
RETURN

DoZCP2Type2:
IF NOT ToolOver?('3')
ZCP2
ELSE
IF NOT ToolOver?('6')
'U' ClearancePlane2#
ELSE
ZCP2 'U' ClearancePlane2#
END
END
RETURN

DoZCP3:
IF NOT ToolOver?('3')
ZCP3C
ELSE
IF NOT ToolOver?('6')
'U' ClearancePlane3#
ELSE
ZCP3 'U' ClearancePlane3#
END
END
RETURN

DoMoveZ:
IF NOT XYPlane?
IF NOT ToolOver?('3')
MoveZC
ELSE
IF NOT ToolOver?('6')
'U' EPZ#
ELSE
'W' EPZ# 'U' EPZ#
END
END
END
RETURN

DoZInPlusInc:
IF NOT ToolOver?('3')
ZInPlusInc
ELSE
IF NOT ToolOver?('6')
'U' ZInPlusInc#
ELSE
ZCP3 'U' ZInPlusInc#
END
END
RETURN

DoZCP2PlusInc:
IF NOT ToolOver?('3')
ZCP2PlusInc
ELSE
IF NOT ToolOver?('6')
'U' ZCP2PlusInc#
ELSE
ZCP3 'U' ZCP2PlusInc#
END
END
RETURN

EntryMove:
SeqC
IF FeedEntry?
Feed
ELSE
RapidC
END
IF NOT ToolOver?('3')
ZIn
ELSE
IF NOT ToolOver?('6')
'U' ZDepth#
ELSE
ZIn 'U' ZDepth#
END
END
IF FeedEntry?
FeedEnt
END
EOL
RETURN

StartSub:
OpenSub
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'; WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
RETURN

StdSub:
SubWarning
SeqC CallLab RepLab RepCycs EOL
StartSub
SeqC AbsOrInc EOL
SeqC Connect StrtPos EOL
RETURN

FinishSub1: {part 1}
UnSkipZ
SeqC CRCOffC EOL
IF NOT FeedConnect?
SeqC RapidC DoZCP3 EOL
END
RETURN

FinishSubG92: {part 2}
SeqC Preset
IF NOT ToolOver?('3')
ShiftRC
ELSE
'X' OriginShiftRX# 'Y' OriginShiftRY#
IF NOT ToolOver?('6')
'U' OriginShiftRZ#
ELSE
'W' OriginShiftRZ# 'U' OriginShiftRZ#
END
END
EOL
SeqC EndSub EOL
CloseSub
SeqC Preset
IF NOT ToolOver?('3')
UnshftRC
ELSE
'X' OriginUSRXCTP#('1') 'Y' OriginUSRYCTP#('1')
IF NOT ToolOver?('6')
'U' OriginUSRZCTP#('1')
ELSE
'W' OriginUSRZCTP#('1') 'U' OriginUSRZCTP#('1')
END
END
EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC 'G45' SetWFO EOL
SeqC CallLab RepLab OnePart EOL
IncWFO
NextWFO
ELSE
SeqC CallLab RepLab Parts EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC 'G45' WFO1 EOL
ELSE
SeqC Preset
IF NOT ToolOver?('3')
ShiftPC
ELSE
'X' OriginShiftPX# 'Y' OriginShiftPY#
IF NOT ToolOver?('6')
'U' OriginShiftPZ#
ELSE
'W' OriginShiftPZ# 'U' OriginShiftPZ#
END
END
EOL
SeqC EndSub EOL
CloseSub
SeqC Preset
IF NOT ToolOver?('3')
UnshftPC
ELSE
'X' OriginUSPXCTP#('1') 'Y' OriginUSPYCTP#('1')
IF NOT ToolOver?('6')
'U' OriginUSPZCTP#('1')
ELSE
'W' OriginUSPZCTP#('1') 'U' OriginUSPZCTP#('1')
END
END
EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYC DoMoveZ
IF AbsoluteMoves?
ArcIJC
ELSE
ArcRC
END
RETURN

StdLine: {enables CRC on first call, .70}
SeqC CRCOnC EOL
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FeedC MoveXYC DoMoveZ FeedRateC EOL
DecelMove2
END
SeqC FeedC MoveXYC DoMoveZ DecelFeed EOL
ELSE
SeqC FeedC MoveXYC DoMoveZ FeedRateC EOL
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
SeqC MoveSXYC EOL
IF AutoCycle?
SeqC CallLab EOL
END
ELSE
IF RapidFeat?
SeqC RapidC MoveXYC DoMoveZ EOL
IF LastFeat? AND AutoCycle? {.70}
SeqC CRCOffC EOL
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC FeedC MoveXYC DoMoveZ FeedRateC EOL
SeqC CRCOffC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYC DoMoveZ FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
EOL
'; *** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
SeqC
ELSE
SeqC 'G45' DoToolNum EOL
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
SeqC 'G45' DoToolNum EOL
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
SeqC StrtPosC EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC CRCOffC EOL
SeqC AbsOrInc EOL
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
SeqC RapidC DoZCP2Type2 EOL
END
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore tool position}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
StdSub
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
SetPass1 {for correct Z's}
EachCycle
IF FeedConnect?
SeqC Feed DoZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC Rapid DoZCP2PlusInc EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqC Feed DoZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid DoZInPlusInc EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
SeqC Rapid DoZCP2Type2 EOL {.69}
END {.69}
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC StrtPos EOL
END
IF FeedConnect?
SeqC Feed DoZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC Rapid DoZCP2PlusInc EOL {can't call for cycle =1}
{.69 added Rapid, reads better}
END
SeqC Feed DoZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid DoZInPlusInc EOL {.69 added Rapid, reads better}
END
END
SeqC CallLab EOL
NextCycle
StartSub
SkipZ
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' Use after ENDOP in previous OP for a same tool WFO change' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'; ' ProgramName$ EOL
END
IF ProgramComment?
'; ' ProgramComment$ EOL
END
IF FormatNameComment?
'; FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'; ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'; OUTPUT IN ' MoveType$ EOL
END
IF PartsComment?
'; PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'; FIRST TOOL NOT IN SPINDLE' EOL
END
END
OpenSub
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq 'G99' EOL
SeqC Plane EOL
SeqC 'G80' EOL
SeqC CRCOff EOL
DoPostScript
SeqC WFOStuff EOL
SeqC ToolOfst EOL
DoOpComments
SeqC Speed EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC AbsOrInc EOL
SeqC Rapid StrtPos EOL
SeqC DoZCP1 EOL
DoCylinderDown
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?
{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
DoLastCylinderUp
DoEndOpPS
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
IF ToolChangeAtHome?
SeqC AbsOrInc EOL
SeqC Rapid Home EOL
ELSE
SeqC EOL
END
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoPostScript
Seq WFOStuff EOL
SeqC ToolOfst EOL
DoOpComments
SeqC PlaneC EOL
ResetCRCNum {.72}
SeqC Speed EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC AbsOrInc EOL
SeqC Rapid StrtPos EOL
SeqC DoZCP1 EOL
DoCylinderDown
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC RapidC 'Z'
IF NOT ToolOver?('3')
'W' LAST ClearancePlane3#
ELSE
IF NOT ToolOver?('6')
'U' LAST ClearancePlane3#
ELSE
'W' LAST ClearancePlane3# 'U' LAST ClearancePlane3#
END
END
EOL
DoCylinderUp
SeqC EOL
SeqC 'M00' EOL

{Start new Operation}

DoOpComments
DoPostScript
SeqC WFOStuff EOL
SeqC ToolOfst EOL
CheckPass
SeqC PlaneC EOL
SeqC AbsOrInc EOL
SeqC Rapid StrtPos Speed EOL
ResetCRCNum {.72}
SeqC DoZCP1 EOL
DoCylinderDown
ELSE
IF NewToolOffset?
DoCylinderUp
END

{Start new Operation}

DoOpComments
DoPostScript
SeqC WFOStuff EOL
IF NewToolOffset?
SeqC ToolOfst EOL
END
CheckPass
SeqC PlaneC EOL
SeqC AbsOrInc EOL
SeqC Rapid StrtPos SpeedC EOL
ResetCRCNum {.72}
SeqC DoZCP1 EOL
DoCylinderDown
END
END
END
END {common point for all operations}
IF Milling?
SeqC DoZCP2Type1 EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqC CRCOffC EOL
SeqC RapidC DoZCP3 EOL
ELSE
IF Drilling?
IF Repeats?
NewProg
SeqC CallLab RepLab RepCycs EOL
OpenSub
DoSubComment
SeqC AbsOrInc EOL
SeqC Rapid StrtPos EOL
END
SeqC
IF NOT ToolOver?('3')
DrillCP
ELSE
IF NOT ToolOver?('6')
IF RetractToCP1?
'U' ClearancePlane1#
ELSE
'U' ClearancePlane2#
END
ELSE
DrillCP
IF RetractToCP1?
'U' ClearancePlane1#
ELSE
'U' ClearancePlane2#
END
END
END
EOL
GetCycle
SeqC Cycle
IF NOT ToolOver?('3')
ZDepth
ELSE
IF NOT ToolOver?('6')
'U' ZDepth#
ELSE
ZDepth 'U' ZDepth#
END
END
RLevel
IF Dwell?
Dwell
END
Peck Retract FeedEnt FromCP EOL
ToolPath
SeqC 'G80' EOL
IF Repeats?
SeqC Preset
IF NOT ToolOver?('3')
ShiftRC
ELSE
'X' OriginShiftRX# 'Y' OriginShiftRY#
IF NOT ToolOver?('6')
'U' OriginShiftRZ#
ELSE
'W' OriginShiftRZ# 'U' OriginShiftRZ#
END
END
EOL
SeqC EndSub EOL
CloseSub
SeqC Preset
IF NOT ToolOver?('3')
UnshftRC
ELSE
'X' OriginUSRXCTP#('1') 'Y' OriginUSRYCTP#('1')
IF NOT ToolOver?('6')
'U' OriginUSRZCTP#('1')
ELSE
'W' OriginUSRZCTP#('1') 'U' OriginUSRZCTP#('1')
END
END
EOL
END
SeqC RapidC DoZCP3 EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
DoCylinderUp
DoEndOpPS
IF ProgStop?
SeqC 'M00' EOL
SeqC Speed EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
IF ToolChangeAtHome?
SeqC AbsOrInc EOL
SeqC Rapid FirstHome EOL
ELSE
SeqC EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'; FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'; FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'; FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END