{6/1/89
Modified; Cincinnati 900V2 (1) M099.54, for C G Richter.
Change "RapidC" to "Rapid" after Drilling.
Add "NullFoot" twice to beginning and twice to end of prog.
Changed "'( MSG" to "'(MSG".
Checked "Use Absolute Drill Depths" in Booleans.
Jim Radcliffe}

{9/6/89
Copied & modified: Cincinnati 900V2 (1) M099.55
For: Hughes T&CSD
Machine: Cincinnati Cintimatic 5VC-750
Control: Acramatic 900 V2
New processer from Manual and Customer requests.
Jim Radcliffe}
{9/15/89, add PostScript, JR}
{10/11/89, modified operation comments, JR}

{2/9/90, Updated: Cin 5VC Acr 900V2 M238.62 to .70 & added Helical Interp, JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{5/7/91, Updated Cin 5VC Acr 900V2 M238.71 to .80 format, JR}
{6/18/91, Changed ArcIJC & ArcRC to ArcIJ & ArcR. Added OptCyc1f to PSInit, JC}

{6/27/91
Modified: Cin 5VC Acr 900V2 M238.80.1
For: Hughes T&CSD per Terry Lowe
Modified Subs;
changed Sub ID from "PGM" to "DFS",
changed to output subs in front of program,
deleted all EOR codes except for the 1st one.
Modified Cutter Radius Compensation, must be in Feed when CRCOn is called and cannot have 2 G codes on same line;
deleted boolean statement that ouputs Feed, after a rapid entry, from; EntryMove, ZonlyRepAutoCycle & ZonlyRep,
added sub CheckCRC to put Feed on line by itself before CRCOn, using flag to check condition,
put CRCOff on line by itself following move line and reset flag.
Modified header and operation comments per 10VC M245.80.
Modified tool ID and tool call per 10VC M245.80.
Jim Radcliffe}


#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '#.0000'
#5 = '#0'
#6 = '00'
#7 = '###^###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5)
FORMAT(Parts#,5) {.72}
FORMAT(NewWFO#,6)
FORMAT(ArcZRads#,7)

DoSubComment:
IF UseComments? AND SubComment?
SeqLabC '( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLabC '( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLabC '( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLabC '( ' WorkGroupComment$ ' )' EOL
END
IF SameTool?
IF NewToolOffset?
IF ToolTypeComment?
SeqLabC '( TOOL ' Tool# ': (' ToolDiameter# ') ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLabC '( ' ToolComment$ ' )' EOL
END
END
ELSE
IF ToolTypeComment?
SeqLabC '( TOOL ' Tool# ': (' ToolDiameter# ') ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLabC '( ' ToolComment$ ' )' EOL
END
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1f
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SeqLabC '(DFS,I' ProgNum ')' EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLabC '(CLS,I' ProgNum ',R' RepsLess1 ')' EOL
StartSub
RETURN

FinishSub1: {part 1}
UnSkipZ
IF NOT FeedConnect?
SeqLabC RapidC ZCP3C EOL
END
SeqLabC CRCOffC SetFlagF('1') EOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftR EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshiftR EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EACHWFO
SeqLabC SetWFO EOL
SeqLabC '(CLS,I' ProgNum ')' EOL
IncWFO
NEXTWFO
ELSE
SeqLabC '(CLS,I' ProgNum ',R' PartsLess1 ')' EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqLabC EndSub EOL
CloseSub
SeqLabC WFO1 EOL
ELSE
SeqLabC Preset ShiftP EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshiftP EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
IF XYPlane? AND ZMove? {helical move}
'K' ArcZRads#
END
RETURN

CheckCRC:
IF CutterRadiusCompensation?
IF Flag?('1')
FeedC
ELSE
FeedC EOL
SeqLabC CRCOn SetFlag('1')
END
ELSE
FeedC
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC CheckCRC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqLabC CheckCRC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC CheckCRC MoveXYZC FeedRateC EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
SeqLabC MoveSXYC EOL
IF AutoCycle?
SeqLabC '(CLS,I' ProgNum ')' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqLabC RapidC MoveXYZC EOL
SeqLabC CRCOffC SetFlagF('1') EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqLabC FeedC MoveXYZC FeedRateC EOL
SeqLabC CRCOffC SetFlagF('1') EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS'
ELSE
'H' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
'H' NewWFO#
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqLabC AbsOrInc EOL {.69 removed RapidC}
ELSE
SeqLabC AbsOrInc RapidC ZCP2 EOL
END
SeqLabC EndSub EOL
CloseSub
SetSRSubXY {restore tool position}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
IF FeedConnect?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC Rapid ZCP2PlusInc EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC '(CLS,I' ProgNum ')' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
SeqLabC Rapid ZCP2 EOL {.69}
END {.69}
SeqLabC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1}
{.69 added Rapid, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
SeqLabC '(CLS,I' ProgNum ')' EOL
NextCycle
StartSub
SkipZ
ToolPath
FinishSub1
SeqLabC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

Approach:
IF Drilling? AND NOT Peck?
GetCycle
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
StrtPos ZDepth RLevelCin FeedEnt
ELSE {milling or pecking}
Rapid StrtPos
IF Peck?
ZCP2
ELSE {milling}
IF NOT SameTool?
ZCP1
END
END
END
RETURN

CheckPreTool:
IF NOT LastTool?
'T' PreToolComment$
END
RETURN

InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50') {?}
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END

{**************** Customized header comments with tool list *****************}

EACHOp
IF FirstOperation?
IF UseComments?
'PARTNO ' ProgramName$ ' BY: T. LOWE PROG:' ProgramComment$ ' ' EOL
SeqLabC '( MACHINE 5VC )' EOL
IF ProgramNameComment?
SeqLabC '( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqLabC '( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLabC '( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqLabC '( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqLabC '( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
SeqLabC '( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
SeqLabC '( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
SeqLabC '( )' EOL
END
IF SameTool?
IF NewToolOffset?
SeqLabC '( TOOL ' Tool# ' (' ToolDiameter# ') ' ToolType$ ' T' ToolComment$ ' ' ToolOfst ' )' EOL
END
ELSE
SeqLabC '( TOOL ' Tool# ' (' ToolDiameter# ') ' ToolType$ ' T' ToolComment$ ' ' ToolOfst ' )' EOL
END
NEXTOp

{*************************** Beginning **********************************}

EACHOp
IF FirstOperation?
SeqLabC '( )' EOL
EOR EOL
IF ToolChangeAtHome?
SetHome
END
OpenSub
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
'O?' Rapid 'T' ToolComment$ ToolChng EOL
DoOpComments
SeqLabC Plane EOL
SeqLabC AbsOrInc EOL
DoPostScript
CheckPass
'O?' Approach Speed CheckPreTool WFOStuff ToolOfst SpinOn EOL
IF MultipleParts? AND OneToolAllParts?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC RapidC Home EOL
END
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

'O?' Rapid 'T' ToolComment$ ToolChng EOL
DoOpComments
SeqLabC PlaneC EOL
DoPostScript
CheckPass
'O?' Approach Speed CheckPreTool WFOStuff ToolOfst SpinOn EOL
IF MultipleParts? AND OneToolAllParts?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL

{Start new Operation}

DoOpComments
SeqLabC PlaneC EOL
DoPostScript
CheckPass
SeqLabC Approach SpeedC WFOStuff ToolOfst SpinOn EOL
ELSE
{Start new Operation}

IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
DoOpComments
SeqLabC PlaneC EOL
DoPostScript
CheckPass
SeqLabC Approach SpeedC WFOStuff
IF NewToolOffset?
ToolOfst
END
EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqLabC RapidC ZCP3C EOL
SeqLabC CRCOffC SetFlagF('1') EOL
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLabC StrtPos EOL
END
IF Peck?
EACHFeat
SeqLabC MoveSXYC EOL
PeckManual
NEXTFeat
ELSE
ToolPath
SeqLabC DrillOff EOL
END
IF Repeats?
FinishSubG92
END
SeqLabC Rapid ZCP3 EOL
END
END
NEXTOp
IF MultipleParts? AND OneToolAllParts?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqLabC FirstHome EOL
END
IF ProgStop?
SeqLabC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLabC EOP EOL
Post
Close
Retag
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END