{Change Comments ***********************************************************}

{created from M001.70, 2/16/90, WFG}
{added calcZFmSurf stuff and ending program #, .71,WFG}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{10/16/90
Copied & modified: Heidenhain 355 BP M290.72
For: Vatterott
Machine: Bridgeport Interact 412
Control: Heidenhein TNC 355
Updated to Version 3.2 per Fanuc 6M M001.76 Format.
Modified calling of sub-programs.
Modified drill cycle paramters.
DWB}

{7/9/93
Copied & modified: Heidenhain 355 BP M290.76
For: Omni Tool
Deleted literal B0 from beginning and end of prog.
Deleted EOR from end of prog.
Updated to .81.2 format.
Jim Radcliffe}

{12/3/93
Modified: Heidenhain 355 [0T] M566.81.2
To: Heidenhain 355 [0T] M566.81.3
Fixed the RestoreScale function to work with both english and metric parts. Also removed
unneeded setscale commands and replaced them with math ( number ) commands.
[cwh]}

{28May97
Original: Heidenhain 355 [0T] M566.81.3
Created: Heidenhain 355 [SSI] Mxxx.81
For: SSI Shreading
Changes made per: Rob Stewart
Added Format#9 and changed formatting of:-
ClearancePlane1#, ClearancePlane2#, ClearancePlane3#, StartPosX#, StartPosX#,
XStockMax#, XStockMax#, XStockMax#, YStockMin#, YStockMin#, YStockMin#,
Changed Default formats for X,Y,Z,I,J,K in MachSpec to Ä…####.###;+0
Changed Rapid from G0 to G00, Feed from G1 to G01 and Arcs from G2 & G3 to G02 & G03 in MachSpec
Adjusted FormatArc:per customers requirments
Added ' G90' & ' R+90' to IF ArcFeat? in ToolPath:
Added G30 & G31 Stock size definitions in FirstOp?
Deleted Toolchange in FirstOp?, NewTool? & EndOps
Changed StrtPos in FirstOp?, NewTool? & SameTool? to output X & Y moves on seperate lins
Added ' Z +20' for manual toolchange in FirstOp?, NewTool?, SameTool? & EndOps at IF LAST ProgStop?
Charles Winston}

{29May97
Original: Heidenhain 355 [SSI] Mxxx.81
Created: Heidenhain 355 [SSI] Mxxx.89
Updated to version .89 per Fanuc 6M M001.89
Charles Winston}

