{Change Comments ***********************************************************}

{9/23/88
Copied & modified: Okuma OSP 3000-LC20 L049.51
For: Shultz
Machine: Okuma
Control: OSP 5000 LB15
Machine only has one Turret, no need to call for or see Tool# for 2nd Turret.
Deleted ToolOver20? stuff, added conventional OpToolID stuff.
Changed FORMATs to 4-place non-decimal trailing Zero's.
Added spaces between Codes.
JR}

{9/29/88
Modified: Okuma OSP 3000-LB20 L067.51
Worked on Canned Cycles.
BG,JR}

{5/9/89
Copied & modified: Okuma OSP 3000-LB20 L067.56
For: Petes Workshop
Machine: Okuma
Control: OSP 5000 LB15
New 1st line of program with End of Record code.
Changed FORMATs to decimal.
Modified Canned Cycles.
JR}

{9/27/89, updated & added PostScript to Okuma OSP 5000 LB15 L103.55, JR}
{3/15/90, Updated: Okuma OSP 5000 LB15 L103.61 to .69.3 format, JR}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/5/91, Updated Okuma OSP 5000 LB15 L103.70 to .82 format, JR}


{5/14/93
Modified: Okuma OSP 5000 LB15 L103.82
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1 Format.
DWB}

{6/2/93
Modified: Okuma OSP 5000 LB15 L103.82.1
For: Gibbs & Associates/Cigraph PTY
Changes made per E-Mail from Maurizio at Cigraph PTY.
Change CutDepth to XCutDepth#/ZCutDepth# at CannedCycle RoughContour.
DWB}

{10/6/94
Updated: Okuma OSP 5000 LB15 L103.82.2
For: Gibbs & Associates/Cigraph PTY/MD Research
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.22
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1a Format.
Added SetAbs at setup and initializations.
Added StandardXZArcs at setup and initializations.
Changed MoveType$ to literal 'ABSOLUTE' at FirstOperation.
Added AND NOT Threading? condition at AutoFinish.
Moved Post command in front of EOR EOL at end of Prog.
DWB}

{2/7/95
Copied & modified: Okuma OSP 5000 LB15 L103.82.3
For: Rick Meide / Cheetah Precision
Control: Okuma OSP 5500
Machine: Okuma Cadet
Added move to Home is FirstOperation.
Go directly to, and stay in, G96 in CSS operations.
Moved tool and spindle calls to Approch sub.
Added Rapid on 1st Approach move and NewHome.
Removed spaces between codes
Modified the program ID line:
removed the '.MIN', the customer will enter it with the program name.
added a liter letter 'O' preceding the program name.
Jim Radcliffe}

{9/10/95, Updated Okuma OSP 5500 Cadet L331.82.3 to .85 foramt per Fanuc 10T MS [-] L001.85.01.01, JR}
{5/3/96,
Initial: Okuma OSP 5500 Cadet L331.85
Created: Okuma OSP 5500 Cadet Lxxx.85
For: Star Metal modifed threading to output Okuma G33 cycle for canned threading
in the case of a balanced in feed and constant cutting. Fanuc-style
G33 threading does not work on this machine. MPK}
{5/9/96,
Initial: Okuma OSP 5500 Cad[SMP] L451.85
Created: Okuma OSP 5500 [SMP] L451.85.1
Added literal 'NOEX' before all comment blocks, MPK }

{8/20/96
Initial: Okuma OSP 5500 [SMP] L451.85.1
Created: Okuma OSP5020L [SMP] L451.85.2
ForUser: Star Metal Products
Control: Okuma OSP5020L
Machine: Okuma Cadet Big Bore
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: Modified Threading per conversations with Dave McCray and review of manual.
Changed G33 to G34 for ThreadFeat in ToolPath.
Fixed output of Rapid after ThreadFeat.
Jim Radcliffe}

