{Change Comments ***********************************************************}

{9/18/92
Updated: Fanuc 0T/3T Miyano L008.82.1
For: ZI Machine
Made generic changes to processor for testing purposes.
Customer will test and then we will make a custom processor from the read-outs.
Removed all 'B' related output.
Changed the literal 'X0.Y0.' to home position.
KLM}

{4/20/95
Updated: Fanuc 0T Miyano (ZI) L267.82.1
Changed Name to Fanuc 0T Miyano [ZI] L267.82.2
For: Gibbs & Associates/Texas Precision Manufacturing
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.05/Catalyst v2.14.40/Compost 4.21.28
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1c Format.
Added RestoreScale Sub per 4-Axis Post Processor.
Added Logic to suppress Feed and FeedRate for Approaches.
Modified non-CannedCycle AutoFinish.
Method of testing for IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple? AND NOT Threading?
did not allow for AutoFinish pass of IF Turning?
Rewrote to test for IF Turning? ELSE IF Roughing? AND NOT RoughSimple?
Added support for AutoFinish of non-Canned Threading Cycle.
DWB}

{4/20/95
Updated:
Modified:
Copied: Fanuc 0T Miyano [ZI] L267.82.2
Created: Fanuc 0T Miyano [TPM] L329.82.1
For: Texas Precision Manufacturing
Machine:
Control:
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.05/Catalyst v2.14.40/Compost 4.21.28
Changes made per Jonathan McCann of Texas Precision Manufacturing.
Added CoolOff at NewTool.
DWB}

{
Format: Fanuc 0T Miyano [TPM] L329.82.2
For: Texas Precision Manufacturing
Change SetMaxRPM to '2500'
TH}

{
Format: Fanuc 0T Miyano [TPM] L329.82.3
For: Texas Precision Manufacturing
Change SetMaxRPM to '5000'
TH}

{12/18/97
Initial: Fanuc 0T Miyano [TPM] L329.82.3
Created: Fanuc 0T Miyano [BD4] L681.85
ForUser: Gibbs / Cimetrix / Boeing
Control: Fanuc 0T
Machine: Miyano ATS 65
Develop: ComPost2 1.1b3, Virtual 4.21.21
Comment: New processor per fax and conversation with Dave Williams
Added saftey start block to beginning of program.
Changed tool offset cancel to ' T00'.
Call tool and offset toghether at beginning of tool in main.
Combined commands that turn on spindle and coolant with M63/M64/M65.
Updated to .85 format per Fanuc 10T MS [-] L001.85.01.02
Jim Radcliffe}

{05Jan98
Original: Fanuc 0T Miyano [BD4] L681.85
Created: Fanuc 0T Miyano [BD4] L681.85.1
For: Cimetrix / Boeing
Changes made per: Bede
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Added formatting for CutDepth# in Prog Numeric Format Definitions
Added leading spaces to all Speed, Tool, G and M-codes in Prog and MachSpec
Added NOT to the CWSpindle? Boolean in SpinAndCoolOn
Moved Saftey Line and CSS Boolean up before DoOpComments in FirstOp
Added literal ' X14. Z12. T00 M65' before DoOpComments in FirstOp
Added Booleans for G96/G97 options in FirstOp and NewTool, Start new Operation
Deleted CSSOff 'G97' CalcRPM2 at NewTool, Finish off last Operation
Deleted Boolean for CSSOn 'G96' Speed at the start of the Common Point
Added 'R' CutDepth# to G71 RoughContour Canned Cycle
Added Drill Canned Cycle
Charles Winston}

