{Change Comments ***********************************************************}

{4/12/91
Copied & modified: Bostomatic SPC-II M081.79
For: C.S. Draper Labs
Changed value for SetMaxRPM & added SetMinRPM this corrects the output of ProSpeed.
Added 'G26 line to beginning of program.
Changed tool change code to M0 in MachSpec and moved to line after OpToolID.
Added EOR to end of program.
Added UnTool to end of program.
Moved ProSpeed line to be inside MPFU sub as it contains the CoolOn command.
Jim Radcliffe}

{7/8/91
Modified: Bosto SPC-II M411.79
For: C.S. Draper Labs
Changed SetMaxRPM & SetMinRPM to 7000 & 700
Change ZCP2C to ZCP2 in Milling.
Jim Radcliffe}

{5/11/92
Modified: Bosto SPC-II M411.80
For: C.S. Draper Labs
Changes made per John Mahoney at C.S. Draper Lab.
Changed Maximum Spindle RPM from 4000 to 7000 in Mach Spec.
Changed 3 occurances of SeqC to SeqLabC.
DWB}

{5/17/94
Modified: Bostomatic SPC-II M411.80.1
For: CS Draper
Per John Mahoney at C.S. Draper
When in incremental, IJK values must be unsigned.
Modified FormatArc to handle with numeric commands for AutoCycles.
The value of the V60 register in drilling should be the incremental depth from the drill surface.
Changed ZDepth# to CalcZFmSurf#, user must enter the drill surface in ncCAM.
Jim Radcliffe}

{6/23/94
Modified: Bostomatic SPC-II M411.80.2
For CS Draper
Updated to .81.2 format.
The Drilling V64 register should be distance between the drill surface and ClearancePlane.
Added 'SUB# CalcZSurf#' to ClearancePlane1# or ClearancePlane2# commands.
Jim Radcliffe}