{6/5/97
Updated & Modified: Okuma OSP5020L [SMP] L451.85.2m
Created: Okuma OSP5020L [H] L601.85m
For: Fructus/Huhnseals
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per Mikael Bagge of Fructus.
Updated for Catalyst v3.33C per Fanuc 10T MS [-] L001.85.02c Format.
Added SetMaxFeed(12700) condition for Metric Files at setup and initializations.
Corrected output of G0 only block at end of Manual Thread Cycle.
Added IF LAST ThreadFeat? at ToolPath RapidFeat?
Forces Rapid.
Deleted Rapid at ToolPath ThreadFeat.
Modified for TailStock Approach
Moved call to AppMove up one block at Approach.
Added support of ToolMonitor code.
Added 'VLMON[' Tool# ']=11', ToolMonitorOn, block at Approach.
Added 'VLMON[' LAST Tool# ']=0', ToolMonitorOff, block at NewTool.
Added 'VLMON[' Tool# ']=0', ToolMonitorOff, block at end of Prog.
DWB}

{7/30/97
Modified: Okuma OSP5020L [H] L601.85m
Created: Okuma OSP7000L [H] L601.85.1m
For: Fructus/Huhnseals
Versions: Catalyst v3.35C/ComPost2 MSL 68K
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.10/ComPost2 MSL 68K
Versions: ncCad 4.33.02/ncEDM 4.33.01/ncPost 4.33.10/ComPost2 MSL 68K
Versions: ncCad 4.33.02/ncMAT 4.21.19/ncPost 4.33.10/ComPost2 MSL 68K
Changes made per Mikael Bagge of Fructus.
Customer requested that post be renamed for an OSP7000L control.
Customer requested that VLMONOn always be output after Rapid Approach and prior to cutting.
Customer requested that VLMONOff always be output after cutting and prior to Rapid Exit.
Added VLMONOn sub before StockOnNoCan sub.
Added VLMONOff sub before StockOnNoCan sub.
Added Canned Cycle/NonCanned Cycle conditions to call VLMONOn 6 places at ApproachSP sub.
Deleted VLMONOn block at Approach sub.
Deleted VLMONOff block at NewTool and end of Prog.
Added call to VLMONOff sub 5 places between common point and NextOp command.
VLMONOff is output between Canned Roughing Block and SetPass2 output.
VLMONOff is output at end of Canned Threading and Drilling and nonCanned Cycle Operations..
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '+#####.###;0'
#3 = '#######0'
#4 = '###.##;0'
#5 = '#####.###;0'
#6 = '###0'
#7 = '#'
#8 = '###.###;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(XCutDepth#,2)
FORMAT(ZCutDepth#,2)
FORMAT(FirstMoveEPX#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(Peck#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(InFeedAngle#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'NOEX ( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'NOEX ( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'NOEX ( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'NOEX ( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'NOEX ( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

VLMONOn:
SeqLabC 'VLMON[' Tool# ']=11' EOL { ToolMonitorOn }
RETURN

VLMONOff:
SeqLabC 'VLMON[' Tool# ']=0' EOL { ToolMonitorOff }
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
IF NOT CannedCycle?
VLMONOn
END
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
ELSE
IF NOT CannedCycle?
VLMONOn
END
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
IF NOT CannedCycle?
VLMONOn
END
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
ELSE
IF NOT CannedCycle?
VLMONOn
END
END
END
IF CannedCycle?
VLMONOn
END
RETURN

AppMove:
StockOff ThisOpEntryZCP OpToolID LatheOffset LatheOffset Speed SpinOn CoolOn 'M42'
RETURN

G97orG96:
IF ConstantSurfaceFeed?
CSSOn 'G96'
ELSE
CSSOff 'G97'
END
RETURN

Approach: { FOR TAILSTOCK, .85 }
Rapid G97orG96 RapidF# { RapidF# Forces FeedRate }
SeqLabC AppMove EOL
IF ApproachOD?
SeqLabC ThisOpEntryXCP EOL
ELSE
IF ApproachID?
SeqLabC XOpCD EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
CSSOff
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF LAST ProgStop?
G97orG96 Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
G97orG96 Speed
END
END
ELSE
SeqLabC Preset MaxRPM EOL
G97orG96 Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
G97orG96 Speed
ELSE
IF LAST ProgStop?
G97orG96 Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
G97orG96 Speed
END
END
END
END
IF LAST ProgStop?
SeqLabC {SpeedC} SpinOn EOL
SeqLabC CoolOn EOL
ELSE
{SeqLabC SpeedC EOL}
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF LastFeat?
CRCOffC { Exit Length Feature }
ELSE
CRCOnC { Entry Length Feature }
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
IF LAST ThreadFeat?
Rapid
END
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G34' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle? OR LAST Threading?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('5000')
ELSE
SetMaxFeed('196.85039370079')
END
IF PSComment? AND UseComments?
'NOEX PostScript:' EOL
'NOEX Literals: put between single or double quotes.' EOL
'NOEX Separate commands and literals with at least one space.' EOL
'NOEX A CR ( RETURN key ) will start a new line.' EOL
'NOEX Commands: must be all capital letters when typed in.' EOL
'NOEX ENDOP -' EOL
'NOEX all literals and commands before an ENDOP command' EOL
'NOEX will appear at the beginning of the operation. All ' EOL
'NOEX literals and commands after an ENDOP command will appear' EOL
'NOEX at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
'$O' ProgramName$ EOR EOL
IF UseComments?
IF ProgramNameComment?
'NOEX ( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'NOEX ( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'NOEX ( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'NOEX ( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'NOEX ( OUTPUT IN ABSOLUTE MILLIMETERS )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
SeqLab {drop unconditional for 1st line}
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
SeqLabC Rapid Home EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
SeqLabC Rapid NewHome
IF LAST ProgStop?
'M0'
ELSE
ProgStop
END
EOL

{Start new Operation}

DoOpComments
DoPostScript
SeqLab {drop unconditional for 1st line}
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF NOT RoughSimple?
TagInc
SetPass2
IF RoughContour?
SeqLabC 'G85Nł' Tag#
IF ApproachFace?
'D' ZCutDepth#
ELSE
'D' XCutDepth#
END
FeedRate XStkLeft ZStkLeft EOL
VLMONOff
'>' Tag# EOL
IF ApproachFace?
SeqLab 'G82' EOL
ELSE
SeqLab 'G81' EOL
END
SeqLabC StepMove StrtPos EOL
ELSE
IF RoughPatternShift?
SeqLabC 'G86Nł' Tag#
IF ApproachFace?
'D' ZCutDepth#
ELSE
'D' XCutDepth#
END
FeedRate XStkLeft ZStkLeft EOL
VLMONOff
'>' Tag# EOL
IF ApproachFace?
SeqLab 'G82' EOL
ELSE
SeqLab 'G81' EOL
END
SeqLabC StepMove StrtPos EOL
END
END
ToolPath
SeqLabC 'G80' EOL
IF AutoFinish?
SeqLabC 'G87Nł' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF SingleEdgeCut? OR ConstantVolumeCut?
{ G72 Face Threads modification would require changes to XTapAtZ command with W Address }

SeqLabC 'G71' XatFinZ FinZ XTapAtZ
IF SingleEdgeCut?
'B' InFeedAngle#
ELSE
'B0'
END
CutDepth ThrdHeight ThrdLead 'M32'
IF ConstantVolumeCut?
'M75'
ELSE
'M74'
END
IF Chamfer?
'M23'
ELSE
'M22'
END
EOL
IF AutoFinish?
SeqLabC 'G33' XatFinZ FinZ XTapAtZ ThrdLead EOL
SeqLabC Rapid XCSP EOL
SeqLabC ZCSP EOL
END
ELSE
SetPass1
'G33'
EachFeat
IF ThreadFeat?
SeqLabC MoveX MoveZC FeedRateC EOL
END
NextFeat
END
VLMONOff
ELSE
IF Drilling?
SeqLabC
IF Tap? AND NOT CWSpindle?
'G78'
ELSE
LCycle
END
XCSP ZDepth Peck Retract
IF PeckFullRetract?
'L' Peck#
END
FeedRate Dwell EOL
VLMONOff
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G34'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
VLMONOff
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle? OR Threading?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC Rapid FirstHome CoolOff EOL
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'NOEX ( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'NOEX ( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'NOEX ( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END