{Change Comments ***********************************************************}

{8/16/88
Modified: Bostomatic SPC-II M081.53
For: Smiths Industries
Machine: Bostomatic
Control: SPC-II
Updated per Fanuc 6M M001.56.
Made changes from marked-up read-out.
JR}

{4/25/90
Modified: Bostomatic SPC-II M081.56
Updated per Fanuc 6M M001.71.2.
Altered for same or corrected output.
JR}

{4/25/90
Copied & modified: Bostomatic SPC-II M081.71.2
For: Diamond Lake Tool
Machine: Bostomatic
Control: SPC 1
Modified format to output trailing zeros.
JR}

{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{9/18/90
Modified: Bostomatic SPC-I M301.72
Delete the comment: START OF MAIN PROGRAM from the beginning of the program.
Delete subroutines.
Delete canned drilling cycles.
Add G26 for preset at the beginning of the program.
Delete ToolChng command, this is a manual tool change machine.
Replaced all Speed commands with literal 'S100'.
Add EOR to end of prog.
Rapid & Plane are not ouput, they are used to set the status only.
Misc other format changes.
JR}

{1/3/91
Copied & modified: Bostomatic SPC-I M301.76.1
For: Gibbs & Associates
Machine: Bostomatic
Control: SPC-I
Made minor fixes.
DWB}

{4/03/91
Modified: Bostomatic SPC-I M301.76.2
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{4/19/91
Modified: Bostomatic SPC-I M301.79
For: Diamond Lake Tool
Added Plane calls, XY=G07G1 , XZ=G07D2 , YZ=G07D3.
Added SpinOff.
Changed 'G26XYZ0' to 'G26X0Y0Z0' in FirstOp
Unconditional 'M00' at tool changes.
Changed 'XYR' to 'X0Y0R' at end of prog.
Changed CRCOffC to CRCOff at end of Milling?
Added TABLE for a proportional speed output in 2 gear ranges.
The output is a percentage of the maximum RPM
High gear is 1000 to 4000 RPM : 4000 RPM = S100 , 3960 RPM = S99 , etc
Low gear is 10 to 990 RPM : 1000 RPM = S100 , 990 RPM = S99 , etc
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###^###;0'
#3 = '*###^###;0'
#4 = '####.####;0.'
#5 = '########;0'
#6 = '####^####;'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

DoCycleComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoPartComment:
IF UseComments? AND SubComment?
TagInc
'( Part Number: ' Tag# ' )' EOL
IF LastPart?
TagInit
END
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoR: {Rapid moves need 'R'}
IF NOT EmptyLine?
'R'
END
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZIn FeedEnt EOL
ELSE
SeqC FeedC ZIn DoR EOL
END
RETURN

CycleWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
ArcIJ
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC CRCOnC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

ToolPath2: {for AutoCycle element moves}
EACHFeat
IF RapidFeat?
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC DoR EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC FeedC MoveXYZC DoR EOL
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
NEXTFeat
RETURN

CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
DoCycleComment
EntryMove
ToolPath2
IF NOT FeedConnect?
SeqC PRIME FeedC ZCP2 DoR EOL
END
NextRep
SeqC AbsOrInc FeedC ZCP2 DoR EOL
ELSE
DoCycleComment
EntryMove
ToolPath2
SeqC AbsOrInc FeedC ZCP2 DoR EOL
END
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
EACHFeat
IF PointFeat?
SeqC MoveSXYC DoR EOL
IF AutoCycle?
CutAutoCycle
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC FeedC MoveXYZC DoR EOL
END
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
{Note: This processor does not support work fixture offsets.}
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

DrillPlane:
IF RetractToCP1?
ZCP1
ELSE
ZCP2
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
ArcsNeedXYZ
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50') {?}
SetMaxRPM('4000')
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
Seq AbsOrInc EOL
SeqC 'G26X0Y0Z0' EOL {edited at machine to preset position}
IF MultipleParts? AND AllToolsOnePart?
EACHPart
DoPartComment
END
SeqC OpToolID EOL
DoOpComments
DoPostScript
SeqC SpinOn EOL
SeqC TABLE(1,Speed,1) EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
EACHPart
DoPartComment
IF NOT FirstPart?
DoOpComments
END
END
CheckPass
SeqC 'G07' Plane EOL
SeqC Feed StrtPos DoR EOL
SeqC 'G48' ZCP1 DoR EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
EACHPart
DoPartComment
IF NOT FirstPart?
DoOpComments
SeqC StrtPos DoR EOL
END
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
NEXTPart
END
SeqC CoolOff EOL
SeqC OfstOff DoR EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
NEXTPart
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC FeedC Home SpinOff DoR EOL
ELSE
SeqC SpinOff EOL
END
SeqC 'M00' EOL

{Start new Operation}

Seq OpToolID EOL
DoOpComments
DoPostScript
SeqC SpinOn EOL
SeqC TABLE(1,Speed,1) EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
EACHPart
DoPartComment
IF NOT FirstPart?
DoOpComments
END
END
CheckPass
SeqC 'G07' Plane EOL
SeqC Feed StrtPos DoR EOL
SeqC 'G48' ZCP1 DoR EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
EACHPart
DoPartComment
IF NOT FirstPart?
DoOpComments
SeqC StrtPos DoR EOL
END
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC OfstOff DoR EOL
SeqC 'M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqC SpinOn EOL
SeqC TABLE(1,Speed,1) EOL
SeqC 'G07' Plane EOL
SeqC Feed StrtPos DoR EOL
SeqC 'G48' ZCP1 DoR EOL
SeqC CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC OfstOff DoR EOL

{Start new Operation}

GetStartOfSameTool
SeqC TABLE(1,Speed,1) EOL
SeqC 'G07' Plane EOL
SeqC Feed StrtPos DoR EOL
SeqC 'G48' ZCP1 DoR EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC TABLE(1,Speed,1) EOL
SeqC 'G07' Plane EOL
SeqC Feed StrtPos DoR EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C DoR EOL
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
FindAnyZMoves
IF NoZMoves?
ELSE
CycleWarning
END
EACHRep
IF NOT AutoCycle?
DoCycleComment
END
IF NOT FirstCycle?
IF FeedConnect?
SeqC FeedC StrtPos EOL
ELSE
SeqC FeedC StrtPos DoR EOL
IF FeedEntry?
SeqC ZCP2C DoR EOL
END
END
END
END
END
IF NOT AutoCycle?
EntryMove
END
ToolPath
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
SeqC CRCOffC
IF NOT FeedConnect?
FeedC PRIME ZCP3C DoR
END
EOL
NEXTRep
END
END
SeqC CRCOff FeedC ZCP3C DoR EOL
ELSE
IF Drilling?
IF NOT RetractToCP1?
SeqC ZCP2 DoR EOL
END
IF Repeats?
EACHRep
IF NOT FirstCycle?
SeqC StrtPos DoR EOL
END
END
EACHFeat
IF NOT FirstFeat?
SeqC MoveSXYC DoR EOL
END
IF Repeats?
DoCycleComment
END
GetCycle
IF Peck?
PeckManual
ELSE
SeqC FeedC ZDepth
IF FirstFeat?
FeedEnt
END
EOL
IF Tap?
SeqC InverseSpinOn EOL
SeqC DrillPlane EOL
SeqC SpinOn EOL
ELSE
IF Dwell?
SeqC 'G4X' Dwell# EOL
END
SeqC DrillPlane
IF NOT FIFO?
DoR
END
EOL
END
END
NEXTFeat
IF Repeats?
NEXTRep
END
END
END
{NextOp} {modified to prevent endless looping in ncPost}

IF MultipleParts? AND LastOp?

{End of program ************************************************************}

{finish last operation}
IF OneToolAllParts? AND ExitClearancePlane?
NEXTPart
END
SeqC CoolOff EOL
SeqC OfstOff DoR EOL
IF OneToolAllParts? AND FullUp?
NEXTPart
END
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqC FeedC FirstHome SpinOff DoR EOL
ELSE
SeqC SpinOff EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
IF AllToolsOnePart?
IF NOT LastPart?
SeqC 'M00' EOL
END
NEXTPart
END
ELSE
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
SeqC CoolOff EOL
SeqC OfstOff DoR EOL
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqC FeedC FirstHome SpinOff DoR EOL
ELSE
SeqC SpinOff EOL
END
END

SeqC 'X0Y0R' EOL {edited at machine to return to start preset position}
SeqC EOP EOL
SeqC EOR EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END