{Change Comments ***********************************************************}

{12/1/93,
Copied & modified: AB 8400 Cincinati M292.81.2
For: AQL
Machine:
Control: Allen Bradely 8400
Changes made per conversation with Denis Theissen at AQL.
Replaced ToolChng command with Rapid Move to Z2. at NewTool and end of Prog.
Added GetZToolChngPos sub to accomplish this.
Sub uses LoadFeat command to keep StatusRegister up to date.
Deleted GearRange at FirstOperation and NewTool.
Deleted SpeedRPM# TABLE outputs at FirstOperation and NewTool.
Machine uses manual Speed handling, SpinOn/SpinOff still supported.
Deleted support of CoolOn and CoolOff.
Deleted G17, G18 and G19 from Mach Spec.
Modified handling of Incremental output.
Control recognizes UpperCase Addresses as Absolute Moves.
Control recognizes LowerCase Addresses as Incremental Moves.
Added special AbsOrInc procedures to support this, located prior to Prog Subroutines.
They are called GetHome, GetFirstHome, GetStrtPos, GetMoveSXYC, GetMoveSXYZC, GetMoveXYZC,
GetArcIJ, GetZCP2, GetZCP2C, GetDrillCP, GetDrillZandR, GetZIn, GetZInPlusInc, GetZCP2PlusInc,
GetZCP2PlusIncC, GetZCP3C and GetZToolChngPos.
Deleted G90 and G91 from Mach Spec.
Changed all occurances of AbsOrInc to SetAbsOrInc.
Added SetAbs and SetAbsOrInc where needed.
Modified handling of Subs.
Customer requested that subs be output as part of Main Program at point of SubCall.
SubRoutine body is output first, followed by Call to sub.
H Address Calls SubRoutine Start Block, E Address Calls SubRoutine End Block, L Address handles
Looping.
When Looping, Loop value includes initial pass through Sub. Example:
N10
[ SubRoutine Body ]
N20
H10E20L5 [ First Pass is included in Loop Value ]
Any Data contained on SubRoutine End Block is not executed as part of the sub.
NOTE: Due to complexity of ZonlyRepAutoCycles, ZPass positions are still output in Absolute,
even when Incremental output has been requested.
DWB}

{11/11/94
Modified: AB 8400 [AQL] M609.81.2
For: AQL
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.23
Versions: Catalyst v2.14.06C/Compost 4.21.23
Changes made per Denis Theissen at AQL, sample Virtual files and editted text files.
Changed the formats for Addresses A, D, F, Q and S.
Deleted G2 and G3 from Arc Fields in Form.
Added spaces between Addresses.
Zero values are output with Address only, no value.
Added support for Helical Arcs.
Made numerous other changes, too many to list.
DWB}

{5/16/97
Updated & Modified: AB 8400 [AQL] M609.81.3
Created: AB 8400 [AQL] M609.89
For: AQL
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per Magnus at AQL, sample Virtual files and editted text files.
Updated for Catalyst v3.33C per Fanuc 6M M001.89b Format.
More numerous changes, too many to list.
Basically, I rewrote entire prog structure.
Radical change to Header.
Rewrote customer subs.
Added more custom subs.
Subs are normal, specifically ZonlyRepAutoCycle and ZonlyRep.
Subs appear prior to M2.
Changed Seq/SeqC to SeqLab/SeqLabC.
Modified special line numbers.
Post now outputs Tool related Line Numbers.
N5000 - N5099 are SinglePart and MultiplePart related Line Numbers.
Using Variable 33 for Program related Line Numbers.
N5100 =
5 = Tool Related Line Number.
1 = Tool Number.
00 = Incrementing value.
Using Variables 1 to 32 for Tool related Line Numbers.
Using Variables 34 to 50 for Drill Sub Tool related Line Numbers.
DWB}

{6/7/97
Copied: AB 8400 [AQL] M609.89
Created: AB 8400 [AQL] M609.89.1
For: AQL
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per Magnus at AQL.
Added literal ';--------------------------------------------------------' at header separating
' G45 O(GF)' and ';MID-PROGRAM_START:' blocks at GetProgComments sub.
Added call to GetTouchOff sub at NewTool.
DWB}

