{Change Comments ***********************************************************}

{12/9/91
Copied & modified: GE 2000 Burgmaster M473.81.1
For: Micron Machine
Machine: Herbert DeVlieg
Control: Allen Bradley 8200
Added Helical Arc Support.
Added #6 = '###.####;0.'
Added FORMAT(ArcZRads#,6).
Added CheckHelix Sub called at FormatArc.
Deleted GetNewProg sub and changed all GetNewProg calls to NewProg.
Deleted 'MSG,' from all Comments.
Deleted Incremental 4thAxis output at PSStuff.
Deleted literal 'M70' for 4thAxis at PSStuff.
Modified 4thAxis PostScript Comments.
Added 5thAxis output.
Added 5thAxis PostScript Comments.
Changed 'ID, GSUB,' to 'DM,' at StartSub for SubID.
Changed all 'GSUB,' with 'CM,' at all CallSubs
Changed all 'P0=' Repeats# to EachRep/NextRep loops.
Changed ShiftR/UnshiftR to ShiftRC/UnshftRC.
Changed all 'P0=' Parts# to EachPart/NextPart loops.
Changed ShiftP/UnshiftP to ShiftPC/UnshftPC.
Changed all 'END, GSUB' to 'EM,'
Modified to output CRCOffC on line by itself, followed by Rapid 'G80' line.
Deleted CRCOnC from IF ArcFeat? in ToolPath.
Deleted GetCoolant Sub.
Deleted Coolant PostScript Comments.
Changed all calls to GetCoolant Sub with CoolOn.
Changed SetMaxFeed from ('400') to ('200').
Madified Formula at FirstOperation to be Save# Num#('1') ADD# Program# Num('1').
This allows suppression of blank line before FIRST Sub.
Added blank line before EOR at FirstOperation.
Changed 'ID, PROG, ' Program# to 'TN,' ProgramName$ at FirstOperation.
Modified SafeStartup blocks at FirstOperation, NewTool and SameTool.
Added literal 'G75' Full 360Ą Arcs at FirstOperation.
Added literal 'W0' Clear Table at FirstOperation and NewTool.
Changed OfstOn to ZCP1.
Tool# specifies Length and Dia Offset#.
Deleted Rapid 'Z0.D00' at NewTool, SameTool and end of Prog.
Replaced ToolChangeAtHome stuff with 'M17T00' followed by 'M19'.
Deleted 'M00' ProgStop at NewTool.
Manual ToolChng automatically causes this.
Added 'G89' Drilling Cycle IF FIFO? AND Dwell? = TRUE.
Deleted Peck and Dwell Parameters from Canned Drill Cycle line.
Added Rapid to 'G80' Cancel Canned Drill Cycle line.
Deleted '(END, PROG)' at end of Prog.
DWB}

{9/12/92
Modified: AB 8200 Herbert M472.81
For: Micron Machine
Updated to Version 4.1 per Fanuc 6M M001.81.2 Format.
Changed literal 'G75' to 'G74' for 90Ą Arcs at FirstOperation.
Set Use Absolute Arc Centers to False in Mach Spec.
Set Arcs Stop on Quadrants to True in Mach Spec.
DWB}

{11/2/92
Modified: AB 8200 Herbert M472.81.2
For: Micron Machine
Changed to unsigned I's and J's.
Deleted two blank lines prior to ProgramName$ at FirstOperation.
Deleted SeqC from ProgramName$ block.
DWB}

{11/20/92
Modified: AB 8200 Herbert M472.81.3
For: Micron Machine
Modified Helical Arcs to ArcSegments.
This is a temporary fix until we can correct the bug with Helical QuadrantStops.
Added Flag(1) to ZOnlyRep so ArcSegments are bypassed.
Deleted TrackZNO# ClearancePlane1# at IF Drilling because control always leaves tool at ZCP2.
DWB}

{4/15/93
Modified: AB 8200 Herbert M472.81.4
For: Micron Machine
Added logic for handling Drilling Cycles AND RetractToCP1 at ToolPath.
Cancels Cycle followed by ZCP1 followed by re-definition of Cycle.
Added back ToolChangeAtHome at NewTool and end of Prog.
Changed TrackZNO# ZDepth# to TrackZNO# FIRST SPZ# at IF Drilling.
SPZ# is affected by SetScale, whereas ZDepth# is not.
DWB}

{12/21/94
Updated: AB 8200 Herbert M472.81.5
For: Gibbs & Associates/ASKO
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.04/Compost 4.21.23
Updated to Version 4.2 per Fanuc 6M M001.81.2f Format.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added logic to output CRCOnC in OneFeat ToolPath.
Added logic to suppress output of CRCOnC on ZMove Feature.
Added support of CRC during multiple pocket dog-bone operation.
Added condition to output CRCOnC for XMove OR YMove only at CkCRC sub.
Outputs G41/G42 on First LineFeat after Z Plunge.
Modified condition to output CRCOffC for LastFeat AND AutoCycle at ToolPath RapidFeat.
Assures that G40 is not output prior to LastFeat.
Added CRCOffC to RapidFeat at ToolPath.
Outputs G40 at all ZMoveOnly Feature Retract blocks.
DWB}

{12/22/94
Copied: AB 8200 Herbert M472.81.6
Created: AB 8200 [ASKO] M725.81.2
For: ASKO
Machine: Hillyer Gantry
Control: AB 8200-5.2.3
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.04/Compost 4.21.23
Versions: Catalyst v2.14.22C/Catalyst v2.14.22PPC/Compost 4.21.23
Changes made per Dave Touron and Tim Thompson of ASKO.
Added Address Spaces.
Added standard WorkFixtureOffset support.
Range is from H01 to H16.
Added FORMAT#8 '00' at Prog Numeric Format Definitions.
Added NewWFO# to FORMAT#8 at Prog Numeric Format Definitions.
Added NewWFOF to FORMAT#8 at PSInit sub.
Added ' H' NewWFO# two places at WFOStuff sub.
Added InitWFONum at setup and initializations.
Added NewWFO(n), NWFO(n) comments at PostScript Comments.
Added call to WFOStuff sub at GetStartOfSameTool sub, FirstOperation and NewTool.
Modified support of CutterRadiusCompensation.
Processor output CRCOnC on StrtPos block at FirstOperation, NewTool and SameTool.
Processor outputs CRCOffC at end of IF Milling?
Modified support of Coolant control.
Outputs CoolOn for ToolChng Operations on initial ZCP2C block for Milling Operations.
Outputs CoolOff for LastOp or NEXT NewTool situations at end of IF Milling.
Outputs CoolOn for ToolChng Operations on Canned Cycle block for Drilling Operations.
Outputs CoolOff for LastOp or NEXT NewTool situations at end of IF Drilling.
Deleted special handling of Drill Cycles that RetractToCP1 at ToolPath.
Was outputting G80 followed by new position and new Canned Cycle block for EachFeature.
Deleted literal 'M17T00' at NewTool and end of Prog.
Deleted literal 'M19' at NewTool and end of Prog.
Added literal ' M00' to LAST ProgStop at NewTool.
Added literal ' M00' to ProgStop at end of Prog.
Changed ASCII(4) top EOR at end of Prog.
Added support of special Sequence Search function.
Control can search for blocks based on Address O.
Added FORMAT#7 '0000' at Prog Numeric Format Definitions.
Added Recall# to FORMAT#7 at Prog Numeric Format Definitions.
Added Variable(2) to increment at each ToolChng.
Initializing Var(2) by storing zero at FirstOperation.
Incrementing Var(2) by 1 and outputting contents with Address O at NewTool.
Added support of PostScript OptionalCycle1 command for Drilling Operations.
IF FIRO? = TRUE, processor will output LongHand Non-Canned Drilling Cycle.
DWB}

{2/16/95
Modified: AB 8200 [ASKO] M725.81.2
For: ASKO
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Compost 4.21.27
Versions: Catalyst v2.14.30C/Catalyst v2.14.30PPC/Compost 4.21.27
Changes made per Tim Thompson of ASKO.
Changed output of Program Identifier at FirstOperation.
Was outputting '(TN,' ProgramName$ ')'.
Changed to '(TN,' Program# ')'.
Added comment to output ProgramName$.
DWB}

{2/9/96, Updated .81 version to .84, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{12/5/95,
Initial: AB 8200 [ASKO] M725.87
Created: AB 8200 [ASKO] M725.87.1
I,J, andK values were unsigned, now are signed,
Added Block delete character before all block in which cutting is being done,
Added Flag 3 to keep track of when the block delete character should be outputting,
MPK}

{18Jun97
Original: AB 8200 [ASKO] M725.87.1
Created: AB 8200 [ASKO] M725.87.2
For: ASKO
Changes made per: Jesse Armstrong
Moved CRCOnC from StrtPos block to a seperate line in FirstOperation, NewTool and SameTool.
Charles Winston}

{6/3/98
Updated & Modified: AB 8200 [ASKO] M725.87.2
Created: AB 8200 [ASKO] M725.89
For: ASKO
Versions: Catalyst v4.21.30(mac)/ComPost2 1.1b3
Changes made per Curt Richardson of Allen Bradley and Pat Kazimer of ASKO, phone calls, faxes and
1522.VNC Test File.
Updated for Catalyst v3.35C per Fanuc 6M M001.89b Format.
Customer reported problem with Sign of Arc Center Addresses.
According to manual, there are 3 Circular Programming Modes.
G74, Full Circle Off, 90Ą Arcs with unsigned Incremental Arc Center Addresses.
G75, Full Circle On, 360Ą Arcs with signed AbsOrInc Arc Center Addresses.
G76, Full Circle On, 360Ą Arcs with signed Incremental Arc Center Addresses.
Post was outputting G74 at FirstOperation, but Arcs being generated fell into G76 mode.
Changed G74 to G76 at FirstOperation.
Customer requested no Block Delete Character on Canned Drilling Cycle Block.
Added call to BlkDelOff just prior to Canned Drilling Cycle Block at IF Drilling.
Added call to BlkDelOn just after Canned Drilling Cycle Block at IF Drilling.
Added BlkDelOn Sub.
Executes SetLineStrtChr('/') IF Flag(3) is set.
Called from all places that did this.
Added BlkDelOff Sub.
Executes SetLineStrtChr('').
Called from all places that did this.
Added GetSubID Sub.
Outputs literal '(DM,' Program# ')'.
Called from all places that did this.
Added GetCallSub Sub.
Outputs literal '(CM,' CallMasterNum# ')' for Drilling CallMasterOp.
Outputs literal '(CM,' Program# ')' for all other cases.
Called from all places that did this.
Added GetEndSub Sub.
Outputs literal '(EM)'.
Called from all places that did this.
Deleted condition to Segment Helical Arcs at CheckHelix sub and ToolPath ArcFeat.
Refer to Developer Notes of 11/20/92.
Problem was corrected a long time ago.
DWB}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '####0.0##;0.'
#3 = '*####0.0##;0.'
#4 = '###0.0##;0.'
#5 = '#######0'
#6 = '+##0.0###;0.'
#7 = '0000'
#8 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(Dwell#,4)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(ArcZRads#,6)
FORMAT(Recall#,7)
FORMAT(NewWFO#,8)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

WFONum:
' H' NewWFO#
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
WFONum
END
ELSE
IF Flag?('2')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
WFO1
ELSE
WFONum
END
ELSE
WFONum
END
END
END
END
SetFlagF('2')
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqC '( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqC '( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqC '( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqC '( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqC '( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqC '( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC Rapid ZIn EOL
END
RETURN

BlkDelOn:
IF Flag?('3')
SetLineStrtChr('/')
END
RETURN

BlkDelOff:
SetLineStrtChr('')
RETURN

GetSubID:
'(DM,' Program# ')'
RETURN

GetCallSub:
IF Drilling? AND CallMasterOp?
'(CM,' CallMasterNum# ')'
ELSE
'(CM,' Program# ')'
END
RETURN

GetEndSub:
'(EM)'
RETURN

StartSub:
OpenSub
BlkDelOff
IF NotEqual? Program# Recall# Num#('1') { Don't output at First Sub }
' ' EOL
END
SeqC GetSubID EOL
DoSubComment
BlkDelOn
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
SeqC '( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
EachRep
SeqC GetCallSub EOL
NextRep
StartSub
RETURN

FinishSub1: {part 1}
SeqC
IF NOT FeedConnect?
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
IF AutoCycle?
Rapid ZCP3C
ELSE
IF FIFO? {.81}
Feed ZCP3C FeedEntC
ELSE
Rapid ZCP3C
END
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
BlkDelOff
SeqC GetEndSub EOL
BlkDelOn
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
NewWFO
EachWFO {simple eachPart}
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqC SetWFO EOL
END
SeqC GetCallSub EOL
IncWFO
NextWFO {simple NextPart}
ELSE
EachPart
SeqC GetCallSub EOL
NextPart
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC GetEndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC GetEndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

CheckHelix:
IF XYPlane?
IF ZMove?
MoveX MoveY MoveZ ArcIJ ' K' ArcZRads#
ELSE
MoveX MoveY ArcIJ
END
ELSE
IF XZPlane?
IF YMove?
MoveX MoveY MoveZ ArcI ' J' ArcZRads# ArcJ
ELSE
MoveX MoveZ ArcIJ
END
ELSE
IF YZPlane?
MoveX MoveY MoveZ ' I' ArcZRads# ArcIJ
ELSE
MoveY MoveZ ArcIJ
END
END
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArc
ELSE
CCWArc
END
CheckHelix
RETURN

ckCRC: { Handled in Main }
IF CutterRadiusCompensation?
SeqC CRCOn EOL
END
RETURN

ckCRCNum:
{ Not Supported }
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC GetCallSub EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF OptCyc1? AND FIRO? { LongHand Non-Canned FI-RO Drilling Cycle }
IF NOT FirstFeat?
IF SPXMove? OR SPYMove?
SeqC Rapid MoveSXYC EOL
END
IF RetractToCP1?
SeqC Rapid ZCP2C EOL
END
END
IF SPZMove?
SeqC Feed MoveSZC FeedEnt EOL
END
IF RetractToCP1?
SeqC Rapid ZCP1C EOL
ELSE
SeqC Rapid ZCP2C EOL
END
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC Rapid MoveXYZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC Feed MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC Feed MoveXYZC DecelFeed EOL
ELSE
SeqC Feed MoveXYZC FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
LoadFeat Num#('0') Num#('0') ClearancePlane2#
IF ZMove?
IF FIFO?
Feed ZCP2 FeedEntC
ELSE
Rapid ZCP2
END
END
END
EOL
SeqC GetEndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC GetCallSub EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
BlkDelOff
SeqC GetEndSub EOL
BlkDelOn
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC Rapid ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
SeqC GetCallSub EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
BlkDelOff
SeqC GetEndSub EOL
BlkDelOn
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
TrackZNO# ClearancePlane2# { Tool always left at RLevel }
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
SeqC WFOStuff EOL
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('3000')
IF Metric?
SetMaxFeed('5080')
ELSE
SetMaxFeed('200')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlagF('3') { Output Block Delete Character at Start of Block }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
Save# Num#('1') Num#('0') { Suppression of blank line prior to FIRST Sub }
Save# Num#('2') Num#('0') { Initial Sequence Search }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify, example A12.5.' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify, example A-22.5.' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify, example B30.' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify, example B-22.5.' EOL
' OptionalCycle1, OptCyc1 -' EOL
' Will output LongHand Non-Canned FI-RO Drilling Cycle.' EOL
END
EachOp {Start of post processing *********************}
IF MultipleParts?
IF AllToolsOnePart?
IF EquallySpacedOffsets?
SetFlag('2') { WFOStuff }
END
ELSE {implied OneToolAllParts?}
IF FullUp?
IF EquallySpacedOffsets?
SetFlag('2') { WFOStuff }
END
ELSE {implied ExitClearancePlane?}
SetFlag('2') { WFOStuff }
END
END
ELSE
SetFlag('2') { WFOStuff }
END
IF FirstOperation?
Save# Num#('1') ADD# Program# Num#('1') { Suppression of blank line prior to FIRST Sub }
EOR EOL
OpenSub
'(TN,' Program# ')' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqC '( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqC '( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqC '( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqC '( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqC '( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
SeqC '( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
SeqC '( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Save# Num#('2') Num#('0') { Initial Sequence Search }
Seq CRCOff AbsOrInc Plane ' G15 G70 G76 G97' Speed EOL
{ G15 = Axis 3 Select, G70 = Inch Mode, G76 = Full Circle Programming On, G97 Not Defined }
DoOpComments
DoPostScript
SeqC OpToolID ToolChng EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqC OpToolID EOL
AbsOrInc
END
CheckPass
SeqC ToolOfst EOL
SeqC WFOStuff EOL
SetFlag('3') { Output Block Delete Character at Start of Block }
BlkDelOn
IF Milling?
SeqC Rapid StrtPos EOL
ckCRC
END
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC WFOStuff EOL
SeqC Speed EOL
SeqC Rapid StrtPos EOL
ckCRC
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC ' T00' EOL { OfstOff }
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home EOL
END
IF LAST ProgStop?
SeqC ' M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

' ' EOL
Save# Num#('2') ADD# Recall# Num#('2') Num#('1')
'O' Recall# Num#('2') EOL { Sequence Search }
DoOpComments
DoPostScript
SeqC Speed OpToolID ToolChng EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqC OpToolID EOL
AbsOrInc
END
CheckPass
SeqC ToolOfst EOL
SeqC WFOStuff EOL
SetFlag('3') { Output Block Delete Character at Start of Block }
BlkDelOn
IF Milling?
SeqC Rapid StrtPos EOL
ckCRC
END
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC WFOStuff EOL
SeqC Speed EOL
SeqC Rapid StrtPos EOL
ckCRC
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
BlkDelOff
SeqC CoolOff EOL
SeqC ' T00' EOL
SeqC ' M00' EOL

{Start new Operation}

GetStartOfSameTool
BlkDelOn
SeqC ToolOfst EOL
IF Milling?
SeqC PlaneC Rapid StrtPos SpeedC EOL
ckCRC
END
SeqC CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
BlkDelOff
SeqC ' T00' EOL

{Start new Operation}

GetStartOfSameTool
SeqC ToolOfst EOL
BlkDelOn
IF Milling?
SeqC PlaneC Rapid StrtPos SpeedC EOL
ckCRC
END
ELSE

{Start new Operation}

GetStartOfSameTool
IF Milling?
SeqC PlaneC Rapid StrtPos SpeedC EOL
ckCRC
END
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
IF FirstOperation? OR NewTool?
SeqC Rapid ZCP2 CoolOn EOL
ELSE
LoadFeat Num#('0') Num#('0') ClearancePlane2#
IF ZMove?
SeqC Rapid ZCP2 EOL
END
END
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF LastOp? OR NEXT NewTool?
SetFlagF('3')
BlkDelOff
END
SeqC CRCOffC EOL
IF LastOp?
SeqC CoolOff EOL
END
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
IF AutoCycle?
SeqC Rapid ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC Feed ZCP3C FeedEntC EOL
ELSE
SeqC Rapid ZCP3C EOL
END
END
END
IF NEXT NewTool?
SeqC CoolOff EOL
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
GetCycle
IF OptCyc1? AND FIRO?
SeqC Rapid StrtPos EOL
SeqC
LoadFeat Num#('0') Num#('0') ClearancePlane2#
IF ZMove?
Rapid ZCP2C
END
IF FirstOperation? OR NewTool?
CoolOn
END
EOL
ToolPath
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
SeqC Rapid ZCP3C EOL
END
IF LastOp? OR NEXT NewTool?
SetFlagF('3')
BlkDelOff
SeqC CoolOff EOL
END
ELSE
BlkDelOff
SeqC
IF FIFO? AND Dwell?
' G89'
ELSE
Cycle
END
StrtPos ZDepth RLevel Dwell Peck FeedEnt
IF FirstOperation? OR NewTool?
CoolOn
END
EOL
BlkDelOn
IF CallMasterOp?
SeqC GetCallSub EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC GetCallSub EOL
StartSub
ToolPath
SeqC GetEndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
IF NEXT NewTool? OR LastOp?
SetFlagF('3')
BlkDelOff
END
SeqC ' G80'
IF LastOp? OR NEXT NewTool?
CoolOff
END
EOL
SeqC Rapid ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC ' T00' EOL { OfstOff }
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC Rapid FirstHome EOL
END
IF ProgStop?
SeqC ' M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END