{Change Comments ***********************************************************}

{9/23/88
Copied & modified: Okuma OSP 3000-LC20 L049.51
For: Shultz
Machine: Okuma
Control: OSP 5000 LB15
Machine only has one Turret, no need to call for or see Tool# for 2nd Turret.
Deleted ToolOver20? stuff, added conventional OpToolID stuff.
Changed FORMATs to 4-place non-decimal trailing Zero's.
Added spaces between Codes.
JR}

{9/29/88
Modified: Okuma OSP 3000-LB20 L067.51
Worked on Canned Cycles.
BG,JR}

{5/9/89
Copied & modified: Okuma OSP 3000-LB20 L067.56
For: Petes Workshop
Machine: Okuma
Control: OSP 5000 LB15
New 1st line of program with End of Record code.
Changed FORMATs to decimal.
Modified Canned Cycles.
JR}

{9/27/89, updated & added PostScript to Okuma OSP 5000 LB15 L103.55, JR}
{3/15/90, Updated: Okuma OSP 5000 LB15 L103.61 to .69.3 format, JR}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/5/91, Updated Okuma OSP 5000 LB15 L103.70 to .82 format, JR}


{5/14/93
Modified: Okuma OSP 5000 LB15 L103.82
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1 Format.
DWB}

{6/2/93
Modified: Okuma OSP 5000 LB15 L103.82.1
For: Gibbs & Associates/Cigraph PTY
Changes made per E-Mail from Maurizio at Cigraph PTY.
Change CutDepth to XCutDepth#/ZCutDepth# at CannedCycle RoughContour.
DWB}

{10/6/94
Updated: Okuma OSP 5000 LB15 L103.82.2
For: Gibbs & Associates/Cigraph PTY/MD Research
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.22
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1a Format.
Added SetAbs at setup and initializations.
Added StandardXZArcs at setup and initializations.
Changed MoveType$ to literal 'ABSOLUTE' at FirstOperation.
Added AND NOT Threading? condition at AutoFinish.
Moved Post command in front of EOR EOL at end of Prog.
DWB}

{2/7/95
Copied & modified: Okuma OSP 5000 LB15 L103.82.3
For: Rick Meide / Cheetah Precision
Control: Okuma OSP 5500
Machine: Okuma Cadet
Added move to Home is FirstOperation.
Go directly to, and stay in, G96 in CSS operations.
Moved tool and spindle calls to Approch sub.
Added Rapid on 1st Approach move and NewHome.
Removed spaces between codes
Modified the program ID line:
removed the '.MIN', the customer will enter it with the program name.
added a liter letter 'O' preceding the program name.
Jim Radcliffe}

{9/10/95, Updated Okuma OSP 5500 Cadet L331.82.3 to .85 foramt per Fanuc 10T MS [-] L001.85.01.01, JR}
{5/3/96,
Initial: Okuma OSP 5500 Cadet L331.85
Created: Okuma OSP 5500 Cadet Lxxx.85
For: Star Metal modifed threading to output Okuma G33 cycle for canned threading
in the case of a balanced in feed and constant cutting. Fanuc-style
G33 threading does not work on this machine. MPK}
{5/9/96,
Initial: Okuma OSP 5500 Cad[SMP] L451.85
Created: Okuma OSP 5500 [SMP] L451.85.1
Added literal 'NOEX' before all comment blocks, MPK }

{8/20/96
Initial: Okuma OSP 5500 [SMP] L451.85.1
Created: Okuma OSP5020L [SMP] L451.85.2
ForUser: Star Metal Products
Control: Okuma OSP5020L
Machine: Okuma Cadet Big Bore
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: Modified Threading per conversations with Dave McCray and review of manual.
Changed G33 to G34 for ThreadFeat in ToolPath.
Fixed output of Rapid after ThreadFeat.
Jim Radcliffe}