{20Jan98
Original: Fanuc 0T Miyano [BD4] L681.85.1
Created: Fanuc 0T Miyano [BD4] L681.85.2
For: Cimetrix / Boeing
Changes made per: Bede
Added formatting for Recall# in Prog Numeric Format Definitions
Supressed ToolTypeComment & ToolComment if SameTool is TRUE
Deleted all Colons from Comment Blocks (Customers control converts them to the letter 'O'
Deleted Time$ from comment Block. (Hours and Minutes are seperated by a colon.)
Added custom line# at tool changes, see Fanuc 6T MS SL4 [HS] L472.85.1 for details
Added Literal 'M1' to Saftey Block in FirstOperation
Supressed Preset line in NewTool, when MaxRPM#Ęhas not changed
Added ApproachOD Boolean after Toolpath, at RoughContour, in Canned Cycles
Deleted CSSOff line at End of Prog
Deleted UnTool line at End of Prog
Charles Winston}

{17Feb98
Original: Fanuc 0T Miyano [BD4] L681.85.2
Created: Fanuc 0T Miyano [BD4] L681.85.3
For: Cimetrix / Boeing
Changes made per: Bede
Moved all occurrences of ProgStop onto a line by itself without a line number, per customers request.
Deleted ApproachFace boolean in RoughContour Cycle and replaced with StepMove StrtPosC
Added Formatting for Peck at Prog Numeric Format Definitions
Adjusted Drill Canned Cycle per customers Printout
Charles Winston}

{8/27/98 thru 9/1/98
Initial: Fanuc 0T Miyano [BD4] L681.85.3
Created: Fanuc 0T Miyano [BD4] L681.85.4
Develop: Compost2 1.6b7, Virtual Gibbs 4.29.51
Comment: Modified per notes and marked up readout from, and conversation with, Rich Zade.
Deleted FI-RO (G81) drill cycle.
Changed XStkLeft to output a radius value.
Changed to output only X or Z as first line following RoughContour cycle line.
Note that this was removed since the 12/18/97 creation! Why?
Added space before literal Q in peck drilling.
Changed Canned Threading to two line style.
Literal R value and LastCutXRadius for Q value!
Changed format #4 from 3 to 4 trailing zeros.
Added Parts Catcher. It is apparently connect to the subspindle!
Jim Radcliffe}

{10/15/98,
Initial: Fanuc 0T Miyano [BD4] L681.85.4
Created: Fanuc 0T Miyano [BD4] L681.85.5
For: Boeing Division 4

Changes to Prog:
1) IF CannedCycle - Added FeedC commands in IF ApproachFace and ELSE
conditions.
2) FORMATs - Added format #9 for Peck#.
3) IF Canned/IF Threading - Added spaces between literal Q and R words. Changed
literal R5 to R50 per customer request.
CDH}

{10/27/98,
Initial: Fanuc 0T Miyano [BD4] L681.85.5
Created: Fanuc 0T Miyano [BD4] L681.85.6
For: Boeing Division 4

Changes to Form:
1) Turn Rough OD/ID - Changed X Stock Left from Dia. to Rad.

