{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=F
MILLTURN_Y-AXIS=F
METRIC=F
}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{1/6/89
Modified Cincinnati 900 V2 M029.54 for Northwest Machining.
Changed OfstOn to ZCP1. Added StrtPos to OpenMP.
Jim Radcliffe}

{11/9/90, Updated: Cincinnati 900V2 M029.56 to .76.1 format, JR}

{4/03/91
Modified: Cincinnati 900V2 M029.76.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{12/14/93
Modified: Cincinnati 900V2 M029.79
For: Northwest
Modified FormatArc to output unconditional G02/G03 and IJK info.
Added missing DoOpComment calls in FirstOp and NewTool.
Deleted PeckManual command and added Manual Peck routine.
Minor uptated stuff per Fanuc 6M M001.81.2
Jim Radcliffe}

{6/27/95
Initial: Cincinnati 900V2 M029.81.3
ForUser: CKC
Control: Acramatic 900
Machine: Cincinnati 10V-2000
Comment: New Processor per marked up readout and conversation with Phil Keisel and Tommy
Deleted program ID line from beginning of program.
Added 'MSG,' to all comments
Tool handling (This is a manual tool change machine):
Deleted OpToolID and ToolChng
Using M00 to stop program for tool change.
Changed StartToolComment to read: FIRST TOOL IN SPINDLE
Added TCZ# with default of 8" for retract
Using WFO Offsets, H code, for tool offsets, outputting the tool number with OpToolID.
Drilling:
Changed RLevelCin to RLevel, he says thats the way it should be!?
Skip move to ZCP1 when drilling, go directly to DrillCP
They will not be using RetractToCP1. I am not supporting it in the prog.
Z Depths are incremental and I added a formula to prperly handle.
NOTES:
They have not run into subs yet and doubt they will
Work Fixture Offset code is being output with OpToolID
Jim Radcliffe}

{9/7/95, Updated Cin Acr 900 [CKC] M818.81.2 to .85 format per Fanuc 6M M001.85.01.03, JR}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{6/22/96
Initial: Cin Acr 900 [CKC] M818.89
Created: Cin Acr 900 [MSI] M000.89
ForUser: CIM Solutions / Metal Stampings
Control: Acramatic 900
Machine: Cincinatti 10V1250
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: New Processor per marked up readout and conversation with Chuck Klinect
Added program ID to beginning of program.
Added too change line, its a manual tool change!
Changed OpToolID label back to T
Added WFOStuff calls
Jim Radcliffe}

{10/22/98
Initial: Cin Acr 900 [MS] MZ14.89
Created: Cin Acr 900V2 [KM] Mxxx.89
ForUser: Krogness Machine
Control: Acramatic 900 V2
Machine: Cincinnati 5VC
Develop: Compost2 v1.6b8, Virtual 4.29.63
Comment: New processor (rough draft) per marked up readout and conversation with Ted.
Moved G90 and G91 to be output on a line by itself.
Add S code to G84 line for threading.
Added O code sequence numbers at beginning of tools.
Added sequence numbers to comment lines.
Modified tool start up.
Added K value for Helical interpolation.
Modified Z and R output on Drill cycle line.
The R value is .100 below ZCP2 as an absolute value.
The Z value is incremental from the R.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = 'Ä…###^###0'
#8 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(ZDepth#,7)
FORMAT(TrackZ#,7)
FORMAT(TCZ#,7)
FORMAT(SUB#,7)
FORMAT(ArcZRads#,7)
FORMAT(NewWFO#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqLabC '(MSG, SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLabC '(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLabC '(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLabC '(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLabC '(MSG, TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLabC '(MSG, ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
NullFoot
NullFoot
NullFoot
NullFoot
EOR EOL
SeqLabC '(PGM,I' ProgNum ')' EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
SeqLabC '(MSG, WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLabC '(CLS,I' ProgNum ',R' RepsLess1 ')' EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC CRCOffC EOL
SeqLabC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftR EOL
SeqLabC EndSub EOL
EOR EOL
CloseSub
SeqLabC Preset UnshiftR EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EACHWFO
SeqLabC SetWFO EOL
SeqLabC '(CLS,I' ProgNum ')' EOL
IncWFO
NEXTWFO
ELSE
SeqLabC '(CLS,I' ProgNum ',R' PartsLess1 ')' EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqLabC EndSub EOL
EOR EOL
CloseSub
SeqLabC WFO1 EOL
ELSE
SeqLabC Preset ShiftP EOL
SeqLabC EndSub EOL
EOR EOL
CloseSub
SeqLabC Preset UnshiftP EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

ArcFormat:
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

FormatArc:
IF ArcCW?
CWArc
ELSE
CCWArc
END
IF XYPlane? AND ZMove?
MoveXYZC ArcFormat 'K' ArcZRads#
ELSE
MoveXYZC ArcFormat
END
RETURN

DoLastPeck: {OldZ - Peck# ² Depth}
SeqLabC Feed 'Z' TrackZ# SPZ# FeedEntC EOL {move to Depth}
IF RetractToCP1?
SeqLabC Rapid ZCP1 EOL {move to CP1}
ELSE
SeqLabC Rapid ZCP2 EOL {move to CP2}
END
RETURN

DoPeck:
IF GreaterThan? SUB# Recall# Num#('1') Peck# SPZ# {IF OldZ - Peck# > Depth}
Save# Num#('1') SUB# Recall# Num#('1') Peck# {Save#1 = OldZ - Peck# = NewZ}
SeqLabC Feed 'Z' TrackZ# Recall# Num#('1') FeedEntC EOL {move to NewZ}
IF PeckFullRetract?
SeqLabC Rapid ZCP2 EOL {move to CP2}
END
SeqLabC RapidC 'Z' TrackZ# ADD# Recall# Num#('1') Retract# EOL {move to RetractZ}
END
RETURN

DrillPath:
EACHFeat
SeqLabC RapidC MoveSXYC EOL
SeqLabC ZCP2C EOL
IF Peck?
Save# Num#('1') ClearancePlane2#
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoLastPeck
END
NEXTFeat
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC '(CLS,I' ProgNum ')' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC DoDrillAbsOrInc EOL
SeqLabC MoveSXYC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat?
SeqLabC DoAbsOrInc EOL
SeqLabC CRCOffC RapidC MoveXYZC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC DoAbsOrInc EOL
SeqLabC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc EOL
SeqLabC CRCOnC RapidC MoveXYZC EOL
END
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqLabC DoAbsOrInc EOL
SeqLabC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC DoAbsOrInc EOL
SeqLabC FeedC MoveXYZC FeedRateC EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc EOL
SeqLabC CRCOnC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqLabC DoAbsOrInc EOL
SeqLabC CRCOnC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc EOL
SeqLabC CRCOnC FeedC MoveXYZC FeedRateC EOL
END
END
END
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc EOL
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC DoAbsOrInc EOL
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC DoAbsOrInc EOL
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS'
EOL
ELSE
'H' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
'H' NewWFO#
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqLabC AbsOrInc EOL
ELSE
IF FIFO? {.81}
SeqLabC AbsOrInc EOL
SeqLabC FeedC ZCP2 FeedEntC EOL
ELSE
SeqLabC AbsOrInc EOL
SeqLabC RapidC ZCP2 EOL
END
END
SeqLabC EndSub EOL
EOR EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC IncValue EOL
SeqLabC Feed StrtPosC EOL
SeqLabC AbsOrInc EOL
SeqLabC
ELSE
SeqLabC Feed
END
ELSE
SeqLabC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC IncValue EOL
SeqLabC Rapid StrtPosC EOL
IF FeedEntry?
SeqLabC AbsOrInc EOL
SeqLabC ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC AbsOrInc EOL
SeqLabC ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLabC Rapid ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC '(CLS,I' ProgNum ')' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLabC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqLabC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqLabC EndSub EOL
EOR EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLabC '(CLS,I' ProgNum ')' EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLabC EndSub EOL
EOR EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN


{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50') {?}
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
SetTCZ('8')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
SeqLabC '(PGM,I' ProgNum ')' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqLabC '(MSG, ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqLabC '(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLabC '(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqLabC '(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqLabC '(MSG, OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
SeqLabC '(MSG, PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
SeqLabC '(MSG, FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Plane SetAbsOrInc
'O?' OpToolID ToolChng EOL
DoOpComments
DoPostScript
CheckPass
'O?' Rapid StrtPos Speed SpinOn WFOStuff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqLabC Rapid StrtPos EOL
END
IF NOT Drilling?
SeqLabC ZCP1 EOL
END
SeqLabC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC Rapid StrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC CoolOff EOL
SeqLabC 'Z' TCZ# EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

Plane SetAbsOrInc
'O?' OpToolID ToolChng EOL
DoOpComments
DoPostScript
CheckPass
'O?' Rapid StrtPos Speed SpinOn WFOStuff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqLabC Rapid StrtPos EOL
END
IF NOT Drilling?
SeqLabC ZCP1 EOL
END
SeqLabC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC Rapid StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLabC CoolOff EOL
SeqLabC 'Z' TCZ# EOL
SeqLabC 'M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC Rapid StrtPos SpeedC SpinOn EOL
IF NOT Drilling?
SeqLabC ZCP1 EOL
END
SeqLabC CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END

{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC Rapid StrtPos SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLabC ZCP2 EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLabC FeedC CRCOffC EOL
SeqLabC ZCP3C FeedEntC EOL
ELSE
SeqLabC CRCOffC EOL
SeqLabC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLabC Rapid StrtPos EOL
END
IF Peck?
DrillPath
ELSE
SeqLabC ZCP2 EOL
GetCycle
SeqLabC Cycle StrtPos
'Z' SUB# ZDepth# SUB# ClearancePlane2# Num#('.1')
'R' SUB# ClearancePlane2# Num#('.1')
Dwell Peck Retract FeedEnt
IF Threading?
Speed
END
EOL
IF CallMasterOp?
SeqLabC '(CLS,I' CallMasterNum# ')' EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLabC '(CLS,I' ProgNum ')' EOL
StartSub
ToolPath
SeqLabC EndSub EOL
EOR EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLabC 'G80' EOL
SeqLabC Rapid ZCP3 EOL
END
IF Repeats?
FinishSubG92
END
SeqLabC RapidC ZCP3C EOL
END
END
NEXTOp
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC CoolOff EOL
SeqLabC 'Z' TCZ# EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF MultipleParts? AND AllToolsOnePart?
IF ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END
CloseMP
END
SeqLabC EOP EOL
EOR EOL
CloseSub
Post2 {organize Subs into one program}
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
SeqLabC '(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
SeqLabC '(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
SeqLabC '(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Close
Retag