{Change Comments ***********************************************************}

{9/21/95, L228.82.1, Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85.02 Format, DWB}

{1/15/96
Modified: Fan 10T Miyano JNC-60 L228.85
Created: Fanuc 3T Miyano [IM] L414.85.1
For: Isimac; per Jim Adams
Deleted M16 bidirectional indexing (deleted CheckIndex & CheckIndex sub) globally.
Deleted M25 parts counter line; not needed.
Corrected G74 (peck drill) cycle to Fanuc 3T (2 line) format.
Corrected G70 > G73 finish/rough cycles. Changed CkCRC sub to output Rapid on last line of canned rough;
Added CkLastMove sub (called from LineFeat in toolpath) to output move to X & Z CSP in canned rough cycle.
Corrected G76 cycle to Fanuc 3T (2 line) format.
Added stock stop sub call (hard coded subprogram call before first op).
Added parts catcher support (M35 in, M36 out).
Added blank line between tools.
Changed DoOpComments; they only want Operation and Tool comments.
Also moved comments to output after the first line of a tool, not before.
Joe Cusimano}

{2/10/96
Modified: Fanuc 3T Miyano [IM] L414.85.1
For: Isimac; per Jim Adams
Corrected G70 > G73 finish/rough cycles; added CkLastLineMove and CkLastArcMove subs (called from
LineFeat, ArcFeat, and RapidFeat in toolpath) to output move to X & Z CSP in canned rough cycle.
Corrected G76 cycle; multiplied infeed angle by 2.
Added SetCutOffFlag sub to determine if any ops had CutOff selected; if any ops had CutOff
selected then I set Flag 3 true. I then use this flag to output their stock stop subprogram
before first op if CutOff? was true in any op.
Changed 'Finish off last op' part of NewTool and 'Finish last operation' to more closely
resemble L001.
Added CalcXStkLeft sub; IF ApproachID? then flip the XStkLeft polarity in ID rough cycle (G71).
(The polarity of the U & W stock values must be reversed when roughing an ID.)
Joe Cusimano}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.####;0'
#6 = '00'
#7 = '#'
#8 = '##^###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(TrackX#,2)
FORMAT(TrackZ#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(ClearancePlane3#,2)
FORMAT(SUB#,3)
FORMAT(InFeedAngle#,3)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(ADD#,5)
FORMAT(FeedIPR#,5)
FORMAT(ToolOffset#,6)
FORMAT(RapidF#,7)
FORMAT(SpringPasses#,6)
FORMAT(Peck#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

CheckCoolOn:
IF Pulse?
'M28' { High Pressure Coolant On }
SetFlag('1')
ELSE
CoolOn
END
RETURN

CheckCoolOff:
IF Flood? and Flag?('1')
SeqLabC 'M29' EOL { High Pressure Coolant Off }
SetFlagF('1')
END
IF Pulse? and NOT Flag?('1')
CoolOff
END
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

CkPartsCatcher:
IF CutOff?
'M35'
END
RETURN

PartsCatcherOut:
IF CutOff?
'M36'
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC CkPartsCatcher EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC CkPartsCatcher EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
IF AutoClearance?
StockOff ThisOpEntryZCP
ELSE
IF ApproachOD?
StockOnNoCan ZSP
ELSE
IF ApproachID?
StockOff ZCP
ELSE {ApproachFace}
StockOff
IF GreaterThan? CycleStartZ# ZStockMax#
{StockOnNoCan} ZSP
ELSE
IF GreaterThan? ZOpCP# ZStockMax#
StockOff ZOpCP
ELSE
StockOff ZCP
END
END
END
END
END
OpToolID ToolOffset# CheckCoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CheckCoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
CSSOff
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF LAST ProgStop?
CSSOn 'G96' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
CSSOn 'G96' Speed
END
END
ELSE
SeqLabC Preset MaxRPM EOL
CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
'G97' Speed
ELSE
IF LAST ProgStop?
'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
'G97' Speed
END
END
END
END
IF LAST ProgStop?
SeqLabC {SpeedC} SpinOn EOL
SeqLabC CheckCoolOn EOL
ELSE
SeqLabC {SpeedC} EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CheckCoolOn EOL
END
END
DoPostScript
RETURN

CkLastLineMove:
IF LastFeat? AND CannedCycle? AND Roughing?
SetPass1
Rapid XCSP ZCSP { output rapid move to X & Z contour start point at end of canned rough }
ResetPass2
ELSE
IF LineFeat?
FeedC MoveXC MoveZC { normal feed move }
ELSE
IF RapidFeat?
RapidC MoveXC MoveZC { normal rapid move }
END
END
END
RETURN

CkLastArcMove: { this will only happen if an arc is the last feature of a canned rough cycle }
{ although I don't think this can happen, I figured I better cover it just in case }
IF LastFeat? AND CannedCycle? AND Roughing?
SetPass1
Rapid XCSP ZCSP { add rapid move to XZ contour start point at end of canned rough after completing the arc move }
ResetPass2
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF LastFeat?
CRCOffC { Exit Length Feature }
ELSE
CRCOnC { Entry Length Feature }
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC CkLastLineMove EOL
ELSE
IF LineFeat?
SeqLabC CkCRC CkLastLineMove FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
CkLastArcMove
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

DoIndex:
IF LTEqual? Recall# Num#('1') Num#('-5')
IF GTEqual? Recall# Num#('1') Num#('-7')
'M16' { ClockWise Turret Index }
END
ELSE
IF LTEqual? Recall# Num#('1') Num#('3')
IF GTEqual? Recall# Num#('1') Num#('1')
'M16' { ClockWise Turret Index }
END
END
END
RETURN

DoBarPuller:
SeqLab 'T' SUB# Tool# Num#('20') '00' EOL
SeqLabC Rapid XCP StockOnNoCan ZSP EOL
SeqLabC 'X' TrackX# Num#('0') EOL
SeqLabC 'M17' EOL { ChuckOpen }
SeqLabC 'G4P400' EOL { Dwell .4 seconds }
SetInc
SeqLabC 'W' ClearancePlane3# 'T' SUB# Tool# Num#('20') ToolOffset# EOL
SetAbs
SeqLabC 'M18' EOL { ChuckClose }
SeqLabC 'G4P300' EOL { Dwell .3 seconds }
RETURN

SetCutOffFlag:
SetFlagF('3')
EachOp
IF CutOff?
SetFlag('3')
END
NextOp
RETURN

CalcXStkLeft:
IF ApproachID?
NegSideLathe
XStkLeft
PosSideLathe
ELSE
XStkLeft
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' PULSECOOLANT, PCOOL -' EOL
' Will output M28 for turning on High Pressure Coolant.' EOL
' Every ToolChange operation afterwords, will output M28, until the FLOODCOOLANT' EOL
' PostScript command has been issued.' EOL
' FLOODCOOLANT, FCOOL -' EOL
' Will output M29 for turning off High Pressure Coolant.' EOL
' Every ToolChange operation afterwords, will output M8, until the PULSECOOLANT' EOL
' PostScript command has been issued.' EOL
END
SetCutOffFlag
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
IF Flag?('3') { IF Flag3 true then call up stock stop cycle }
SeqLab 'M98P9950 (Stock Stop)' EOL { subprogram call for stock stop cycle }
END
DoPostScript
Plane
IF ToolOver?('20') AND NOT ToolOver?('28') { Special BarPuller Routine }
DoBarPuller
ELSE
SeqLab OpToolID '00' EOL
DoOpComments
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
CSSOn 'G96'
ELSE
CSSOff 'G97'
END
SeqLabC Speed SpinOn EOL
Approach
END
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
SetTTOff
IF LAST ToolOver?('20') AND LAST NOT ToolOver?('28') { Special BarPuller Routine }
LoadFeat Num#('0') XStockMax#
IF XMove?
SeqLabC SETLASTOP MoveX EOL
END
{ No MoveZ here! }
ELSE
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
END
SetTTOk
IF ToolOver?('20') AND NOT ToolOver?('28') { Special BarPuller Routine }
SeqLabC NewHome SpinOff EOL
DoEndOpPS
SeqLabC CoolOff EOL
ELSE
SeqLabC NewHome EOL
DoEndOpPS
END
SeqLabC CheckCoolOff EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoPostScript
IF ToolOver?('20') AND NOT ToolOver?('28') { Special BarPuller Routine }
DoBarPuller
ELSE
' ' EOL
SeqLab OpToolID '00' EOL
DoOpComments
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
CSSOn 'G96'
ELSE
CSSOff 'G97'
END
SeqLabC Speed SpinOn EOL
Approach
END
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ToolOver?('20') AND NOT ToolOver?('28') { Special BarPuller Routine }
ELSE
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# CalcXStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
SeqLab StepMove StrtPos EOL
ELSE
IF RoughPatternShift?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# CalcXStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
FORMAT(MUL#,6)
SeqLabC LCycle 'P' SpringPasses# '00' MUL# Num#('2') InFeedAngle# 'Q10R5' EOL
SeqLabC LCycle XatFinZ FinZ
IF Taper?
XTapAtZ
END
ThrdHeight CutDepth ThrdLead
IF Chamfer?
SeqLabC 'M23' EOL
ELSE
SeqLabC 'M24' EOL
END
EOL
FORMAT(MUL#,2)
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ
IF Taper?
XTapAtZ
END
ThrdLead EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'F' FeedIPR# EOL
SeqLabC Feed ZSP 'F' ADD# FeedIPR# Num#('.001') InverseSpinOn EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle Retract EOL
SeqLabC LCycle ZDepth 'Q' Peck# FeedRate EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap? AND NOT CannedCycle?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
END { Special BarPuller Routine }
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
SetTTOff
IF ToolOver?('20') AND NOT ToolOver?('28') { Special BarPuller Routine }
LoadFeat Num#('0') XStockMax#
IF XMove?
SeqLabC MoveX PartsCatcherOut EOL
END
{ No MoveZ here! }
ELSE
IF ApproachOD?
SeqLabC OpExitXCPC PartsCatcherOut EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC PartsCatcherOut EOL
END
END
SeqLabC OpExitZCPC EOL
END
SetTTOk
SeqLabC FirstHome EOL
DoEndOpPS
SeqLabC CheckCoolOff EOL
IF ProgStop?
SeqLabC 'M0' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag