{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=F
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{9/27/89, added PostScript to: Okuma OSP5000M-G M101.51, JR}
{3/29/90, Updated: Okuma OSP5000M-G M101.61 to .70.3 format, JR}
{7/5/90, Updated: Okuma OSP5000M-G M101.70.3 to .72.1 format, JR}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{12/19/90
Copied & modified: Okuma 5000M-G M101.73
For: Gibbs & Associates
Machine: Okuma
Control: 5000M-G
Updated to Version 3.2 per Fanuc 6M M001.76.1 Format.
DWB}

{4/03/91
Modified: Okuma 5000M-G M101.76.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{09/30/91
Modified: Okuma 5000M-G M101.79
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.81 Format.
Kim Michelman}

{2/11/94, Updated Okuma 5000M-G M101.81 to .81.2 format, JR}

{10/6/95, Updated Okuma 5000M-G M101.81.2 to .85 format per Fanuc 6M M001.85.01.03, JR}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{6/19/96
Initial: Okuma 5000M-G M101.89
Created: Okuma OSP7000M Mxxx.89
ForUser: DEN-TAL-EZ, Inc.
Control: Okuma OSP7000M
Machine: Okuma MC500H
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: New Processor per manual.
Manual says it is totaly comapataple with the OSP5000M-G
and after some review it appears so!
Changed to First Tool Not In Spindle format.
Deleted PreTool
Moved OfstOn to nest line, off of the StrtPos line.
Added support for additional Drill Cycles.
Jim Radcliffe}

{10/4/97
Initial: Okuma OSP7000M M143.89
Created: Okuma OSP700M [GTR] MW14.89
Version: ComPost2 1.0b11
Control: Okuma OSP700M
Machine: Okuma
Customer: GTR Enterprises.
Comments: Change tool change commands to full pre-select method.
Added the literal line 'G11T2Q2' at start of program. This is a Okuma macro call to avoid
a machine alarm if the spindle tool is selected.
Change G53 to Z30. for Z axis zero return. (The Z30. value must exceed the
distance to Machine zero).
Cancel canned cycles with G0 in place of G80.
Added Y30. on the line before M30 to move spindle clear for easy access to table.
KC}

{10/9/97
Removed literal G28's from Z axis machine zero commands. Machine does not accept them.
Updated from Okuma OSP700M [GTR] MW14.89 to Okuma OSP700M [GTR] MW14.89.1
KC}

{29Dec97
Original: Okuma OSP700M [GTR] MW14.89.1
Created: Okuma LH OSP700M [HIR] MW84.12
For: Hirschler Maunfacturing
Changes made per: Jim or Matt
Provisional LONGHAND post processor for customer testing.
Changes too numerous to list at this time: To be made into an Advanced mill post.
Charles Winston}

{25Feb98
Original: Okuma LH OSP700M [HIR] MW84.12
Created: Okuma LH OSP700M [HIR] CW84.12
For: Hirschler Maunfacturing
Changes made per: Jim or Matt
Created C Style Advanced Mill Longhand Post
Charles Winston}

{25Feb98, Created: Okuma LH 5020M [WMC] BW84.12, B Style Advanced Mill Longhand Post, Charles Winston}

{7Mar98
Original: Okuma LH OSP700M [HIR] BW84.12
Created: Okuma LH OSP700M [HIR] BW84.12.1
For: Hirschler Maunfacturing
Changes made per: Jim or Matt
Changes to B Style Advanced Mill Longhand Post per customers fax
Changed formatting for Line Numbers in Mach Spec to ####^b
Changed all Feeds and Rapids to be modal
Changed all XYZ moves to be modal
Moved PreTool CoolOn after the StartPos Line in FirstOp3 and NewToolOp5
Moved Speed SpinOn to the StartPos Line in FirstOp3 and NewToolOp5
Changed the MP1ToollAllPXcp Sub suit the above 2 alterations.
Charles Winston}

{29 Oct98
Original: Okuma OSP700 LH [HIR] BW84.12.1
Created: Okuma OSP700 LH [HIR] BW84.12.2
For: Hirschler Maunfacturing
Changes made per: Jim or Matt
Added Post Header Comment at the top of Prog.
Re-Wrote the logic at PointFeat in Toolpath to suppress the drill cycle on a blank line. SrtPos is called in DrillStuff.
Using MoveXC or MoveYC does not work here because the drill cycle is being output on every line.
Charles Winston}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '###0'
#8 = '###0.000#;0.'
#9 = '#'
#10 = 'Ä…#bbbb.bbbb#'
#11 = '######00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,3)
FORMAT(CSOffsetB#,3)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackZNO#,4)
FORMAT(TLLength#,4)
FORMAT(TLNum#,5)
FORMAT(Tag#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(ADD#,5)
FORMAT(Dwell#,6)
FORMAT(ToolDiameter#,8)
FORMAT(TLDia#,8)
FORMAT(RapidF#,9)
FORMAT(PartShiftX#,10)
FORMAT(PartShiftY#,10)
FORMAT(PartShiftZ#,10)
FORMAT(Recall#,11)

{Testing Subroutines *}

#20 = 'Ä…0000.0000'
FORMAT(OriginShiftPX#,20)
FORMAT(OriginShiftPY#,20)
FORMAT(OriginShiftPZ#,20)
FORMAT(OriginUnshiftPX#,20)
FORMAT(OriginUnshiftPY#,20)
FORMAT(OriginUnshiftPZ#,20)
FORMAT(OriginUSPXCTP#,20)
FORMAT(OriginUSPYCTP#,20)
FORMAT(OriginUSPZCTP#,20)

Report:
IF MultipleParts? AND WorkFixtureOffsets?
SetStatusOff
' ' EOL
' PartShiftX# = ' PartShiftX# ' '
' PartShiftY# = ' PartShiftY# ' '
' PartShiftZ# = ' PartShiftZ# EOL
'OriginUnshiftPX#(0) = ' OriginUnshiftPX#('0') ' '
'OriginUnshiftPY#(0) = ' OriginUnshiftPY#('0') ' '
'OriginUnshiftPZ#(0) = ' OriginUnshiftPZ#('0') EOL
'OriginUnshiftPX#(1) = ' OriginUnshiftPX#('1') ' '
'OriginUnshiftPY#(1) = ' OriginUnshiftPY#('1') ' '
'OriginUnshiftPZ#(1) = ' OriginUnshiftPZ#('1') EOL
'OriginUnshiftPX#(2) = ' OriginUnshiftPX#('2') ' '
'OriginUnshiftPY#(2) = ' OriginUnshiftPY#('2') ' '
'OriginUnshiftPZ#(2) = ' OriginUnshiftPZ#('2') EOL
' OriginShiftPX# = ' OriginShiftPX# ' '
' OriginShiftPY# = ' OriginShiftPY# ' '
' OriginShiftPZ# = ' OriginShiftPZ# EOL
' OriginUSPXCTP#(0) = ' OriginUSPXCTP#('0') ' '
' OriginUSPYCTP#(0) = ' OriginUSPYCTP#('0') ' '
' OriginUSPZCTP#(0) = ' OriginUSPZCTP#('0') EOL
' OriginUSPXCTP#(1) = ' OriginUSPXCTP#('1') ' '
' OriginUSPYCTP#(1) = ' OriginUSPYCTP#('1') ' '
' OriginUSPZCTP#(1) = ' OriginUSPZCTP#('1') EOL
' OriginUSPXCTP#(2) = ' OriginUSPXCTP#('2') ' '
' OriginUSPYCTP#(2) = ' OriginUSPYCTP#('2') ' '
' OriginUSPZCTP#(2) = ' OriginUSPZCTP#('2') EOL
' ' EOL
SetStatusOn
END
RETURN

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoPartCycleComment:
IF MultipleParts? AND UseComments? AND SubComment?
'( PART NO. ' Tag# ' )' EOL
END
RETURN

DoCycleComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
' ( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
' ( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
' ( ' WorkGroupComment$ ' )' EOL
END
RestoreScale
END
RETURN

BadMPWFOReport:
SetStatusOff
' ' EOL
'Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„' EOL
'Ä„ NOTE: Even though you have elected to Ä„' EOL
'Ä„ process this file using Multiple Ä„' EOL
'Ä„ Parts with Work Fixtures, there exist Ä„' EOL
'Ä„ non-zero values in the invisible, Ä„' EOL
'Ä„ Equally SpacedÉ fields, as follows: Ä„' EOL
'Ä„ Ä„' EOL
'*****************************************' EOL
IF NotEqual? PartShiftX# Num#('0')
' X axis shift = ' PartShiftX# EOL
END
IF NotEqual? PartShiftY# Num#('0')
' Y axis shift = ' PartShiftY# EOL
END
IF NotEqual? PartShiftZ# Num#('0')
' Z axis shift = ' PartShiftZ# EOL
END
'*****************************************' EOL
'Ä„ Ä„' EOL
'Ä„ Please reset these values to zero as Ä„' EOL
'Ä„ they affect the coordinate values Ä„' EOL
'Ä„ output, starting with Part# 2. Ä„' EOL
'Ä„ Thank You. Ä„' EOL
'Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„' EOL
' ' EOL
SetStatusOn
RETURN

CSWFO:
' G15 H' ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CalcCSWFO: {(iPart-1)*NumOfCS#)}
IF MultipleParts?
IF Flag?('3')
' G15 H' ADD# NewWFO# SUB# Tag# Num#('1')
ELSE
' G15 H' ADD# NewWFO# SUB# Parts# Tag#
END
ELSE
CSWFO
END
RETURN

CSAngleA:
IF AAxisAvail?
IF WFOCS?
' A0.'
ELSE
' A' CSOffsetA#
END
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
IF WFOCS?
' B0.'
ELSE
' B' CSOffsetB#
END
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

DoCSWFOComment:
' ( CS#' CS# ' - ' CSComment$ ' )' EOL
' (' CalcCSWFO '= X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ#
IF AAxisAvail?
' A' CSOffsetA#
END
IF BAxisAvail?
' B' CSOffsetB#
END
' )' EOL
RETURN

DoCSG52Comment:
' ( CS#' CS# ' - ' CSComment$ ' )' EOL
RETURN

PSInit:
NewWFOF
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZIn FeedEntC EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

ExitMove:
SeqC
IF FeedConnect?
IF NOT AutoCycle?
IF NOT NoZMoves?
FeedC ZInC FeedEntC
END
END
ELSE
CRCOffC
IF FIFO? { .81 }
FeedC
ELSE
RapidC
END
PRIME ZCP2C
IF FIFO? { .81 }
FeedEntC
END
END
EOL
RETURN

ExitMove2:
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
RETURN

CycleWarning:
{ NOTE: This Post Processor takes care of Z Clearance. }
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

OpenMP:
IF Flag?('2') OR WFOCS?
ClearCSOffset
IF Flag?('3')
IF Flag?('2')
SeqC CalcCSWFO EOL
DoCSG52Comment
ClearCSOffset
SeqC ' G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
ELSE
DoCSWFOComment
ClearCSOffset
SeqC CalcCSWFO EOL
END
ClearCSOffset
ELSE
IF Flag?('2')
SeqC CalcCSWFO EOL
DoCSG52Comment
ClearCSOffset
SeqC ' G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
ELSE
DoCSWFOComment
ClearCSOffset
SeqC CalcCSWFO EOL
END
END
END
RETURN

CloseMP:
IF Flag?('2') OR WFOCS?
IF Flag?('4')
ToggleIncDecWFO
END
END
RETURN

SubCSMP:
IF WFOCS?
ClearCSOffset
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
SetFlag('1') { CRCOffsetC }
CRCOnC
END
END
RETURN

ckCRCNum:
IF Flag?('1')
SetFlagF('1')
CRCOffsetC
END
RETURN

FormatLine:
ckCRC ckCRCNum FeedC MoveXYZC
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat? { Drilling Only }
IF Drilling?
IF SPXMove?
SeqC Cycle MoveSX
IF SPYMove?
MoveSY
END
MoveSZC EOL
ELSE
IF SPYMove?
SeqC Cycle MoveSY MoveSZC EOL
END
END
ELSE
SeqC MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC ckCRCNum RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatLine FeedRateC EOL
DecelMove2
END
SeqC FormatLine DecelFeed EOL
ELSE
SeqC FormatLine FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
IF AutoCycle?
SetAbs
Save# Num#('46') SUB# EPX# CurOriginPosX#
Save# Num#('47') SUB# EPY# CurOriginPosY#
SetInc
END
END
NEXTFeat
RETURN

AutoCycCutSub1: {part 1}
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
IF Repeats? AND ZShiftOnly?
EntryMove
END
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
SeqC AbsOrInc
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
EOL
SetSRSubXY {restore SR to 1st position value}
ReSetPass2 {restore for positioning moves}
RETURN

Milling:
EntryMove
ToolPath
RETURN

XYZRep:
CycleWarning
FindAnyZMoves
EachRep
DoCycleComment
IF FirstCycle?
EntryMove
ELSE
CRCOffC
IF FeedConnect?
IF SPXMove? OR SPYMove?
SeqC FeedC MoveSXYC FeedEntC EOL
END
IF ZShiftOnly?
EntryMove
END
ELSE
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
IF FeedEntry?
SeqC ZCP2C EOL
END
EntryMove
END
END
ToolPath
ExitMove
NextRep
RETURN

NoRepAutoCycle:
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
Milling
AutoCycCutSub2
NEXTFeat
RETURN

XYZRepAutoCycle:
CycleWarning
EachRep
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
SetAbs
Save# Num#('44') SPX#
Save# Num#('45') SPY#
SetInc
AutoCycCutSub1
Milling
AutoCycCutSub2
SetAbs
TrackXNO# ADD# Recall# Num#('44') Recall# Num#('46')
TrackYNO# ADD# Recall# Num#('45') Recall# Num#('47')
SetAbsOrInc
NEXTFeat
NextRep
RETURN

ZonlyRepAutoCycle:
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
EachRep
IF NOT FirstCycle?
IF FeedConnect?
SeqC AbsOrInc EOL
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC IncValue MoveSXYC EOL
AbsOrInc
END
ELSE
AbsOrInc
ExitMove
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC IncValue MoveSXYC EOL
AbsOrInc
END
IF FeedEntry? AND NOT FIFO?
SeqC ZCP2 EOL
END
END
EntryMove
SeqC IncValue EOL
END
EntryMove
ToolPath
NextRep
AutoCycCutSub2
NEXTFeat
RETURN

DrillStuff:
IF RetractToCP1?
SeqC ' G71' ZCP1 EOL
END
GetCycle
SeqC
IF Tap? AND NOT CWSpindle?
' G74'
ELSE
Cycle
END
StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt FromCP EOL
TrackZNO# FIRST SPZ# {.81.2}
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SetZero:
Save# NUM#('50') ADD# Recall# NUM#('50') NUM#('1') { Increment counter by 1 }
Save# Recall# NUM#('50') NUM#('0')
RETURN

Call_SetZero:
Save# Num#('50') NUM#('0') { Initialises variables from 0 thru 40 to Zero }
SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero
SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero
SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero
SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero {Call 41 times}
Save# Num#('50') NUM#('0')
EOL
RETURN

IncrementToolUseage: { Adds an index e.g. 01, 02, 03 etc each time the tool is used }
Save# Tool# ADD# Recall# Tool# NUM#('1')
RETURN

DoToolLineNumber: { uses Tool# as the line number and adds an index e.g. 01, 02, 03 etc each time the tool is re-used }
'N' Tool#
IF NotEqual? Recall# Tool# NUM#('0')
Recall# Tool#
END
IncrementToolUseage
RETURN

ProgStart:
InitProg
TagInit
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('10000')
SetMaxFeed('500')
Call_SetZero { Initialises variables from 0 thru 40 to Zero }
Save# Num#('41') Num#('0') { This Tool FirstOp# }
Save# Num#('42') Num#('0') { This Tool LastOp# }
Save# Num#('43') Num#('0') { LastOp# }
Save# Num#('44') Num#('0') { XPos Status Register Updated Position for Repeated AutoCycles }
Save# Num#('45') Num#('0') { YPos Status Register Updated Position for Repeated AutoCycles }
Save# Num#('46') Num#('0') { LastFeat EPX# AbsPosValue for Repeated AutoCycles }
Save# Num#('47') Num#('0') { LastFeat EPY# AbsPosValue for Repeated AutoCycles }
SetFlagF('2') { use WFO for CS changes }
SetFlag('3') {True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP}
SetFlag('4') {True = toggle between incrementing/decrementing WFO's }
SetFlagF('5') { CRCOffsetC }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('20')
SetWFOCS { use WFO for CS changes }
ELSE
SetFlag('2')
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to G52 style output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('20')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to G52 style output. )' EOL
END
END
END
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
RapidF# { No Output }
IF Milling?
SeqC ZCP2C EOL
IF AutoCycle?
IF Repeats?
IF ZShiftOnly?
ZonlyRepAutoCycle
ELSE
XYZRepAutoCycle
END
IF NOT FeedConnect?
SeqC ExitMove2 EOL
END
ELSE
NoRepAutoCycle
SeqC ExitMove2 EOL
END
ELSE { NOT AutoCycle }
IF Repeats?
XYZRep
ELSE
Milling
END
SeqC CRCOffC EOL
SeqC ExitMove2 EOL
END
ELSE
IF Drilling?
IF Repeats?
EachRep
DoCycleComment
IF FirstCycle?
DrillStuff
END
ToolPath
NextRep
ELSE
DrillStuff
ToolPath
END
SetDrillEndOpZ
SeqC RapidC CoolOff ' G80' CRCOff EOL
END
END
RETURN

WFOStuff:
IF NOT WorkFixtureOffsets?
SeqC ' G15' WFO1
END
RETURN

ResetWFO:
IF WorkFixtureOffsets?
SeqC ' G15' WFO1 EOL
END
RETURN

NotSameToolWFO:
IF WFOCS?
DoCSWFOComment
SeqC CSWFO EOL
ELSE
IF ChangeCS?
DoCSG52Comment
SeqC ' G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
ELSE
IF NeedWFO1?
SeqC ' G15 H' NewWFO# EOL
END
END
END
ClearCSOffset
RETURN

SameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
SeqC CSWFO EOL
END
ELSE
IF ChangeCS?
DoCSG52Comment
SeqC 'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
END
END
ClearCSOffset
RETURN

InitOp:
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
' ( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
' ( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
' ( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
' ( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
' ( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
' ( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
' ( FIRST TOOL IN SPINDLE )' EOL
END
END
EachTool
' (T #' TLNum# ': ' TLDia# ' ' TLToolType$ ' ' TLToolComment$ ' )' EOL
NextTool
OpenSub
RestoreScale
RETURN

FirstOp1:
'N' Tool# ' G15 H20' EOL
IncrementToolUseage
SeqC Rapid ' Z0' EOL
SeqC RapidC ' X0 Y0' EOL
SeqC ' M00 (Load Pallet)' EOL
SeqC Plane CRCOff ' G80' AbsOrInc ' G94 (T #' Tool# ': ' ToolDiameter# ' ' ToolType$ ' ' ToolComment$ ' )' EOL
SeqC WFOStuff ' G71' ZCP2 EOL
DoOpComments
DoPostScript
RETURN

FirstOp2:
RETURN

FirstOp3:
CheckPass
SeqC AbsOrInc Rapid StrtPos CSAngleA CSAngleB OfstOn Speed SpinOn EOL
SeqC PreTool CoolOn EOL
RETURN

FirstOp3a: {can't XY position before WFO}
CheckPass
IF Flag?('2') OR WFOCS?
ClearCSOffset
END
SeqC OfstOn PreTool CoolOn EOL
RETURN

NewToolOp1:
IF NOT LAST Drilling?
SeqC RapidC CoolOff ' G80' CRCOff EOL
END
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home EOL
END
IF LAST ProgStop?
SeqC ' M00' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
SeqC ToolChng EOL
IF OptCyc1?
SeqC ' G15 H20' EOL
SeqC Rapid ' Z0' EOL
SeqC RapidC ' X0 Y0' EOL
SeqC ' M00 (Change Clamps)' EOL
END
'VC' LAST Tool# '=VC' LAST Tool# '+1' EOL
DoToolLineNumber WFOStuff ' M01 G71' ZCP2 ' (T #' Tool# ': ' ToolDiameter# ' ' ToolType$ ' ' ToolComment$ ' )' EOL
DoOpComments
DoPostScript
RETURN

NewToolOp4:
RETURN

NewToolOp5:
CheckPass
SeqC AbsOrInc Rapid StrtPos CSAngleA CSAngleB OfstOn Speed SpinOn EOL
SeqC PreTool CoolOn EOL
RETURN

NewToolOp5a:
CheckPass
IF Flag?('2') OR WFOCS?
ClearCSOffset
END
SeqC OfstOn PreTool CoolOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC ' G53' EOL
SeqC ' M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset? OR ChangeCS?
SeqC ' G53' EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
DoPartCycleComment
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqC PlaneC AbsOrInc Rapid StrtPos CSAngleA CSAngleB SpeedC SpinOn EOL
SeqC OfstOn EOL
SeqC CoolOn EOL
ELSE
SeqC PlaneC AbsOrInc Rapid StrtPos CSAngleA CSAngleB SpeedC EOL
IF NewToolOffset? OR ChangeCS?
SeqC OfstOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

End1:
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqC RapidC FirstHome EOL
END
IF NOT Equal? CSOffsetA# Num#('0') OR NOT Equal? CSOffsetB# Num#('0')
IF AAxisAvail?
SeqC CSAngleA
END
IF BAxisAvail?
SeqC CSAngleB
END
EOL

SeqC 'G92'
IF AAxisAvail?
'A0'
END
IF BAxisAvail?
'B0'
END
EOL
END
IF ProgStop?
SeqC 'M00' EOL
ELSE
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart?
SeqC ProgStop EOL
END
END
IF NOT LAST Drilling?
SeqC RapidC CoolOff ' G80' CRCOff EOL
END
'VC' LAST Tool# '=VC' LAST Tool# '+1' EOL
SeqC ToolChng EOL
SeqC ' G15 H20' EOL
SeqC Rapid ' Z0' EOL
SeqC RapidC ' X0 Y0' EOL
'VC21=VC21+1' EOL
RETURN

End3:
SeqC EOP EOL
EOR EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
' ( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
' ( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
' ( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
IF FirstOperation?
IF FirstPart?
InitOp
END
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
IF FirstOperation?
IF FirstPart?
InitOp
FirstOp1
FirstOp2
OpenMP
FirstOp3
END
ELSE
IF NewTool?
IF FirstPart?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
OpenMP
NewToolOp5
END
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
IF FirstOperation?
IF FirstPart?
InitOp
FirstOp1
FirstOp2
FirstOp3a
OpenMP
SeqC AbsOrInc Rapid StrtPos CSAngleA CSAngleB Speed SpinOn EOL
END
ELSE
IF NewTool?
IF FirstPart?
CloseMP
NewToolOp1
ResetWFO
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5a
OpenMP
SeqC AbsOrInc Rapid StrtPos CSAngleA CSAngleB Speed SpinOn EOL
END
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

NoMPs: {no multiple parts}
IF FirstOperation?
InitOp
FirstOp1
NotSameToolWFO
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NotSameToolWFO
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolWFO
SameToolOp3
END
END
OpGuts
RETURN

MasterSub:
IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END
RETURN

EndPartSub:
{End of program ************************************************************}

{finish last operation}
IF MultipleParts?
IF AllToolsOnePart?
End1
End2
CloseMP
ELSE {implied OneToolAllParts?}
IF FullUp?
End1
CloseMP
ResetWFO
End2
ELSE {implied ExitClearancePlane?}
CloseMP
End1
ResetWFO
End2
END
END
ELSE {NoMPs}
End1
End2
END
RETURN

DoNewPart:
IF NOT FirstPart?

{Finish off last Part}

IF FullUp?
SeqC CoolOff EOL
IF AbsoluteMoves?
IncValue
END
SeqC OfstOff EOL
END
{DoEndOpPS}

{Start new Part}

DoPartCycleComment
DoOpComments
DoPostScript
OpenMP
WFOStuff
CheckPass
SeqC PlaneC AbsOrInc Rapid CSAngleAC CSAngleBC StrtPos SpeedC EOL
IF FullUp?
SeqC OfstOn EOL
SeqC CoolOn EOL
ELSE
IF ChangeCS?
TrackZNO# ClearancePlane1#
END
END
END
RETURN

DoParts:
TagInit
EachPart
TagInc
EachOp
IF AllToolsOnePart?
MasterSub
ELSE { OneToolAllParts }
IF GTEqual? Operation# Recall# Num#('41') { Tool First Op }
IF LTEqual? Operation# Recall# Num#('42') { Tool Last Op }
IF Equal? Operation# Recall# Num#('41') { Tool First Op }
DoNewPart
END
MasterSub
END
END
END
NextOp
IF AllToolsOnePart?
EndPartSub
END
NextPart
RETURN

GetToolFirstOp:
Save# Num#('42') Recall# Num#('41')
RETURN

GetToolLastOP:
EachOp
IF Equal? Operation# Recall# Num#('42')
Save# Num#('42') ADD# Operation# Num#('1')
IF NewTool?
IF Equal? Recall# Num#('41') Recall# Num#('43')
Save# Num#('42') Operation#
ELSE
IF NotEqual? Recall# Num#('41') SUB# Recall# Num#('42') Num#('1')
Save# Num#('42') SUB# Operation# Num#('1')
END
END
END
END
NextOp
RETURN

MPLoop:
IF AllToolsOnePart?
DoParts
ELSE { OneToolAllParts }
GetToolFirstOp
IF LTEqual? Recall# Num#('41') Recall# Num#('43')
GetToolLastOP
DoParts
Save# Num#('41') ADD# Recall# Num#('42') Num#('1') { Next Tool First Op }
END
END
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF WorkFixtureOffsets?
{'NOTE: This Post Processor does not support Work Fixture Offsets for Multiple Parts.' EOL
'Therefore, the output will be controlled by the following values that are' EOL
'already entered in Equally Spaced Offsets Edit Fields:' EOL
'X' PartShiftX# ' Y' PartShiftY# ' Z' PartShiftZ# EOL
'It is recommended that you change your selection to Equally Spaced Offsets.' EOL}
IF NotEqual? PartShiftX# Num#('0')
BadMPWFOReport
ELSE
IF NotEqual? PartShiftY# Num#('0')
BadMPWFOReport
ELSE
IF NotEqual? PartShiftZ# Num#('0')
BadMPWFOReport
END
END
END
END
EachOp
IF FirstOperation?
Save# Num#('41') Operation#
ELSE
IF LastOp?
Save# Num#('43') Operation#
END
END
NextOp
MPLoop
IF OneToolAllParts?
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
EndPartSub
ELSE
ResetWFO
END
ELSE
EachOp
MasterSub
NextOp
EndPartSub
END
End3