{Change Comments ***********************************************************}

{8/16/91
Copied & modified: AB Sheldon [BRL+] L142.80
For: Norton Company
Machine: Pneumo
Control: Allen Bradley Series 8200
Made modifications per conversations with Jeff at Norton, sample program and AB 8200 manual.
DWB}

{3/31/94
Modified: AB 8200 Pneumo L230.82
For: Norton
Updated to .82 format per Fanuc 10T MS [-] L001.82ż
Added Tool calls in 1st op and NewTool.
Suppress output of CoolOff at end of program.
Jim Radcliffe}

{5/30/95
Initial: AB 8200 Pneumo L230.82.1
ForUser: CNCCS / Norton Company
Control:
Machine:
Develop: ComPost 4.21.26, ncCAD 4.33, ncCAM 4.33, ncPost 4.33.04
Comment: New Processor per before and after edits readouts and phone support.
Added G76 to beginning of program.
This sets full circle programming without dwelling at quadrant crossover points.
Unconditional G02/G03 arc commands.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = 'ą0.######;+0.0'
#3 = '########;0'
#4 = '+0.######'
#5 = '0000'
#6 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(CycleStartX#,2)
FORMAT(CycleStartZ#,2)
FORMAT(FinishXRadius#,2)
FORMAT(FinishZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(DIV#,4)
FORMAT(FeedIPR#,4)
FORMAT(CalcEPRPM#,5)
FORMAT(RapidF#,6)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ODApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

IDApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

FaceApproachSP:
SeqC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN

AppMove:
StockOff ZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqC StockOff XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqC StockOff XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqC StockOnNoCan XSP AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC ' M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqC Preset MaxRPM EOL
END
ELSE
SeqC Preset MaxRPM EOL
SeqC CSSOn ' G96 R' CycleStartX# Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqC CSSOff ' G97' Speed
END
END
IF LAST ProgStop?
SeqC SpeedC SpinOn EOL
SeqC CoolOn EOL
ELSE
SeqC SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveX MoveZ ArcIJ
RETURN

GetTaper:
IF Taper?
' I' DIV# MUL# FeedIPR# ABS# Taper# ABS# FinishZInc#
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC ' G94 G04 F2.' EOL
SeqC ' G95' Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqC ' G94 G04 F' Dwell# EOL
' G95'
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC ' G33' MoveXC MoveZC GetTaper ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
PosSideLathe
XsAreRadii
SetMaxRPM('2000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
Seq AbsOrInc EOL
SeqC ' G76' EOL
SeqC ' G70' EOL { Inch }
IF ConstantSurfaceFeed?
SeqC Preset MaxRPM EOL
SeqC CSSOn ' G97' CalcRPM1 SpinOn EOL
ELSE
SeqC CSSOff ' G97' Speed SpinOn EOL
END
SeqC OpToolID LatheOffset EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC XCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
END
SeqC ZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqC CSSOff ' G97' CalcRPM2 EOL
END
SeqC NewHome SpinOff EOL
IF LAST ProgStop?
SeqC ' M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
Seq Preset MaxRPM EOL
SeqC CSSOn ' G97' CalcRPM1 SpinOn EOL
ELSE
Seq CSSOff ' G97' Speed SpinOn EOL
END
SeqC OpToolID LatheOffset EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
SeqC ZCPC EOL
SeqC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC XCPC EOL
END
SeqC ZCPC EOL
SeqC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC XCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqC CSSOn ' G96 R' CycleStartX# Speed EOL
END
IF CannedCycle?
StockOff
IF Threading?
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF Taper?
SeqC ' X' ADD# FinishXRadius# MUL# Taper# NumSc#('1') EOL
SeqC LCycle ' X' FinishXRadius# ' Z' FinishZ# GetTaper ThrdLead EOL
ELSE
SeqC ' X' FinishXRadius# EOL
SeqC LCycle ' Z' FinishZ# ThrdLead EOL
END
SeqC Rapid ' X' CycleStartX# EOL
SeqC ' Z' CycleStartZ# EOL
END
ELSE
IF Drilling?
IF Tap?
SeqC LCycle ZDepth ' K' FeedIPR# EOL
SeqC SpinOff EOL
SeqC ' G94 G04 F2.' EOL
SeqC ' G95' Speed InverseSpinOn EOL
SeqC LCycle ZSP ' K' FeedIPR# EOL
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
SeqC ZOpECPC EOL
FaceApproachSP
ELSE
SeqC XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
ELSE
SetPass2
SeqC RapidC StrtPos EOL
END
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC ' G94 G04 F2.' EOL
SeqC ' G95' Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqC XCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC EOL
END
END
SeqC ZCPC EOL
DoEndOpPS
IF NOT CoolOff?
SeqC CoolOff EOL
END
IF ConstantSurfaceFeed?
SeqC CSSOff ' G97 S' CalcEPRPM# EOL
END
SeqC FirstHome SpinOff EOL
IF ProgStop?
SeqC 'M00' EOL
END
SeqC EOP EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END