{Prog Comments ****}

{
10/21/94 [cwh]
M703.82

Initial creation from M688.82.
Removed EOR from start and end of prog.
Added PRG comment line as first line.
Modified drill cycle commands.
Forced quotes around all comment lines.
}

{
11/9/94 [cwh]
Cin Acr A2100 M703.82.03 ( from M703.82.02 )

Added the function DoLastEndOpPS.
Modified End2 function to call DoLastEndOpPS.
}

{
Format: Cin Acr A2100 [TVR] Mxxx.82.4
10/24/95
Removed pretool info
Removed G52 from end of program
Removed code to add 1000 to tool number
Added Z10 to end of program
TH}

{
Format: Cin Acr A2100 [TVR] M875.82.5
1/9/96
Removed first SeqLab from output
TH}

{12/3/96,
Intial: Cin Acr A2100 [TVR] M875.82.5
Created: Cin Acr A2100 [TVR] M875.82.6
Modified drilling section in OpGuts per Acr A2100-Generic M750.12.1, MPK}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '####.####;0'
#5 = '#######0'
#6 = '##.##;0'
#7 = '0000'
#8 = '+####.####;0'
#9 = '####0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CP1LessCP2#,4)
FORMAT(ADD#,4)
FORMAT(ToolDiameter#,4)
FORMAT(Repeats#,5)
FORMAT(Tag#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(Program#,7)
FORMAT(HelixPitch#,8)
FORMAT(Program#,9)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'(MSG, "SUB NUMBER: ' Tag# '" )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'(MSG, "OPERATION ' Operation# ': ' OperationType$ '" )' EOL
END
IF OperationComment?
'(MSG, "' OperationComment$ '" )' EOL
END
IF WorkGroupComment?
'(MSG, "' WorkGroupComment$ '" )' EOL
END
IF ToolTypeComment?
'(MSG, "TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ '" )' EOL
END
IF ToolComment?
'(MSG, "' ToolComment$ '" )' EOL
END
RestoreScale
END
RETURN

CMI_Wvalue:
IF RetractToCP1?
IF NotEqual? SUB# ClearancePlane1# CalcZSurf# Num#('0')
IF GreaterThan? SUB# ClearancePlane1# CalcZSurf# Num#('0')
'W' SUB# ClearancePlane1# CalcZSurf#
END
END
ELSE
IF NotEqual? SUB# ClearancePlane2# CalcZSurf# Num#('0')
IF GreaterThan? SUB# ClearancePlane2# CalcZSurf# Num#('0')
'W' SUB# ClearancePlane2# CalcZSurf#
END
END
END
RETURN

CSWFO:
'H' ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CalcCSWFO: {(iPart-1)*NumOfCS#)}
'H' ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CSAngleA:
IF WFOCS?
'A0.'
ELSE
'A' CSOffsetA#
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF WFOCS?
'B0.'
ELSE
'B' CSOffsetB#
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

DoCSWFOComment:
'( CS#' CS# ' - ' CSComment$ ' )' EOL
'( ' CalcCSWFO '= X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' A' CSOffsetA# ' B' CSOffsetB# ' )' EOL
RETURN

DoCoolOn:
IF ThruSpin?
'M27'
ELSE
CoolOn
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F { ??? }
RETURN

GetIndex:
IF FourthCW?
FORMAT(FourthDegree#,2)
'A' FourthDegree#
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
'A' FourthDegree#
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
'B' FifthDegree#
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
'B' FifthDegree#
FifthCCWF {reset flag}
END
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
SeqLabC GetIndex EOL
NextPS
RETURN

DoLastEndOpPS:
PSInit
NEXT EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
SeqLabC GetIndex EOL
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'(DFS,L' Tag# ')' EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'(MSG, "WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT" )' EOL
' ' EOL
END
END
RETURN

StdSub: {not used in Virtual, only used in non SepSub Repeats}
SeqLabC 'G10=[T2]V0' EOL {sets temporary register #2 to 0}
SeqLabC 'Q' Tag# '1' EOL {branch label 1}
SeqLabC '(CLS,L' Tag# ')' EOL {call subroutine}
SeqLabC 'G10=[T2]V[T2]+1' EOL {increment register #2 by 1}
SeqLabC 'G11E[T2]=' Repeats# 'L' Tag# '2' EOL {if register #2 is equal to number of repeats then jump to branch label 2}
SeqLabC 'G11L-' Tag# '1' EOL {jump backwards to branch label 1}
SeqLabC 'Q' Tag# '2' EOL {branch label 2}
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC '(ENS)' EOL
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN

OpenMP:
IF WFOCS?
'(Advanced Mill Multiple parts, Long Hand not supported in this post)' EOL
ELSE
{TagInc}
IF WorkFixtureOffsets?
ELSE
'(Non-WFO Multiple parts, Long Hand not supported in this post)' EOL
END
END
RETURN

CloseMP:
IF WFOCS?
'(Advanced Mill Multiple parts, Long Hand not supported in this post)' EOL
ELSE
IF WorkFixtureOffsets?
ELSE
'(Non-WFO Multiple parts, Long Hand not supported in this post)' EOL
END
END
RETURN

SubCSMP:
IF WFOCS? AND ChangeCS?
SeqLabC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
RETURN

SetZRepInc: {rep change 10}
IF Flag?('1') AND ZMove? AND AbsoluteMoves?
IncValue
SetFlag('2')
END
RETURN

RestoreAbsOrInc: {rep change 11}
IF Flag?('2') AND NOT ZMove?
AbsValue
SetFlagF('2')
END
RETURN

ckHMove:
SetStatusOff
SetFlagF('9')
IF YZPlane?
IF NotEqual? SUB# SPY# ArcI# SUB# ArcI# EPY#
SetFlag('9')
END
ELSE
IF NotEqual? SUB# SPX# ArcI# SUB# ArcI# EPX#
SetFlag('9')
END
END
SetStatusOn
RETURN

ckVMove:
SetStatusOff
SetFlagF('9')
IF XYPlane?
IF NotEqual? SUB# SPY# ArcJ# SUB# ArcJ# EPY#
SetFlag('9')
END
ELSE
IF NotEqual? SUB# SPZ# ArcJ# SUB# ArcJ# EPZ#
SetFlag('9')
END
END
SetStatusOn
RETURN

ckMove:
IF NOT FullArc?
IF XYPlane? AND NOT ZMove?
IF NOT XMove?
ckVMove
ELSE
IF NOT YMove?
ckHMove
END
END
ELSE
IF XZPlane? AND NOT YMove?
IF NOT XMove?
ckVMove
ELSE
IF NOT ZMove?
ckHMove
END
END
ELSE
IF YZPlane? AND NOT XMove?
IF NOT YMove?
ckVMove
ELSE
IF NOT ZMove?
ckHMove
END
END
END
END
END
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
IF ZMove?
MoveX MoveY MoveZ ArcIJ 'K' HelixPitch#
ELSE
MoveX MoveY ArcIJ
END
ELSE
{ ??? what about incr subs here ??? }
IF XZPlane?
IF YMove?
MoveX MoveY MoveZ ArcIJ 'J' HelixPitch#
ELSE
MoveX MoveZ ArcIJ
END
ELSE { YZPlane }
IF XMove?
MoveX MoveY MoveZ ArcIJ 'I' HelixPitch#
ELSE
MoveY MoveZ ArcIJ
END
END
{ ??? }
END
RETURN

CkCRC:
IF LastFeat? { Exit Length Feature }
CRCOffC
ELSE
IF XMove? OR YMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
END
RETURN

StdLine: {enables CRC on first call}
IF Decelerate?
IF RoomToDecel?
DecelMove1
RestoreAbsOrInc
SetZRepInc
SeqLabC FeedC CkCRC MoveXYC MoveZC FeedRateC EOL { CRCOffsetC }
RestoreAbsOrInc
DecelMove2
END
RestoreAbsOrInc
SetZRepInc
SeqLabC FeedC CkCRC MoveXYC MoveZC DecelFeed EOL { CRCOffsetC }
ELSE
IF XMove? OR YMove? OR ZMove?
RestoreAbsOrInc
SetZRepInc
SeqLabC FeedC CkCRC MoveXYC MoveZC FeedRateC EOL { CRCOffsetC }
END
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC '(CLS,L' Tag# ')' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF Drilling?
IF SPXMove? OR SPYMove? OR SPZMove?
SeqLabC MoveSXYZC CMI_Wvalue EOL
END
ELSE
SeqLabC MoveSXYZC EOL
END
END
ELSE
IF RapidFeat?
IF AutoCycle?
IF LastFeat?
CRCOffC
END
RestoreAbsOrInc
SetZRepInc
SeqLabC RapidC MoveXYC MoveZC EOL
ELSE
IF ZMove? AND NOT XMove? AND NOT YMove?
CRCOffC
END
IF XMove? OR YMove? OR ZMove?
RestoreAbsOrInc
SetZRepInc
SeqLabC RapidC MoveXYC MoveZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle?
IF LastFeat?
RestoreAbsOrInc
SetZRepInc
SeqLabC CRCOffC FeedC MoveXYC MoveZC FeedRateC EOL {MoveXYC SetZRepInc MoveZC, was MoveXYZC}
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
RestoreAbsOrInc
SetZRepInc
SeqLabC FeedC MoveXYC MoveZC FeedRateC EOL {MoveXYC SetZRepInc MoveZC, was MoveXYZC}
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
ckMove
IF Flag?('9')
SetFlagF('9')
StdLine
ELSE
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
RestoreAbsOrInc
SetZRepInc
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
RestoreAbsOrInc
SetZRepInc
SeqLabC FormatArc DecelFeed EOL
ELSE
RestoreAbsOrInc
SetZRepInc
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
IF LastFeat? AND CutterRadiusCompensation? AND NOT AutoCycle?
CRCOffC
IF NOT EmptyLine?
RestoreAbsOrInc
SetZRepInc
SeqLabC LastFeatExtend EOL { ??? any zmoves ??? }
END
END
END
NEXTFeat
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{removed RapidC}
{removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLabC '(ENS)' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagInc
EachCycle
IF FeedConnect?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC Rapid ZCP2PlusInc EOL {added Rapid, reads better}
{can't call for cycle = 1, changed to ZCP2PlusInc}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL {added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC '(CLS,L' Tag# ')' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLabC Feed ZCP2 FeedEnt EOL
ELSE
SeqLabC Rapid ZCP2 EOL
END
END
SeqLabC '(ENS)' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
SetFlag('1') {std sep sub Zreps are in effect}
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL {added Connect}
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL {changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {added Rapid, reads better} {changed to RapidC, reads better}
END
END
TrackZNO# FIRST SPZ#
ToolPath
IF NOT FeedConnect?
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO?
SeqLabC FeedC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
END
END
END
NextCycle
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 2}
UseSeparateSubCalls
SetMaxSeparateSubCalls('500')
SetMaxRPM('10000')
SetMaxFeed('500')

IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('0')
SetWFOCS { use WFO for CS changes }
END
END
ELSE
IF LTEqual? NumOfCS# Num#('0')
SetWFOCS { use WFO for CS changes }
END
END
RETURN

OpGuts:
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
ZonlyRep {rep change 1}
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO?
SeqLabC FeedC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagInc
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
SeqLabC DrillCP EOL
GetCycle

SeqLabC PlaneC
IF FIFO? AND Dwell? { Bore/Ream with Dwell }
'G89'
ELSE
IF Tap? AND OptCyc1?
'G84.1'
ELSE
Cycle
END
END
StrtPos
'Z' Sub# Add# ClearancePlane2# Zdepth# CalcZSurf# { Z = tip depth - Top Surface}
IF AbsValue?
'R' CalcZSurf#
ELSE
SetAbs
'R' CalcZSurf#
SetInc
END
CMI_Wvalue
IF Peck?
IF NotEqual? Peck# Num#('0')
'K' ABS# Peck#
END
END
Peck GetIndex FeedEnt
IF Peck?
IF PeckChipBreaker?
'J11'
ELSE
'J13'
END
ELSE
{
IF Tap? AND OptCyc1?
'J1'
END
}
END
EOL

TrackZNO# FIRST SPZ#
ToolPath
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqLabC DrillOff
{
IF Tap? AND OptCyc1?
'J0'
END
}
EOL
IF Repeats?
FinishSubG92
END
SeqLabC Rapid ZCP3C EOL
END
END
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 3}
RETURN

NotSameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
ClearCSOffset
SeqLabC CSWFO EOL
END
ELSE
IF NeedWFO1?
'H' NewWFO#
END
END
RETURN

SameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
ClearCSOffset
SeqLabC CSWFO EOL
END
END
RETURN

InitOp:
EOL
'(PGM, NAME="' ProgramComment$ '",'
IF GTEqual? Program# Num#('0')
' ID="' Program# '",'
END
' TYPE="A2100_247" )'
EOL

IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'(MSG, "PROGRAM: ' ProgramName$ '" )' EOL
END
IF ProgramComment?
'(MSG, "' ProgramComment$ '" )' EOL
END
IF FormatNameComment?
'(MSG, "FORMAT: ' FormatName$ '" )' EOL
END
IF TimeComment?
'(MSG, "' Date$ ' AT ' Time$ '" )' EOL
END
IF MovesComment?
'(MSG, "OUTPUT IN ' MoveType$ ' INCHES" )' EOL
END
IF PartsComment?
'(MSG, "PARTS PROGRAMMED: ' Parts# '" )' EOL
END
IF StartToolComment?
'(MSG, "FIRST TOOL NOT IN SPINDLE" )' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
DoOpComments
DoPostScript
':?' Plane 'G70' AbsOrInc Rapid { Inch }
OpToolID ToolChng EOL
RETURN

FirstOp2:
RETURN

FirstOp3:
CheckPass
SeqLabC Rapid StrtPos ZCP1 GetIndex Speed SpinOn EOL
SeqLabC DoCoolOn EOL
RETURN

FirstOp3a: {can't XY position before WFO}
CheckPass
SeqLabC Rapid StrtPos ZCP1 GetIndex Speed SpinOn EOL
SeqLabC DoCoolOn EOL
RETURN

FirstOp3b:
CheckPass
SeqLabC Rapid StrtPos ZCP1 GetIndex Speed NotSameToolWFO SpinOn EOL
SeqLabC DoCoolOn EOL
RETURN

NewToolOp1:
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC AbsOrInc Rapid Home EOL
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
DoOpComments
DoPostScript
':?' Plane 'G70' AbsOrInc Rapid { Inch }
OpToolID ToolChng EOL
RETURN

NewToolOp4:
RETURN

NewToolOp5:
CheckPass
SeqLabC PlaneC Rapid StrtPos ZCP1 GetIndex Speed SpinOn
FORMAT(ADD#,7)
'T' ADD# NextTool# Num#('1000') EOL { PreTool }
FORMAT(ADD#,4)
SeqLabC DoCoolOn EOL
RETURN

NewToolOp5a:
CheckPass
SeqLabC PlaneC Rapid StrtPos ZCP1 GetIndex Speed SpinOn EOL
SeqLabC DoCoolOn EOL
RETURN

NewToolOp5b:
CheckPass
SeqLabC PlaneC Rapid StrtPos ZCP1 GetIndex Speed SpinOn NotSameToolWFO EOL
SeqLabC DoCoolOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLabC SpinOff EOL
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset? OR ChangeCS?
{ ??? due full up here ??? }
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqLabC PlaneC Rapid StrtPos ZCP1 GetIndex Speed SpinOn EOL
SeqLabC DoCoolOn EOL
ELSE
IF NewToolOffset? OR ChangeCS?
SeqLabC PlaneC Rapid StrtPos ZCP1 GetIndex SpeedC EOL
ELSE
SeqLabC PlaneC Rapid StrtPos GetIndex SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC DoCoolOn EOL
END
END
RETURN

End1:
RETURN

End2:
DoLastEndOpPS
IF FIRST ToolChangeAtHome?
SeqLabC AbsOrInc Rapid FirstHome EOL
END
IF ProgStop?
SeqLabC 'M0' EOL
END
RETURN

End3:
SeqLabC 'Z10' EOL
SeqLabC EOP EOL { Unload Last Tool }
CloseSub
Post2 {organize Subs into one program}
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
'(MSG, "FILE LENGTH: ' FileBytes# ' CHARACTERS" )' EOL
END
IF FileFeetComment?
'(MSG, "FILE LENGTH: ' FileFeet# ' FEET" )' EOL
END
IF FileMetersComment?
'(MSG, "FILE LENGTH: ' FileMeters# ' METERS" )' EOL
END
END
{ EOR EOL }
Close
ReTag
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
NewWFO
EachWFO {simple eachPart, ***start loop}
SeqLabC SetWFO EOL
IncWFO
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
IF LastOP?
End1 {End of program}
End2
CloseMP
NextWFO {simple NextPart**** end loop}
SeqLabC WFO1 EOL
END
NextOp {loops back to EachOP until last Operation}
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
OpenMP
NewWFO
EachWFO {simple eachPart, ***start loop}
SeqLabC SetWFO EOL
IncWFO
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NextWFO {simple NextPart**** end loop}
SeqLabC WFO1 EOL
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
OpenMP
NewWFO
EachWFO {simple eachPart, ***start loop}
SeqLabC SetWFO EOL
IncWFO
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
IF LastOP?
End1 {End of program}
CloseMP
NextWFO {simple NextPart**** end loop}
SeqLabC WFO1 EOL
END
NextOp {loops back to EachOP until last Operation}
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3a
OpenMP
NewWFO
EachWFO {simple eachPart, ***start loop}
SeqLabC SetWFO EOL
IncWFO
SeqLabC StrtPos EOL
ELSE
IF NewTool?
CloseMP
NextWFO {simple NextPart**** end loop}
SeqLabC WFO1 EOL
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5a
OpenMP
NewWFO
EachWFO {simple eachPart, ***start loop}
SeqLabC SetWFO EOL
IncWFO
SeqLabC StrtPos EOL
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
IF LastOP?
CloseMP
NextWFO {simple NextPart**** end loop}
SeqLabC WFO1 EOL
END
NextOp {loops back to EachOP until last Operation}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3b
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5b
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolWFO
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, top level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END