Changes to Prog:
1) PartsCatcherUp - Deleted M35.
2) PartsCatcherDown - Deleted M36.
3) FORMATs - Changed LastCutXRadius# from FORMAT 4 to FORMAT 9.
Added FORMAT for Tag#.
4) End Of Prog - Deleted SeqLabC in front of EOP.
CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '#'
#8 = '00'
#9 = '###^###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(ADD#,2)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(FinishXDia#,2)
FORMAT(Taper#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(CutDepth#,2)
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Recall#,3)
FORMAT(Dwell#,4)
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(Tag#,7)
FORMAT(SpringPasses#,8)
FORMAT(DIV#,8)
FORMAT(ADD#,8)
FORMAT(Peck#,9)
FORMAT(LastCutXRadius#,9)

{New Command Subroutines ***************************************************}

SpinAndCoolOff:
' M65'
RETURN

SpinAndCoolOn:
IF NOT CWSpindle?
IF NOT CoolOff?
' M63'
ELSE
' M03'
END
ELSE
IF NOT CoolOff?
' M64'
ELSE
' M04'
END
END
RETURN

PartsCatcherUp:
SeqLabC ' G101' EOL
SeqLabC Rapid ' B-' EOL {BLOCK TO POSITION SUBSPINDLE}
SeqLabC ' M90' EOL
SeqLabC ' G100' EOL
SeqLabC ' M40' EOL
SeqLabC ' M90' EOL
RETURN

PartsCatcherDown:
SeqLabC ' G101' EOL
SeqLabC Rapid ' B0' EOL {RETURNS B TO HOME}
SeqLabC ' M90' EOL
SeqLabC ' G100' EOL
SeqLabC ' M40' EOL
SeqLabC ' M90' EOL
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ' ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF NOT SameTool?
IF ToolTypeComment?
'( TOOL ' Tool# ' ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP SpinAndCoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
IF CutOff?
PartsCatcherUp
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC SpinAndCoolOff EOL
SeqLabC ' M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
END
END
SeqLabC
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
ELSE
CSSOn ' G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
CSSOff ' G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
END
END
IF NewToolOffset?
' T00'
END
EOL
SeqLabC
IF NewToolOffset?
OpToolID LatheOffset
END
IF LAST ProgStop?
SpinAndCoolOn
ELSE
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
END
EOL
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC:
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC ' G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC ' G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC
IF LAST ThreadFeat?
Rapid
ELSE
RapidC
END
MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC ' G32' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
IF LAST Threading?
Rapid
ELSE
RapidC
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('5000')
SetMaxFeed('500')
Save# Num#('1') Num#('1')
Save# Num#('2') Num#('2')
Save# Num#('3') Num#('3')
Save# Num#('4') Num#('4')
Save# Num#('5') Num#('5')
Save# Num#('6') Num#('6')
Save# Num#('7') Num#('7')
Save# Num#('8') Num#('8')
Save# Num#('9') Num#('9')
Save# Num#('10') Num#('10')
Save# Num#('11') Num#('11')
Save# Num#('12') Num#('12')
Save# Num#('13') Num#('13')
Save# Num#('14') Num#('14')
Save# Num#('15') Num#('15')
Save# Num#('16') Num#('16')
Save# Num#('17') Num#('17')
Save# Num#('18') Num#('18')
Save# Num#('19') Num#('19')
Save# Num#('20') Num#('20')
Save# Num#('21') Num#('21')
Save# Num#('22') Num#('22')
Save# Num#('23') Num#('23')
Save# Num#('24') Num#('24')
Save# Num#('25') Num#('25')
IF PSComment? AND UseComments?
'PostScript- ' EOL
' Literals- put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands- must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT- ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' )' EOL
{ '( ' Date$ ' AT ' Time$ ' )' EOL }
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff
SetHome
Plane
SeqLab Rapid ' G20' CRCOff ' G99' EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
SeqLabC ' X14. Z12. T00 M65' EOL
'M1' EOL
DoOpComments
DoPostScript
Save# Tool# Add# Recall# Tool# Num#('1000')
'N' Recall# Tool#
IF ConstantSurfaceFeed?
CSSOn ' G96'
ELSE
CSSOff ' G97'
END
Speed OpToolID LatheOffset EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
IF LAST CutOff?
PartsCatcherDown
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
SeqLabC NewHome ' T00' SpinAndCoolOff EOL
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
'M1' EOL
END

{Start new Operation}

DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
END
END
Save# Tool# Add# Recall# Tool# Num#('1000')
'N' Recall# Tool#
IF ConstantSurfaceFeed?
CSSOn ' G96'
ELSE
CSSOff ' G97'
END
Speed OpToolID LatheOffset EOL
Approach
ELSE
IF SameTool?

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
IF LAST CutOff?
PartsCatcherDown
END
CheckOffset
IF CutOff?
PartsCatcherUp
END
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
' Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle CutDepth ' R' CutDepth# EOL
SeqLabC LCycle ' PÅ‚' Tag# ' Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove ZSP EOL
SeqLabC FeedC XSPC EOL
ELSE
SeqLab StepMove XSP EOL
SeqLabC FeedC ZSPC EOL
END
ELSE
IF RoughPatternShift?
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle ' PÅ‚' Tag# ' Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
IF ApproachOD?
SetPass1
StockOff
LoadFeat Num#('0') CycleStartX#
IF XMove?
SeqLab Rapid MoveX EOL
END
END
'<' Tag# EOL
IF AutoFinish?
SeqLabC ' G70' ' PÅ‚' Tag# ' Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
SeqLabC LCycle ' P' SpringPasses#
DIV# RunOutZ# Div# Num#('1') Thread# { Run out is output in units of lead }
ADD# InFeedAngle# InFeedAngle#
IF ConstantVolumeCut?
' Q' LastCutXRadius# {last cut depth is minimum cut depth}
ELSE
CutDepth {if not ConstantVolumeCut? CutDepth is min depth, volume increases with depth}
END
' R5' EOL
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead EOL
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC ' G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
SeqLabC LCycle ZDepth Dwell
IF Peck?
' Q' Peck#
END
Retract FeedRate EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC ' G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC ' X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC ' G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC ' G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
IF Threading?
Rapid
ELSE
RapidC
END
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
IF CutOff?
PartsCatcherDown
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC FirstHome ' T00' SpinAndCoolOff EOL
IF ProgStop?
SeqLabC ' M0' EOL
END
EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END