{29May97
Original: Heidenhain 355 [SSI] Mxxx.89
Created: Heid 355 [SSI] Mxxx.12 Longhand
For: SSI Shreading
Updated to version .12 Longhand per LongHand M001.12
Charles Winston}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '#####.###;0'
#7 = '*####.####;0.'
#8 = '####^0'
#9 = 'Ä…#####.####;0'
#10 = 'Ä…#bbbb.bbbb#'
#11 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(CalcZFmSurf#,4)
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Repeats#,5)
FORMAT(Program#,5)
FORMAT(Program2#,5)
FORMAT(Operation#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(CalcCP2FmSurf#,7)
FORMAT(Peck#,7)
FORMAT(FeedEntry#,8)
FORMAT(ClearancePlane3#,9)
FORMAT(ClearancePlane2#,9)
FORMAT(ClearancePlane1#,9)
FORMAT(XStockMax#,9)
FORMAT(YStockMax#,9)
FORMAT(ZStockMax#,9)
FORMAT(XStockMin#,9)
FORMAT(YStockMin#,9)
FORMAT(ZStockMin#,9)
FORMAT(StartPosX#,9)
FORMAT(StartPosY#,9)
FORMAT(PartShiftX#,10)
FORMAT(PartShiftY#,10)
FORMAT(PartShiftZ#,10)
FORMAT(RapidF#,11)

{Testing Subroutines *}

#20 = 'Ä…0000.0000'
FORMAT(OriginShiftPX#,20)
FORMAT(OriginShiftPY#,20)
FORMAT(OriginShiftPZ#,20)
FORMAT(OriginUnshiftPX#,20)
FORMAT(OriginUnshiftPY#,20)
FORMAT(OriginUnshiftPZ#,20)
FORMAT(OriginUSPXCTP#,20)
FORMAT(OriginUSPYCTP#,20)
FORMAT(OriginUSPZCTP#,20)

Report:
IF MultipleParts? AND WorkFixtureOffsets?
SetStatusOff
' ' EOL
' PartShiftX# = ' PartShiftX# ' '
' PartShiftY# = ' PartShiftY# ' '
' PartShiftZ# = ' PartShiftZ# EOL
'OriginUnshiftPX#(0) = ' OriginUnshiftPX#('0') ' '
'OriginUnshiftPY#(0) = ' OriginUnshiftPY#('0') ' '
'OriginUnshiftPZ#(0) = ' OriginUnshiftPZ#('0') EOL
'OriginUnshiftPX#(1) = ' OriginUnshiftPX#('1') ' '
'OriginUnshiftPY#(1) = ' OriginUnshiftPY#('1') ' '
'OriginUnshiftPZ#(1) = ' OriginUnshiftPZ#('1') EOL
'OriginUnshiftPX#(2) = ' OriginUnshiftPX#('2') ' '
'OriginUnshiftPY#(2) = ' OriginUnshiftPY#('2') ' '
'OriginUnshiftPZ#(2) = ' OriginUnshiftPZ#('2') EOL
' OriginShiftPX# = ' OriginShiftPX# ' '
' OriginShiftPY# = ' OriginShiftPY# ' '
' OriginShiftPZ# = ' OriginShiftPZ# EOL
' OriginUSPXCTP#(0) = ' OriginUSPXCTP#('0') ' '
' OriginUSPYCTP#(0) = ' OriginUSPYCTP#('0') ' '
' OriginUSPZCTP#(0) = ' OriginUSPZCTP#('0') EOL
' OriginUSPXCTP#(1) = ' OriginUSPXCTP#('1') ' '
' OriginUSPYCTP#(1) = ' OriginUSPYCTP#('1') ' '
' OriginUSPZCTP#(1) = ' OriginUSPZCTP#('1') EOL
' OriginUSPXCTP#(2) = ' OriginUSPXCTP#('2') ' '
' OriginUSPYCTP#(2) = ' OriginUSPYCTP#('2') ' '
' OriginUSPZCTP#(2) = ' OriginUSPZCTP#('2') EOL
' ' EOL
SetStatusOn
END
RETURN

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
ELSE
SetScale('1')
END
RETURN

DoPartCycleComment:
IF MultipleParts? AND UseComments? AND SubComment?
'( PART NO. ' Tag# ' )' EOL
END
RETURN

DoCycleComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'; OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'; ' OperationComment$ EOL
END
IF WorkGroupComment?
'; ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'; TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'; ' ToolComment$ EOL
END
RestoreScale
END
RETURN

BadMPWFOReport:
SetStatusOff
' ' EOL
'Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„' EOL
'Ä„ NOTE: Even though you have elected to Ä„' EOL
'Ä„ process this file using Multiple Ä„' EOL
'Ä„ Parts with Work Fixtures, there exist Ä„' EOL
'Ä„ non-zero values in the invisible, Ä„' EOL
'Ä„ Equally SpacedÉ fields, as follows: Ä„' EOL
'Ä„ Ä„' EOL
'*****************************************' EOL
IF NotEqual? PartShiftX# Num#('0')
' X axis shift = ' PartShiftX# EOL
END
IF NotEqual? PartShiftY# Num#('0')
' Y axis shift = ' PartShiftY# EOL
END
IF NotEqual? PartShiftZ# Num#('0')
' Z axis shift = ' PartShiftZ# EOL
END
'*****************************************' EOL
'Ä„ Ä„' EOL
'Ä„ Please reset these values to zero as Ä„' EOL
'Ä„ they affect the coordinate values Ä„' EOL
'Ä„ output, starting with Part# 2. Ä„' EOL
'Ä„ Thank You. Ä„' EOL
'Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„' EOL
' ' EOL
SetStatusOn
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

ExitMove:
SeqC
IF FeedConnect?
IF NOT AutoCycle?
IF NOT NoZMoves?
FeedC ZInC FeedEntC
END
END
ELSE
CRCOffC
IF FIFO? { .81 }
FeedC
ELSE
RapidC
END
PRIME ZCP2C
IF FIFO? { .81 }
FeedEntC
END
END
EOL
RETURN

ExitMove2:
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
RETURN

CycleWarning:
{ NOTE: This Post Processor takes care of Z Clearance. }
RETURN

FormatArc:
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveXYZC
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
SetFlag('1') { CRCOffsetC }
CRCOnC
END
END
RETURN

FormatLine:
ckCRC FeedC MoveXYZC
RETURN

ckCRCNum:
IF Flag?('1')
SetFlagF('1')
CRCOffsetC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
SeqC MoveSXYC EOL
SeqC ' M99' EOL
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatLine FeedRateC EOL
DecelMove2
END
SeqC FormatLine DecelFeed EOL
ELSE
SeqC FormatLine FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC ' G90 ' FormatArc ArcFeedC ' R+90' EOL
END
NEXTQuadrant
END
END
END
IF AutoCycle?
SetAbs
Save# Num#('6') SUB# EPX# CurOriginPosX#
Save# Num#('7') SUB# EPY# CurOriginPosY#
SetInc
END
END
NEXTFeat
RETURN

AutoCycCutSub1: {part 1}
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
IF Repeats? AND ZShiftOnly?
EntryMove
END
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
SeqC AbsOrInc
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
EOL
SetSRSubXY {restore SR to 1st position value}
ReSetPass2 {restore for positioning moves}
RETURN

Milling:
EntryMove
ToolPath
RETURN

XYZRep:
CycleWarning
FindAnyZMoves
EachRep
DoCycleComment
IF FirstCycle?
EntryMove
ELSE
CRCOffC
IF FeedConnect?
IF SPXMove? OR SPYMove?
SeqC FeedC MoveSXYC FeedEntC EOL
END
IF ZShiftOnly?
EntryMove
END
ELSE
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
IF FeedEntry?
SeqC ZCP2C EOL
END
EntryMove
END
END
ToolPath
ExitMove
NextRep
RETURN

NoRepAutoCycle:
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
Milling
AutoCycCutSub2
NEXTFeat
RETURN

XYZRepAutoCycle:
CycleWarning
EachRep
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
SetAbs
Save# Num#('4') SPX#
Save# Num#('5') SPY#
SetInc
AutoCycCutSub1
Milling
AutoCycCutSub2
SetAbs
TrackXNO# ADD# Recall# Num#('4') Recall# Num#('6')
TrackYNO# ADD# Recall# Num#('5') Recall# Num#('7')
SetAbsOrInc
NEXTFeat
NextRep
RETURN

ZonlyRepAutoCycle:
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
EachRep
IF NOT FirstCycle?
IF FeedConnect?
SeqC AbsOrInc EOL
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC IncValue MoveSXYC EOL
AbsOrInc
END
ELSE
AbsOrInc
ExitMove
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC IncValue MoveSXYC EOL
AbsOrInc
END
IF FeedEntry? AND NOT FIFO?
SeqC ZCP2 EOL
END
END
EntryMove
SeqC IncValue EOL
END
EntryMove
ToolPath
NextRep
AutoCycCutSub2
NEXTFeat
RETURN

DrillStuff:
SeqC DrillCP EOL
SeqC
IF Tap?
' G84'
' P01 ' CalcCP2FmSurf#
' P02 ' CalcZFmSurf#
' P03 ' Dwell#
' P04 ' FeedEntry#
ELSE
' G83'
' P01 ' CalcCP2FmSurf#
' P02 ' CalcZFmSurf#
IF Peck?
' P03 ' Peck#
ELSE
' P03 ' CalcZFmSurf#
END
' P04 ' Dwell#
' P05 ' FeedEntry#
END
EOL
TrackZNO# FIRST SPZ# {.81.2}
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

ProgStart:
InitProg
TagInit
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('10000')
SetMaxFeed('500')
Save# Num#('1') Num#('0') { This Tool FirstOp# }
Save# Num#('2') Num#('0') { This Tool LastOp# }
Save# Num#('3') Num#('0') { LastOp# }
Save# Num#('4') Num#('0') { XPos Status Register Updated Position for Repeated AutoCycles }
Save# Num#('5') Num#('0') { YPos Status Register Updated Position for Repeated AutoCycles }
Save# Num#('6') Num#('0') { LastFeat EPX# AbsPosValue for Repeated AutoCycles }
Save# Num#('7') Num#('0') { LastFeat EPY# AbsPosValue for Repeated AutoCycles }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
RapidF# { No Output }
IF Milling?
SeqC ZCP2C EOL
IF AutoCycle?
IF Repeats?
IF ZShiftOnly?
ZonlyRepAutoCycle
ELSE
XYZRepAutoCycle
END
IF NOT FeedConnect?
SeqC ExitMove2 EOL
END
ELSE
NoRepAutoCycle
SeqC ExitMove2 EOL
END
ELSE { NOT AutoCycle }
IF Repeats?
XYZRep
ELSE
Milling
END
SeqC CRCOffC ExitMove2 EOL
END
ELSE
IF Drilling?
IF Repeats?
EachRep
DoCycleComment
IF FirstCycle?
DrillStuff
END
ToolPath
NextRep
ELSE
DrillStuff
ToolPath
END
SetDrillEndOpZ
SeqC RapidC ZCP3C EOL
END
END
RETURN

WFOStuff:
IF MultipleParts?
IF WorkFixtureOffsets? AND NewWFO?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
IF NewWFO?
SeqC 'G' NewWFO# EOL
ELSE
IF WorkFixtureOffsets? AND NOT SameTool?
FORMAT(ADD#,5)
SeqC 'G' ADD# NewWFO# SUB# Tag# Num#('1') EOL
FORMAT(ADD#,4)
ELSE
IF NeedWFO1? AND NOT SameTool?
SeqC 'G' NewWFO# EOL
END
END
END
END
ELSE
END
RETURN

ResetWFO:
IF WorkFixtureOffsets?
SeqC WFO1 EOL
END
RETURN

GetSpinOn:
IF CoolOff?
IF CWSpindle?
' M3'
ELSE
' M4'
END
ELSE
SpinOn
END
RETURN

InitOp:
' ' EOL
'%' Program# ' G70' EOL
SaveProgNum2 {for use at end of file}
SeqC ' G30 G17 X' XStockMin# ' Y' YStockMin# ' Z' ZStockMin# EOL
SeqC ' G31 G90 X' XStockMax# ' Y' YStockMax# ' Z' ZStockMax# EOL
IF UseComments? AND ProgramNameComment?
'; ' ProgramName$ EOL
END
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'; ' ProgramComment$ EOL
END
IF FormatNameComment?
'; FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'; ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'; OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
'; PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'; FIRST TOOL NOT IN SPINDLE ' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
SeqC OpToolID Plane Speed EOL
DoPartCycleComment
DoOpComments
DoPostScript
RETURN

FirstOp2:
CheckPass
SeqC Rapid AbsOrInc ' X' StartPosX# EOL
SeqC ' Y' StartPosY# EOL
SeqC ' Z' ClearancePlane1# GetSpinOn EOL
RETURN

FirstOp3:
RETURN

FirstOp3a: {can't XY position before WFO}
RETURN

NewToolOp1:
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home EOL
END
IF LAST ProgStop?
SeqC ' Z +20' EOL
SeqC ' M0' EOL
ELSE
SeqC ' Z +20' EOL
SeqC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
Seq OpToolID Plane Speed EOL
DoPartCycleComment
DoOpComments
DoPostScript
RETURN

NewToolOp4:
CheckPass
SeqC Rapid AbsOrInc ' X' StartPosX# EOL
SeqC ' Y' StartPosY# EOL
SeqC ' Z' ClearancePlane1# GetSpinOn EOL
RETURN

NewToolOp5:
RETURN

NewToolOp5a:
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC RapidC 'Z' LAST ClearancePlane3# EOL
SeqC ' Z +20' EOL
SeqC ' M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC RapidC 'Z' LAST ClearancePlane3# EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
DoPartCycleComment
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqC PlaneC Rapid AbsOrInc ' X' StartPosX# EOL
SeqC ' Y' StartPosY# EOL
SeqC ' Z' ClearancePlane1# SpeedC GetSpinOn EOL
ELSE
SeqC PlaneC Rapid AbsOrInc ' X' StartPosX# EOL
SeqC ' Y' StartPosY# EOL
SeqC ' Z' ClearancePlane1# SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

End1:
SeqC Rapid AbsOrInc ' Z' ClearancePlane1# EOL
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC AbsOrInc Rapid FirstHome EOL
END
IF ProgStop?
SeqC ' Z +20' EOL
SeqC ' M0' EOL
ELSE
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart?
SeqC ' Z +20' EOL
SeqC ' M0' EOL
END
END
RETURN

End3:
SeqC EOP EOL
'N9999 %' Program2# ' G70' EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
IF FirstOperation?
IF FirstPart?
InitOp
END
OpenMP
FirstOp1
WFOStuff
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
IF FirstOperation?
IF FirstPart?
InitOp
FirstOp1
WFOStuff
FirstOp2
OpenMP
FirstOp3
END
ELSE
IF NewTool?
IF FirstPart?
NewToolOp1
CloseMP
ResetWFO
NewToolOp2
NewToolOp3
WFOStuff
NewToolOp4
OpenMP
NewToolOp5
END
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
IF FirstOperation?
IF FirstPart?
InitOp
FirstOp1
WFOStuff
FirstOp2
FirstOp3
OpenMP
END
ELSE
IF NewTool?
IF FirstPart?
CloseMP
NewToolOp1
ResetWFO
NewToolOp2
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp5
OpenMP
END
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

NoMPs: {no multiple parts}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
WFOStuff
SameToolOp3
END
END
OpGuts
RETURN

MasterSub:
IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END
RETURN

EndPartSub:
{End of program ************************************************************}

{finish last operation}
IF MultipleParts?
IF AllToolsOnePart?
End1
End2
CloseMP
ELSE {implied OneToolAllParts?}
IF FullUp?
End1
CloseMP
ResetWFO
End2
ELSE {implied ExitClearancePlane?}
CloseMP
End1
ResetWFO
End2
END
END
ELSE {NoMPs}
End1
End2
END
RETURN

DoNewPart:
IF NOT FirstPart?

{Finish off last Part}

IF FullUp?
SeqC CoolOff EOL
IF AbsoluteMoves?
IncValue
END
SeqC OfstOff EOL
END
{DoEndOpPS}

{Start new Part}

DoPartCycleComment
DoOpComments
DoPostScript
WFOStuff
CheckPass
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
IF FullUp?
SeqC OfstOn EOL
SeqC CoolOn EOL
END
END
RETURN

DoParts:
TagInit
EachPart
TagInc
EachOp
IF AllToolsOnePart?
MasterSub
ELSE { OneToolAllParts }
IF GTEqual? Operation# Recall# Num#('1') { Tool First Op }
IF LTEqual? Operation# Recall# Num#('2') { Tool Last Op }
IF Equal? Operation# Recall# Num#('1') { Tool First Op }
DoNewPart
END
MasterSub
END
END
END
NextOp
IF AllToolsOnePart?
EndPartSub
END
NextPart
RETURN

GetToolFirstOp:
Save# Num#('2') Recall# Num#('1')
RETURN

GetToolLastOP:
EachOp
IF Equal? Operation# Recall# Num#('2')
Save# Num#('2') ADD# Operation# Num#('1')
IF NewTool?
IF Equal? Recall# Num#('1') Recall# Num#('3')
Save# Num#('2') Operation#
ELSE
IF NotEqual? Recall# Num#('1') SUB# Recall# Num#('2') Num#('1')
Save# Num#('2') SUB# Operation# Num#('1')
END
END
END
END
NextOp
RETURN

MPLoop:
IF AllToolsOnePart?
DoParts
ELSE { OneToolAllParts }
GetToolFirstOp
IF LTEqual? Recall# Num#('1') Recall# Num#('3')
GetToolLastOP
DoParts
Save# Num#('1') ADD# Recall# Num#('2') Num#('1') { Next Tool First Op }
END
END
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF WorkFixtureOffsets?
{'NOTE: This Post Processor does not support Work Fixture Offsets for Multiple Parts.' EOL
'Therefore, the output will be controlled by the following values that are' EOL
'already entered in Equally Spaced Offsets Edit Fields:' EOL
'X' PartShiftX# ' Y' PartShiftY# ' Z' PartShiftZ# EOL
'It is recommended that you change your selection to Equally Spaced Offsets.' EOL}
IF NotEqual? PartShiftX# Num#('0')
BadMPWFOReport
ELSE
IF NotEqual? PartShiftY# Num#('0')
BadMPWFOReport
ELSE
IF NotEqual? PartShiftZ# Num#('0')
BadMPWFOReport
END
END
END
END
EachOp
IF FirstOperation?
Save# Num#('1') Operation#
ELSE
IF LastOp?
Save# Num#('3') Operation#
END
END
NextOp
MPLoop
IF OneToolAllParts?
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
EndPartSub
ELSE
ResetWFO
END
ELSE
EachOp
MasterSub
NextOp
EndPartSub
END
End3