{Change Comments ***********************************************************}

{12/7/88
Copied and massivly changed Cincinnati-225W M027.53
for Grand Valley's Cincinnati 10H with Acramatic 338-D control
Jim Radcliffe}

{5/31/90
Copied & modified: Cincinnati Acr 338-D 55
For: Grand Valley
Machine: Cincinnati
Control: Acramatic 338-D
Added G80 to safe startup block in each operation.
Modified Speed Table to output low gear S00 to S39 when RPM = 0 to 630.
Modified Speed Table to output high gear S64 to S79 when RPM = 631 to 4000.
Before, low gear stopped at S27 when RPM = 160.
Modified ToolOffset from safe startup block in each operation to be 'W00' and moved ToolOffset
to line following.
Replaced all occurances of M26 with R0W00.
Replaced all occurances of G01 with G79 by modifying Feed in the form.
Modified SegLabC to be 'H?' if 'No Home' is not checked in same tool operation.
Added 'W00' to be output if 'No Home' is not checked in same tool operation for moving tool
to tool change plane.
DWB}

{7/3/90
Copied & modified: Cincinnati Acr 338-D M160.72.1
For: Grand Valley
Machine: Cincinnati
Control: Acramatic 338-D
Updated to Version 3.2 per Fanuc 6M M001.72 Format.
Added Z0 to safe startup block in milling or peck drilling operation.
Modified G00R0R0 to G00R0Z0 at end of all operations.
Replaced ToolOffset in safe startup block of Drilling operation and deleted ToolOffset
in line following.
Added Psuedo Tool Change handling 'M26' when RetractToCP1 = true in drilling cycles.
DWB}

{11/14/91
Copied & modified: Cincinnati Acr 338-D M160.73.1
For: Grand Valley
Updated to .80 format
Modified SameTool to go home if ToolChangeAtHome.
Added a blank line between tools in NewTool and in SameTool if LAST ProgStop or ToolChangeAtHome.
Modified FormatArc for unconditional IJKR.
Modified FormatArc to force a line move if there is not motion in both of the arc planes axis.
Repalced PackManual with DoPeck and DoLastPeck.
Jim Radcliffe}

{1/13/92
Modified: Cinicinnati Acr 338-D M160.80
For: Grand Valley
Doubled the number of DoPeck calls to 100.
Discriminated so that the 'W00' at beginning of operations is ouput on 'H' blocks only.
Jim Radcliffe}

{11/15/94
Updated: Cincinnati Acr 338-D M160.80.1
For: Winegar
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.04/Compost 4.21.23
Versions: Catalyst v2.14.14C/Compost 4.21.23
Changes made per Pete Jackson
Updated to Version 4.2 per LongHand M001.81.3e Format.
This supports MultipleParts.
Using Var(1), Var(2) and Var(3) for logical control of MultiplePart Operations.
Using Var(4), Var(5), Var(6) and Var(7) for correct Positioning of AutoCycles that Repeat in
X and/or Y, and when AbsoluteMoves = FALSE.
Corrected FORMAT5 from '########;0' to '#######0'.
Added Recall# to FORMAT5.
Added RestoreScale Sub per 4-Axis Post Processor.
Supports FIFO? Milling Operations.
Supports Variable Drill Depths.
Supports logic of MPLoop sub to handle IF NewTool? and LastOp? situations.
Commented out DoEndOpPS at MPLoop for OneToolAllParts, it does not work correctly.
Does not support WorkFixtureOffsets.
Does not support CutterRadiusCompensation.
Supports Move to ZInC for Non-AutoCycle FeedConnect Repeats with ZMoves at ExitMove sub.
Contains BadMPWFOReport sub.
Reports when MultipleParts AND WorkFixtureOffsets = TRUE AND EquallySpacedOffset values exist.
Added FORMAT7, 'Ä…#bbbb.bbbb#', for PartShiftX#, PartShiftY# and PartShiftZ# commands.
Supports Rapid between Features of FeedConnect Operations at ZonlyRepAutoCycle sub.
FeedConnect only applies to Each Repeat, not Each Feature.
DWB}

{
Format: Cincinnati Acr 338-D M160.80.3
For: Winegar
Changed format for X,Y,Z,I,J,K from Ä…###^###0 to Ä…###^0000
TH}