{5/15/97
Modified: Okuma OSP5020L [SMP] L451.85.2
Created: Okuma OSP5020L [SMP] L451.85.3
ForUser: Star Metal Products per Dave McCray
Modified Threading to use G33 style canned cycle instead of G71; left in the
G71 stuff in case they ever decide they want it back.
Also added PIN(1) to force G33 canned cycle even in AutoClearance.
Added GetMaxRPM sub; this sub looks for the first ConstantSurfaceFeed op and saves
the MaxRPM value to var 1 ( if there are no ConstantSurfaceFeed ops, then I save
3500 as the value in var 1). I then use this value to output a G50 MaxRPM line at
the beginning of the program. This is necessary because they ALWAYS have to start
a program with a spindle restraint, even if the first op is drilling or threading.
It is also possible to write a whole program with NO ConstantSurfaceFeed ops, so
I use 3500 RPM as the value in this case per Dave McCray.
Joe Cusimano}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '+####.####;0'
#3 = '#######0'
#4 = '###.##;0'
#5 = '####.####;0'
#6 = '###0'
#7 = '#'
#8 = '###.###;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(XCutDepth#,2)
FORMAT(ZCutDepth#,2)
FORMAT(FirstMoveEPX#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(Peck#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(InFeedAngle#,8)
FORMAT(Recall#,6) { for MaxRPM }

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'NOEX ( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'NOEX ( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'NOEX ( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'NOEX ( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'NOEX ( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
SetFlagF('3') { initialize Canned Cycle Override flag }
Save# Num#('10') Num#('0') { initialize PIN tracking }
RETURN

PSInit2: {reset flags from last Op, .70}
RETURN

SetPSFlags:
Save# Num#('10') Pallet#
IF Equal? Recall# Num#('10') Num#('1')
SetFlag('2') { set G33 Thread Cycle flag }
SetFlag('3')
END
RETURN

PSStuff:
IF PalletIn?
SetPSFlags
END
RETURN

PSStuff2:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
PalletInF
RETURN

DoEndOpPS:
PSInit2
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff2 {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP OpToolID LatheOffset LatheOffset Speed SpinOn CoolOn 'M42'
RETURN

G97orG96:
IF ConstantSurfaceFeed?
CSSOn 'G96'
ELSE
CSSOff 'G97'
END
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid G97orG96 RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC
IF LAST ThreadFeat?
Rapid
ELSE
RapidC
END
MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G34' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
Rapid
RETURN

GetMaxRPM:
SetFlag('1')
EachOp
IF Flag?('1')
IF ConstantSurfaceFeed?
Save# Num#('1') MaxRPM#
SetFlagF('1')
END
END
NextOp
IF Flag?('1')
{ if Flag 1 is still true, there were no G96 ops; but we still need to set MaxRPM }
Save# Num#('1') Num#('3500')
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('3500')
SetMaxFeed('500')
PalletInF
SetFlag('1') { initialize MaxRPM flag }
SetFlag('2') { initialize G33 Thread Cycle flag }
SetFlagF('3') { initialize Canned Cycle Override flag }
Save# Num#('10') Num#('0') { initialize PIN tracking }
IF PSComment? AND UseComments?
'NOEX PostScript:' EOL
'NOEX Literals: put between single or double quotes.' EOL
'NOEX Separate commands and literals with at least one space.' EOL
'NOEX A CR ( RETURN key ) will start a new line.' EOL
'NOEX Commands: must be all capital letters when typed in.' EOL
'NOEX ENDOP -' EOL
'NOEX all literals and commands before an ENDOP command' EOL
'NOEX will appear at the beginning of the operation. All ' EOL
'NOEX literals and commands after an ENDOP command will appear' EOL
'NOEX at the end of the operation. ' EOL
'NOEX PIN(2) -' EOL
'NOEX this command selects G33 canned thread cycle.' EOL
'NOEX placing this command in the -At Op Start- section of an operation will force' EOL
'NOEX a G33 canned thread cycle, even if AutoClearance is selected.' EOL
END
GetMaxRPM
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
'$O' ProgramName$ EOR EOL
IF UseComments?
IF ProgramNameComment?
'NOEX ( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'NOEX ( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'NOEX ( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'NOEX ( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'NOEX ( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
Plane
DoOpComments
DoPostScript
SeqLab Preset 'S' Recall# Num#('1') EOL
SeqLabC Rapid Home EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
SeqLabC Rapid NewHome
IF LAST ProgStop?
'M0' EOL
ELSE
ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLab {drop unconditional for 1st line}
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF Flag?('3') OR CannedCycle?
StockOff
IF Roughing?
IF NOT RoughSimple?
TagInc
SetPass2
IF RoughContour?
SeqLabC 'G85Nł' Tag#
IF ApproachFace?
'D' ZCutDepth#
ELSE
'D' XCutDepth#
END
FeedRate XStkLeft ZStkLeft EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab 'G82' EOL
ELSE
SeqLab 'G81' EOL
END
ELSE
IF RoughPatternShift?
SeqLabC 'G86Nł' Tag#
IF ApproachFace?
'D' ZCutDepth#
ELSE
'D' XCutDepth#
END
FeedRate XStkLeft ZStkLeft EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab 'G82' EOL
ELSE
SeqLab 'G81' EOL
END
END
END
SeqLabC StepMove StrtPos EOL
ToolPath
SeqLabC 'G80' EOL
IF AutoFinish?
SeqLabC 'G87Nł' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF Flag?('2') { G33 style Canned Cycle }
SetPass1
'G33'
EachFeat
IF ThreadFeat?
SeqLabC MoveX MoveZC FeedRate EOL
END
NextFeat
ELSE
{ G71 style Canned Cycle }
{ G72 Face Threads modification would require changes to XTapAtZ command with W Address }

SeqLabC 'G71' XatFinZ FinZ XTapAtZ
IF SingleEdgeCut?
'B' InFeedAngle#
ELSE
'B0'
END
CutDepth ThrdHeight ThrdLead 'M32'
IF ConstantVolumeCut?
'M75'
ELSE
'M74'
END
IF Chamfer?
'M23'
ELSE
'M22'
END
EOL
IF AutoFinish?
SeqLabC 'G33' XatFinZ FinZ XTapAtZ ThrdLead EOL
SeqLabC Rapid XCSP EOL
SeqLabC ZCSP EOL
END
END
ELSE
IF Drilling?
SeqLabC
IF Tap? AND NOT CWSpindle?
'G78'
ELSE
LCycle
END
XCSP ZDepth Peck Retract
IF PeckFullRetract?
'L' Peck#
END
FeedRate Dwell EOL
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC Rapid
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC Rapid FirstHome CoolOff EOL
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'NOEX ( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'NOEX ( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'NOEX ( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END