{Change Comments ***********************************************************}

{3/7/89
Copied & modified; Fanuc 10T-MS [-] L001.57, for Angelus Can.
Machine is a Warner & Swasey 2SC with Alan Bradley 7360 control
Jim Radcliffe}

{3/10/89
Deleted 'StockOnNoCan:' subroutine which sets post to 'StockOn' if
'CannedCycle?' is false. Changed 'StockOnNoCan' subcall to 'StockOn'
Altough this machine has no canned cycles, and ncPOST should always
be directed to 'StockOn', I left the canned cycle
info in the Mach Spec and am using the 'CannedCycle?' boolean
to control the rapid feed around the part if
'Prefered Canned Cycles' was selected in ncCAM.
Jim Radcliffe}

{9/27/89, updated & added PostScript to W & S 2SC AB 7360 L096.55, JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{8/9/90, Updated: W & S 2SC AB 7360 L096.62 to .71 format, JR}

{11/16/90
Copied & modified: W & S 2SC AB 7360 L096.71
For: Chandler Evans (Colt Ind.)
Min Seq number to be the same as the offset number.
Change colons to spaces in comments.
Deleted CalcRPM1 & CalcRPM2 lines, no G97 ouput when CSS is used,
moved G96 line to where G97 line was. This was done to give programmer
control over the S numbers output for proper gear selection.
Changed Rapid to Feed & RapidC to FeedC.
Changed G01, G02 & G03 to G21, G22 & G23 in Mach Spec.
Deleted CheckFeed sub, changed CheckFeed calls to RapidFC or FeedRateC.
Modified MachSpec to output F01 for RapidF.
Changed RapidF in Approach sub and return to home lines to F0.
Jim Radcliffe}

{09/05/91
Updated: W & S 2SC AB [CE] L186.71
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}

{02/21/92
Updated: W & S 2SC AB [CE] L186.82
For: Gibbs & Associates/Chandler Evans
Updated to Version 4.0 per Fanuc 6M M001.82.1 Format.
Added 'F0' in the Approach Stuff.
Added Flag('1') to IF RapidFeat? in Toolpath to distinguish the
first RapidFeat from any following in the same operation, like in
a threadfeat, and added a 'F0' to the first pass.
Changed FeedRateC in LineFeat? of Toolpath to FeedRate.
Added 'F0' to ZCPC in - (IF 'LAST' ApproachOD?)
Kim Michelman}

{Prog Numeric Format Definitions *******************************************}

#1 = '0.00'
#2 = '0#^####'
#3 = '########;0'
#4 = '0000'
#5 = '00'
#6 = '###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,2)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(StartPosX#,2)
FORMAT(Program#,3) {.70}
FORMAT(Operation#,3) {.70}
FORMAT(Tool#,3) {.70}
FORMAT(ToolOffset#,4)
FORMAT(TurretX#,2)
FORMAT(RapidF#,5)
FORMAT(CalcEPRPM#,6)

{Prog Subroutines **********************************************************}


DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ' ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ' ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

ODApproachSP:
SeqC StockOn ZSPC 'F0' EOL
SeqC StockOff XOpCDC EOL
SeqC StockOn XSPC 'F0' EOL
RETURN

IDApproachSP:
SeqC StockOn ZSPC 'F0' EOL
SeqC XSPC EOL
RETURN

FaceApproachSP:
SeqC StockOff ZOpCPC 'F0' EOL
SeqC StockOn ZSPC 'F0' EOL
RETURN

AppMove:
ZCP 'F0'
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqC Feed XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqC Feed XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqC Feed XSP StockOff AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC LOfstOff '00' EOL
SeqC OpToolID LatheOffset EOL
END
IF LAST ProgStop?
SeqC SpinOn EOL
SeqC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcJC ArcIC
ELSE
ArcRC
END
RETURN

ThreadPath: {straight thread along Z axis no single edge or chamfer}
EACHFeat
SeqC
IF ThreadFeat?
LCycle MoveZC ThrdLead EOL
ELSE
IF RapidFeat?
IF LAST ThreadFeat?
Feed MoveXC RapidF EOL
ELSE
MoveXC MoveZC EOL
END
END
END
NEXTFeat
RETURN

ToolPath:
EACHFeat
GetToolTip
SeqC
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC 'G4P2000' EOL
SeqC Speed InverseSpinOn EOL
ELSE
IF Dwell?
'G04X' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
MoveSXYC EOL
ELSE
IF RapidFeat?
FeedC MoveXC MoveZC
IF Flag?('1')
EOL
SetFlagF('1')
ELSE
'F0' EOL
SetFlag('1')
END
ELSE
IF LineFeat?
FeedC MoveXC MoveZC FeedRate EOL
ELSE
IF ArcFeat?
EACHQuadrant
FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
LCycle MoveXC MoveZC XTapAtZ ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

GetSequence:
IF MinimizeSequencing?
'N' ToolOffset#
ELSE
Seq
END
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
XsAreRadii
NoIJKSigns
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
Plane
SeqC 'G70' EOL
SeqC 'G95' EOL
DoOpComments
DoPostScript
GetSequence Preset Home MaxRPM EOL
IF ConstantSurfaceFeed?
SeqC CSSOn 'G96R' TurretX# Speed SpinOn EOL
ELSE
SeqC CSSOff 'G97' Speed SpinOn EOL
END
SeqC OpToolID LatheOffset CoolOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
SeqC FeedC
IF LAST ApproachOD?
XCPC 'F0' EOL
SeqC ZCPC 'F0' EOL
ELSE
IF LAST ApproachID?
LAST XOpECDC EOL
END
END
ZCPC 'F0' EOL
DoEndOpPS
SeqC NewHome EOL
SeqC LOfstOff '00' EOL
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

SeqC 'G95' EOL
DoOpComments
DoPostScript
GetSequence Preset Home MaxRPM EOL
IF ConstantSurfaceFeed?
SeqC CSSOn 'G96R' TurretX# Speed SpinOn EOL
ELSE
SeqC CSSOff 'G97' Speed SpinOn EOL
END
SeqC OpToolID LatheOffset CoolOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

DoOpComments
StockOff
SeqC FeedC
IF LAST StraightConnect?
CheckOffset
SeqC StockOn XSPC ZSPC RapidFC EOL
ELSE
IF ApproachOD?
IF LAST NOT ApproachOD?
SeqC ZCPC RapidFC EOL
END
SeqC XCPC RapidFC EOL
CheckOffset
ELSE
IF LAST ApproachOD?
SeqC XCPC RapidFC EOL {around}
END
IF ApproachID?
IF LAST NOT ApproachID?
SeqC ZCPC RapidFC EOL
END
CheckOffset
SeqC XOpCDC EOL
ELSE {ApproachFace}
SeqC ZCPC RapidFC EOL
CheckOffset
SeqC XSPC EOL
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
SeqC SpeedC EOL
ELSE
SeqC Preset MaxRPM EOL
SeqC CSSOn 'G96R' StartPosX# Speed EOL
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqC CSSOff 'G97' Speed EOL
ELSE
SeqC SpeedC EOL
END
END
END
END
END
END
END
END {common point for all operations}
StockOn
SetPass1
IF Threading?
ThreadPath
ELSE
ToolPath
END
IF AutoFinish? AND NOT Drilling?
StockOff
IF Turning? {OR RoughSimple?}
SetPass1
IF ApproachOD?
SeqC RapidC XOpECDC EOL
ODApproachSP
ELSE
IF ApproachID?
SeqC RapidC XOpECDC EOL
IDApproachSP
ELSE {ApproachFace}
SeqC RapidC ZOpECPC EOL
FaceApproachSP
END
END
ELSE
SetPass2
END
SeqC FeedC StrtPos RapidFC EOL
ToolPath
END
END
END
IF Threading?
ThreadPath
ELSE
ToolPath
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
SeqC FeedC
IF ApproachOD?
XCPC 'F0' EOL
SeqC ZCPC 'F0' EOL
ELSE
IF ApproachID?
XOpECDC EOL
SeqC ZOpECPC EOL
END
END
ZCPC 'F0' EOL
DoEndOpPS
SeqC CoolOff EOL
IF ConstantSurfaceFeed?
SeqC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqC FirstHome EOL
SeqC OpToolID '00' EOL
IF ProgStop?
SeqC 'M0' EOL
END
SeqC EOP EOL
Post
EOR EOL
Close
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH ' FileMeters# ' METERS )' EOL
END
Close
END