{3/7/89
Copied & modified; Fanuc 10T-MS [-] L001.57, for Angelus Can.
Machine is a Warner & Swasey 2SC with Alan Bradley 7360 control
Jim Radcliffe}

{3/10/89
Deleted 'StockOnNoCan:' subroutine which sets post to 'StockOn' if
'CannedCycle?' is false. Changed 'StockOnNoCan' subcall to 'StockOn'
Altough this machine has no canned cycles, and ncPOST should always
be directed to 'StockOn', I left the canned cycle
info in the Mach Spec and am using the 'CannedCycle?' boolean
to control the rapid feed around the part if
'Prefered Canned Cycles' was selected in ncCAM.
Jim Radcliffe}

{9/27/89, updated & added PostScript to W & S 2SC AB 7360 L096.55, JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{8/9/90, Updated: W & S 2SC AB 7360 L096.62 to .71 format, JR}

{8/13/92
Updated: W & S 2SC AB 7360 L096.71
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Converted file to metric.
Kim Michelman}

{Prog Numeric Format Definitions *******************************************}

#1 = '0.00'
#2 = '0#^####'
#3 = '########;0'
#4 = '###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,2)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(StartPosX#,2)
FORMAT(Program#,3) {.70}
FORMAT(Operation#,3) {.70}
FORMAT(Tool#,3) {.70}
FORMAT(CalcEPRPM#,4)

{Prog Subroutines **********************************************************}


DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

ODApproachSP:
SeqC StockOn ZSPC EOL
SeqC StockOff XOpCDC EOL
SeqC StockOn XSPC EOL
RETURN

IDApproachSP:
SeqC StockOn ZSPC EOL
SeqC XSPC EOL
RETURN

FaceApproachSP:
SeqC StockOff ZOpCPC EOL
SeqC StockOn ZSPC EOL
RETURN

AppMove:
ZCP RapidF
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqC Rapid XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqC Rapid XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqC Rapid XSP StockOff AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC LOfstOff '00' EOL
SeqC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST NOT ConstantSurfaceFeed?
SeqC Preset MaxRPM EOL
END
SeqC CSSOff 'G97' CalcRPM1 EOL
ELSE
SeqC CSSOff 'G97' Speed EOL
END
IF LAST ProgStop?
SeqC SpinOn EOL
SeqC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcJC ArcIC
ELSE
ArcRC
END
RETURN

CheckFeed:
IF RapidFeat?
IF CannedCycle?
IF NOT LAST RapidFeat?
'F01' {optional slower rapid feed}
END
ELSE
RapidFC
END
ELSE
IF CannedCycle? AND LAST RapidFeat?
FeedRate {reset from literal feedrate}
ELSE
FeedRateC
END
END
RETURN

ThreadPath: {straight thread along Z axis no single edge or chamfer}
EACHFeat
SeqC
IF ThreadFeat?
LCycle MoveZC ThrdLead EOL
ELSE
IF RapidFeat?
IF LAST ThreadFeat?
Rapid MoveXC CheckFeed EOL
ELSE
MoveXC MoveZC EOL
END
END
END
NEXTFeat
RETURN

ToolPath:
EACHFeat
GetToolTip
SeqC
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC 'G4P2000' EOL
SeqC Speed InverseSpinOn EOL
ELSE
IF Dwell?
'G04X' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
MoveSXYC EOL
ELSE
IF RapidFeat?
RapidC MoveXC MoveZC CheckFeed EOL
ELSE
IF LineFeat?
FeedC MoveXC MoveZC CheckFeed EOL
ELSE
IF ArcFeat?
EACHQuadrant
FormatArc CheckFeed EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
LCycle MoveXC MoveZC XTapAtZ ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
XsAreRadii
NoIJKSigns
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
END
OpenSub
StockOff {.71.2}
SetHome
Plane
SeqC 'G70' EOL
SeqC 'G95' EOL
DoOpComments
DoPostScript
Seq Preset Home MaxRPM EOL
SeqC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1 SpinOn EOL
ELSE
Speed SpinOn EOL
END
SeqC OpToolID LatheOffset CoolOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
SeqC RapidC
IF LAST ApproachOD?
XCPC RapidFC EOL
SeqC ZCPC RapidFC EOL
ELSE
IF LAST ApproachID?
LAST XOpECDC EOL
END
END
ZCPC RapidFC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqC CSSOff 'G97' CalcRPM2 EOL
END
SeqC NewHome EOL
SeqC LOfstOff '00' EOL
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

SeqC 'G95' EOL
DoOpComments
DoPostScript
Seq Preset Home MaxRPM EOL
SeqC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1 SpinOn EOL
ELSE
Speed SpinOn EOL
END
SeqC OpToolID LatheOffset CoolOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

DoOpComments
StockOff
SeqC RapidC
IF LAST StraightConnect?
CheckOffset
SeqC StockOn XSPC ZSPC RapidFC EOL
ELSE
IF ApproachOD?
IF LAST NOT ApproachOD?
SeqC ZCPC RapidFC EOL
END
SeqC XCPC RapidFC EOL
CheckOffset
ELSE
IF LAST ApproachOD?
SeqC XCPC RapidFC EOL {around}
END
IF ApproachID?
IF LAST NOT ApproachID?
SeqC ZCPC RapidFC EOL
END
CheckOffset
SeqC XOpCDC EOL
ELSE {ApproachFace}
SeqC ZCPC RapidFC EOL
CheckOffset
SeqC XSPC EOL
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed?
SeqC CSSOn 'G96R' StartPosX# Speed EOL
END
StockOn
SetPass1
IF Threading?
ThreadPath
ELSE
ToolPath
END
IF AutoFinish? AND NOT Drilling?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqC RapidC StrtPos RapidFC EOL
IF Threading?
ThreadPath
ELSE
ToolPath
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
SeqC RapidC
IF ApproachOD?
XCPC RapidFC EOL
SeqC ZCPC RapidFC EOL
ELSE
IF ApproachID?
XOpECDC EOL
SeqC ZOpECPC EOL
END
END
ZCPC RapidFC EOL
DoEndOpPS
SeqC CoolOff EOL
IF ConstantSurfaceFeed?
SeqC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqC RapidC FirstHome RapidFC EOL
SeqC OpToolID '00' EOL
IF ProgStop?
SeqC 'M0' EOL
END
SeqC EOP EOL
Post
EOR EOL
Close
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END