{2/9/96, Updated .81 version to .84, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{3/3/97
Initial: Bostomatic SPC-II M411.87
Created: Bostomatic SPC-II M411.87.01
For: CS Draper per John Mahoney
Removed G26 block at the beginning of the program - block "SeqLabC 'G26XYZ0' EOL"
Removed restriction allowing only Milling Cycles to move to StrPos before rapiding down to clearance.
Added Tab character in front of begin parenthesis to indicate the comment start characters.
Added test for Xmove or Ymove before making an arc move to prevent small moves beyond a quadrant boundary.
WS}

{6/26/97
Updated: Bostomatic SPC-II M411.87.1
Created: Bostomatic SPC-II M411.89
For: CS Draper
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per John Mahoney of CS Draper.
Updated for Catalyst v3.33C per Fanuc 6M M001.89b Format.
Changed FORMAT#2 from ###.###;0. to #####.###;0. at Prog Numeric Format Definitions.
Changed FORMAT#3 from *###.###;0. to *#####.###;0. at Prog Numeric Format Definitions.
Deleted version comments.
Added SetMaxFeed(12700) for Metric VNC files at setup and initializations.
Added ProSpeed SpinOn 'G4X3.' for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added ckCRC sub.
Changed FeedRateC to FeedEntC for support of FIFO Exit at FinishSub1, AutoCycCutSub2,
ZonlyRepAutoCycle subs and end of IF Milling.
Added support of ZOnlyRep SepSubs.
Added TrackZNO# to FORMAT#4 at Prog Numeric Format Definitions.
Added DoAbsOrInc and RestoreAbsOrInc subs.
Changed SkipZ to TrackZNO# FIRST SPZ# and deleted UnSkipZ at ZOnlyRep sub.
Added Flag(1) at setup and initializations.
Corrected MultipleParts output when WorkFixtureOffsets is selected.
Post does not support WorkFixtureOffsets.
Limited MP Subs and output to EquallySpacedOffsets at OpenMP and CloseMP.
Limited output of second StrtPos block at MP-OTAP-ECP condition at FirstOperation and NewTool.
Moved LastFeatExtend from Milling and ZOnlyRep subs to end of ToolPath.
Rewrote ZonlyRepAutoCycle sub.
To make it easier to comment out SetSRXYtoEP and IF SPXMove? OR SPYMove? boolean because this
post will be used to create Gibbs System only post.
Customer stated that this post should be identicle to Bostomatic SPC-II CSD M947.87.3 with the
exception that this control has a SetMaxRPM(7000) and a manual ToolChanger so OpToolID and
ToolChng should reside on separate blocks, and ToolChng should output M0.
Added missing Macro calls at IF Drilling.
NOTE: This post does not support Drill Subs.
DWB}

{27Aug97
Original: Bostomatic SPC-II M411.89
Created: Bostomatic SPC-II M411.15
For: C S Draper
Changes made per: John Mahoney
Updated to .15 Format per Fanuc 6M M001.15
CallMasterOp not supported
Charles Winston}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '##^0'
#8 = '+##^0000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ABS#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(FeedEntry#,7)
FORMAT(SUB#,8)
FORMAT(CalcZFmSurf#,8)
FORMAT(Peck#,8)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

WFONum:
{ Not Supported }
RETURN

WFOStuff:
{Note: This processor does not support work fixture offsets.}
RETURN

DoSubComment:
IF UseComments? AND SubComment?
' ( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
' ( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
' ( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
' ( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
' ( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
' ( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

DoR: {Rapid moves need 'R'}
IF NOT EmptyLine?
'R'
END
RETURN

EntryMove:
IF FeedEntry?
SeqLabC FeedC ZIn FeedEnt EOL
ELSE
SeqLabC FeedC ZIn DoR EOL
END
RETURN

StartSub:
OpenSub
DoSubComment
SeqLab 'G92' SubID EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
' ( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLabC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C DoR
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
FeedC ZCP3C DoR
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
NewProg
SeqLabC SubCall CallLab RepLab Parts EOL
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
SeqLabC Preset ShiftPC EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
{ Not Supported }
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
MoveX MoveY MoveZC
ELSE
IF XZPlane?
MoveX MoveYC MoveZ
ELSE
MoveXC MoveY MoveZ
END
END
IF ArcIJFormat?
IF AbsValue?
ArcIJ
ELSE
IF XYPlane?
'I' ABS# ArcI# 'J' ABS# ArcJ#
ELSE
IF XZPlane?
'I' ABS# ArcI# 'K' ABS# ArcJ#
ELSE
'J' ABS# ArcI# 'K' ABS# ArcJ#
END
END
END
ELSE
ArcR
END
RETURN

CheckOptCyc: { Drilling Only }
IF OptCyc1? {call subroutine already in memory}
IF FIFO?
'G94D249' {for single direction positioning}
ELSE
IF Tap?
'G94D252' {for tap cycle}
END
END
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
{ Not Supported }
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC DoR EOL
SeqLabC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC MoveSXYC DoR CheckOptCyc EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC DoR EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed EOL
ELSE
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
IF XMove? OR YMove?
SeqLabC FormatArc ArcFeedC EOL
END
END
NEXTQuadrant
END
END
END
IF LastFeat?
CRCOffC
IF NOT EmptyLine?
SeqLabC FeedC LastFeatExtend EOL
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
FeedC ZCP2 DoR
END
END
EOL
SeqLabC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Feed StrtPos
IF NOT FeedConnect?
DoR
END
EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
Feed
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqLabC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC IncValue StrtPosC DoR EOL
AbsOrInc
END
IF FeedEntry?
SeqLabC ZCP2PlusInc DoR EOL
END
END
IF FeedEntry?
SeqLabC ZInPlusInc FeedEnt EOL
ELSE
SeqLabC ZInPlusInc DoR EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLabC Feed ZCP2 FeedEnt EOL
ELSE
SeqLabC Feed ZCP2 DoR EOL
END
END
SeqLabC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Feed StrtPos
IF NOT FeedConnect?
DoR
END
EOL
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC FeedC ZCP2PlusIncC DoR EOL
END
SeqLabC FeedC ZInPlusInc FeedEnt EOL
ELSE
SeqLabC FeedC ZInPlusInc DoR EOL
END
END
SeqLabC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLabC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
{ Not Supported }
RETURN

SetDrillEndOpZ:
{ Not Supported }
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

OpGuts:
IF Milling?
SeqLabC FeedC ZCP2 DoR EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C DoR EOL
ELSE
IF FIFO?
SeqLabC FeedC ZCP3C FeedEntC EOL
ELSE
SeqLabC FeedC ZCP3C DoR EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
END
SeqLabC Feed StrtPos DoR EOL
SeqLabC { needs unconditional output of Z position here, Z not yet output }
IF RetractToCP1?
ZCP1
ELSE
ZCP2
END
DoR EOL
GetCycle
SeqLabC 'V60D' CalcZFmSurf# EOL
SeqLabC 'V64D' {unsigned incremental distance from current Z position to drill surface}
IF RetractToCP1?
SUB# ClearancePlane1# CalcZSurf#
ELSE
SUB# ClearancePlane2# CalcZSurf#
END
EOL
SeqLabC 'V67D' FeedEntry# EOL
IF Peck?
SeqLabC 'V63D' Peck# EOL
END
IF FIRO?
SeqLabC 'M2007' EOL
ELSE
IF FIDRO?
SeqLabC 'M2008' EOL
ELSE
IF FIFO?
SeqLabC 'M2009' EOL
ELSE
IF PeckChipBreaker?
SeqLabC 'M2001' EOL
ELSE
IF PeckFullRetract?
SeqLabC 'M2000' EOL
END
END
END
END
END
SeqLabC Cycle EOL
SeqLabC StrtPos DoR CheckOptCyc EOL
ToolPath
SeqLabC 'G80' EOL
IF Repeats?
FinishSubG92
END
SeqLabC FeedC ZCP3C DoR EOL
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
ArcsNeedXYZ
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('7000')
SetMinRPM('700')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' OptionalCycle1, OptCyc1 -' EOL
' when used in a drilling cycle all positioning moves will be output' EOL
' with a G94D249 on the same line if FI-FO is selected,' EOL
' or G94D252 if Tap is selected.' EOL
END
RETURN

InitOp:
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
' ( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
' ( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
' ( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
' ( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
' ( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
' ( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
' ( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN


FirstOp1:
IF UseComments?
' ( START OF MAIN PROGRAM )' EOL
END
SeqLab Feed AbsOrInc Plane CRCOff 'G49' EOL { OfstOff }
DoOpComments
SeqLabC OpToolID EOL
SeqLabC ToolChng EOL
DoPostScript
RETURN

FirstOp2:
SeqLabC ProSpeed SpinOn 'G4X3.' EOL
CheckPass
IF Milling?
SeqLabC StrtPos DoR EOL
END
RETURN

FirstOp3:
SeqLabC OpToolID 'G48R' CoolOn EOL { OfstOn }
RETURN

NewToolOp1:
SeqLabC CoolOff EOL
SeqLabC 'G49R' EOL { OfstOff }
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC FeedC Home DoR EOL
END
SeqLabC SpinOff 'G4X2.' EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
DoOpComments
SeqLab OpToolID EOL
SeqLabC ToolChng EOL
DoPostScript
RETURN

NewToolOp4:
SeqLabC Plane ProSpeed SpinOn 'G4X3.' EOL
CheckPass
IF Milling?
SeqLabC Feed AbsOrInc StrtPos DoR EOL
END
RETURN

NewToolOp5:
SeqLabC OpToolID 'G48R' CoolOn EOL { OfstOn }
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLabC CoolOff EOL
SeqLabC 'G49R' EOL { OfstOff }
SeqLabC SpinOff 'G4X2.' EOL
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?
SeqLabC 'G49R' EOL { OfstOff }
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqLabC PlaneC ProSpeed SpinOn 'G4X3.' EOL
IF Milling?
SeqLabC Feed AbsOrInc StrtPos DoR EOL
END
SeqLabC OpToolID 'G48R' CoolOn EOL { OfstOn }
ELSE
IF NewToolOffset?
IF Milling?
SeqLabC Feed AbsOrInc PlaneC ProSpeed StrtPos DoR EOL
ELSE
SeqLabC PlaneC ProSpeed EOL
END
SeqLabC OpToolID 'G48R' EOL { OfstOn }
ELSE
IF Milling?
SeqLabC Feed AbsOrInc PlaneC ProSpeed StrtPos DoR EOL
ELSE
SeqLabC PlaneC ProSpeed EOL
END
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
RETURN

End1:
SeqLabC CoolOff EOL
SeqLabC 'G49R' EOL { OfstOff }
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqLabC FeedC FirstHome DoR EOL
END
SeqLabC SpinOff 'G4X2.' EOL
IF ProgStop?
SeqLabC 'M0' EOL
END
RETURN

End3:
SeqLabC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
' ( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
' ( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
' ( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { WFOStuff }
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END