{
MILL=T
LATHE=F
SIMPLE_ROT_POS=T
ROTARY_MILL=T
ADV_MILL=F
SUBS=T
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{10/28/98
Copied: Fanuc 6M M001.16
Created: Fanuc 6M RM001.16.04
For: Gibbs & Associates
Versions: Virtual 5.02/Compost2 PPC 1.6b7
Var(1) = Operation X EndPoint
Var(2) = Operation Y EndPoint
Var(4) = Operation A EndPoint
Flag(9) = Valid Drill Rotate Sub
DWB}

{10/30/98
Copied: Fanuc 6M RM001.16.04
Created: Fanuc 6M RM001.16.05
For: Gibbs & Associates
Versions: Virtual 5.02/Compost2 PPC 1.6b7
Corrected missing G0 at ZCP3.
Corrected missing AngleFeed at start of Sub.
DWB}

{11/4/98
Copied: Fanuc 6M RM001.16.05
Created: Fanuc 6M RM001.16.06
For: Gibbs & Associates
Added resetting the A-axis to be between -0.001 and -359.999 at setAngleUnder360.
Cleaned up.
DWB}

{11/6/98
Copied: Fanuc 6M RM001.16.06
Created: Fanuc 6M RM001.16.07
For: Gibbs & Associates
Changed FORMAT for Address A from '#####.###;0.' to '*#####.###;0.' in Compost Default Format Dialog.
Changed TrackC#, TrackCNO#, MoveC# and UnitAngle# from FORMAT#2 to FORMAT#3 at Prog Numeric Format Definitions.
FORMAT changes are for staying consistant with 4th Axis Verticle Rotary 4th X+ SetUp.
Additional cleaning up.
DWB}

{11/10/98
Copied: Fanuc 6M RM001.16.07
Created: Fanuc 6M RM001.17
For: Gibbs & Associates
Added IF AAxisAvail condition at doStartPos procedure.
DWB}

{11/20/98
Copied: Fanuc 6M RM001.17
Created: Fanuc 6M RM001.17.1
For: Gibbs & Associates
Modified to support Incremental Rotated RotaryMill Subs.
Identicle situation to Patterns.
Modified doAbsOrInc Procedure.
Modified doACAbsOrInc Procedure.
Modified doDrillAbsOrInc Procedure.
Modified restoreAbsOrInc Procedure.
Added doSepSubFeedConnect Procedure.
Changed name of rotaryStartPosC Procedure to rotateStartPosC.
Added IF NOT RotaryMill? for MoveSYC.
Changed calls five places at rotaryReps Procedure.
DWB}

{11/24/98
Copied: Fanuc 6M RM001.17.1
Created: Fanuc 6M RM001.17.2
For: Gibbs & Associates
Versions: Virtual 5.03/ComPost2 1.7b11
Added IF AAxisAvail? condition at setAngleUnder360.
Deleted FIFO Boolean condition at finishSub1, autoCycCutSub2, doSepSubExit and millingOp.
Deleted NotEqual CP2 CP3 Boolean condition at rotaryReps.
DWB}

{12/23/98
Copied: Fanuc 6M RM001.17.2
Created: Fanuc 6M RM001.17.3
For: Gibbs & Associates
Versions: Virtual 5.03/ComPost2 1.7b11
Change IF Flag(9) to IF Rotations at doDrillAbsOrInc.
Deleted FIRST modifier two places at doSepSubContour.
Deleted Rotations? Boolean at doSepSubSPMove.
Deleted FIRST modifier at setSepSubZ.
Deleted ZCP3 for non-AutoCycle at doSepSubExit.
Added Rapid command in its place.
Deleted AND NOT Rotations? Boolean at zonlyRepAutoCycle.
Moved resetSepSubSR to before TrackZNO# at zonlyRepAutoCycle.
Deleted IF FeedConnect? AND Rotations? Boolean at zonlyRepAutoCycle.
Moved resetSepSubSR to before IF FeedConnect? at zonlyRep.
Moved TrackZNO# ClearancePlane3# to IF FeedConnect? ELSE at zonlyRep.
Deleted FIRST modifier at drillingOp.
Moved TrackXNO# to end of rotaryReps.
Moved TrackZNO# to end of rotaryReps.
Added TrackYNO# to end of rotaryReps.
DWB}

{1/13/99
Copied: Fanuc 6M RM001.17.3
Created: Fanuc 6M RM001.17.4
For: Gibbs & Associates
Versions: Virtual 5.03.06/ComPost2 1.7b14
Corrected Bad AutoCycle MoveC.
Added SUB# to FORMAT#2 at Prog Numeric Format Definitions.
Changed FORMAT for UnitAngle# from #3 to #2 at Prog Numeric Format Definitions.
Changed FORMAT for TrackCNO# from #3 to #2 at Prog Numeric Format Definitions.
Modified report procedure.
Added spReset procedure.
Contains Tracking code from resetSP.
Added Save# Num#(5) MoveC#
Added call to report procedure.
Modified resetSP.
Moved Tracking code to spReset.
Functions same as getEP now.
Modified saveEP.
Changed to Save# Num#(4) MoveC# to one place at end.
Added Save# Num#(5) SUB# MoveC# Recall# Num#(5) for AutoCycle Contour.
Added call to report procedure.
Modified getEP.
Deleted call to report procedure.
Modified setSRXYtoACEP.
Added TrackCNO# ADD# Recall# Num#(4) Recall# Num#(5) EOL
Modified tpPointFeat.
Added TrackCNO# ADD# Recall# Num#(5) MoveC# EOL
Added Save# Num#(5) Num#(0) initialization at progStart.
Deleted FIRST modifier at end2.
DWB}

{1/19/99
Copied: Fanuc 6M RM001.17.4
Created: Fanuc 6M RM001.17.5
For: Gibbs & Associates
Versions: Virtual 5.05.04/ComPost2 1.7b15
Changed SetArcSegmentAccuracy to be .0005 for English and .0127 for Metric at progStart.
DWB}

{2/9/99,
Initial : Fanuc 6M RM001.17.5
Created: Acr A2100 [VG] RMT97.17.5
Customer: Gibbs & Associates
ComPost2: v1.7b15

Changes to "Form":

1. Under General Info, removed Program ID Label, Optional Program ID Label, and
changed Sequence Label to N?
2. Under Default Formats, changed P to ####.####;0.
3. Under Origins and Values, changed First WFO to H1 and Last WFO to H16
4. Under Arcs, changed R-Format Arc Label to P and checked Use Absolute Arc Center
5. Under Subs, removed all Labels and changed all Numbers to 0
6. Under Tool Offsets, changed CRC Offset Label to O and Tool Length Offset Label to D
Removed Tool Length Offset Enable and Tool Length Offset Cancel Labels and changed
the Numbers to 0
7. Under Program Stops, changed End Program Number to 2
8. Under Drill Cycles, changed Peck Labels to K and Peck Partial Retract Number to 83.
Removed Dwell Labels. Removed Drill From Part Clearance and Drill From Entry Clearance
Labels and changed the Numbers to 0

Changes to "Prog":

1. Added MSG, to all comments.
2. Removed EOR at tape start and changed ProgID1 to (PGM, ID=Program#).
Added start-up block after ProgID.
3. Changed all Seq to ':?', all SeqC to SeqLabC, and added ReTag at end3.
4. Added inchOrMetric sub to output G70/71.
5. Changed #6 FORMAT (Dwell) to decimal point.
6. Moved wfoStuff into StartPos block.
7. Changed wfo sub name to doNewWFO and changed 'G' to 'H'.
8. Changed ckCRCNum sub and removed all call from toolPath to StartPos.
9. Changed ckCRC sub and added a call in tpArcFeat. (version .6)
10. Changed firstOp1, 2, & 3 to match the output of M930.
11. Changed newToolOp1, 3, 4, & 5 to match the output of M930.
12. Changed sameToolOp1, 2, & 3 to match the output of M930.
13. Changed end1, 2, & 3 to match the output of M930.
14. Changed all CoolOn to doCoolOn and added doCoolOn sub. The new sub can output
up to 6 different types of coolant.
15. Under tpArcFeat, removed C from ArcIJ and ArcR. Force the output of 2 axes and
added Helix lead for XY-plane helix cuts.

drilling cycles:

16. Changed DrillOff to be output in a block by itself.
17. Changed RLevel to 'R' CalcZSurf# and added FORMAT for CalcZSurf#.
18. Removed Dwell and Retract from drill cycle line.
19. Changed DrillCP to ZCP2C.
20. Changed FromCP to doFromCP sub and added calls to this sub in tpPointFeat.
21. Added doFromCP sub to output W when RetractToCP1 and added FORMAT for ABS#.
22. Added G84.1 for RigidTap and G89 for Bore & Dwell.
23. Changed Peck to doPeck sub to output J11 for ChipBreaker and J13 for FullRetract.
24. Changed ZDepth to 'Z' CalcZFmSurf# and added FORMAT for CalcZFmSurf#.

sub routines:

25. Changed all CallLab to '(CLS, ' Program# and CallLabB to '(CLS, '.
26. Changed all EndSub to '(ENS)' and removed all SubCall.
27. Changed SubID to '(DFS, ' Program# ')'.
28. Added ')' at the end of all CLS blocks.
29. Changed all RepLab to ',', Parts to Parts#, and removed OnePart.
30. Changed RepCycs to Repeats# and added FORMAT for Repeats#.

inverse time feedrate:

31. Added inverseTime sub to output G93 and perMinute sub to output G94.
32. Added calls to perMinute sub in restoreAbsOrInc sub, doSepSubZMoves sub,
and restart blocks (3 places).
33. Added SetFlagF('11') after outputing perMinute (G94) Feed Mode.
34. Changed all AngleFeedC (3 places) to doInverseTimeFeed.
35. Added doInverseTimeFeed sub to force output of 1/T but not for IPM.
36. Added doFeedrateMode sub to output G94 or G93 modes.
37. Added calls to doFeedrateMode sub in tpLineFeat, tpArcFeat, & doSepSubSPMove subs.
38. Changed doSepSubSPMove sub in case of FeedConnect.
JHE}

{2/11/99,
Initial : Acr A2100 [VG] RMT97.17.5
Created: Acr A2100 [VG] RMT97.17.6
Customer: Gibbs & Associates
ComPost2: v1.7b15

Changes to "Prog": See item #9 above.
JHE}

{2/15/99,
Initial : Acr A2100 [VG] BT97.16
Created: Acr A2100 [VG] BT97.16.1
Customer: Gibbs & Associates
ComPost2: v1.7b15

Changes to "Prog":

1. Moved ZCP1 from firstOp3 to firstOp2 (to startPos block).
2. Added firstOp2Xcp sub to restate startPos in mP1ToollAllPXcp after openMP.
3. Moved ZCP1 from newToolOp5 to newToolOp4 (to startPos block).
4. Added newToolOp4Xcp sub to restate startPos in mP1ToollAllPXcp after openMP.
5. Under sameToolOp3 and ProgStop, moved ZCP1 to StartPos block.
JHE}

{Prog Numeric Format Definitions ***********************}

#1 = '###.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####.##0' {Changed from ####^##0 - JHE}
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SUB#,2)
FORMAT(UnitAngle#,2)
FORMAT(TrackCNO#,2)
FORMAT(TrackC#,3)
FORMAT(MoveC#,3)
FORMAT(Recall#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TrackX#,4)
FORMAT(TrackXNO#,4)
FORMAT(TrackYNO#,4)
FORMAT(TrackZNO#,4)
FORMAT(CalcZSurf#,4) {Added - JHE}
FORMAT(CalcZFmSurf#,4) {Added - JHE}
FORMAT(ABS#,4) {Added - JHE}
FORMAT(ADD#,4)
FORMAT(Repeats#,5) {Added - JHE}
FORMAT(TRUNC#,5)
FORMAT(Program#,5)
FORMAT(Program2#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)

{Added Subroutines *************************}

report:
IF PalletIn?
'------------------------------------' EOL
SetStatusOff
IF FirstFeat?
IF AutoCycle? AND NOT PointFeat?
'Num#(5) cSP = ' Recall# Num#('5') EOL
END
END
IF LastFeat?
'Num#(1) xEP = ' Recall# Num#('1') EOL
'Num#(2) yEP = ' Recall# Num#('2') EOL
'Num#(4) cEP = ' Recall# Num#('4') EOL
IF AutoCycle?
'#5 AC cDist = ' Recall# Num#('5') EOL
IF PointFeat?
' AC cEP = ' ADD# Recall# Num#('5') MoveC# EOL
END
END
END
' UnitAngle = ' UnitAngle# EOL
SetStatusOn
'------------------------------------' EOL
END
RETURN

spReset: {update to the correct StartPos}
TrackXNO# SPX#
TrackYNO# SPY#
TrackCNO# MoveC#
IF AutoCycle? AND NOT PointFeat?
Save# Num#('5') MoveC# { cOpEP }
END
report
RETURN

resetSP: {update to the correct StartPos}
IF Rotations? OR Repeats? OR AutoCycle?
CalcSCAng
IF AbsValue?
spReset
ELSE
SetAbs
spReset
SetInc
END
END
RETURN

saveEP: {save the correct EndPos}
IF PointFeat?
IF AutoCycle?
SetACSPCompF
Save# Num#('1') ADD# Recall# Num#('1') SPX# { xOpEP }
Save# Num#('2') ADD# Recall# Num#('2') SPY# { yOpEP }
SetACSPComp
ELSE
Save# Num#('1') SPX# { xOpEP }
Save# Num#('2') SPY# { yOpEP }
END
ELSE
Save# Num#('1') EPX# { xOpEP }
Save# Num#('2') EPY# { yOpEP }
END
Save# Num#('4') MoveC# { cOpEP }
IF AutoCycle? AND NOT PointFeat?
Save# Num#('5') SUB# MoveC# Recall# Num#('5') { cOpEP }
END
report
RETURN

getEP: {save the correct EndPos}
IF Rotations? OR Repeats? OR AutoCycle?
IF AbsValue?
saveEP
ELSE
SetAbs
saveEP
SetInc
END
END
RETURN

setSRXYtoACEP:
TrackXNO# Recall# Num#('1') { xOpEP }
TrackYNO# Recall# Num#('2') { yOpEP }
TrackCNO# ADD# Recall# Num#('4') Recall# Num#('5') { cOpEP }
RETURN

{Prog Subroutines ***************************}

restoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

inchOrMetric: {Added this sub - JHE}
IF Metric?
'G71' {metric mode}
ELSE
'G70' {inch mode}
END
RETURN

doNewWFO:
'H' NewWFO#
RETURN

wfoStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
doNewWFO
END
ELSE
IF Flag?('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
WFO1
ELSE
doNewWFO
END
ELSE
doNewWFO
END
END
END
END
SetFlagF('2') { Do not output WFO second time wfoStuff is called for MP-WFO-OTAP-ECP }
RETURN

doSubComment:
IF UseComments? AND SubComment?
'(MSG, SUB NUMBER: ' Program# ' )' EOL
END
RETURN

doOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'(MSG, TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'(MSG, ' ToolComment$ ' )' EOL
END
restoreScale
END
RETURN

psInit:
NewWFOF
FourthCWF
FourthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
PalletInF
RETURN

psStuff:
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

doPostScript:
psInit
EachPS
SeqLabC PostScript EOL
psStuff
NextPS
RETURN

doEndOpPS:
psInit
EachEOPS
SeqLabC EndOpPS EOL
psStuff
NextPS
RETURN

absValueC:
IF NOT AbsValue?
AbsValue
END
RETURN

incValueC:
IF AbsValue?
IncValue
END
RETURN

absOrIncC:
IF AbsoluteMoves?
absValueC
ELSE
incValueC
END
RETURN

setAngleUnder360: {sets status register and machine to current rotary position between -360 and 360 deg}
IF AAxisAvail?
SetAbs
IF GTEqual? MoveC# Num#('360') {reset the A-axis to be between 0 and 359.999}
ResetAngle
SeqLabC Preset 'A' TrackC# UnitAngle# EOL
ELSE
IF LTEqual? MoveC# Num#('-360')
IF Equal? UnitAngle# Num#('0') {reset the A-axis to be 0}
ResetAngle
SeqLabC Preset 'A' TrackC# UnitAngle# EOL
ELSE {reset the A-axis to be between -0.001 and -359.999}
ResetAngle
SeqLabC Preset 'A' TrackC# SUB# UnitAngle# Num#('360') EOL
END
END
END
SetInc { Because we call setAngleUnder360 right after incValueC OfstOff }
END
RETURN

inverseTime: {Added this sub - JHE}
'G93'
RETURN

perMinute: {Added this sub - JHE}
'G94'
RETURN

doFeedrateMode: {Added this sub - JHE}
IF RotaryMill?
IF FirstFeat?
IF CMove?
inverseTime {Inverse Time Mode}
SetFlag('11') {inverse Time Mode On}
END
ELSE
IF CMove?
IF Flag?('11') {if inverse Time is in effect}
{no output}
ELSE
inverseTime {Inverse Time Mode}
SetFlag('11') {inverse Time Mode On}
END
ELSE {implies no rotary cut}
IF XMove? OR ZMove?
IF Flag?('11') {if inverse Time is in effect}
perMinute {Feed per Minute Mode}
SetFlagF('11') {Feed per Minute Mode On}
END
END
END
END
END
RETURN

doInverseTimeFeed: {Added this sub - JHE}
IF RotaryMill?
IF Flag?('11') {if inverse Time is in effect}
InverseTimeFeed {forcing feedrate output}
ELSE
FeedRateC
END
END
RETURN

doCoolOn: {Added this sub - JHE}
IF ThruSpin?
'M27'
ELSE
IF Pulse?
'M28'
ELSE
IF Mist?
'M29'
ELSE
IF HiPressure?
'M7'
ELSE
IF FloodThruSpin?
'M8M27'

ELSE {implies Flood}
CoolOn {output M8}
END
END
END
END
END
RETURN

doFromCP: {Added this sub - JHE}
IF RetractToCP1?
'W' ABS# SUB# ClearancePlane1# CalcZsurf#
END
RETURN

doPeck: {Added this sub - JHE}
IF Peck?
IF PeckChipBreaker?
Peck 'J11'
ELSE {implies PeckFullRetract}
Peck 'J13'
END
END
RETURN

doStartPos:
IF RotaryMill?
'X' TrackX# StartPosX# 'Y0.' TrackYNO# StartPosY#
ELSE
StrtPos
END
IF AAxisAvail?
CalcSCAng MoveC
ELSE
TrackCNO# Num#('0')
END
RETURN

entryMove:
IF FirstOperation? OR NewTool?
RapidF# { Forces FeedEnt/FeedRate }
ELSE
IF LAST Rotations? OR LAST Repeats?
RapidF# { Forces FeedEnt/FeedRate }
END
END
IF FeedEntry?
SeqLabC Feed ZIn FeedEntC EOL {'*01*'}
ELSE
SeqLabC RapidC ZIn EOL {'*02*'}
END
RETURN

startSub:
OpenSub
'(DFS, ' Program# ')' EOL
doSubComment
RETURN

subWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'(MSG, WARNING: Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

stdSub:
SeqLabC {*SubCall*} '(CLS, ' Program# ',' Repeats# ')' EOL
startSub
RETURN

finishSub1: {part 1}
SeqLabC CRCOffC
IF NOT FeedConnect?
RapidC ZCP3C
END
EOL
RETURN

finishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
'(ENS)' EOL
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN

doWFOOps:
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
ELSE
SeqLabC SetWFO EOL
END
SeqLabC {*SubCall*} '(CLS, ' Program# ')' EOL
RETURN

openMP:
NewProg
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
END
NewWFO
EachWFO {simple eachPart}
doWFOOps
IncWFO
NextWFO {simple NextPart}
startSub
ELSE
SeqLabC {*SubCall*} '(CLS, ' Program# ',' Parts# ')' EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
startSub
END
RETURN

closeMP:
IF WorkFixtureOffsets?
'(ENS)' EOL
CloseSub
SeqLabC WFO1 EOL
ELSE
SeqLabC absOrIncC EOL
SeqLabC Preset ShiftPC EOL
'(ENS)' EOL
CloseSub
SeqLabC Preset UnshftPC EOL
END
RETURN

doAbsOrInc:
IF Rotations? AND RotaryMill?
incValueC
ELSE
IF Flag?('1') { Milling ZShiftOnly SepSubs/DrillSubs activated }
IF ZMove?
incValueC
ELSE
absOrIncC
END
END
END
RETURN

doACAbsOrInc:
IF Rotations? AND CMove?
incValueC
ELSE
absOrIncC
END
RETURN

doDrillAbsOrInc:
IF Rotations? AND RotaryMill?
incValueC
ELSE
IF Flag?('1') { DrillSubs activated }
IF SPZMove?
incValueC
ELSE
absOrIncC
END
END
END
RETURN

restoreAbsOrInc:
IF Rotations? AND RotaryMill? AND NOT AutoCycle?
SeqLabC absOrIncC EOL
ELSE
IF Flag?('1') { Milling ZShiftOnly SepSubs/DrillSubs activated }
SeqLabC absOrIncC EOL
END
END
IF Rotations? OR Repeats? OR AutoCycle? {Added this section - JHE}
IF Flag?('11') {if inverse Time is in effect}
SeqLabC perMinute EOL {Feed per Minute Mode}
SetFlagF('11') {Feed per Minute Mode On}
END
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
{IF NOT ZMove?} {Removed - JHE}
CRCOnC
{END}
END
RETURN

ckCRCNum: {Changed - JHE}
IF CutterRadiusCompensation?
CRCOfst
ELSE
'O0'
END
RETURN

tpPointFeat:
IF AutoCycle?
IF RotaryMill?
CalcSCAng
SeqLabC doACAbsOrInc MoveSXC MoveCC EOL
SetAbsOrInc
TrackCNO# ADD# Recall# Num#('5') MoveC# EOL {calc MoveC position after sub call}
ELSE
SeqLabC MoveSXYC EOL
END
IF Repeats? AND ZshiftOnly?
SeqLabC {*SubCall*} '(CLS, ' TRUNC# SUB# Program# Num#('1') ')' EOL
ELSE
SeqLabC {*SubCall*} '(CLS, ' Program# ')' EOL
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF FirstFeat?
SetFlagF('9') { For valid Drill Rotation Sub }
IF Rotations?
IF NOT LastFeat?
IF NOT MasterOp?
SetFlag('9') { valid Drill Rotation Sub }
NewProg
StartSub
END
END
END
ELSE
IF RotaryMill?
CalcSCAng
SeqLabC doDrillAbsOrInc MoveSXC MoveSZC MoveCC doFromCP EOL
ELSE
SeqLabC doDrillAbsOrInc MoveSXYZC doFromCP EOL
END
END
IF LastFeat?
IF Flag?('9') { valid Drill Rotation Sub }
restoreAbsOrInc
IF NOT MasterOp?
'(ENS)' EOL
CloseSub
END
END
END
END
RETURN

tpRapidFeat:
IF RotaryMill?
CalcCAng
IF XMove? OR ZMove? OR CMove?
SeqLabC doAbsOrInc ckCRC RapidC MoveXC MoveZC MoveCC {ckCRCNum} EOL
END
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC doAbsOrInc ckCRC RapidC MoveXYZC {ckCRCNum} EOL
END
END
RETURN

tpLineFeat:
IF RotaryMill?
CalcCAng
IF XMove? OR ZMove? OR CMove?
SeqLabC doAbsOrInc ckCRC doFeedrateMode FeedC MoveXC MoveZC MoveCC doInverseTimeFeed {ckCRCNum} EOL
END
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC doAbsOrInc ckCRC FeedC MoveXYZC FeedRateC {ckCRCNum} EOL
END
END
RETURN

tpArcFeat:
IF RotaryMill?
EachArcSegment
CalcCAng
SeqLabC doAbsOrInc ckCRC doFeedrateMode FeedC MoveXC MoveZC MoveCC doInverseTimeFeed {ckCRCNum} EOL
NextArcSegment
ELSE
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
SeqLabC doAbsOrInc ckCRC
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
IF ZMove?
MoveX MoveY MoveZ 'K' ABS# MUL# ArcZRads# Num#('6.283185')
{Added lead per 360 deg}
ELSE
MoveX MoveY
END
ELSE
IF XZPlane?
MoveX MoveZ
ELSE {implies YZ-Plane}
MoveY MoveZ
END
END
IF ArcIJFormat?
ArcIJ {Removed C - JHE}
ELSE
ArcR {Removed C - JHE}
END
ArcFeedC EOL
NEXTQuadrant
END
RETURN

toolPath:
ResetCRCNum
EACHFeat
IF FirstFeat?
resetSP
END
IF PointFeat?
tpPointFeat
ELSE
IF RapidFeat?
tpRapidFeat
ELSE
IF LineFeat?
tpLineFeat
ELSE
IF ArcFeat?
tpArcFeat
END
END
END
END
IF LastFeat?
getEP
END
NEXTFeat
restoreAbsOrInc
RETURN

autoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
startSub
SetSRXYtoSP
SeqLabC incValueC EOL
RETURN

autoCycCutSub2: {part 2}
toolPath
SeqLabC absOrIncC CRCOffC
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
RapidC ZCP2
END
EOL
'(ENS)' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

autoCycPat:
SetPass2 {position pattern}
toolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

milling:
IF AutoCycle?
NewProg
autoCycCutSub1
entryMove
autoCycCutSub2
autoCycPat
ELSE
entryMove
toolPath
END
RETURN

g92Sub:
subWarning
stdSub
SeqLabC absOrIncC Connect doStartPos EOL
milling
finishSub1
finishSubG92
RETURN

doSepSubContour:
SetPass1
TrackZNO# SPZ#
startSub
RapidF#
IF AutoCycle?
NewProg
autoCycCutSub1 {build element sub}
TrackZNO# SPZ#
autoCycCutSub2
ELSE
toolPath
finishSub1
'(ENS)' EOL
CloseSub
END
SetPass1
SetStatusRapid
RapidF#
SetSRXYtoEP
TrackZNO# ClearancePlane2#
TrackCNO# Recall# Num#('4') { cOpEP }
RETURN

doSepSubFeedConnect:
IF FeedConnect?
IF CMove?
doInverseTimeFeed
ELSE
FeedEntC
END
END
RETURN

doSepSubSPMove:
SetStatusOff
IF RotaryMill?
CalcSCAng
IF SPXMove? OR CMove?
IF Rotations? OR AutoCycle?
incValueC
END
{*SeqLabC Connect MoveSXC MoveCC doSepSubFeedConnect EOL*} {Removed - JHE}
IF FeedConnect? {Changed to this - JHE}
SeqLabC doFeedrateMode Feed MoveSXC MoveCC doSepSubFeedConnect EOL
ELSE
SeqLabC Rapid MoveSXC MoveCC EOL
END
absOrIncC
ELSE
Connect
END
ELSE
IF SPXMove? OR SPYMove?
IF AutoCycle?
incValueC
END
SeqLabC Connect StrtPosC doSepSubFeedConnect EOL
absOrIncC
ELSE
Connect
END
END
SetStatusOn
RETURN

doSepSubZMoves:
IF FeedConnect?
SeqLabC perMinute FeedC ZInPlusInc FeedEnt EOL {Added perMinute - JHE}
SetFlagF('11') {Feed per Minute Mode On}
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusInc EOL
END
SeqLabC Feed ZInPlusInc FeedEnt EOL {'*04*'}
ELSE
IF FirstCycle? AND AutoCycle?
Rapid
END
SeqLabC RapidC ZInPlusInc EOL {'*05*'}
END
END
SeqLabC {*SubCall*} '(CLS, ' Program# ')' EOL
IF NOT FeedConnect? AND NOT AbsValue?
TrackZNO# ZCP2PlusInc#
SeqLabC ZCP2C EOL
IF NOT AutoCycle?
TrackZNO# ClearancePlane3#
END
END
RETURN

setSepSubZ:
SetAbs
TrackZNO# ADD# SPZ# MUL# RepsLess1# RepeatZ#
SetInc
RETURN

doSepSubExit:
IF NOT AbsValue?
setSepSubZ
END
IF AutoCycle?
SeqLabC Rapid ZCP2 EOL
ELSE
Rapid { Will be output at millingOp ZCP3 }
END
RETURN

resetSepSubSR:
SetPass1
SetStatusRapid
RapidF#
TrackXNO# Recall# Num#('1') { xOpEP }
TrackYNO# Recall# Num#('2') { yOpEP }
TrackCNO# Recall# Num#('4') { cOpEP }
RETURN

zonlyRepAutoCycle:
doSepSubContour
EachCycle
IF NOT FirstCycle?
doSepSubSPMove
END
doSepSubZMoves
NextCycle
IF FeedConnect?
doSepSubExit
END
'(ENS)' EOL
CloseSub
{Element shift, not pattern}
autoCycPat {write pattern moves and main calls}
resetSepSubSR
TrackZNO# ClearancePlane2#
RETURN

zonlyRep:
doSepSubContour
EachCycle
IF NOT FirstCycle?
doSepSubSPMove
END
doSepSubZMoves
NextCycle
resetSepSubSR
IF FeedConnect?
doSepSubExit
ELSE
TrackZNO# ClearancePlane3#
END
RETURN

millingOp:
SeqLabC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
zonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
SetFlag('1') { Milling ZShiftOnly SepSubs activated }
zonlyRep
SetFlagF('1') { Milling ZShiftOnly SepSubs deactivated }
END {end Auto Cycle IF}
ELSE {not Z only}
g92Sub
END {end Z only IF}
ELSE {no repeat OPs}
milling
END
IF AutoCycle?
SeqLabC CRCOffC ZCP3C EOL
setSRXYtoACEP
ELSE
SeqLabC CRCOffC RapidC ZCP3C EOL
END
RETURN

skipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
CalcSCAng
TrackCNO# MoveC#
END
NextFeat
RETURN

setDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

drillingOp:
SeqLabC ZCP2C EOL
GetCycle
IF RigidTap?
SeqLabC 'G84.1'
ELSE
IF FIFO? AND Dwell?
SeqLabC 'G89'
ELSE
SeqLabC Cycle
END
END
doStartPos 'Z' CalcZFmSurf# 'R' CalcZSurf# doFromCP doPeck FeedEnt EOL
IF CallMasterOp?
SeqLabC {*SubCall*} '(CLS, ' CallMasterNum# ')' EOL
skipToLastFeat
ELSE
TrackZNO# SPZ#
IF MasterOp?
SetFlag('1') { DrillSubs activated }
NewMasterProg
SeqLabC {*SubCall*} '(CLS, ' Program# ')' EOL
startSub
toolPath
'(ENS)' EOL
CloseSub
SetFlagF('1') { DrillSubs deactivated }
ELSE
toolPath
END
END
setDrillEndOpZ
IF NOT Rotations?
SeqLabC DrillOff EOL
SeqLabC Rapid ZCP3 EOL
END
RETURN

checkPass: {use the correct StrtPos}
IF AutoCycle?
SetPass2
ELSE
SetPass1
END
RETURN

rotateStartPosC:
TrackXNO# Recall# Num#('1') { xOpEP }
MoveSXC
IF NOT RotaryMill?
TrackYNO# Recall# Num#('2') { yOpEP }
MoveSYC
END
CalcSCAng MoveC
RETURN

rotaryReps: {use the correct EndPos}
EachRotation
IF Milling?
IF FirstRotation?
NewProg
SaveProgNum2
StartSub
millingOp
'(ENS)' EOL
CloseSub
checkPass
ELSE
SeqLabC rotateStartPosC EOL
END
SeqLabC {*SubCall*} '(CLS, ' Program2# ')' EOL
ELSE
IF Drilling?
IF FirstRotation?
drillingOp
checkPass
ELSE
IF RetractToCP1? AND Equal? ClearancePlane1# ClearancePlane3#
SeqLabC rotateStartPosC EOL
ELSE
IF NOT RetractToCP1? AND Equal? ClearancePlane2# ClearancePlane3#
SeqLabC rotateStartPosC EOL
ELSE { Need to cancel Drill Cycle between Rotations }
SeqLabC DrillOff EOL
SeqLabC Rapid ZCP3 EOL
SeqLabC rotateStartPosC EOL
SeqLabC ZCP2C EOL
IF RigidTap?
SeqLabC 'G84.1'
ELSE
IF FIFO? AND Dwell?
SeqLabC 'G89'
ELSE
SeqLabC Cycle
END
END
rotateStartPosC 'Z' CalcZFmSurf# 'R' CalcZSurf# doFromCP doPeck FeedEnt EOL
END
END
END
IF CallMasterOp?
IF NOT FirstRotation?
SeqLabC {*SubCall*} '(CLS, ' CallMasterNum# ')' EOL
END
ELSE
IF MasterOp?
IF NOT FirstRotation?
SeqLabC {*SubCall*} '(CLS, ' Program# ')' EOL
END
ELSE
IF Flag?('9') { valid Drill Rotation Sub }
SeqLabC {*SubCall*} '(CLS, ' Program# ')' EOL
END
END
END
IF LastRotation?
SeqLabC DrillOff EOL
SeqLabC Rapid ZCP3 EOL
END
END
END
IF LastRotation?
EachFeat
IF LastFeat?
IF PointFeat?
CalcSCAng
ELSE
CalcCAng
END
TrackCNO# MoveC# EOL
END
NextFeat
END
NextRotation
TrackXNO# Recall# Num#('1') { xOpEP }
TrackYNO# Recall# Num#('2') { yOpEP }
TrackZNO# ClearancePlane3#
RETURN

opGuts:
IF Rotations?
rotaryReps
ELSE
IF Milling?
millingOp
ELSE
IF Drilling?
drillingOp
END
END
END
RETURN

progStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
SetArcSegmentAccuracy('.0127')
ELSE
SetMaxFeed('500')
SetArcSegmentAccuracy('.0005')
END
Save# Num#('1') Num#('0') { Status Register Variable for X Axis }
Save# Num#('2') Num#('0') { Status Register Variable for Y Axis }
Save# Num#('4') Num#('0') { Status Register Variable for C Axis }
Save# Num#('5') Num#('0') { AutoCycle SetPass1 C Axis Travel }
SetFlagF('1') { Milling ZShiftOnly SepSubs/DrillSubs deactivated }
SetFlagF('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
SetFlagF('9') { For valid Drill Rotation Sub }
SetFlagF('11') {Feed per Minute Mode On}
IF PSComment? AND UseComments?
'Utility Data:' EOL
' At Op Start: All literals and commands will appear at the beginning of the operation.' EOL
' At Op End: All literals and commands will appear at the end of the operation.' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

initOp:
{EOR EOL} {Removed - JHE}
'(PGM, ID="' Program# '")' EOL {Changed from ProgID1 - JHE}
':' Plane inchOrMetric AbsOrInc 'M26' EOL {M26 = full retract}
IF UseComments?
IF ProgramNameComment?
'(MSG, PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'(MSG, OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'(MSG, PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'(MSG, FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
restoreScale
RETURN

firstOp1:
IF ToolChangeAtHome?
SetHome
END
doOpComments
':? ' Rapid Plane inchOrMetric AbsOrInc perMinute OpToolID ToolChng EOL
SetFlagF('11') {Feed per Minute Mode On}
doPostScript
RETURN

firstOp2:
checkPass
SeqLabC Rapid doStartPos ZCP1 Speed SpinOn ToolOfst ckCRCNum wfoStuff PreTool EOL
RETURN

firstOp2Xcp: {called only in mP1ToollAllPXcp after openMP}
checkPass
SeqLabC Rapid doStartPos Speed SpinOn ToolOfst ckCRCNum wfoStuff EOL
RETURN

firstOp3:
SeqLabC doCoolOn EOL
RETURN

newToolOp1:
SeqLabC RapidC ZCP1C CoolOff EOL
setAngleUnder360
IF MultipleParts? AND FullUp?
SeqLabC 'M26' EOL {retract spindle}
END
RETURN

newToolOp2:
doEndOpPS
IF ToolChangeAtHome?
IF MultipleParts? AND FullUp?
{no output}
ELSE
SeqLabC 'M26' EOL {retract spindle}
END
IF AbsoluteMoves?
SeqLabC 'G98.1' Home SpinOff EOL
ELSE
SetAbs
SeqLabC 'G98.1' Home SpinOff EOL
SetInc
END
ELSE
SeqLabC SpinOff EOL
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
RETURN

newToolOp3: {Start new Operation}
doOpComments
':? ' Rapid Plane inchOrMetric AbsOrInc perMinute OpToolID ToolChng EOL
SetFlagF('11') {Feed per Minute Mode On}
doPostScript
RETURN

newToolOp4:
checkPass
SeqLabC Rapid doStartPos ZCP1 Speed SpinOn ToolOfst ckCRCNum wfoStuff PreTool EOL
RETURN

newToolOp4Xcp: {called only in mP1ToollAllPXcp after openMP}
checkPass
SeqLabC Rapid doStartPos Speed SpinOn ToolOfst ckCRCNum wfoStuff EOL
RETURN

newToolOp5:
SeqLabC doCoolOn EOL
RETURN

sameToolOp1:
doEndOpPS
IF LAST ProgStop?
SeqLabC RapidC ZCP1C CoolOff EOL
SeqLabC 'M26' EOL {retract spindle}
SeqLabC SpinOff EOL
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?
SeqLabC RapidC ZCP1C 'M26' EOL
END
END
setAngleUnder360
RETURN

sameToolOp2: {Start new Operation}
doOpComments
':? ' Rapid Plane inchOrMetric AbsOrInc perMinute EOL
SetFlagF('11') {Feed per Minute Mode On}
doPostScript
checkPass
RETURN

sameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqLabC Rapid doStartPos ZCP1 Speed SpinOn ToolOfst ckCRCNum wfoStuff EOL
SeqLabC doCoolOn EOL
ELSE
SeqLabC Rapid doStartPos SpeedC ToolOfst ckCRCNum wfoStuff EOL
IF NewToolOffset?
SeqLabC ZCP1 EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC doCoolOn EOL
END
END
RETURN

end1:
SeqLabC RapidC ZCP1C CoolOff EOL
setAngleUnder360
IF MultipleParts? AND FullUp?
SeqLabC 'M26' EOL {retract spindle}
END
RETURN

end2:
doEndOpPS
IF ToolChangeAtHome?
IF MultipleParts? AND FullUp?
{no output}
ELSE
SeqLabC 'M26' EOL {retract spindle}
END
IF AbsoluteMoves?
SeqLabC 'G98.1' Home SpinOff EOL
ELSE
SetAbs
SeqLabC 'G98.1' Home SpinOff EOL
SetInc
END
ELSE
SeqLabC SpinOff EOL
END
IF NotEqual? UnitAngle# Num#('0')
SeqLabC RapidC absOrIncC 'A' TrackC# Num#('0') EOL
END
IF ProgStop?
SeqLabC 'M0' EOL
END
RETURN

end3:
IF ToolChangeAtHome?
SeqLabC EOP EOL
ELSE
IF MultipleParts? AND FullUp?
SeqLabC EOP EOL
ELSE
SeqLabC 'M26' EOP EOL
END
END
CloseSub
Post2 {organize Subs into one program}
{EOR EOL} {Removed % - JHE}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
ReTag {Added - JHE}
RETURN

mpAllTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
openMP
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2 {to tool change, CS problem}
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1
end2
closeMP
end3
RETURN

mp1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
firstOp1
openMP
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
closeMP
newToolOp2 {to tool change, CS problem}
newToolOp3
openMP
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1
closeMP
end2
end3
RETURN

mp1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
openMP
firstOp2Xcp {need StrtPos in Sub}
ELSE
IF NewTool?
closeMP
newToolOp1
newToolOp2 {to tool change, CS problem}
newToolOp3
newToolOp4
newToolOp5
openMP
newToolOp4Xcp {need StrtPos in Sub}
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
closeMP
end1
end2
end3
RETURN

noMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1
end2
end3
RETURN

{Start of executable Prog, Top Level ****}

progStart {setup and initializations}
initOp

IF MultipleParts?
IF AllToolsOnePart?
mpAllTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
mp1ToollAllPfu
ELSE {implied ExitClearancePlane?}
mp1ToollAllPXcp
END
END
ELSE
noMPs
END