{
MILL=F
LATHE=T
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=F
}

{Change Comments ***********************************************************}

{9/18/95, L201.82.1, Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85.02 Format, DWB}

{8/14/96,
Initial: Fanuc 0TA Colchester L201.85
Created: Fanuc 0T Col [HS] L500.85
Added custom line# at tool changes, see Fanuc 6T MS SL4 [HS] L472.85.1 for details
Moved tool comments out of DoOpComments, added them to FirstOperation and NewTool after custom line#
Moved output of lathe offset into Approach sub
Eliminated GearRange stuff, made output of M41/M42 contingent upon whether Tap? was true (M41 for tapping, M42 for all others)
Changed ckCRC to output G41 for OD cutting, G42 for all others
Changed LineFeat to output Dwell value after each peck of a manual peck drilling cycle
Eliminated saftey G97 at the end of CSS operation in NewTool and end section
Added CRCOff to G97 block athe beginning of operations
Put Speed on separate line after G97 line
Added checking for spindle direction reversal, stops spindle before changing directions
Deleted UnTool block at program end
Added Optional stop at program end
Deleted CoolOff and SpinOff at prgram end
Customized Tapping non-canned tapping cycle per customer request,
MPK}

{10/2/96
Initial: Fanuc 0T Col [HS] L500.85
Created: Fanuc 0T Col [HS] L500.85.1
changed format for X taper at Z to *####.####;0,
MPK}

{11/18/96
Initial: Fanuc 0T Col [HS] L500.85.1
Created: Fanuc 0T Col [HS] L500.85.2
added literal 'F' before FeedTapIPR(1)# in ToolPath LineFeat,
MPK}

{1/22/97,
Initial: Fanuc 0T Col [HS] L500.85.2
Created: Fanuc 0T Col [HS] L500.85.3
Added FeedC to line after Stepmove in Canned RoughContour section, MPK}
{4/10/97,
Initial: Fanuc 0T Col [HS] L500.85.3
Created:Fanuc 0T Col [MS] Lxxx.85
For: McKay/Stine
eliminated all occurances of M41/M42, MPK}

{16Sep98
Original: Fanuc 0T Col [MS] L577.85
Created: Fanuc 0T [NAWCAD] Lxxx.85
For: NAWCAD ( Naval Air Warfare, Central Aircraft Division )
Changes made per: William Flaherty
Added Post Boolean Description at the top of comments.
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Added FORMAT#9 and formatting for ToolOffset# at Prog Numeric Format Definitions
Moved ToolTypeComment$ and ToolComment$ to DoOpComments from FirstOperation amd NewTool
Moved CoolOn from Approach to FirstOperation amd NewTool
Moved OpToolID LatheOffset from Approach to FirstOperation amd NewTool
Replaced LatheOffset with ToolOffset# throughout the Prog
Deleted Setup of Variables 1 thru 25, at Start of executable Prog
Deleted Custom Tool and Line Numbering from FirstOperation amd NewTool
Rewrote FirstOperation, NewTool and End of Prog per FAX and conversation with Customer
Deleted CSS Boolean at the Start of the Comon Point
Changed Default Format for M,T and G in MachSpec from '00' to '#0'
Charles Winston}