{2/9/96, Updated .81 number to .84, no changes necessary, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{4/29/97
Initial: Cin Acr 338-D M160.87
Created: Cin Acr A8-D 7VT-1000 Mxxx.89
ForUser: HMD Engineering
Control: Cincinnati Acramatic A8-D
Machine: Cincinnati Cintimatic 7VT-1000
Develop: ComPost2 68K 1.0b11, CatalystPPC v3.33C
Comment: New Processor per manual and sample programs.
Added spaces between codes.
No Plane output! Arcs in XY plane only. Non XY arcs and helix are segmented!
Special Z handling:
Uses R for Rapid position on Z axis. Machine actually position .100 above value output.
All feed Z positions are incremental form the previous R output!!!
All R and Z output must be unsigned!
Program zero should be the highest point on Z to go to in the program.
Use move origin even after all work is done!! Set clearance and depth will change!!
All Z numbers in Virtual should be zero or less.
Search oputput for R- to be sure!!
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###^###0'
#3 = '*###^###0'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '*##^###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(ZDepth#,6)
FORMAT(TrackZ#,6)
FORMAT(Recall#,6)
FORMAT(ADD#,6)
FORMAT(SUB#,6)

{Special Z Command and Calculation Subroutines *****************************}

SaveCurrentR:
Save# Num#('5')
RETURN

CurrentR#:
Recall# Num#('5')
RETURN

SaveCurrentZ:
Save# Num#('6')
RETURN

CurrentZ#:
Recall# Num#('6')
RETURN

MoveCinR:
' R' ADD# CurrentR# Num#('-.1')
RETURN

MoveCinZ:
' Z' SUB# CurrentZ# ADD# CurrentR# Num#('-.1')
RETURN

CinZInC:
IF Rapid?
IF NotEqual? CurrentR# SPZ#
SaveCurrentR SPZ#
SaveCurrentZ SPZ#
MoveCinR
END
ELSE
IF NotEqual? CurrentZ# SPZ#
SaveCurrentZ SPZ#
MoveCinZ
END
END
RETURN

CinZCP1:
IF Rapid?
SaveCurrentR ClearancePlane1#
SaveCurrentZ ClearancePlane1#
MoveCinR
ELSE
SaveCurrentZ ClearancePlane1#
MoveCinZ
END
RETURN

CinZCP2:
IF Rapid?
SaveCurrentR ClearancePlane2#
SaveCurrentZ ClearancePlane2#
MoveCinR
ELSE
SaveCurrentZ ClearancePlane2#
MoveCinZ
END
RETURN

CinZCP2C:
IF Rapid?
IF NotEqual? CurrentR# ClearancePlane2#
SaveCurrentR ClearancePlane2#
SaveCurrentZ ClearancePlane2#
MoveCinR
END
ELSE
IF NotEqual? CurrentZ# ClearancePlane2#
SaveCurrentZ ClearancePlane2#
MoveCinZ
END
END
RETURN

CinZCP3:
IF Rapid?
SaveCurrentR ClearancePlane3#
SaveCurrentZ ClearancePlane3#
MoveCinR
ELSE
SaveCurrentZ ClearancePlane3#
MoveCinZ
END
RETURN

CinZCP3C:
IF Rapid?
IF NotEqual? CurrentR# ClearancePlane3#
SaveCurrentR ClearancePlane3#
SaveCurrentZ ClearancePlane3#
MoveCinR
END
ELSE
IF NotEqual? CurrentZ# ClearancePlane3#
SaveCurrentZ ClearancePlane3#
MoveCinZ
END
END
RETURN

CinMoveZC:
IF Rapid?
IF NotEqual? CurrentR# EPZ#
SaveCurrentR EPZ#
SaveCurrentZ EPZ#
MoveCinR
END
ELSE
IF NotEqual? CurrentZ# EPZ#
SaveCurrentZ EPZ#
MoveCinZ
END
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF MultipleParts? AND SubComment?
'( PART ' Tag# ' )' EOL
END
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC ' A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC ' A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

ExitType:
IF FIFO?
FeedC
ELSE
RapidC
END
RETURN

ExitFeed:
IF FIFO?
FeedEntC
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYC
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

StdRapid:
IF XMove? OR YMove? OR ZMove?
SeqLabC RapidC MoveXYC CinMoveZC EOL
END
RETURN

StdLine: {enables CRC on first call, .70}
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FeedC MoveXYC CinMoveZC FeedRateC EOL
DecelMove2
END
SeqLabC FeedC MoveXYC CinMoveZC DecelFeed EOL
ELSE
SeqLabC FeedC MoveXYC CinMoveZC FeedRateC EOL
END
END
RETURN

StdArc:
IF ZMove? OR XZPlane? OR YZPlane?
EachArcSegment
StdLine
NextArcSegment
ELSE
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
RETURN

ToolPath2: {for AutoCycle element moves}
EACHFeat
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

EntryMove:
IF FeedEntry?
SeqLabC FeedC CinZInC FeedEntC EOL
ELSE
SeqLabC RapidC CinZInC EOL
END
RETURN

CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqLabC IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
IF FeedConnect?
SeqLabC FeedC StrtPosC EOL
ELSE
SeqLabC RapidC StrtPosC EOL
END
END
END
EntryMove
ToolPath2
IF NOT FeedConnect?
SeqLabC ExitType PRIME CinZCP2 ExitFeed EOL
END
NextRep
ELSE
EntryMove
ToolPath2
END
SeqLabC AbsOrInc ExitType CinZCP2 ExitFeed EOL
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
SeqLabC
IF FIFO?
Rapid
END
MoveSXYC EOL
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
CutAutoCycle
ELSE
SeqLabC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
NEXTFeat
RETURN

DoPeck:
IF NOT Flag?('2')
IF GreaterThan? SUB# Recall# Num#('4') Peck# SPZ# {IF OldZ - Peck# > Depth}
Save# Num#('4') SUB# Recall# Num#('4') Peck# {Save#1 = OldZ - Peck# = NewZ}
SaveCurrentZ Recall# Num#('4')
SeqLabC ' G70' MoveCinZ FeedEntC EOL {move to NewZ}
IF PeckFullRetract?
SaveCurrentZ ADD# ClearancePlane2# Num#('-.1')
SeqLabC ' G0' MoveCinZ EOL {move to CP2}
END
SaveCurrentZ ADD# Recall# Num#('4') Retract#
SeqLabC ' G0' MoveCinZ EOL {move to RetractZ}
ELSE
SeqLabC ' G70 Z' TrackZ# SPZ# FeedEntC EOL {move to Depth}
IF RetractToCP1?
SeqLabC Rapid ' Z0' CinZCP1 EOL {move to CP1}
ELSE
SeqLabC Rapid ' Z0' CinZCP2 EOL {move to CP2}
END
SetFlag('2')
END
END
RETURN

DrillPath:
EACHFeat
IF Peck?
SeqLabC RapidC MoveSXYC EOL
SeqLabC RapidC CinZCP2C EOL
SetFlagF('2') { done flag }
Save# Num#('4') ADD# ClearancePlane2# Num#('-.1')
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
ELSE
IF RetractToCP1? AND NOT FirstFeat?
SeqLabC DrillOff CinZCP1 EOL
SeqLabC Cycle MoveSXYC CinZDepth RLevelCin EOL
ELSE
SeqLabC MoveSXYC
IF SPZMove?
CinZDepth
END
EOL
END
END
NEXTFeat
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

Approach:
IF Drilling? AND NOT Peck?
GetCycle Cycle ' V00' StrtPos CinZDepth FeedEnt RLevelCin
TrackZNO# FIRST SPZ#
ELSE
Rapid
IF CutterRadiusCompensation?
CRCOfst
ELSE
' V00'
END
StrtPos ' Z0' FeedEnt CinZCP2
END
RETURN

DoSpinOn:
IF CoolOff?
SpinOn
ELSE
IF CWSpindle?
' M13'
ELSE
' M14'
END
END
RETURN

DoOp:
IF FirstOperation?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
OfstOff ' M26' EOL
END
DoOpComments
ELSE
DoOpComments
DoPostScript
END
Plane {no output}
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
SeqLabC Rapid StrtPos EOL
ELSE
'H?' AbsOrInc Approach TABLE(1,Speed,1) ToolOfst OpToolID DoSpinOn EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
{only need to set up for tool change on 1st part}
ELSE
OfstOff
IF ToolChangeAtHome?
' M26' EOL
SeqLabC Rapid Home ToolChng EOL
ELSE
ToolChng EOL
END
DoEndOpPS
IF LAST ProgStop?
SeqLabC Rapid ' M00' EOL
ELSE
IF OptionalStops?
SeqLabC Rapid ProgStop EOL
END
END
END

{Start new Operation}

IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
OfstOff ' M26' EOL
END
DoOpComments
ELSE
DoOpComments
DoPostScript
END
Plane {no output}
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
SeqLabC Rapid StrtPos EOL
ELSE
'H?' AbsOrInc Approach TABLE(1,Speed,1) ToolOfst OpToolID DoSpinOn EOL
END
ELSE
IF SameTool?

{Finish off last Operation}

IF LAST ProgStop? OR NewToolOffset?
OfstOff ' M26'
END
EOL
DoEndOpPS
IF LAST ProgStop?
SeqLabC ' M00' EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Plane {no output}
CheckPass
SeqLabC AbsOrInc Approach
IF NotEqual? SpeedRPM# LAST SpeedRPM#
TABLE(1,Speed,1)
END
IF LAST ProgStop?
DoSpinOn
END
EOL
END
END
END

{ Common Point for All Operations }

IF Milling?
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
EACHRep
DoSubComment
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL
IF NOT FeedConnect?
SeqLabC CinZCP2C EOL
END
END
END
END
IF NOT AutoCycle?
EntryMove
END
ToolPath
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
IF NOT FeedConnect?
SeqLabC ExitType PRIME CinZCP3C ExitFeed EOL
END
NEXTRep
END
END
SeqLabC Rapid ' Z0' CinZCP3 {Don't put EOL here}
ELSE
IF Drilling?
IF Repeats?
EACHRep
DoSubComment
IF NOT FirstCycle?
SeqLabC DrillOff CinZCP3C EOL
SeqLabC Approach EOL
END
DrillPath
NEXTRep
ELSE
DrillPath
END
SeqLabC DrillOff ' Z0' CinZCP3 {Don't put EOL here}
END
END
RETURN

FinishLastOp:
OfstOff
IF FIRST ToolChangeAtHome?
' M26' EOL
SeqLabC Rapid FirstHome ToolChng EOL
ELSE
ToolChng EOL
END
DoEndOpPS
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart? {no tool change after doing last part}
IF ProgStop?
SeqLabC Rapid ' M00' EOL
ELSE
IF OptionalStops?
SeqLabC Rapid ProgStop EOL
END
END
ELSE
SeqLabC Rapid EOP EOL
END
RETURN

DoToolsOps:
EachOp
IF GTEqual? Operation# Recall# Num#('1') AND LTEqual? Operation# Recall# Num#('2')
{Tools1stOp ² op ² ToolsLastOp}
DoOp
END
NextOp
RETURN

NextTools1stOp:
SetNextToolOp Operation#
RETURN

GetToolsOps:
EachOp
IF Equal? Operation# Recall# Num#('1') {if op = Tools1stOp}
IF GreaterThan? NextTools1stOp Recall# Num#('1') {if NextTools1stOp is greater Tools1stOp}
Save# Num#('2') SUB# NextTools1stOp Num#('1') {ToolsLastOp becomes NextTools1stOp less 1}
ELSE {else}
Save# Num#('2') Recall# Num#('3') {ToolsLastOp becomes ncCAMsLastOp}
END
END
NextOp
RETURN

DoTool:
IF NOT Flag?('1')
GetToolsOps
EachPart
TagInc
DoToolsOps
NextPart
IF LessThan? Recall# Num#('2') Recall# Num#('3') {if ToolsLastOp < ncCAMsLastOp}
Save# Num#('1') ADD# Recall# Num#('2') Num#('1') {Tools1stOp becomes NextTools1stOp}
ELSE {else}
SetFlag('1') {set DoneFlag}
END
TagInit
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
SetFlagF('1') {Multiple Parts done flag}
SetFlagF('2') {Peck Drilling done flag}
Save# Num#('1') Num#('0') {tools 1st op}
Save# Num#('2') Num#('0') {tools last op}
Save# Num#('3') Num#('0') {ncCAMs last op}
Save# Num#('4') Num#('0') {peck drill Z position}
Save# Num#('5') Num#('0') {current R position}
Save# Num#('6') Num#('0') {current Z position}
ReverseXZArcs
SetFlood
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
END
NextOp
IF MultipleParts?
IF WorkFixtureOffsets?
SetFlag('1')
ASCII('13') EOL
ASCII('13') EOL
'This processor does not support' EOL
'work fixture offsets!' EOL
ASCII('13') EOL
ASCII('13') EOL
ELSE
IF AllToolsOnePart?
EachPart
TagInc
EachOp
DoOp
NextOp
FinishLastOp
NextPart
ELSE
IF OneToolAllParts?
EachOp
IF FirstOperation?
Save# Num#('1') Operation# {ncCAMs1stOp becomes Tools1stOp}
END
IF LastOp?
Save# Num#('3') Operation# {save ncCAMsLastOp}
END
NextOp
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
FinishLastOp
END
END
END
ELSE
EachOp
DoOp
NextOp
FinishLastOp
END
EOR EOL
CloseSub
Post2
IF UseComments?
SetScale('1')
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Close
ReTag