{6/11/97
Copied: AB 8400 [AQL] M609.89.1
Created: AB 8400 [AQL] M609.89.2
For: AQL
Fixed Backslash Literal conversion problem, using ASCII command
JM}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;'
#3 = '*#####.###;'
#4 = '####.####;'
#5 = '#######0'
#6 = '##.#0'
#7 = '+####.####;'
#8 = '#00'
#9 = '###.000;'
#10 = '####.bb#;0 '
#11 = '##0.00'
#12 = '####.0000;'
#13 = 'ą####.####;+0'
#14 = '#00'
#20 = 'ą#bbbb.bbbb#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Recall#,4)
FORMAT(XStockMax#,4)
FORMAT(YStockMax#,4)
FORMAT(ZStockMin#,4)
FORMAT(HomeX#,4)
FORMAT(HomeY#,4)
FORMAT(StartPosX#,4)
FORMAT(StartPosY#,4)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(SPZ#,4)
FORMAT(EPX#,4)
FORMAT(EPY#,4)
FORMAT(EPZ#,4)
FORMAT(ArcI#,4)
FORMAT(ArcJ#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(ClearancePlane3#,4)
FORMAT(ZInPlusInc#,4)
FORMAT(ZCP2PlusInc#,4)
FORMAT(OriginShiftRX#,4)
FORMAT(OriginShiftRY#,4)
FORMAT(OriginShiftRZ#,4)
FORMAT(OriginUSRXCTP#,4)
FORMAT(OriginUSRYCTP#,4)
FORMAT(OriginUSRZCTP#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(ADD#,5)
FORMAT(ToolOffset#,5)
FORMAT(TLNum#,5)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Dwell#,6)
FORMAT(HelixPitch#,7)
FORMAT(Tag#,8)
FORMAT(Parts#,8)
FORMAT(SUB#,9)
FORMAT(PartShiftX#,10)
FORMAT(PartShiftY#,10)

{Variable Control Subroutines *******}

CTV: { ClearToolVariables }
TagInc
Save# Tag# Num#('-1')
RETURN

ClearToolVariables: { 32 Tools }
TagInit
CTV CTV CTV CTV CTV CTV CTV CTV
CTV CTV CTV CTV CTV CTV CTV CTV
CTV CTV CTV CTV CTV CTV CTV CTV
CTV CTV CTV CTV CTV CTV CTV CTV
RETURN

ToolSeqInc:
IF LTEqual? Tool# Num#('32')
Save# Tool# ADD# Recall# Tool# Num#('1')
END
RETURN

ToolSeqDec:
IF LTEqual? Tool# Num#('32')
Save# Tool# SUB# Recall# Tool# Num#('1')
END
RETURN

ToolSeq:
IF LTEqual? Tool# Num#('32')
'N' ADD# Tool# Num#('50')
FORMAT(Recall#,8)
Recall# Tool#
FORMAT(Recall#,4)
END
RETURN

CallToolSub:
IF LTEqual? Tool# Num#('32')
' H' ADD# Tool# Num#('50')
FORMAT(Recall#,8)
Recall# Tool#
FORMAT(Recall#,4)
' E' ADD# Tool# Num#('50')
FORMAT(ADD#,8)
ADD# Recall# Tool# Num#('1')
FORMAT(ADD#,5)
END
RETURN

ProgSeqInit:
Save# Num#('33') Num#('4999') { Part Program Sequence Numbers }
RETURN

ProgSeqInc:
Save# Num#('33') ADD# Recall# Num#('33') Num#('1')
RETURN

ProgSeqDec:
Save# Num#('33') SUB# Recall# Num#('33') Num#('1')
RETURN

ProgToolSeqNum:
Save# Num#('33') ADD# Recall# Tool# MUL# ADD# Num#('50') Tool# Num#('100')
RETURN

ProgSeq:
FORMAT(Recall#,5)
'N' Recall# Num#('33')
FORMAT(Recall#,4)
RETURN

CallProgSeq:
FORMAT(Recall#,5)
' H' Recall# Num#('33')
FORMAT(Recall#,4)
RETURN

MPSeq1C:
IF MultipleParts?
IF AllToolsOnePart?
IF FirstOperation?
ProgSeqInc
ProgSeq
ELSE
SeqLabC
END
ELSE { OneToolAllParts }
ToolSeqInc
ProgToolSeqNum
ProgSeq
END
ELSE
SeqLabC
END
RETURN

MPSeq2C:
IF MultipleParts?
IF AllToolsOnePart?
SeqLabC
ELSE
IF ExitClearancePlane?
ToolSeqInc
END
ToolSeqInc
ProgToolSeqNum
IF FullUp?
ProgSeq
ELSE { ExitClearancePlane }
SeqLabC CallProgSeq
END
END
ELSE
SeqLabC
END
RETURN

MPSeq3C:
IF MultipleParts?
IF FirstOperation? OR NewTool?
IF OneToolAllParts? AND ExitClearancePlane?
ProgSeqInc
ProgSeq
ELSE
SeqLabC
END
ELSE
SeqLabC
END
ELSE
SeqLabC
END
RETURN

DSSI: { DrillSubSeqInit }
Save# Num#('34') ADD# Recall# Num#('34') Num#('2')
Save# Recall# Num#('34') Num#('0') { Drill Sub Program Number }
Save# ADD# Recall# Num#('34') Num#('1') Num#('0') { Drill Sub Sequence Number }
RETURN

DrillSubSeqInit: { 8 Groups range from Var(35) to Var(50) }
Save# Num#('34') Num#('33')
DSSI DSSI DSSI DSSI DSSI DSSI DSSI DSSI
RETURN

DrillSubStartSeq:
IF Flag?('5')
FORMAT(Recall#,5)
'N' Recall# ADD# Recall# Num#('34') Num#('1')
FORMAT(Recall#,4)
END
RETURN

DrillSubEndSeq:
IF Flag?('5')
'N' ADD# Recall# ADD# Recall# Num#('34') Num#('1') Num#('1')
END
RETURN

CallDrillSubSeq:
IF Flag?('5')
FORMAT(Recall#,5)
' H' Recall# ADD# Recall# Num#('34') Num#('1')
' E' ADD# Recall# ADD# Recall# Num#('34') Num#('1') Num#('1')
FORMAT(Recall#,4)
END
RETURN

StartDrillSub:
SetFlag('4') { Need to Call N5000 at end of Prog }
OpenSub
';' EOL
DrillSubStartSeq
IF UseComments? AND SubComment?
';SUB_NUMBER:_' Program#
END
EOL
RETURN

GetDrillSub:
IF NOT Flag?('5')
IF CallMasterOp?
IF Equal? Recall# Recall# Num#('34') Program#
SetFlag('5')
END
ELSE
IF MasterOp?
IF Equal? Recall# Recall# Num#('34') Num#('0')
SetFlag('5')
ToolSeqInc
Save# Recall# Num#('34') Program#
Save# ADD# Recall# Num#('34') Num#('1')
ADD# Recall# Tool# MUL# ADD# Num#('50') Tool# Num#('100')
ToolSeqInc
END
END
END
END
IF NOT Flag?('5')
Save# Num#('34') ADD# Recall# Num#('34') Num#('2')
END
RETURN

ckDrillSub:
SetFlagF('5')
Save# Num#('34') Num#('35')
GetDrillSub
GetDrillSub
GetDrillSub
GetDrillSub
GetDrillSub
GetDrillSub
GetDrillSub
GetDrillSub
RETURN

VarInit: { Initialize Variables }
ClearToolVariables
ProgSeqInit
DrillSubSeqInit
RETURN

{Added Subroutines *********************************************************}

PSScanInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RETURN

PSScan:
PSScanInit
OpenSub
SetLineStrtChr(';')
EachPS
PostScript
IF NOT EmptyLine?
'_Op' Operation# 'Data$'
SetFlag('4') { Need to Call N5000 at end of Prog }
END
EOL
NextPS
SetLineStrtChr('')
CloseSub
RETURN

GetProgComments:
';' ProgramName$ EOL
';AQL_-_' ProgramComment$ EOL
';WORK_ORDER_No.*_-_COMPANY*_-_PART_NUMBER*_-_DISCRIPTION*' EOL
';AQL_DISK_-_No.FIFTEEN_-_SHOW_SUB-DIRECTORY' EOL
';ARCHIVED_AS_=_B:'ASCII('92')'SHOW'ASCII('92')'AQL-SHOW.ZIP' EOL
';ORIGINAL_ARCHIVE_DATE_=_' Date$ '_AT_' Time$ EOL
';MINOR_CORRECTION_DATE_=_' Date$ EOL
';--------------------------------------------------------' EOL
';VIRTUAL_GIBBS_w'ASCII('92')'_' FormatName$ EOL
';--------------------------------------------------------' EOL
';VARIABLE_PARAMETERS:' EOL
SeqLabC ' G79 A' Parts# '. ;No._OF_PARTS_PER_PROGRAM' EOL
SeqLabC ' G79 T_.____ ;MATERIAL_THICKNESS_=_' SUB# ZStockMax# ZStockMin# '"_NOMINALLY' EOL
SeqLabC ' G79 D__ ;DESIRED_MATERIAL_THICKNESS' EOL
SeqLabC ' G79 S(GT-GD) ;MATERIAL_MILLED_TO_ZERO' EOL
SeqLabC ' G79 F1 ;START_OF_FIXTURE_OFFSET' EOL
';--------------------------------------------------------' EOL
';CONSTANT_PARAMETERS:' EOL
SeqLabC ' G79 B' PartShiftX# ';OFFSET_[X]_BETWEEN_PARTS_=_'
FORMAT(PartShiftX#,11)
PartShiftX# '"' EOL
SeqLabC ' G79 C' PartShiftY# ';OFFSET_[Y]_BETWEEN_PARTS_=_'
FORMAT(PartShiftY#,11)
PartShiftY# '"' EOL
';--------------------------------------------------------' EOL
';PART' ASCII('39') 's_[X0'ASCII('92')'Y0]_=_NEAR'ASCII('92')'FAR_LEFT'ASCII('92')'RIGHT-HAND_CORNER' EOL
';--------------------------------------------------------' EOL
';1_-_ALUM.'ASCII('92')'G-10_PIECE_='
FORMAT(SUB#,4)
'_[X]' SUB# XStockMax# XStockMin# '"'
'_[Y]' SUB# YStockMax# YStockMin# '"'
'_[Z]' SUB# ZStockMax# ZStockMin# '"' EOL
';--------------------------------------------------------' EOL
';TOOL_OFFSETS_USED:' EOL
FORMAT(ToolDiameter#,12)
EachOp
IF FirstOperation? OR NewTool? OR NewToolOffset?
';O' ToolOffset# '_=_' ToolComment$ EOL
END
NextOp
FORMAT(ToolDiameter#,4)
';--------------------------------------------------------' EOL
';TOOLS:' EOL
EachTool
';' TLNum#
IF Equal? TLNum# Num#('1')
'st'
ELSE
IF Equal? TLNum# Num#('2')
'nd'
ELSE
IF Equal? TLNum# Num#('3')
'rd'
ELSE
'th'
END
END
END
'_=_' TLToolComment$
SetFlag('3') { Header ToolList/End of Prog }
EachOp
IF Equal? TLNum# Tool#
IF Flag?('3')
SetFlagF('3')
'_-_O' ToolOffset#
END
EOL
IF OperationComment?
';' OperationComment$
END
END
NextOp
EOL
SetFlagF('3')
';--------------------------------------------------------' EOL
NextTool
SeqC SpinOn EOL
SeqC ' G99' EOL
SeqC ' G45 O(GF)' EOL
';--------------------------------------------------------' EOL
';MID-PROGRAM_START:' EOL
EachOp
IF FirstOperation? OR NewTool? OR NewToolOffset?
IF LTEqual? Tool# Num#('32')
ToolSeqInc
END
IF NOT FirstOperation?
';'
IF LTEqual? Tool# Num#('32')
'H' ADD# Tool# Num#('50')
FORMAT(Recall#,8)
Recall# Tool#
FORMAT(Recall#,4)
ELSE
' '
END
';STARTS_@_TOOL_' Tool# '_=_' ToolComment$ '_-_O' ToolOffset# EOL
END
IF FirstOperation? OR NewTool?
IF LTEqual? Tool# Num#('32')
IF MultipleParts?
IF OneToolAllParts?
ToolSeqInc
ToolSeqInc
IF ExitClearancePlane?
ToolSeqInc
END
END
END
END
END
END
IF LTEqual? Tool# Num#('32')
IF Repeats?
ToolSeqInc
ToolSeqInc
END
IF AutoCycle?
ToolSeqInc
ToolSeqInc
END
PSScan
IF MasterOp?
ToolSeqInc
ToolSeqInc
END
END
NextOp
PSScanInit
';--------------------------------------------------------' EOL
RETURN

GetTouchOff:
TrackZNO# Num#('0')
SeqLabC ' G4 Z(GS) F3.;-------------------("ZERO"_' ToolDiameter# '"_'
IF Milling?
'MILL'
ELSE
'BIT'
END
'_TO_MATERIAL)' EOL
';' EOL
RETURN

GetToolBlock:
IF FirstOperation? OR NewTool? OR NewToolOffset?
IF LTEqual? Tool# Num#('32')
ToolSeqInc
ToolSeq
ELSE
IF FirstOperation? OR NewTool?
SeqLab
ELSE
SeqLabC
END
END
ELSE
SeqLabC
END
EachTool
IF Equal? TLNum# Tool#
';' TLNum#
IF Equal? TLNum# Num#('1')
'st'
ELSE
IF Equal? TLNum# Num#('2')
'nd'
ELSE
IF Equal? TLNum# Num#('3')
'rd'
ELSE
'th'
END
END
END
'_TOOL_=_' ToolComment$ '_-_O' ToolOffset#
END
NextTool
IF EmptyLine?
' '
END
RETURN

ckCRCOn:
IF CutterRadiusCompensation?
IF FirstOperation? OR NewTool?
SeqLabC CRCOn EOL
ELSE
IF LAST CutterRadiusCompensation?
IF CRCLeft? AND LAST NOT CRCLeft?
SeqLabC CRCOn EOL
ELSE
IF NOT CRCLeft? AND LAST CRCLeft?
SeqLabC CRCOn EOL
END
END
ELSE
SeqLabC CRCOn EOL
END
END
END
RETURN

ckCRCOff:
IF Flag?('3') { Header ToolList/End of Prog }
CRCOffC
ELSE
IF NewTool?
CRCOffC
ELSE
IF LAST CutterRadiusCompensation?
IF CutterRadiusCompensation?
IF CRCLeft? AND LAST NOT CRCLeft?
CRCOffC
ELSE
IF NOT CRCLeft? AND LAST CRCLeft?
CRCOffC
END
END
ELSE
CRCOffC
END
END
END
END
IF NOT EmptyLine?
SeqLabC EOL
SeqLabC Rapid ' x0 y0' EOL
END
RETURN

{Added AbsOrInc Test Subroutines *******************************************}

GetHome:
IF AbsValue?
Home
ELSE
' x' HomeX# ' y' HomeY#
END
RETURN

GetFirstHome:
IF AbsValue?
FirstHome
ELSE
' x' FIRST HomeX# ' y' FIRST HomeY#
END
RETURN

GetStrtPos:
IF AbsValue?
StrtPos
ELSE
' x' StartPosX# ' y' StartPosY#
END
RETURN

GetStrtPosC: { ZonlyRepAutoCycle }
IF SPXMove?
' x' StartPosX#
END
IF SPYMove?
' y' StartPosY#
END
RETURN

GetMoveSXYC: { AutoCycles }
IF AbsValue?
MoveSXYC
ELSE
IF SPXMove?
' x' SPX#
END
IF SPYMove?
' y' SPY#
END
END
RETURN

GetMoveSXYZC: { Drilling }
IF NOT FirstFeat?
IF AbsValue?
MoveSX MoveSY MoveSZC
ELSE
IF AbsoluteMoves? { DrillSubs }
SetAbs
MoveSX MoveSY
SetInc
ELSE
' x' SPX# ' y' SPY#
END
' z' SPZ#
END
END
RETURN

GetMoveXYZC:
IF AbsValue?
MoveXYZC
ELSE
IF AutoCycle?
IF XMove?
' x' EPX#
END
IF YMove?
' y' EPY#
END
ELSE { ZShift SepSubs }
SetAbs
MoveXYC
SetInc
END
IF ZMove?
' z' EPZ#
END
END
RETURN

GetArcIJ:
IF AbsValue?
ArcIJ
ELSE
IF AutoCycle?
IF XYPlane?
' i' ArcI# ' j' ArcJ#
ELSE
IF XZPlane?
' i' ArcI# ' k' ArcJ#
ELSE { YZPlane }
' j' ArcI# ' k' ArcJ#
END
END
ELSE { ZShift SepSubs }
SetAbs
ArcIJ
SetInc
END
END
RETURN

GetArcIJK:
IF AbsValue?
IF XYPlane?
ArcIJ ' ' ASCII('75') HelixPitch# { ASCII(75) = K }
ELSE
IF XZPlane?
ArcI ' J' HelixPitch# ArcJ
ELSE { YZPlane }
' I' HelixPitch# ArcIJ
END
END
ELSE
IF AutoCycle?
IF XYPlane?
' i' ArcI# ' j' ArcJ# ' k' HelixPitch#
ELSE
IF XZPlane?
' i' ArcI# ' j' HelixPitch# ' k' ArcJ#
ELSE { YZPlane }
' i' HelixPitch# ' j' ArcI# ' k' ArcJ#
END
END
ELSE { ZShift SepSubs }
IF XYPlane?
SetAbs
ArcIJ
SetInc
' k' HelixPitch#
ELSE
IF XZPlane?
SetAbs
ArcI ' J' HelixPitch#
SetInc
' k' ArcJ#
ELSE { YZPlane }
SetAbs
' I' HelixPitch# ArcI
SetInc
' k' ArcJ#
END
END
END
END
RETURN

GetZCP1:
IF AbsValue?
ZCP1
ELSE
' z' ClearancePlane1#
END
RETURN

GetZCP2:
IF AbsValue?
ZCP2C
ELSE
' z' ClearancePlane2#
END
RETURN

GetZCP2C:
IF AbsValue?
ZCP2C
ELSE
SetAbs
LoadFeat Num#('0') Num#('0') ClearancePlane2#
SetInc
IF ZMove?
' z' EPZ#
END
END
RETURN

GetDrillCP:
IF AbsValue?
DrillCP
ELSE
SetAbs
IF RetractToCP1? {.81}
LoadFeat Num#('0') Num#('0') ClearancePlane1#
ELSE
LoadFeat Num#('0') Num#('0') ClearancePlane2#
END
SetInc
IF ZMove?
' z' EPZ#
END
END
RETURN

GetZDepth:
IF AbsValue?
ZDepth
ELSE
' z' FIRST SPZ#
END
RETURN

GetRLevel:
IF AbsValue?
RLevel
ELSE
SetStatusOff
' r' ClearancePlane2#
SetStatusOn
END
RETURN

GetZIn:
IF AbsValue?
ZIn
ELSE
' z' FIRST SPZ#
END
RETURN

GetZInPlusInc:
IF AbsValue?
ZInPlusInc
ELSE
' z' ZInPlusInc#
END
RETURN

GetZCP2PlusInc:
IF AbsValue?
ZCP2PlusInc
ELSE
' z' ZCP2PlusInc#
END
RETURN

GetZCP2PlusIncC:
IF AbsValue?
ZCP2PlusIncC
ELSE
SetAbs
LoadFeat Num#('0') Num#('0') ZCP2PlusInc#
SetInc
IF ZMove?
' z' EPZ#
END
END
RETURN

GetZCP3:
IF AbsValue?
ZCP3
ELSE
' z' ClearancePlane3#
END
RETURN

GetZCP3C:
IF AbsValue?
ZCP3C
ELSE
SetAbs
LoadFeat Num#('0') Num#('0') ClearancePlane3#
SetInc
IF ZMove?
' z' EPZ#
END
END
RETURN

GetZUp: { Manual }
IF AbsValue?
LoadFeat Num#('0') Num#('0') Num#('2')
MoveZC
ELSE
SetAbs
LoadFeat Num#('0') Num#('0') Num#('2')
SetInc
IF ZMove?
' z' EPZ#
END
END
RETURN

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

WFONum:
' G45 O(GF)' EOL
';'
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
EOL
';--------------------------------------------------------' EOL
';VARIABLE_PARAMETER_CHANGE:' EOL
SeqLabC ' G79 F' NewWFO# ' ;NEW_FIXTURE_OFFSET' EOL
';--------------------------------------------------------' EOL
SeqLabC WFONum
END
ELSE
IF Flag?('2')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
IF AllToolsOnePart?
IF FirstOperation?
WFONum
END
ELSE
WFONum
END
ELSE
IF AllToolsOnePart?
IF FirstOperation?
WFONum
END
ELSE
WFONum
END
END
ELSE
WFONum
END
END
END
END
SetFlagF('2')
RETURN

DoSubComment:
IF UseComments? AND SubComment?
';SUB_NUMBER:_' Program# EOL
END
RETURN

DoOpComments:
';' EOL
IF UseComments?
SetScale('1')
IF OperationIDComment?
';OPERATION_' Operation# ':_' OperationType$ EOL
END
IF OperationComment?
';' OperationComment$ EOL
END
IF WorkGroupComment?
';' WorkGroupComment$ EOL
END
IF ToolTypeComment?
';TOOL_' Tool# ':_' ToolDiameter# '_' ToolType$ EOL
END
IF ToolComment?
';T' Tool# '_' ToolComment$ EOL
END
';' EOL
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC ' A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC ' A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC ' B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC ' B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed GetZIn FeedEnt EOL
ELSE
SeqLabC RapidC GetZIn EOL
END
RETURN

StartSub:
SetFlag('4') { Need to Call N5000 at end of Prog }
OpenSub
';' EOL
ToolSeq DoSubComment EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
';' EOL
';WARNING___Z_CLEARANCE_WILL_CHANGE_WITH_EACH_CYCLE_OF_SUB_REPEAT' EOL
';' EOL
END
END
RETURN

StdSub:
EachRep
SeqLabC CallToolSub EOL { SubCall }
NextRep
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC
IF NOT FeedConnect?
IF AutoCycle?
GetZCP3C
ELSE
IF FIFO?
FeedC GetZCP3C FeedEntC
ELSE
RapidC GetZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset
IF AbsValue?
ShiftRC
ELSE
IF NotEqual? RepeatX# Num#('0')
' x' OriginShiftRX#
END
IF NotEqual? RepeatY# Num#('0')
' y' OriginShiftRY#
END
IF NotEqual? RepeatZ# Num#('0')
' z' OriginShiftRZ#
END
END
EOL
ToolSeqInc
ToolSeq EOL { EndSub }
CloseSub
SeqLabC Preset
IF AbsValue?
UnshftRC
ELSE
IF NotEqual? RepeatX# Num#('0')
' x' OriginUSRXCTP#('1')
END
IF NotEqual? RepeatY# Num#('0')
' y' OriginUSRYCTP#('1')
END
IF NotEqual? RepeatZ# Num#('0')
' z' OriginUSRZCTP#('1')
END
END
EOL
RETURN

OpenMP:
IF OneToolAllParts? AND ExitClearancePlane?
ProgSeqDec
ProgSeq ToolOfst EOL
IF CutterRadiusCompensation?
SeqLabC CRCOn EOL
END
END
IF EquallySpacedOffsets? OR AllToolsOnePart?
SetFlag('2') { WFOStuff }
END
RETURN

CloseMP:
ckCRCOff
';' EOL
IF EquallySpacedOffsets?
FORMAT(ADD#,13)
SeqLabC Preset
' X(-GB' ADD# PartShiftX# OriginShiftPX# ')'
' Y(-GC' ADD# PartShiftY# OriginShiftPY# ')'
EOL
FORMAT(ADD#,5)
IF OneToolAllParts? AND ExitClearancePlane?
ProgSeqDec
END
SeqLabC CallProgSeq ' L(GA)' EOL
';' EOL
SeqLabC ' G99' EOL { Cancel Program Zero }
END
IF OneToolAllParts?
ProgSeqDec
END
SeqLabC ' G45' CallProgSeq EOL { Increment WorkFixtureOffset }
IF OneToolAllParts?
ProgSeqInit
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
SetInc
ELSE
IF NOT ZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
SetInc
ELSE
IF NOT SPZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SetAbs
END
RETURN

FormatHelix:
IF ArcCW?
' G22'
ELSE
' G23'
END
GetMoveXYZC GetArcIJK
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArc { No Output - Allows output of next G0 or G1 }
ELSE
CCWArc { No Output - Allows output of next G0 or G1 }
END
IF XYPlane? AND ZMove?
FormatHelix
ELSE
IF XZPlane? AND YMove?
FormatHelix
ELSE
IF YZPlane? AND XMove?
FormatHelix
ELSE
IF ArcCW?
' G2'
ELSE
' G3'
END
GetMoveXYZC GetArcIJ
END
END
END
RETURN

ckCRC:
{ NOTE: CutterRadiusCompensation supported above ZCP2/ZCP3 }
{ This is only to turn back on if turned off due to HelixMove }
SeqLabC CRCOnC EOL
RETURN

ckCRCNum:
{ NOTE: CutterRadiusCompensation supported above ZCP2/ZCP3 }
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC GetMoveSXYC EOL
SeqLabC CallToolSub EOL { SubCall }
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC DoDrillAbsOrInc GetMoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
ckCRC
SeqLabC DoAbsOrInc RapidC GetMoveXYZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
ckCRC
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc FeedC GetMoveXYZC FeedRateC EOL
DecelMove2
END
SeqLabC DoAbsOrInc FeedC GetMoveXYZC DecelFeed EOL
ELSE
SeqLabC DoAbsOrInc FeedC GetMoveXYZC FeedRateC EOL
END
END
ELSE
IF ArcFeat?
IF XYPlane? AND ZMove?
SeqLabC CRCOffC EOL
ELSE
IF XZPlane? AND YMove?
SeqLabC CRCOffC EOL
ELSE
IF YZPlane? AND XMove?
SeqLabC CRCOffC EOL
ELSE
ckCRC
END
END
END
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC SetAbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC GetZCP2 FeedEntC
ELSE
RapidC GetZCP2
END
END
EOL
ToolSeqInc
ToolSeq EOL { EndSub }
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
ToolSeqInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
ToolSeqDec
AutoCycPat
ToolSeqInc
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC SetAbsOrInc Connect GetStrtPos EOL
IF AutoCycle?
ToolSeqInc
END
Milling
FinishSub1
IF AutoCycle?
ToolSeqDec
ToolSeqDec
ToolSeqDec
END
FinishSubG92
IF AutoCycle?
ToolSeqInc
ToolSeqInc
END
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
ToolSeqInc
ToolSeqInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC SetInc GetStrtPosC EOL
SetAbsOrInc
END
END
SeqLabC GetZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqLabC SetInc GetStrtPosC EOL
SetAbsOrInc
END
IF FeedEntry?
SeqLabC GetZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqLabC Feed GetZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqLabC RapidC GetZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC CallToolSub EOL { SubCall }
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLabC Feed GetZCP2 FeedEnt EOL
ELSE
SeqLabC Rapid GetZCP2 EOL
END
END
ToolSeqDec
ToolSeqDec
ToolSeq EOL { EndSub }
ToolSeqInc
ToolSeqInc
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL
END
IF FeedConnect?
SeqLabC FeedC GetZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC GetZCP2PlusIncC EOL
END
SeqLabC Feed GetZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC GetZInPlusInc EOL
END
END
SeqLabC CallToolSub EOL { SubCall }
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
ToolSeqInc
ToolSeq EOL { EndSub }
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
Plane { No Output }
SeqLabC WFOStuff EOL
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbsOrInc
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetLowerCaseOK { For Incremental Addresses }
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlagF('3') { Header ToolList/End of Prog }
SetFlagF('4') { Need to Call N5000 at end of Prog }
SetFlagF('5') { Drill Subs Tool Sequence Line Number }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END

EOR EOL
OpenSub
VarInit
GetProgComments
VarInit
RestoreScale

EachOp {Start of post processing *********************}
IF MultipleParts?
IF AllToolsOnePart?
IF EquallySpacedOffsets?
SetFlag('2') { WFOStuff }
END
ELSE {implied OneToolAllParts?}
IF FullUp?
IF EquallySpacedOffsets?
SetFlag('2') { WFOStuff }
END
ELSE {implied ExitClearancePlane?}
SetFlag('2') { WFOStuff }
END
END
ELSE
SetFlag('2') { WFOStuff }
END
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
Plane { No Output }
';PROGRAM:' EOL
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
GetToolBlock EOL
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
SeqLabC WFOStuff EOL
MPSeq1C SpinOn EOL
SeqLabC ToolOfst EOL
ckCRCOn
';' EOL
CheckPass
SeqLabC Rapid GetStrtPos EOL
GetTouchOff
MPSeq2C GetZCP1 EOL { OfstOn }
IF MultipleParts? AND OneToolAllParts?
IF ExitClearancePlane?
OpenMP
ELSE
SeqLabC ToolOfst EOL
ckCRCOn
END
SeqLabC Rapid GetStrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
ckCRCOff
SeqLabC Rapid GetZUp EOL
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC Rapid GetHome EOL
END
IF LAST ProgStop?
SeqLabC ' M' EOL
ELSE
IF OptionalStops?
SeqLabC ProgStop EOL
END
END

{Start new Operation}

';' EOL
GetToolBlock EOL
DoOpComments
DoPostScript
Plane { No Output }
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
SeqLabC WFOStuff EOL
MPSeq1C SpinOn EOL
SeqLabC ToolOfst EOL
ckCRCOn
';' EOL
CheckPass
SeqLabC Rapid GetStrtPos EOL
GetTouchOff
MPSeq2C GetZCP1 EOL { OfstOn }
IF MultipleParts? AND OneToolAllParts?
IF ExitClearancePlane?
OpenMP
ELSE
SeqLabC ToolOfst EOL
ckCRCOn
END
SeqLabC Rapid GetStrtPos EOL
END
ELSE
IF SameTool?
ckCRCOff
DoEndOpPS
IF LAST ProgStop?
SeqLabC Rapid GetZUp EOL { OfstOff }
SeqLabC ' M' EOL

{Start new Operation}

IF NewToolOffset?
';' EOL
GetToolBlock EOL
END
GetStartOfSameTool
SeqLabC SpinOn EOL
SeqLabC ToolOfst EOL
ckCRCOn
';' EOL
SeqLabC Rapid GetStrtPos EOL
SeqLabC GetZCP1 EOL { OfstOn }
ELSE
IF NewToolOffset?
SeqLabC Rapid GetZUp EOL { OfstOff }

{Start new Operation}

';' EOL
GetToolBlock EOL
GetStartOfSameTool
SeqLabC ToolOfst EOL
ckCRCOn
';' EOL
SeqLabC Rapid GetStrtPos EOL
SeqLabC GetZCP1 EOL { OfstOn }
ELSE

{Start new Operation}

GetStartOfSameTool
ckCRCOn
SeqLabC Rapid GetStrtPos EOL
END
END
END
END
END {common point for all operations}
IF Milling?
MPSeq3C GetZCP2C EOL
IF Repeats?
NewProg
ToolSeqInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC GetZCP3C EOL
ELSE
IF FIFO?
SeqLabC FeedC GetZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC GetZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
ToolSeqInc
StdSub
SeqLabC Rapid GetStrtPos EOL
END
SeqLabC GetDrillCP EOL
GetCycle
SeqLabC Cycle GetStrtPos GetZDepth GetRLevel
IF Dwell?
' D' Dwell#
END
IF Peck?
Peck
END
IF RetractToCP1?
' P1.' { FromCP }
ELSE
{' P0'} { Default }
END
FeedEnt
IF Peck?
IF PeckChipBreaker?
' J*' { Delta Z Peck - Incremental Distance to subtract from the Last Peck to form
the next Peck distance. For example, starting with the initial I value Peck,
the Peck distances will be I - J = 2nd Peck distance and 2nd peck - J = 3rd
Peck distance and so on until the minimum peck value, K, is obtained. If J
and K are not programmed, the Peck distance is constantly the I value. }
' K*' { Minimum Z Peck - Specifies the minimum Peck distance. The K value is used
when Last Peck - J <_ K. The K value remains in effect after this point
until total Depth is reached. If K and J are not programmed, the Peck
distance is constantly the I value. }
' W' Retract
' U*' { Z W/O Retract - Magnitude of Depth between Rapid Retracts to the R-Plane,
an incremental Z negative distance regardless of AbsOrInc. Each time the
current Depth of cut without Retract is equal to or greater than the U
value, a Rapid Retract to the R-Plane is performed. If U is not programmed,
or is less that 1, the Tool will Retract to the R-Plane after each Peck. If
U is greater than Z minus R, there will be no Retract to the R-Plane until
final depth is reached. }
ELSE
Retract
END
END
EOL
SetFlagF('5')
IF CallMasterOp?
ckDrillSub
IF Flag?('5')
SeqLabC CallDrillSubSeq EOL { SubCall }
SetDrillEndOpZ
ELSE
TrackZNO# FIRST SPZ#
ToolPath
END
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
NewMasterProg
ckDrillSub
IF Flag?('5')
SetFlag('1') {std sep sub Zreps in effect}
SeqLabC CallDrillSubSeq EOL { SubCall }
StartDrillSub
ToolPath
DrillSubEndSeq EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
ELSE
ToolPath
END
END
SetFlagF('5')
SetDrillEndOpZ
';' EOL
SeqLabC ' G80' EOL
SeqLabC Rapid GetZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
SetFlag('3') { Header ToolList/End of Prog }
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
ckCRCOff
SeqLabC Rapid GetZUp EOL
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqLabC Rapid GetFirstHome EOL
END
IF ProgStop?
SeqLabC ' M' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
IF Flag?('4')
ProgSeqInc
SeqLabC CallProgSeq EOL
END
CloseSub
Post2 {organize Subs into one program}
IF Flag?('4')
';' EOL
ProgSeq
ELSE
SeqLabC
END
EOP EOL
EOR EOL
Close
ReTag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
';FILE_LENGTH:_' FileBytes# '_CHARACTERS' EOL
END
IF FileFeetComment?
';FILE_LENGTH:_' FileFeet# '_FEET' EOL
END
IF FileMetersComment?
';FILE_LENGTH:_' FileMeters# '_METERS' EOL
END
Close
END