{10/09/98,
Initial: Fanuc 0T [NP] L774.85
Created: Fanuc 0T [NP] L774.85.1
For: NAUCAD

Changes to Prog:
1) FirstOp - Deleted everything between Plane and DoPostScript
CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '#####^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '###.####;0.'
#8 = '#'
#9 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(InFeedAngle#,2)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(CycleStartX#,2)
FORMAT(FinishXDia#,2)
FORMAT(CycleStartZ#,2)
FORMAT(FinishZ#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(FeedTapIPR#,2)
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Dwell#,4)
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(CutDepth#,7)
FORMAT(RapidF#,8)
FORMAT(ToolOffset#,9)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF NOT CWSpindle? AND LAST CWSpindle?
SpinOff
ELSE
IF CWSpindle? AND LAST NOT CWSpindle?
SpinOff
END
END
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID ToolOffset# EOL
END
CSSOff
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF LAST ProgStop?
SeqLabC CSSOn 'G96' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC CSSOn 'G96' Speed
END
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC 'G97' Speed
ELSE
IF LAST ProgStop?
SeqLabC 'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC 'G97' Speed
END
END
END
END
IF LAST ProgStop?
SeqLabC {SpeedC} SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC {SpeedC} EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC:
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat? AND CutterRadiusCompensation?
IF NOT Flag?('5')
IF ApproachOD?
'G41' CRCOnC
ELSE
'G42' CRCOnC
END
SetFlag('5')
END
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
SetFlagF('5')
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
ELSE
IF Dwell? AND NOT Peck?
SeqLabC 'G04P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
IF Tap?
SeqLabC Feed MoveZC
IF LastFeat?
'F' FeedTapIPR#('1') InverseSpinOn EOL
ELSE
FeedRate EOL
END
ELSE
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
END
IF Peck? And Dwell?
SeqLabC 'G04P' Dwell# EOL
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G33' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
StandardXZArcs
SetMaxRPM('2000')
SetMaxFeed('200')
SetFlagF('5') {For CRC handling}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff
SetHome
Plane
SeqLab ' ' EOL
DoPostScript
DoOpComments
SeqLabC
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
SeqLabC OpToolID ToolOffset# CoolOn EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOn 'G96' SpinOn CalcRPM1 EOL
ELSE
SeqLabC CSSOff 'G97' SpinOn Speed EOL
END
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF NOT CWSpindle? AND LAST CWSpindle?
SeqLabC SpinOff EOL
ELSE
IF CWSpindle? AND LAST NOT CWSpindle?
SeqLabC SpinOff EOL
END
END
SeqLabC NewHome EOL
SeqLabC LOfstOff '00' EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

' ' EOL
SeqLab ' ' EOL
DoPostScript
DoOpComments
SeqLabC
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
SeqLabC OpToolID ToolOffset# CoolOn EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOn 'G96' SpinOn CalcRPM1 EOL
ELSE
SeqLabC CSSOff 'G97' SpinOn Speed EOL
END
Approach
ELSE
IF SameTool?

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle CutDepth 'R' CutDepth# EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC FeedC 'X' SPX# EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC FeedC 'Z' SPZ# EOL
END
ELSE
IF RoughPatternShift?
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
SeqLabC LCycle 'P'
IF AutoFinish?
'02' {2 finish passes}
ELSE
'01'
END
IF Chamfer?
'07' {.7 thread lead distance for chamfer}
ELSE
'00'
END
IF SingleEdgeCut?
'60' {using 60 for standard tool angle, need ToolAnge# command}
ELSE
'00'
END
'Q'
IF ConstantVolumeCut?
'20' {.0020 minimum cut depth}
ELSE
CutDepth# {if not ConstantVolumeCut? CutDepth is min depth, volume increases with depth}
END
'R0' {using zero for no finish stock allowance, need XStckLeft# command}
EOL
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead EOL
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
ELSE
IF Drilling?
IF PeckChipBreaker?
SeqLabC LCycle Retract EOL
SeqLabC LCycle ZDepth Peck 'R0' FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC FeedC ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
ELSE
SeqLabC 'G98' EOL
SeqLabC LCycle XSP 'C0' ZDepth 'R0'
IF Peck?
Peck
END
Dwell FeedRate
IF AutoFinish?
'K2'
ELSE
'K1'
END
EOL
SeqLabC DrillOff EOL
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
IF Dwell?
SeqLabC 'G04P' Dwell# EOL
END
SeqLabC SpinOff EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC RapidC FirstHome EOL
SeqLabC OpToolID '00' CoolOff EOL
IF ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END